Funcions financeres, primera part
Aquesta categoria conté les funcions financeres matemàtiques del LibreOffice Calc.
BD
Retorna la depreciació d'un actiu en un període determinat mitjançant el mètode d'amortització de saldo decreixent.
Utilitzeu aquesta forma de depreciació si voleu aconseguir un valor de depreciació superior al començament de la depreciació (en contrast amb la depreciació lineal). El valor de depreciació es redueix amb cada període de depreciació a partir de la que es dedueix del cost inicial.
BD(Cost; Rescat; Vida; Període [; Mes])
Cost és el cost inicial d'un actiu.
Valor residual és el valor d'un actiu al final de la depreciació.
Vida defineix el període durant el qual es deprecia un actiu.
Període és la durada d'un període. Heu d'indicar el període en la mateixa unitat de temps que el període de depreciació.
Mes (opcional) és el nombre de mesos del primer any de depreciació. Si no definiu cap entrada, s'utilitza 12 com a valor per defecte.
Un sistema informàtic amb un cost inicial de 25.000 unitats monetàries s’ha d’amortitzar en un període de tres anys. El valor de recuperació serà de 1.000 unitats monetàries. El primer període d'amortització comprèn 6 mesos. Quina és la depreciació fixa decreixent del sistema informàtic en el segon període, que és un any complet a partir del final del primer període de sis mesos?
=BD(25000; 1000; 3; 2; 6) retorna 11.037,95 unitats monetàries.
BDD
Retorna la depreciació d'un actiu en un període determinat mitjançant el mètode aritmètic decreixent.
Utilitzeu aquesta forma de depreciació si necessiteu un valor més alt de depreciació inicial, a diferència de la depreciació lineal. El valor de depreciació disminueix amb cada període; normalment, s'utilitza en aquells actius que perden més valor poc després d'adquirir-los (per exemple, automòbils o ordinadors). Tingueu en compte que el valor comptable mai no arribarà a zero amb aquest tipus de càlcul.
BDD(Cost; Rescat; Vida; Període [; Factor])
Cost fixa el cost inicial d'un actiu.
ValorResidual fixa el valor d'un actiu en acabar la seva vida útil.
Vida és el nombre de períodes (per exemple, anys o mesos) que defineixen la durada de la utilització de l'actiu.
Període és el període per al qual s'ha de calcular el valor.
Factor (opcional) és el factor de reducció de la depreciació. Si no introduïu cap valor, el valor per defecte és el factor 2.
Un ordinador amb un preu de compra de 75.000 unitats monetàries s'ha de depreciar mensualment durant 5 anys. El valor al final de la depreciació ha de ser d'una unitat monetària. El factor és 2.
=BDD(75000;1;60;12;2) = 1.721,81 unitats monetàries. Per tant, la depreciació doble decreixent al dotzè mes després de la compra és de 1.721,81 unitats monetàries.
CDECRAMOR
Calcula l'import de la depreciació en un període de liquidació en forma d'amortització decreixent. A diferència de CLINAMOR, en aquesta funció s'utilitza un coeficient de depreciació independent de la vida útil.
CDECRAMOR(Cost; DataCompra; PrimerPeriode; ValorResidual; Període; Tipus[; Base])
Cost representa els costos d'adquisició.
DataDeCompra és la data d'adquisició.
PrimerPeríode és la data final del primer període de la liquidació.
ValorResidual és el valor residual del capital actiu al final de la seva vida útil.
Període és el període de liquidació que s'ha de tenir en compte.
Taxa és la taxa de depreciació.
An asset was acquired on 2020-02-01 at a cost of 2000 currency units. The end date of the first settlement period was 2020-12-31. The salvage value of the asset at the end of its depreciable life will be 10 currency units. The rate of depreciation is 0.1 (10%) and the year is calculated using the US method (Basis 0). Assuming degressive depreciation, what is the amount of depreciation in the fourth depreciation period?
=CDECRAMOR(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0.1; 0) retorna una depreciació de 163 unitats monetàries.
Be aware that Basis 2 is not supported by Microsoft Excel. Hence, if you use Basis 2 and export your document to XLSX format, it will return an error when opened in Excel.
CLINAMOR
Calcula l'import de la depreciació en un període de liquidació en forma d'amortització lineal. Si es compra el capital actiu durant el període de liquidació, es té en compte l'import proporcional de la depreciació.
CLINAMOR(Cost; DataCompra; PrimerPeriode; ValorResidual; Període; Tipus[; Base])
Cost representa els costos d'adquisició.
DataDeCompra és la data d'adquisició.
PrimerPeríode és la data final del primer període de la liquidació.
ValorResidual és el valor residual del capital actiu al final de la seva vida útil.
Període és el període de liquidació que s'ha de tenir en compte.
Taxa és la taxa de depreciació.
Es va adquirir un actiu el 01-02-2020 amb un cost de 2.000 unitats monetàries. La data de finalització del primer període de liquidació va ser el 31/12/2020. El valor de recuperació de l’actiu al final de la seva vida amortitzable serà de 10 unitats monetàries. El tipus de deprecació és de 0,1 (10%) i l’any es calcula mitjançant el mètode nord-americà (base 0). Suposant una depreciació lineal, quina és l’amortització del quart període d’amortització?
=CLINAMOR(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0.1; 0) retorna una depreciació de 200 unitats monetàries.
Be aware that Basis 2 is not supported by Microsoft Excel. Hence, if you use Basis 2 and export your document to XLSX format, it will return an error when opened in Excel.
DESC
Calcula la bonificació (el descompte) del títol en forma de percentatge.
DESC(Liquidació; Venciment; Preu; Estalvi[; Base])
Liquidació és la data de compra del títol.
Venciment és la data en què venç el títol (caduca).
Preu és el preu del títol per cada 100 unitats monetàries de valor a la par.
Reemborsament representa el valor de reemborsament del títol per 100 unitats monetàries del valor a la par.
Es compra un títol el 25/1/2001; la data de venciment és el 15/11/2001. El preu (preu de compra) és 97, el valor de reemborsament és 100. Mitjançant el càlcul del saldo diari (base 3), a quant puja la liquidació (el descompte)?
=DESC("2001-01-25";"2001-11-15";97;100;3) retorna aproximadament 0,0372 o 3,72%.
DTA
Retorna la taxa de depreciació aritmètica decreixent.
Utilitzeu aquesta funció per calcular la quantitat de depreciació per a un període de l'interval total de depreciació d'un objecte. La depreciació aritmètica decreixent redueix la quantitat de depreciació d'un període a un altre amb una suma fixa.
DTA(Cost; ValorResidual; Vida; Període)
Cost és el cost inicial d'un actiu.
ValorResidual és el valor d'un actiu després de la depreciació.
Vida és el període que determina el nombre de períodes de depreciació de l'actiu.
Període defineix el període per al qual s'ha de calcular la depreciació.
Un sistema de vídeo que inicialment costa 50.000 unitats monetàries es depreciarà anualment durant els 5 anys següents. El valor residual serà de 10.000 unitats monetàries. Voleu calcular la depreciació per al primer any.
=DTA(50000;10000;5;1)=13.333,33 unitats monetàries. L'import de la depreciació per al primer any és de 13.333,33 unitats monetàries.
Per fer-se una idea de les taxes de depreciació per període, és millor definir una taula de depreciació. En introduir les diferents fórmules de depreciació disponibles al LibreOffice Calc l'una al costat de l'altra, podreu veure quina forma de depreciació és la més apropiada. Introduïu la taula de la manera següent:
|
A |
B |
C |
D |
E |
|
|---|---|---|---|---|---|
|
1 |
Cost inicial |
Valor residual |
Vida útil |
Període de temps |
Deprec. DTA |
|
2 |
50.000 unitats monetàries |
10.000 unitats monetàries |
5 |
1 |
13.333,33 unitats monetàries |
|
3 |
2 |
10.666,67 unitats monetàries |
|||
|
4 |
3 |
8.000,00 unitats monetàries |
|||
|
5 |
4 |
5.333,33 unitats monetàries |
|||
|
6 |
5 |
2.666,67 unitats monetàries |
|||
|
7 |
6 |
0,00 unitats monetàries |
|||
|
8 |
7 |
||||
|
9 |
8 |
||||
|
10 |
9 |
||||
|
11 |
10 |
||||
|
12 |
|||||
|
13 |
0 |
Total |
40.000,00 unitats monetàries |
La fórmula d'E2 és la següent:
=DTA($A$2;$B$2;$C$2;D2)
Aquesta fórmula es duplica a la columna E fins a la cel·la E11 (seleccioneu E2 i arrossegueu la cantonada inferior dreta amb el ratolí).
La cel·la E13 conté la fórmula que s'ha d'utilitzar per comprovar el total de les quantitats de depreciació. Utilitza la funció SUMASI, ja que no s'han de tenir en compte els valors negatius de les cel·les E8:E11. La cel·la A13 conté la condició >0. La fórmula d'E13 és la següent:
=SUMASI(E2:E11;A13)
Ara podeu veure la depreciació en 10 anys, consultar-la amb un valor residual d'una unitat monetària, introduir un altre cost inicial, etcètera.
DURADA
Calcula la durada d'un valor de renda fixa en anys.
DURADA(Liquidació; Venciment; Cupó; Rendiment; Freqüència [; Base])
Liquidació és la data de compra del títol.
Venciment és la data en què venç el títol (caduca).
Cupó és el tipus d'interès anual del cupó (el tipus d'interès nominal)
Rendiment és el rendiment anual del títol.
Freqüència és el nombre de pagaments d'interessos per any (1, 2 o 4).
Es compra un títol el dia 1/1/2001; la data de venciment és l'1/1/2006. El tipus d'interès del cupó és del 8%. El rendiment és del 9,0%. L'interès es paga semestralment (la freqüència és 2). Si feu un càlcul (base 3) d'interessos sobre saldos diaris, quina és la durada?
=DURADA("2001-01-01";"2006-01-01";0.08;0.09;2;3) retorna 4,2 anys.
EFECTIU
Retorna el tipus d'interès anual net d'un tipus d'interès nominal.
L'interès nominal es refereix a l'import d'interès que venç al final d'un període de càlcul. L'interès efectiu augmenta amb el nombre de pagaments fets. En altres paraules, l'interès sovint es paga en terminis (per exemple, mensualment o trimestralment) abans del final del període de càlcul.
EFECTIU (Nom; P)
Nom és l'interès nominal.
P és el nombre de períodes de pagament d'interessos per any.
Si el tipus d'interès anual nominal és del 9,75% i es defineixen quatre períodes de càlcul d'interessos, quin és el tipus d'interès real (la taxa efectiva)?
=EFECTIU (9.75%;4) = 10,11% Per tant, la taxa efectiva anual és del 10,11%.
EFECTIU_ADD
Calcula la taxa anual equivalent a partir del tipus d'interès nominal i del nombre de pagaments d'interessos per any.
Les funcions el nom de les quals acaba amb _ADD o _EXCEL 2003 retornen els mateixos resultats que les funcions corresponents del Microsoft Excel 2003 sense el sufix. Utilitzeu les funcions sense sufix per a obtenir resultats basats en els estàndards internacionals.
EFECTIU_ADD(TipusNominal; NPerA)
TipusNominal representa el tipus d'interès nominal anual.
NPerA és el nombre de pagaments d'interessos per any.
Quin és l'interès anual equivalent per a un interès nominal del 5,25% amb pagaments trimestrals?
=EFECTIU_ADD(0,0525;4) retorna 0,053543 o bé 5,3543%.
INTCOMP
Calcula l'interès acumulat d'un títol en el cas de pagaments periòdics.
ACCRINT(Issue; FirstInterest; Settlement; Rate; [Par]; Frequency [; Basis])
Emissió és la data d'emissió del títol.
PrimerInterès és la data del primer interès del títol.
Liquidació és la data en què s'han de calcular els interessos acumulats fins aquell moment.
Tipus és el tipus d'interès nominal anual (tipus d'interès del cupó)
Paritat (opcional) és el valor a la par del títol. Si s'omet, s'empra un valor per defecte de 1000.
Recomanem que sempre especifiqueu el valor que necessiteu per a l'argument Par d'INTCOMP en lloc de permetre que el Calc apliqui un valor per defecte arbitrari. Això farà que la vostra fórmula sigui més fàcil d'entendre i de mantenir.
Freqüència és el nombre de pagaments d'interessos per any (1, 2 o 4).
Un títol s'emet el 28/2/2001. Es decideix que el primer interès serà el 31/8/2001. La data de liquidació és l'1/5/2001. El tipus d'interès és del 0,1% o del 10% i el valor nominal és de 1.000 unitats monetàries. L'interès es paga semestralment (la freqüència és 2). La base és el mètode dels EUA (0). Quina és la quantitat d'interessos acumulats?
=INTCOMP("2001-02-28";"2001-08-31";"2001-05-01";0,1;1000;2;0) retorna 16,94444.
INTCOMPV
Calcula l'interès acumulat d'un títol en el cas d'un pagament únic en la data de liquidació.
ACCRINTM(Issue; Settlement; Rate [; Par [; Basis]])
Emissió és la data d'emissió del títol.
Liquidació és la data en què s'han de calcular els interessos acumulats fins aquell moment.
Tipus és el tipus d'interès nominal anual (tipus d'interès del cupó).
Paritat (opcional) és el valor a la par del títol. Si s'omet, s'empra un valor per defecte de 1000.
We recommend that you always specify the value that you require for ACCRINTM’s Par argument, rather than allowing Calc to apply an arbitrary default. This will make your formula easier to understand and easier to maintain.
Un títol s'emet l'1/4/2001. La data de venciment és el 15/6/2001. El tipus d'interès és del 0,1% o del 10% i la paritat és de 1.000 unitats monetàries. La base del càlcul diari/anual és el saldo diari (3). Quina és la quantitat d'interessos acumulats?
=INTCOMPV("2001-04-01";"2001-06-15";0,1;1000;3) retorna 20,54795.
IPDPE
Calcula el nivell d'interès dels terminis d'amortització fixa.
IPDPE(Tipus; Període; PeríodesTotals; Inversió)
Tipus estableix el tipus d'interès periòdic.
Període és el nombre de terminis que s'han d'utilitzar per al càlcul dels interessos.
PeríodesTotals és el nombre total de terminis.
Inversió és la quantitat de la inversió.
Per a un crèdit de 120.000 unitats monetàries, amb un període de 2 anys i terminis mensuals amb un tipus d'interès anual del 12%, cal saber la quantitat dels interessos al cap d'1,5 anys.
=IPDPE(1%;18;24;120000) = -300 unitats monetàries. L'interès mensual després d'1,5 anys és de 300 unitats monetàries.
REBUT
Calcula l'import rebut que es paga per un valor de renda fixa en un moment determinat.
REBUT(Liquidació; Venciment; Inversió; Descompte [; Base])
Liquidació és la data de compra del títol.
Venciment és la data en què venç el títol (caduca).
Inversió és el preu de compra.
Descompte és el percentatge de descompte en comprar el títol.
Data de liquidació: 15 de febrer del 1999; data de venciment: 15 de maig del 1999; quantitat de la inversió: 1.000 unitats monetàries; descompte: 5,75%; base: saldo diari/360 = 2.
La quantitat que s'ha rebut en la data de venciment es calcula de la manera següent:
=REBUT("1999-02-15";"1999-05-15";1000;0,0575;2) retorna 1014,420266.
TIR
Calcula la taxa interna de rendibilitat d'una inversió. Els valors representen el flux d'efectiu a intervals regulars; com a mínim un dels valors ha de ser negatiu (pagaments), i com a mínim un dels valors ha de ser positiu (ingressos).
Si els pagaments es produeixen en intervals irregulars, feu servir la funció TIRX.
TIR(Valors [; Estimació])
Valors representa una matriu que conté els valors.
Estimació (opcional) és el valor estimat. S'utilitza un mètode iteratiu per calcular la taxa interna de rendibilitat. Si només podeu proporcionar uns quants valors, proporcioneu una estimació inicial per habilitar la iteració.
This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.
Si assumim que els continguts de les cel·les són A1=-10000, A2=3500, A3=7600 i A4=1000, el resultat de la fórmula =TIR(A1:A4) és 11,33%.
A causa del mètode iteratiu utilitzat, és possible que el TIR falli i retorni Error 523 amb "Error: El càlcul no convergeix" a la barra d'estat. En aquest cas, proveu un altre valor per l'estimació.
VA
Retorna el valor actual d'una inversió fruit d'una sèrie de pagaments regulars.
Utilitzeu aquesta funció per calcular la quantitat de diners que heu d'invertir avui amb un interès fix per rebre una quantitat de diners (anualitat) determinada durant un nombre de períodes determinat. Opcionalment, també podeu definir l'import que ha de quedar disponible al final d'aquests períodes. També podeu indicar si l'import s'ha de pagar al començament o al final d'un període.
Introduïu els valors en forma de nombres, d'expressions o de referències. Si, per exemple, obteniu interessos anuals del 8% però voleu utilitzar el mes com a període, introduïu 8%/12 a Tipus i el LibreOffice Calc calcularà el factor correcte automàticament.
VA(Taxa; NPer; Pmt [; VF [; Tipus]])
Tipus defineix el tipus d'interès per període.
NPer és el nombre total de períodes (període de pagament).
PMT és el pagament regular fet per període.
VF (opcional) defineix el valor futur que ha de restar quan s'hagi pagat el darrer termini.
Tipus (opcional) és la data de venciment dels pagaments. Tipus = 1 vol dir que el pagament venç a l'inici d'un període i Tipus = 0 (valor per defecte) vol dir que venç al final del període.
En les funcions del LibreOffice Calc, els paràmetres marcats com a «opcionals» es poden ometre quan no hi ha cap altre paràmetre que els segueixi. Per exemple, en una funció amb quatre paràmetres, en què els dos darrers estan marcats com a «opcionals», es pot ometre el paràmetre 4 o bé els paràmetres 3 i 4; en canvi, no es pot ometre únicament el paràmetre 3.
Quin és el valor actual d'una inversió si es paguen 500 unitats monetàries mensualment i el tipus d'interès anual és del 8%? El període de pagament és de 48 mesos i queden 20.000 unitats per al final del període de pagament.
=VA(8%/12;48;500;20000) = -35.019,37 unitats monetàries. En les condicions indicades, heu de dipositar 35.019,37 unitats monetàries avui si voleu rebre 500 unitats monetàries al mes durant 48 mesos i tenir 20.000 unitats monetàries restants al final. Una verificació encreuada mostra que 48 x 500 unitats monetàries + 20.000 unitats monetàries = 44.000 unitats monetàries. La diferència entre aquest import i les 35.000 unitats monetàries dipositades representa els interessos pagats.
Si introduïu referències a la fórmula en comptes d'introduir-hi aquests valors, podeu calcular qualsevol nombre del tipus "Si-llavors". Recordeu que heu de definir les referències a les constants com a referències absolutes. Podeu trobar exemples d'aquest tipus d'aplicació a les funcions de depreciació.