Text Functions

This section contains descriptions of the Text functions.

এই নির্দেশাবলীতে সন্নিবেশ করতে...

সন্নিবেশ - ফাংশন - শ্রেণী পাঠ্য


Using double quotation marks in formulas

To include a text string in a formula, place the text string between two double quotation marks (") and Calc takes the characters in the string without attempting to interpret them. For example, the formula ="Hello world!" displays the text string Hello world! in the cell, with no surrounding double quotation marks.

The more complex formula =CONCATENATE("Life is really simple, "; "but we insist on making it complicated "; "(Confucius).") concatenates three individual strings in double quotation marks, outputting Life is really simple, but we insist on making it complicated (Confucius).

To place a literal double quotation mark within a string inside a formula, two methods can be used:

  1. You can "escape" the double quotation mark with an additional double quotation mark, and Calc treats the escaped double quotation mark as a literal value. For example, the formula ="My name is ""John Doe""." outputs the string My name is "John Doe". Another simple example is the formula =UNICODE("""") which returns 34, the decimal value of the Unicode quotation mark character (U+0022) — here the first and fourth double quotation marks indicate the beginning and end of the string, while the second double quotation mark escapes the third.

  2. You can use the CHAR function or the UNICHAR function to insert a double quotation mark. For example, the formula =UNICHAR(34) & "The Catcher in the Rye" & UNICHAR(34) & " is a famous book by J. D. Salinger." displays the string "The Catcher in the Rye" is a famous book by J. D. Salinger.

Beware that Calc's AutoCorrect function may modify double quotation marks. AutoCorrect should not change the double quotation marks within formula cells but may change those used in non-formula cells containing text. For example, if you copy a string that is surrounded by some other form of typographical double quotation marks, such as the left double quotation mark (U+201C) and the right double quotation mark (U+201D), and then paste into a formula cell, an error may result. Open the Double Quotes area of the Tools - AutoCorrect Options - Localized Options dialog to set the characters used to automatically correct the start and end typographical double quotation marks. Uncheck the Replace toggle button to disable the feature.

ARABIC

Returns the numeric value corresponding to a Roman number expressed as text.

ASC

Converts double-byte (full-width) characters to single-byte (half-width) ASCII and katakana characters.

JIS

Converts single-byte (half-width) ASCII or katakana characters to double-byte (full-width) characters.

REGEX

Matches and extracts or optionally replaces text using regular expressions.

ROMAN

Converts a number into a Roman numeral. The value range must be between 0 and 3999. A simplification mode can be specified in the range from 0 to 4.

VALUE

Converts the string representation of a number to numeric form. If the supplied string is a valid date, time, or date-time, the corresponding date-time serial number is returned.

WEBSERVICE

Get some web content from a URI.

FILTERXML

Apply a XPath expression to a XML document.

ENCODEURL

Returns a URL-encoded string.

BAHTTEXT

একটি সংখ্যাকে থাই টেক্সটে রূপান্তর করে, থাই মুদ্রার নাম সহকারে।

Syntax

BAHTTEXT(Number)

Number হলো যেকোনো সংখ্যা। "Baht" সংখ্যার অখন্ড অংশের শেষে যোগ করা হয়, এবং "Satang" সংখ্যার দশমিক অংশের শেষে যোগ করা হয়।

Example

=BAHTTEXT(12.65) থাই অক্ষরে একটি স্ট্রিং প্রদান করে, যার অর্থ "বারো বাত এবং পয়ষট্রি সাতাং।

BASE

Converts a positive integer to a specified base into a text from the numbering system. The digits 0-9 and the letters A-Z are used.

Syntax

BASE(Number; Radix [; MinimumLength])

সংখ্যা হলো রূপান্তর করা হবে এমন একটি ধনাত্বক ইনটিজার।

রেডিক্স সংখ্যা সিস্টেমের ভিত্তি নির্দেশ করে থাকে। ২ এবং ৩৬ এর মধ্যে যেকোনো একটি ধনাত্মক ইনটিজার।

MinimumLength (ঐচ্ছিক) অক্ষরের ক্রমের সর্বনিম্ন দৈর্ঘ্য নির্ধারণ করে, যা তৈরি করা হয়েছে। যদি টেক্সটটি নির্দেশিত সর্মনিম্ন দৈর্ঘ্যের তুলনায় ছোট হয়, স্ট্রিংয়ের বামে শূন্য যোগ করা হয়।

Example

=BASE(17;10;4) বাইনারি ব্যবস্থায় ০০১৭ প্রদান করে।

=BASE(17;2) বাইনারি ব্যবস্থায় ১০০০১ প্রদান করে।

=BASE(255;16;4) হেক্সাডেসিমাল পদ্ধতিতে 00FF প্রদান করে থাকে।

CHAR

বর্তমান কোড টেবিল অনুসারে একটি সংখ্যাকে অক্ষরে রূপান্তর করে। সংখ্যাটি দুই-ডিজিট বা তিন-ডিজিটের পূর্ণ সংখ্যা হতে পারে।

১২৭ অপেক্ষা বড় কোডসমূহ আপনার সিস্টেমের অক্ষর ম্যাপিংয়ের উপর নির্ভর করতে পারে (উদাহরণস্বরূপ, iso-8859-1, iso-8859-2, Windows-1252, Windows-1250), এবং এ কারণে সুবহনীয় নাও হতে পারে।

Syntax

CHAR(Number)

সংখ্যা হলো অক্ষরের জন্য কোড মান নির্দেশ করার জন্য ১ থেকে ২৫৫ এর মধ্যে একটি সংখ্যা।

Example

=CHAR(100) d অক্ষরটি প্রদান করে।

="abc" & CHAR(10) & "def" স্ট্রিং এ একটি নতুনলাইন অক্ষর সন্নিবেশ করানো হয়।

CLEAN

স্ট্রিং হতে সকল অমুদ্রণীয় অক্ষর অপসারণ করা হয়।

Syntax

CLEAN("Text")

পাঠ্য পাঠ্য নির্দেশ করে থাকে যা থেকে সকল অমুদ্রণযোগ্য অক্ষর অপসারণ করা হয়।

Example

=LEN(CLEAN(CHAR(7) & "LibreOffice Calc" & CHAR(8))) returns 16, showing that the CLEAN function removes the non-printable Unicode U+0007 ("BEL") and U+0008 ("BS") characters at the beginning and end of the string argument. CLEAN does not remove spaces.

CODE

একটি টেক্সট স্ট্রিংয়ে প্রথম অক্ষরের জন্য সংখ্যাসূচক কোড প্রদান করে।

Syntax

CODE("Text")

পাঠ্য হলো একটি পাঠ্য যার জন্য প্রথম অক্ষরের কোড খুঁজে পাওয়া যাবে।

১২৭ অপেক্ষা বড় কোডসমূহ আপনার সিস্টেমের অক্ষর ম্যাপিংয়ের উপর নির্ভর করতে পারে (উদাহরণস্বরূপ, iso-8859-1, iso-8859-2, Windows-1252, Windows-1250), এবং এ কারণে সুবহনীয় নাও হতে পারে।

Example

=CODE("Hieronymus") ৭২ প্রদান করে, =CODE("hieroglyphic") ১০৪ প্রদান করে।

note

এখানে ব্যবহৃত কোড ASCII কে নির্দেশ করে না, কিন্তু বর্তমানে লোডকৃত কোড টেবিলকে নির্দেশ করে।


CONCATENATE

বিভিন্ন টেক্সট স্ট্রিংকে একত্রিত করে একটি স্ট্রিংয়ে রূপান্তর করে।

Syntax

CONCATENATE(String 1 [; String 2 [; … [; String 255]]])

String 1[; String 2][; … ;[String 255]] are strings or references to cells containing strings.

Example

=CONCATENATE("Good ";"Morning ";"Mrs. ";"Doe") Good Morning Mrs. Doe প্রদান করে।

DECIMAL

Converts text with characters from a number system to a positive integer in the base radix given. The radix must be in the range 2 to 36. Spaces and tabs are ignored. The Text field is not case-sensitive.

যদি রেডিক্স ১৬ হয়, একটি নেতৃত্বদানকারী x অথবা X অথবা 0x অথবা 0X, এবং একটি সংযুক্ত h অথবা H, হলো অবহেলিত। যদি রেডিক্স ২ হয়, একটি সংযুক্ত b অথবা B অবহেলিত হয়। অন্য অক্ষর য়া সংখ্যা ব্যবস্থাতে নয় তা ত্রুটি উৎপাদন করে।

Syntax

DECIMAL("Text"; Radix)

Text হলো এমন টেক্সট, যা রূপান্তর করা হবে। একটি হেক্সাডেসিমেল সংখ্যা, যেমন A1 এবং A1 ঘরের রেফারেন্সের মধ্যে পার্থক্য তৈরি করে, আপনাকে অবশ্যই সংখ্যাটি একটি উদ্ধৃতি চিহ্নের মধ্যে স্থাপন করতে হবে, যেমন, "A1" বা "FACE"।

রেডিক্স সংখ্যা সিস্টেমের ভিত্তি নির্দেশ করে থাকে। ২ এবং ৩৬ এর মধ্যে যেকোনো একটি ধনাত্মক ইনটিজার।

Example

=DECIMAL("17";10) ১৭ প্রদান করে।

=DECIMAL("FACE";16) ৬৪২০৬ প্রদান করে।

=DECIMAL("0101";2) ৫ প্রদান করে।

DOLLAR

একটি সখ্যাকে মুদ্রা বিন্যাসে একটি পরিমানে রূপান্তর করা হয়, একটি উল্লেখিত ডেসিমেল স্থানের দিকে পূর্ণ সংখ্যায় পরিবর্তন করে। মান ক্ষেত্রে মুদ্রাতে রূপান্তরযোগ্য সংখ্যা সন্নিবেশ করান। ঐচ্ছিকভাবে, ডেসিমেল স্থানের ডেসিমেল ক্ষেত্রে সংখ্যাটি প্বেশ করাতে পারেন। যদি কোন মান উল্লেখিত না হয়, মুদ্রা বিন্যাসে সকল সংখ্যা দুই ডেসিমেল স্থান দ্বারা প্রদর্শিত হবে।

আপনার সিস্টেমের সেটিংয়ে আপনি মুদ্রার বিন্যাস নির্ধারণ করেন।

Syntax

DOLLAR(Value [; Decimals])

Value হলো একটি সংখ্যা, সংখ্যা রয়েছে এমন একটি ঘরের রেফারেন্স, বা সংখ্যা প্রদান করে এমন একটি সূত্র।

দশমিক হলো দশমিক স্থানের ঐচ্ছিক সংখ্যা।

Example

=DOLLAR(255) returns $255.00 for the English (USA) locale and USD (dollar) currency; ¥255.00 for the Japanese locale and JPY (yen) currency; or 255,00 € for the German (Germany) locale and EUR (euro) currency.

=DOLLAR(367.456;2) $৩৬৭.৪৬ প্রদান করে। বর্তমান লোক্যাল সেটিং এর সাথে সঙ্গতিপূর্ণ দশমিক বিভাজক ব্যবহার করুন।

EXACT

দুইটি টেক্সট স্ট্রিং তুলনা করা হয় এবং যদি তারা একই রকম হয়, তবে TRUE প্রদান করে। এই ফাংশনটি অক্ষরের ছাঁদ-নির্ভরশীল নয়।

Syntax

EXACT("Text1"; "Text2")

Text1 তুলনা করার জন্য প্রথম পাঠ্য নির্দেশ করে থাকে।

Text2 হলো তুলনা করার জন্য দ্বিতীয় পাঠ্য।

Example

=EXACT("microsystems";"Microsystems") FALSE প্রদান করে।

FIND

Returns the position of a string of text within another string.You can also define where to begin the search. The search term can be a number or any string of characters. The search is case-sensitive.

Syntax

FIND("FindText"; "Text" [; Position])

FindText খুঁজে পাওয়া যাবে এমন পাঠ্য নির্দেশ করে থাকে।

পাঠ্য হলো পাঠ্য যেখানে অনুসন্ধান করা হয়।

অবস্থান (ঐচ্ছিক) হলো পাঠ্যের মধ্যে একটি স্থান যেখান থেকে অনুসন্ধান শুরু করা হয়।

Example

=FIND(76;998877665544) ৬ প্রদান করে।

FIXED

Returns a number as text with a specified number of decimal places and optional thousands separators.

Syntax

FIXED(Number; [Decimals = 2 [; NoThousandsSeparators = FALSE]])

Number is rounded to Decimals places (after the decimal separator) and the result formatted as text, using locale-specific settings.

Decimals (optional) refers to the number of decimal places to be displayed. If Decimals is negative, Number is rounded to ABS(Decimals) places to the left from the decimal point. If Decimals is a fraction, it is truncated actually ignoring what is the closest integer.

NoThousandsSeparators (optional) determines whether the thousands separator is used. If it is TRUE or non-zero, then group separators are omitted from the resulting string. If the parameter is equal to 0 or if it is missing altogether, the thousands separators of your current locale setting are displayed.

Example

=FIXED(1234567.89;3) টেক্সট স্ট্রিং হিসেবে ১,২৩৪,৫৬৭.৮৯০ প্রদান করে।

=FIXED(123456.789;;TRUE) returns 123456.79 as a text string.

=FIXED(12345.6789;-2) returns 12,300 as a text string.

=FIXED(12134567.89;-3;1) returns 12135000 as a text string.

=FIXED(12345.789;3/4) returns 12,346 as a text string.

=FIXED(12345.789;8/5) returns 12,345.8 as a text string.

LEFT

প্রথম অক্ষর বা টেক্সটের অক্ষর প্রদান করে।

Syntax

LEFT("Text" [; Number])

Text হলো একটি টেক্সট, যেখান থেকে প্রারম্ভিক আংশিক শব্দ নির্ধারণ করে।

Number (ঐচ্ছিক), প্রারম্ভিক টেক্সটের জন্য অক্ষরের সংখ্যা উল্লেখ করে। যদি এই প্যারামিটারটি নির্ধারিত না থাকে, একটি অক্ষর প্রদান করা হয়।

Example

=LEFT("output";3) “out” প্রদান করে।

LEFTB

Returns the first characters of a DBCS text.

tip

This function is available since LibreOffice 4.2.


Syntax

LEFTB("Text" [; Number_bytes])

Text is the text where the initial partial words are to be determined.

Number_bytes (optional) specifies the number of characters you want LEFTB to extract, based on bytes. If this parameter is not defined, one character is returned.

Example

=LEFTB("中国";1) returns " " (1 byte is only half a DBCS character and a space character is returned instead).

=LEFTB("中国";2) returns "中" (2 bytes constitute one complete DBCS character).

=LEFTB("中国";3) returns "中 " (3 bytes constitute one DBCS character and a half; the last character returned is therefore a space character).

=LEFTB("中国";4) returns "中国" (4 bytes constitute two complete DBCS characters).

=LEFTB("office";3) returns "off" (3 non-DBCS characters each consisting of 1 byte).

LEN

স্পেস সহ স্ট্রিংয়ের দৈর্ঘ্য প্রদান করে।

Syntax

LEN("Text")

পাঠ্য হলো পাঠ্য যার দৈর্ঘ্য নির্ধারণ করা হবে।

Example

=LEN("Good Afternoon") ১৪ প্রদান করে।

=LEN(12345.67) ৮ প্রদান করে।

LENB

For double-byte character set (DBCS) languages, returns the number of bytes used to represent the characters in a text string.

tip

This function is available since LibreOffice 4.2.


Syntax

LENB("Text")

পাঠ্য হলো পাঠ্য যার দৈর্ঘ্য নির্ধারণ করা হবে।

Example

LENB("中") returns 2 (1 DBCS character consisting of 2 bytes).

LENB("中国") returns 4 (2 DBCS characters each consisting of 2 bytes).

LENB("office") returns 6 (6 non-DBCS characters each consisting of 1 byte).

=LENB("Good Afternoon") returns 14.

=LENB(12345.67) returns 8.

LOWER

একটি টেক্সট স্ট্রিংয়ের সকল বড় হাতের অক্ষরকে ছোট হাতের অক্ষরে রূপান্তর করে।

Syntax

LOWER("Text")

পাঠ্য রূপান্তর করা হবে এমন পাঠ্য নির্দেশ করে থাকে।

Example

=LOWER("Sun") sun প্রদান করে।

MID

একটি টেক্সটের টেক্সট স্ট্রিং প্রদান করে। প্যারামিটারসমূহ শুরুর অবস্থান এবং অক্ষরের সংখ্যা উল্লেখ করে।

Syntax

MID("Text"; Start; Number)

পাঠ্য হলো টেনে বের করে আনার জন্য একটি অক্ষর সম্বলিত পাঠ্য।

শুরু হলো টেনে বের করে আনার জন্য পাঠ্যের অফম অক্ষরের অবস্থান।

সংখ্যা পাঠ্যের একটি অংশের অক্ষরের সংখ্যা উল্লেখ করে থাকে।

Example

=MID("office";2;2) ff প্রদান করে।

MIDB

Returns a text string of a DBCS text. The parameters specify the starting position and the number of characters.

tip

This function is available since LibreOffice 4.2.


Syntax

MIDB("Text"; Start; Number_bytes)

পাঠ্য হলো টেনে বের করে আনার জন্য একটি অক্ষর সম্বলিত পাঠ্য।

Start is the position of the first character in the text to extract.

Number_bytes specifies the number of characters MIDB will return from text, in bytes.

Example

=MIDB("中国";1;0) returns "" (0 bytes is always an empty string).

=MIDB("中国";1;1) returns " " (1 byte is only half a DBCS character and therefore the result is a space character).

=MIDB("中国";1;2) returns "中" (2 bytes constitute one complete DBCS character).

=MIDB("中国";1;3) returns "中 " (3 bytes constitute one and a half DBCS character; the last byte results in a space character).

=MIDB("中国";1;4) returns "中国" (4 bytes constitute two complete DBCS characters).

=MIDB("中国";2;1) returns " " (byte position 2 is not at the beginning of a character in a DBCS string; 1 space character is returned).

=MIDB("中国";2;2) returns " " (byte position 2 points to the last half of the first character in the DBCS string; the 2 bytes asked for therefore constitutes the last half of the first character and the first half of the second character in the string; 2 space characters are therefore returned).

=MIDB("中国";2;3) returns " 国" (byte position 2 is not at the beginning of a character in a DBCS string; a space character is returned for byte position 2).

=MIDB("中国";3;1) returns " " (byte position 3 is at the beginning of a character in a DBCS string, but 1 byte is only half a DBCS character and a space character is therefore returned instead).

=MIDB("中国";3;2) returns "国" (byte position 3 is at the beginning of a character in a DBCS string, and 2 bytes constitute one DBCS character).

=MIDB("office";2;3) returns "ffi" (byte position 2 is at the beginning of a character in a non-DBCS string, and 3 bytes of a non-DBCS string constitute 3 characters).

PROPER

একটি টেক্সট স্ট্রিংয়ের সকল শব্দের প্রথম অক্ষর বড় হাতের অক্ষরে পরিবর্তন করে।

Syntax

PROPER("Text")

পাঠ্য রূপান্তর করা হবে এমন পাঠ্য নির্দেশ করে থাকে।

Example

=PROPER("the document foundation") returns The Document Foundation.

REPLACE

একটি ভিন্ন টেক্সট স্ট্রিং দ্বারা একটি টেক্সট স্ট্রিংয়ের অংশ প্রতিস্থাপন করে। এই ফাংশনটি অক্ষর এবং সংখ্যা উভয়ই প্রতিস্থাপন করতে ব্যবহৃত হতে পারে (যেগুলো স্বয়ংক্রিয়ভাবে টেক্সটে রূপান্তর করা হয়েছে)। ফাংশনের ফলাফল সবসময় টেক্সট হিসেবে প্রদর্শিত হয়। আপনি যদি সংখ্যা দ্বারা পরবর্তী গণনা সম্পাদনা করতে চান, যা টেক্সট দ্বারা প্রতিস্থাপন করা হয়েছে, আপনাকে VALUE ফাংশন ব্যবহার করে পুনরায় এটাকে সংখ্যায় রূপান্তর করতে হবে।

সংখ্যা যুক্ত যেকোনো টেক্সট অবশ্যই একটি উদ্ধৃতি চিহ্নের থাকবে, যদি আপনি এটাকে সংখ্যা হিসেবে প্রকাশ করতে না চান বা স্বয়ংক্রিয়ভাবে টেক্সটে রূপান্তর করতে না চান।

Syntax

REPLACE("Text"; Position; Length; "NewText")

পাঠ্য পাঠ্য নির্দেশ করে যার একটি অংশ প্রতিস্থাপন করা হবে।

অবস্থান পাঠ্যের মধ্যে একটি অবস্থান নির্দেশ করে যেখানে পুনরায় স্থাপন করা শুরু হবে।

দৈর্ঘ্য হলো প্রতিস্থাপন করা হবে এমন পাঠ্য তে বিদ্যমান অক্ষরের সংখ্যা।

NewText পাঠ্য নির্দেশ করে থাকে যা পাঠ্য প্রতিস্থাপন করে থাকে।

Example

=REPLACE("1234567";1;1;"444") "444234567" প্রদান করে থাকে। অবস্থান ১ এর একটি অক্ষর সম্পূর্ণ NewText দ্বারা প্রতিস্থাপন করা হয়।

REPT

একটি অক্ষরের স্ট্রিং প্রদত্ত অনুলিপি সংখ্যা অনুসারে পুনরাবৃত্ত হয়।

Syntax

REPT("Text"; Number)

পাঠ্য হলো পুনরাবৃত্তি করা হবে এমন পাঠ্য।

সংখ্যা হলো পুনরাবৃত্তির জন্য সংখ্যা।

Example

=REPT("Good morning";2) Good morningGood morning প্রদান করে থাকে।

tip

Refer to the REPT wiki page for more details about this function.


RIGHT

টেক্সটের সর্বশেষ অক্ষর বা অক্ষরসমূহ প্রদান করে।

Syntax

RIGHT("Text" [; Number])

পাঠ্য হলো পাঠ্য যার সঠিক অংশটি নির্ধারণ করা হবে।

Number (optional) is the number of characters from the right part of the text. If this parameter is not defined, one character is returned.

Example

=RIGHT("Sun";2) un প্রদান করে।

RIGHTB

Returns the last character or characters of a text with double bytes characters sets (DBCS).

tip

This function is available since LibreOffice 4.2.


Syntax

RIGHTB("Text" [; Number_bytes])

Text is the text of which the right part is to be determined.

Number_bytes (optional) specifies the number of characters you want RIGHTB to extract, based on bytes. If this parameter is not defined, one byte is returned.

Example

RIGHTB("中国";1) returns " " (1 byte is only half a DBCS character and a space character is returned instead).

RIGHTB("中国";2) returns "国" (2 bytes constitute one complete DBCS character).

RIGHTB("中国";3) returns " 国" (3 bytes constitute one half DBCS character and one whole DBCS character; a space is returned for the first half).

RIGHTB("中国";4) returns "中国" (4 bytes constitute two complete DBCS characters).

RIGHTB("office";3) returns "ice" (3 non-DBCS characters each consisting of 1 byte).

SEARCH

Returns the position of a text segment within a character string. You can set the start of the search as an option. The search text can be a number or any sequence of characters. The search is not case-sensitive. If the text is not found, returns error 519 (#VALUE).

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in - LibreOffice Calc - Calculate.

warning

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".


Syntax

SEARCH("FindText"; "Text" [; Position])

FindText হলো অনুসন্ধান করা হবে এমন একটি পাঠ্য।

পাঠ্য হলো একটি পাঠ্য যেখানে অনুসন্ধান করা হবে।

অবস্থান (ঐচ্ছিক) হলো পাঠ্যের মধ্যে বিদ্যমান একটি অবস্থান যেখান থেকে অনুসন্ধান শুরু হয়।

Example

=SEARCH(54;998877665544) ১০ প্রদান করে।

SUBSTITUTE

একটি স্ট্রিংয়ের পুরনো টেক্সটকে নতুন টেক্সট দিয়ে প্রতিস্থাপন করে।

Syntax

SUBSTITUTE("Text"; "SearchText"; "NewText" [; Occurrence])

পাঠ্য হলো পাঠ্য যাতে পাঠ্যের অংশ বিনিময় করা যাবে।

SearchText হলো একটি পাঠ্য অংশ যা প্রতিস্থাপন করা যাবে (কিছু সময়)।

NewText হলো পাঠ্য অংশ প্রতিস্থাপন করার জন্য পাঠ্য।

Occurrence (ঐচ্ছিক) নির্দেশ করে যে অনুসন্ধান টেক্সট কতবার প্রতিস্থাপন করা হবে। যদি এই প্যারামিটারটি অনুপস্তিত থাকে, অনুসন্ধান টেক্সটটি যতবার পাওয়া যাবে ততবার প্রতিস্থাপন করা হবে।

Example

=SUBSTITUTE("123123123";"3";"abc") 12abc12abc12abc প্রদান করে

=SUBSTITUTE("123123123";"3";"abc";2) 12312abc123 প্রদান করে।

T

এই ফাংশনটি উদ্দিষ্ট টেক্সট প্রদান করে, বা যদি লক্ষ্যবস্তুটি টেক্সট না হয়, ফাঁকা টেক্সট স্ট্রিং প্রদান করে।

Syntax

T(Value)

যদি Value টেক্সট স্ট্রিং হয় বা একটি টেক্সট স্ট্রিংকে উল্লেখ করে ,T ঐ টেক্সট স্ট্রিংকে প্রদান করে; অন্যথায় এটা একটি ফাঁকা টেক্সট স্ট্রিং প্রদান করে।

Example

=T(12345) একটি ফাঁকা স্ট্রিং প্রদান করে।

=T("12345") ১২৩৪৫ স্ট্রিং প্রদান করে।

TEXT

Converts a value into text according to a given format.

Syntax

TEXT(Value; Format)

Value is the value (numerical or textual) to be converted.

Format হলো একটি টেক্সট, যা ফরম্যাট নির্ধারণ করে। ঘরের বিন্যাসে নির্ধারিত ভাষা অনুসারে দশমিক এবং সহস্র বিভাজক ব্যবহার করুন।

Example

=TEXT(12.34567;"###.##") ১২.৩৫ লেখা প্রদান করে

=TEXT(12.34567;"000.00") ০১২.৩৫ লেখা প্রদান করে

=TEXT("xyz";"=== @ ===") returns the text === xyz ===

tip

See also Number format codes: custom format codes defined by the user.


TRIM

স্ট্রিং থেকে ফাঁকা স্থান সরিয়ে ফেলে, শব্দের মধ্যে শুধুমাত্র এক অক্ষর সমান ফাঁকা স্থান রাখে।

Syntax

TRIM("Text")

Text refers to text in which spaces are to be removed.

Example

=TRIM(" hello world ") returns hello world without leading and trailing spaces and with single space between words.

UNICHAR

একটি কোড সংখ্যাকে উইনিকোড অক্ষর অথবা বর্ণে রূপান্তর করে থাকে।

Syntax

UNICHAR(number)

Example

=UNICHAR(169) কপিরাইট অক্ষর © প্রদান করে।

tip

See also the UNICODE() function.


UNICODE

একটি পাঠ্য স্ট্রিং এ সংখ্যাসূচক কোডটিকে প্রথম উইনিকোড অক্ষর হিসেবে প্রদান করে থাকে।

Syntax

UNICODE("Text")

Example

=UNICODE("©") কপিরাইট অক্ষরের জন্য 169 ইউনিকোড ক্রম প্রদান করে থাকে।

tip

See also the UNICHAR() function.


UPPER

text ক্ষেত্রে উল্লেখিত স্ট্রিংকে বড় হাতের অক্ষরে রূপান্তর করে।

Syntax

UPPER("Text")

Text ছোট হাতের অক্ষরের স্ট্রিং উল্লেখ করে, যা আপনি বড় হাতের অক্ষরে রূপান্তর করতে চান।

Example

=UPPER("Good Morning") GOOD MORNING প্রদান করে।

Please support us!