স্প্রেডশীট ফাংশন

This section contains descriptions of the Spreadsheet functions together with an example.

[text/scalc/01/func_error_type.xhp#error_type_head not found].

Returns a number representing a specific Error type, or the error value #N/A, if there is no error.

STYLE

Applies a style to the cell containing the formula.

ADDRESS

উল্লেখিত সারি এবং কলাম সংখ্যা অনুযায়ী, টেক্সট হিসেবে একটি ঘরের ঠিকানা (রেফারেন্স) প্রদান করে। ঠিকানাটি পরম ঠিকানা হিসেবে (যেমন, $A$1) বা আপেক্ষিক ঠিকানা (A1 হিসেবে) হিসেবে বা একটি মিশ্র ফরমে (A$1 বা $A1) ব্যাখ্যা করা যায় কিনা তা আপনি নির্ধারণ করতে পারবেন। আপনি শীটের নামও উল্লেখ করতে পারবেন।

পারস্পরিক ক্রিয়ার জন্য ADDRESS এবং INDIRECT ফাংশনটি একটি ঐচ্ছিক প্যারামিটার সমর্থন করে, সাধারণ A1 নোটাশনের পরিবর্তে R1C1 নোটেশন ব্যবহার হওয়া উচিত কিনা তা উল্লেখ করতে।

ADDRESS এ, ঐচ্ছিক শীট নামের প্যারামিটারটি পঞ্চম স্থানে সরিয়ে, প্যারামিটারটি চতুর্থ প্যারামিটার হিসেবে সন্নিবেশ করা হয়েছে।

INDIRECT এ, প্যারামিটারটি দ্বিতীয় প্যারামিটার হিসাবে যোগ করা হয়েছে।

উভয় ফাংশনে, যদি আর্গুমেন্টটি মান ০ সহ সন্নিবেশ করানো হয়, তবে R1C1 নোটেশন ব্যবহৃত হয়। যদি আর্গুমেন্টটি প্রদান করা না হয় বা ০ ব্যতীত অন্য মান দেওয়া হয়, তবে A1 নোটেশন ব্যবহৃত হয়।

R1C1 নোটেশনের ক্ষেত্রে, ADDRESS আশ্চর্যবোধক চিহ্ন '!' ব্যবহার করে শীট নামের বিভাজক হিসেবে ঠিকানার স্ট্রিং প্রদান করে, এবং INDIRECT শীট নামের বিভাজক হিসেবে আশ্চর্যবোধক চিহ্ন ব্যবহার করতে চায়। উভয় ফাংশন এখনও A1 নোটেশনের সাথে শীট নামের বিভাজক ডট '.' ব্যবহার করে।

When opening documents from ODF 1.0/1.1 format, the ADDRESS functions that show a sheet name as the fourth parameter will shift that sheet name to become the fifth parameter. A new fourth parameter with the value 1 will be inserted.

একটি নথি ODF 1.0/1.1 ফরম্যাটে সংরক্ষণ করার সময়, যদি ADDRESS ফাংশনের একটি চতুর্থ প্যারামিটার থাকে, ঐ প্যারামিটারটি অপসারণ করা হবে।

ADDRESS(Row; Column [; Abs [; A1 [; "Sheet"]]])

সারি ঘরের রেফারেন্সের সারি সংখ্যা উল্লেখ করে থাকে।

কলাম ঘরের রেফারেন্সের কলাম সংখ্যা প্রদান করে থাকে (সংখ্যা, অক্ষর নয়)

Abs রেফারেন্সর ধরন নির্ধারণ করে:

১: সম্পূর্ণ ($A$1)

২: সারির রেফারেন্সের ধরন হলো সম্পূর্ণ; কলাম রেফারেন্স হলো আপাক্ষিক (A$1)

৩: সারি (আপেক্ষিক); কলাম (সম্পূর্ণ) ($A1)

৪: আপেক্ষিক (A1)

A1 (ঐচ্ছিক) - যদি ০ তে নির্ধারিত হয়, R1C1 নোটেশন ব্যবহৃত হয়। যদি প্যারামিটারটি অনুপস্থিত থাকে অথবা ০ ব্যতীত অন্য একটি মানে নির্ধারিত থাকে, তাহলে A1 নোটেশনটি ব্যবহৃত হয়।

Sheet শীটের নাম উল্লেখ করে। এটা অবশ্যই ডবল উদ্ধৃতি চিহ্নের মধ্যে রাখতে হবে।

উদাহরণ:

=ADDRESS(1;1;2;;"Sheet2") : Sheet2.A$1 প্রদান করে

If the formula above is in cell B2 of current sheet, and the cell A1 in sheet 2 contains the value -6, you can refer indirectly to the referenced cell using a function in B2 by entering =ABS(INDIRECT(B2)). The result is the absolute value of the cell reference specified in B2, which in this case is 6.

AREAS

পৃথক পরিসর সংখ্যা প্রদান করে, যা একাধিক পরিসরের অন্তর্ভুক্ত। একটি পরিসর নিকটস্থ ঘরসমূহ বা একক ঘর দ্বারা গঠিত হতে পারে।

ফাংশনটি একটি একক আরগুমেন্ট প্রত্যাশা করে থাকে। আপনি যদি একাধিক পরিসর বর্ণনা করেন, তাহলে এদেরকে অবশ্যই একটি অতিরিক্ত জোড়া বন্ধনীর মধ্যে আবদ্ধ করতে হবে। বহু পরিসর একটি বিভাজক সেমিকোলন (;) ব্যবহার করে সন্নিবেশ করানো যায়, কিন্তু এটি স্বয়ংক্রিয়ভাবে টিল্ড (~) অপারেটরে রূপান্তরিত হয়। টিল্ড ব্যবহার করে পরিসরসমূহ একত্রিত করা যায়।

AREAS(Reference)

Reference ঘরের বা ঘরের পরিসরের রেফারেন্স উল্লেখ করে।

=AREAS((A1:B3;F2;G1)) ফলাফল 3 প্রদান করে থাকে, যেহেতু এটি তিনটি ঘর এবং/অথবা এলাকার রেফারেন্স। সন্নিবেশ করানোর পর এটি =AREAS((A1:B3~F2~G1)) তে রূপান্তরিত হয়।

=AREAS(All) ১ প্রদান করে যদি আপনি All নামের একটি এলাকা ডাটা - পরিসর নির্ধারণ এর অধীনে নির্ধারণ কর থাকেন।

CHOOSE

সর্বোচ্চ ৩০টি মানের তালিকা হতে একটি মান প্রদান করতে একটি ইনডেক্স ব্যবহার করে।

CHOOSE(Index; Value 1 [; Value 2 [; ... [; Value 30]]])

Index হলো একটি রেফারেন্স বা ১ এবং ৩০ এর মধ্যবর্তী একটি সংখ্যা, যা নির্দেশ করে যে কোন মানটি তালিকা থেকে নেয়া হবে।

Value 1, Value 2, ..., Value 30 is the list of values entered as a reference to a cell or as individual values.

=CHOOSE(A1;B1;B2;B3;"Today";"Yesterday";"Tomorrow"), উদাহরণস্বরূপ, A1 = ২ হলে, B2 এর বিষয়বস্তু প্রদান করে; A1 = ৪ হলে, ফাংশনটি টেক্সট "Today" প্রদান করে।

COLUMN

Returns the column number of a cell reference. If the reference is a cell the column number of the cell is returned; if the parameter is a cell area, the corresponding column numbers are returned in a single-row array if the formula is entered as an array formula. If the COLUMN function with an area reference parameter is not used for an array formula, only the column number of the first cell within the area is determined.

COLUMN([Reference])

Reference হলো একটি ঘর বা ঘরের এলাকার রেফারেন্স, যার প্রথম কলাম নম্বর খোঁজা হবে।

যদি কোনো রেফারেন্স সন্নিবেশ করানো না হয়, সূত্রটি সন্নিবেশ করানো হয় এমন ঘরের কলাম নম্বর খোঁজা হয়। LibreOffice ক্যালক স্বয়ংক্রিয়ভাবে বর্তমান ঘরে রেফারেন্স নির্ধারণ করে।

=COLUMN(A1) ১ এর সমান। কলাম A হলো সারণির প্রথম কলাম।

=COLUMN(C3:E3) ৩ এর সমান। কলাম C হলো সারণির তৃতীয় কলাম।

=COLUMN(D3:G10) ৪ প্রদান করে, কারণ কলাম D হলো টেবিলে চতুর্থ কলাম এবং COLUMN ফাংশনটি অ্যারে সূত্র হিসেবে ব্যবহৃত হয় না। (এই ক্ষেত্রে, অ্যারের প্রথম মান সবসময় ফলাফল হিসেবে ব্যবহৃত হয়।)

{=COLUMN(B2:B7)} এবং =COLUMN(B2:B7) উভয়ই ২ ফলাফল প্রদান করে কারণ reference টি শুধুমাত্র টেবিলে দ্বিতীয় কলাম হিসেবে B ধারণ করে। কারণ একক-এলাকার শুধুমাত্র একটি কলাম ক্রম রয়েছে, একটি বিন্যাস সূত্র হিসেবে সূত্রটি ব্যবহার হওয়া এবং না হওয়ার মধ্যে কোন পার্থক্য করে না।

=COLUMN() ৩ প্রদান করে, যদি সূত্রটি C কলাম সন্নিবেশ করানো হয়ে থাকে।

{=COLUMN(Rabbit)} একক-সারি অ্যারে (৩, ৪) প্রদান করে, যদি এলাকার (C1:D3) নাম "Rabbit" হয়।

COLUMNS

প্রদত্ত রেফারেন্সে কলাম সংখ্যা প্রদান করে।

COLUMNS(Array)

Array হলো ঘরের পরিসরে রেফারেন্স, যার সর্বমোট কলাম সংখ্যা খোঁজা হবে। আর্গুমেন্ট একটি একক ঘরও হতে পারে।

=COLUMNS(B5) ১ প্রদান করে কারণ ঘরে শুধুমাত্র একটি কলাম বিদ্যমান।

=COLUMNS(A1:C5) ৩ এর সমান। রেফারেন্সটি তিনটি কলামের সমন্বয়ে গঠিত।

=COLUMNS(Rabbit) ২ প্রদান করে, যদি Rabbit একটি নামযুক্ত পরিসর (C1:D3) হয়।

DDE

DDE-ভিত্তিক লিঙ্ক এর ফলাফল প্রদান করে। যদি লিঙ্ককৃত পরিসরের উপাদান অথবা অংশ পরিবর্তিত হয়, ফলাফল প্রদানকৃত মানটিও পরিবর্তিত হয়। আপনার অবশ্যই স্প্রেডশীটটি পুনঃস্থাপন করতে হবে অথবা আপডেট করা লিঙ্ক দেখার জন্য সম্পাদনা - লিঙ্ক পছন্দ করুন। ক্রস-প্ল্যাটফর্ম লিঙ্ক, উদাহরনস্বরূপ, লিনাক্স মেশিনে তৈরিকৃত একটি নথি উইন্ডোজ মাশিনে চালানো হচ্ছে এমন একটি LibreOfficeসংস্থাপন হতে, অনুমোদিত নয়।

DDE("Server"; "File"; "Range" [; Mode])

Server is the name of a server application. LibreOffice applications have the server name "soffice".

File হলো সম্পূর্ণ ফাইলের নাম, পাথের বিবরণী সহকারে।

পরিসর পরূক্ষা করার জন্য ডাটা সম্বলিত এলাকা।

Mode হলো একটি ঐচ্ছিক প্যারামিটার, যা এমন মেথড নিয়ন্ত্রণ করে, যা দ্বারা DDE সার্ভার নিজের ডাটাকে সংখ্যায় রূপান্তর করে।

Mode	Effect
০ বা হারিয়ে গিয়েছে	"পূর্বনির্ধারিত" ঘরের শৈলীর সংখ্যা বিন্যাস
1	US ইংরেজীর জন্য ডাটা সর্বদা আদর্শ ফরম্যাটে ব্যাখ্যা করা হয়।
2	ডাটা টেক্সট হিসাবে উদ্ধার করা হয়; সংখ্যার কোনো রূপান্তর করা হবে না

=DDE("soffice";"c:\office\document\data1.ods";"sheet1.A1") reads the contents of cell A1 in sheet1 of the LibreOffice Calc spreadsheet data1.ods.

=DDE("soffice";"c:\office\document\motto.odt";"Today's motto") returns a motto in the cell containing this formula. First, you must enter a line in the motto.odt document containing the motto text and define it as the first line of a section named Today's Motto (in LibreOffice Writer under Insert - Section). If the motto is modified (and saved) in the LibreOffice Writer document, the motto is updated in all LibreOffice Calc cells in which this DDE link is defined.

ERRORTYPE

সংখ্যা ফলাফল ত্রুটি মানসংশ্লিষ্ট ভিন্ন ঘরে সংঘটিত প্রদান করে। এই সংখ্যার aid এর সাহায্যে, আপনি একটি ত্রুটি বার্তা টেক্সট উৎপাদন করতে পারবেন।

ERRORTYPE(Reference)

Reference-এ এমন একটি ঘরের ঠিকান রয়েছে, যেখানে ত্রুটি সংগঠিত হয়।

যদি A1 ঘর Err:518 প্রদর্শন করে, =ERRORTYPE(A1) ফাংশনটি ৫১৮ সংখ্যা প্রদান করে।

ORG.OPENOFFICE.ERRORTYPE

GETPIVOTDATA

The GETPIVOTDATA function returns a result value from a pivot table. The value is addressed using field and item names, so it remains valid if the layout of the pivot table changes.

দুইটি ভিন্ন সিনট্যাক্স সংজ্ঞা ব্যবহার করা যেতে পারে:

GETPIVOTDATA(TargetField; pivot table[; Field 1; Item 1][; ... [Field 126; Item 126]])

or

GETPIVOTDATA(pivot table; Constraints)

যদি দুইটি প্যারামিটার উল্লেখ করা হয়, দ্বিতীয় সিনট্যাক্সটি ধরে নেওয়া হয়েছে, যার প্রথম প্যারামিটার হলো ঘর বা ঘর পরিসরের রেফারেন্স। অন্য সব ক্ষেত্রে প্রথম সিনট্যাক্সটি ধরে নেওয়া হয়। ফাংশন উইজার্ডটি প্রথম সিনট্যাক্স প্রদর্শন করে।

First Syntax

TargetField is a string that selects one of the pivot table's data fields. The string can be the name of the source column, or the data field name as shown in the table (like "Sum - Sales").

pivot table is a reference to a cell or cell range that is positioned within a pivot table or contains a pivot table. If the cell range contains several pivot tables, the table that was created last is used.

If no Field n / Item n pairs are given, the grand total is returned. Otherwise, each pair adds a constraint that the result must satisfy. Field n is the name of a field from the pivot table. Item n is the name of an item from that field.

If the pivot table contains only a single result value that fulfills all of the constraints, or a subtotal result that summarizes all matching values, that result is returned. If there is no matching result, or several ones without a subtotal for them, an error is returned. These conditions apply to results that are included in the pivot table.

If the source data contains entries that are hidden by settings of the pivot table, they are ignored. The order of the Field/Item pairs is not significant. Field and item names are not case-sensitive.

If no constraint for a filter is given, the field's selected value is implicitly used. If a constraint for a filter is given, it must match the field's selected value, or an error is returned. Filters are the fields at the top left of a pivot table, populated using the "Filters" area of the pivot table layout dialog. From each filter, an item (value) can be selected, which means only that item is included in the calculation.

Subtotal values from the pivot table are only used if they use the function "auto" (except when specified in the constraint, see Second Syntax below).

Second Syntax

pivot table has the same meaning as in the first syntax.

সীমাবদ্ধতা হলো একটি ফাঁকা স্থান-বিভাজিত তালিকা। এন্ট্রি কোট (একক কোট) করা যেতে পারে। সম্পূর্ণ স্ট্রিংটি অবশ্যই কোট (ডাবল-কোট) দ্বারা আবদ্ধ করা হবে,যদি না আপনি অন্য ঘর হতে স্ট্রিংটি উল্লেখ না করেন।

One of the entries can be the data field name. The data field name can be left out if the pivot table contains only one data field, otherwise it must be present.

Each of the other entries specifies a constraint in the form Field[Item] (with literal characters [ and ]), or only Item if the item name is unique within all fields that are used in the pivot table.

একটি ফাংশন একটি ফরম Field[Item;Function] তে সংযুক্ত করা যেতে পারে, যা শুধুমাত্র সাবটোটাল মানের সাথে সীমাবদ্ধতা মিল রাখার কারণ ঘটায় যা সেই ফাংশনটি ব্যবহার করে। সম্ভাব্য ফাংশনের নাম হলো Sum, Count, Average, Max, Min, Product, Count (শুদুমাত্র সংখ্যা), StDev (নমুনা), StDevP (জনসংখ্যা), Var (Sample), and VarP (জনসংখ্যা), অক্ষরের আকার-সংবেদনশীল।উ

HLOOKUP

নির্বাচিত এলাকার নিচে ঘরে একটি মান এবং reference এর জন্য অনুসন্ধান করে। এই ফাংশনটি যাচাই করে যদি বিন্যাসের প্রথম সারিটি একটি নির্দিষ্ট মান ধারণ করে। ফাংশনটি ফলাফল প্রদান করে তারপর বিন্যাসের সারির মান, ইনডেক্স তে নামাঙ্কিত করা হয়, একই কলামে।

HLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

For an explanation on the parameters, see: VLOOKUP (columns and rows are exchanged)

Suppose we have built a small database table occupying the cell range A1:DO4 and containing basic information about 118 chemical elements. The first column contains the row headings “Element”, “Symbol”, “Atomic Number”, and “Relative Atomic Mass”. Subsequent columns contain the relevant information for each of the elements, ordered left to right by atomic number. For example, cells B1:B4 contain “Hydrogen”, “H”, “1” and “1.008”, while cells DO1:DO4 contain “Oganesson”, “Og”, “118”, and “294”.

	A	B	C	D	...	DO
1	Element	Hydrogen	Helium	Lithium	...	Oganesson
2	Symbol	H	He	Li	...	Og
3	Atomic Number	1	2	3	...	118
4	Relative Atomic Mass	1.008	4.0026	6.94	...	294

=HLOOKUP("Lead"; $A$1:$DO$4; 2; 0) returns “Pb”, the symbol for lead.

=HLOOKUP("Gold"; $A$1:$DO$4; 3; 0) returns 79, the atomic number for gold.

=HLOOKUP("Carbon"; $A$1:$DO$4; 4; 0) returns 12.011, the relative atomic mass of carbon.

HYPERLINK

আপনি যখন HYPERLINK ফাংশন রয়েছে এমন একটি ঘরে ক্লিক করেন, হাইপারলিংক খোলে যায়।

If you use the optional CellValue parameter, the formula locates the URL, and then displays the text or number.

HYPERLINK("URL" [; CellValue])

URL specifies the link target. The optional CellValue parameter is the text or a number that is displayed in the cell and will be returned as the result. If the CellValue parameter is not specified, the URL is displayed in the cell text and will be returned as the result.

ফাঁকা ঘর এবং ম্যাট্রিক্স এলিমেন্টের জন্য ০ প্রদান করে থাকে।

=HYPERLINK("http://www.example.org") displays the text "http://www.example.org" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";"Click here") displays the text "Click here" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";12345) displays the number 12345 and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK($B4) where cell B4 contains http://www.example.org. The function adds http://www.example.org to the URL of the hyperlink cell and returns the same text which is used as formula result.

=HYPERLINK("http://www.";"Click ") & "example.org" displays the text Click example.org in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("#Sheet1.A1";"Go to top") displays the text Go to top and jumps to cell Sheet1.A1 in this document.

=HYPERLINK("file:///C:/writer.odt#Specification";"Go to Writer bookmark") displays the text "Go to Writer bookmark", loads the specified text document and jumps to bookmark "Specification".

=HYPERLINK("file:///C:/Documents/";"Open Documents folder") displays the text "Open Documents folder" and shows the folder contents using the standard file manager in your operating system.

INDEX

INDEX returns a reference, a value or an array of values from a reference range, specified by row and column index number or array of row and array of columns index numbers, and an optional range index.

INDEX() returns a reference if the argument is one or more references. When used in a cell in the form =INDEX(), the reference is resolved and the values displayed. When INDEX() is used in arguments of other functions, =FUNCTION(INDEX()...), the function gets the reference passed that was returned by INDEX(). Returning a reference is different from returning an array of values for functions that handles them differently.

INDEX(Reference [; [Row] [; [Column] [; Range]]])

Reference is a reference, entered either directly or by specifying a range name. If the reference consists of multiple ranges, you must enclose the list of references or range names in parentheses, or either use the tilde (~) range concatenation operator or define a named range with multiple areas.

Row (optional) represents the row or the array of row indexes of the reference range, for which to return a value. In case of zero or omitted (no specific row) all referenced rows are returned.

Column (optional) represents the column or array of column indexes of the reference range, for which to return a value. In case of zero or omitted (no specific column) all referenced columns are returned.

Range (optional) represents the index of the subrange if referring to a multiple range, default is 1.

{=INDEX({1,3,5;7,9,10},{2;1},1)} return a 2 row array containing 7 and 1. The row index {2;1} pick row 2 then row 1. The columns index 1 picks the first column.

{=INDEX(D3:G12,{1;2;3;4},{3,1})} return a 4 rows by 2 columns array. The row index array {1;2;3;4} picks rows 3 to 6 and {3;1} picks the third (F) and first column (D). Columns 1 and 3 of the source reference are swapped in the resulting array.

=INDEX(Prices;4;1), Prices হিসেবে ডাটা - নির্ধারণ করা হবে এ নির্ধারিত ডাটাবেস পরিসরের ৪ নং সারি এবং ১ নং কলাম হতে মান প্রদান করে।

=INDEX(SumX;4;1) returns the value from the range SumX in row 4 and column 1 as defined in Sheet - Named Ranges and Expressions - Define.

{=INDEX(A1:B6;1)} returns the values of the first row of A1:B6. Enter the formula as an array formula.

{=INDEX(A1:B6;0;1)} returns the values of the first column of A1:B6. Enter the formula as an array formula.

=INDEX(A1:B6;1;1) A1:B6 পরিসরের উপরে বামের মান নির্দেশক।

{=INDEX((A1:B6;C1:D6);0;0;2)} returns the values of the second range C1:D6 of the multiple range. Enter the formula as an array formula.

INDIRECT

একটি টেক্সট স্ট্রিং দ্বারা উল্লেখিত রেফারেন্স প্রদান করে। এই ফাংশনটি সংশ্লিষ্ট স্ট্রিংয়ের এলাকা প্রদান করতেও ব্যবহৃত করা হতে পারে।

INDIRECT(Ref [; A1])

Ref একটি ঘর বা এলাকার (টেক্সট ফরমে) রেফারেন্স উল্লেখ করে, যার জন্য বিষয়বস্তু প্রদান করা হয়।

A1 (ঐচ্ছিক) - যদি ০ তে নির্ধারিত হয়, R1C1 নোটেশন ব্যবহৃত হয়। যদি প্যারামিটারটি অনুপস্থিত থাকে অথবা ০ ব্যতীত অন্য একটি মানে নির্ধারিত থাকে, তাহলে A1 নোটেশনটি ব্যবহৃত হয়।

=INDIRECT(A1) ১০০ এর সমান, যদি A1-এ রেফারেন্স হিসেবে C108 থাকে এবং C108 ঘরে ১০০ থাকে।

=SUM(INDIRECT("a1:" & ADDRESS(1;3))) সারি ১ এবং কলাম ৩ দ্বারা উল্লেখিত ঠিকানা দ্বারা ঘর পর্যন্ত A1 এর এলাকাতে ঘর সমষ্টি করুন। এর অড়্থ হলো A1:C1 সমষ্টিবদ্ধ করা হয়েছে।

LOOKUP

Returns the contents of a cell either from a one-row or one-column range. Optionally, the assigned value (of the same index) is returned in a different column and row. As opposed to VLOOKUP and HLOOKUP, search and result vector may be at different positions; they do not have to be adjacent. Additionally, the search vector for the LOOKUP must be sorted ascending, otherwise the search will not return any usable results.

LOOKUP(Lookup; SearchVector [; ResultVector])

Lookup is the value of any type to be looked for; entered either directly or as a reference.

SearchVector হলো একক-সারি বা একক-কলাম এলাকা, যা অনুসন্ধান করা হবে।

ResultVector হলো অন্য একটি একক-সারি বা একক-কলাম, যা হতে ফাংশনের ফলাফল গ্রহণ করা হয়। ফলাফলটি অনুসন্ধান ভেক্টরে পাওয়া উদাহারণের মতো একই ইনডেক্স সহ ফলাফল ভেক্টরের ঘর।

=LOOKUP(A1;D1:D100;F1:F100), A1 এ আপনার সন্নিবেশকৃত সংখ্যার জন্য D1:D100 পরিসরের সংশ্লিষ্ট ঘর অনুসন্ধান করে। খুঁজে পাওয়া উদাহরণের জন্য, ইনডেক্স নির্ধারণ করা হয়েছে, যেমন, এই পরিসরের ১২তম ঘর। তারপর, ১২তম ঘরের বিষয়বস্তু ফাংশনের মান হিসেবে প্রদান করা হয় (ফলাফল ভেক্টরে)।

MATCH

একটি অ্যারেতে আইটেমের আপেক্ষিক অবস্থান প্রদান করে, যা একটি সুনির্দিষ্ট মানের সাথে মিলে। ফাংশনটি নম্বর হিসেবে lookup_array-তে প্রাপ্ত মানের অবস্থান প্রদান করে।

MATCH(Search; LookupArray [; Type])

Search is the value which is to be searched for in the single-row or single-column array.

LookupArray হলো রেফারেন্স, যা খোঁজা হয়েছিল। একটি লুকআপ অ্যারে একটি একক সারি বা কলাম হতে পারে, বা একক সারি বা কলামের অংশ হতে পারে।

ধরন মান ১, ০, অথবা -১ গ্রহণ করতে পারে। যদি ধরন = ১ হয় অথবা যদি এই ঐচ্ছিক প্যারামিটার অনুপস্থিত থাকে, এইটি ধারনা করা হয় যে অনুসন্ধান বিন্যাসের প্রথম কলামটি আরোহী ক্রমানুসারে সজ্জিত হয়। যদি ধরন = -১ এইটি ধারনা করা হয় যে অনুসন্ধান বিন্যাসের প্রথম কলামটি অবরোহী ক্রমানুসারে সজ্জিত হয়। এইটি মাইক্রোসফ্ট এক্সেলে একই ফাংশনে সঙ্গতিপূর্ণ হয়।

If Type = 0, only exact matches are found. If the search criterion is found more than once, the function returns the index of the first matching value. Only if Type = 0 can you search for regular expressions (if enabled in calculation options) or wildcards (if enabled in calculation options).

If Type = 1 or the third parameter is missing, the index of the last value that is smaller or equal to the search criterion is returned. For Type = -1, the index of the last value that is larger or equal is returned.

=MATCH(200;D1:D100) এলাকা D1:D100 অনুসন্ধান করে, যা কলাম D দ্বারা সজ্জিত হয়, মান ২০০ এর জন্য। মানটিতে পৌঁছানোর সাথে সাথে, সারির ক্রম যার মধ্যে এইটি পাওয়া যায় তা প্রদান করে। যদি স্তম্বে অনুসন্ধান করার সময় একটি উচ্চতর মান পাওয়া যায়, পূর্বের সারির ক্রম প্রদান করে।

OFFSET

একটি প্রদত্ত রেফারেন্স হতে কিছু সারি এবং কলাম সংখ্যা দ্বারা ঘর অফসেটের মান প্রদান করে।

OFFSET(Reference; Rows; Columns [; Height [; Width]])

Reference হলো এমন একটি রেফারেন্স, যা হতে ফাংশন নতুন রেফারেন্স অনুসন্ধান করে।

সারি হলো সারির সংখ্যা যা দ্বারা reference টি উপরে অথবা নিচে সঠিক (ঋনাত্বক মান) করা হয়।

সারি হলো সারির সংখ্যা যা দ্বারা reference টি উপরে অথবা নিচে সঠিক (ঋনাত্বক মান) করা হয়।

Height (ঐচ্ছিক) হলো একটি এলাকার জন্য উল্লম্ব উচ্চতা, যা নতুন রেফারেন্স অবস্থানে শুরু হয়।

Width (ঐচ্ছিক) হলো একটি এলাকার জন্য অনুভূমিক প্রস্থ, যা নতুন রেফারেন্স অবস্থানে শুরু হয়।

আর্গুমেন্টের Height এবং Width অবশ্যই সারি বা কলামের শূন্য অথবা ঋনাত্মক গণনার নেতৃত্ব দেয়।

আর্গুমেন্টের Height এবং Width অবশ্যই সারি বা কলামের শূন্য অথবা ঋনাত্মক গণনার নেতৃত্ব দেয়।

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

=OFFSET(A1;2;2) C3 ঘরে মান প্রদান করে (A1 দুইটি সারি বা দুইটি কলাম নিচে সরানো হয়েছে)। যদি C3 ঘরে ১০০ থাকে, ফাংশনটি ১০০ প্রদান করে।

=OFFSET(B2:C3;1;1) B2:C3 এ রেফারেন্স প্রদান করে, যা এক সারি নিচে এবং এক কলাম ডানে (C3:D4) সরানো হয়েছে।

=OFFSET(B2:C3;-1;-1) B2:C3 তে একটি রেফারেন্স প্রদান করে যা বামে ১ সারি এবং এক কলাম (A1:B2) উপরে সরায়।

=OFFSET(B2:C3;0;0;3;4) B2:C3 তে একটি রেফারেন্স প্রদান করে যা ৩ সারি এবং ৪ কলাম (B2:E4) এ পুনরায় আকৃতিপ্রাপ্ত হয়।

=OFFSET(B2:C3;1;0;3;4) B2:C3 এ রেফারেন্স প্রদান করে, যার আকার নিচের দিকে এক সারি বৃদ্ধি করে ৩টি সারি এবং ৪টি কলামে (B2:E4) পরিবর্তন করা হয়েছে।

=SUM(OFFSET(A1;2;2;5;6)), এলাকার পরিমাণ নির্ধারণ করে, যা C3 ঘর থেকে শুরু হয় এবং উচ্চতা ৫টি সারি বিশিষ্ট এবং প্রস্থ ৬টি কলাম বিশিষ্ট (এলাকা=C3:H7)।

ROW

Returns the row number of a cell reference. If the reference is a cell, it returns the row number of the cell. If the reference is a cell range, it returns the corresponding row numbers in a one-column Array if the formula is entered as an array formula. If the ROW function with a range reference is not used in an array formula, only the row number of the first range cell will be returned.

ROW([Reference])

Reference হলো একটি ঘর, একটি এলাকা বা একটি এলাকার নাম।

যদি আপনি একটি রেফারেন্স নির্দেশ না করেন, সূত্র সন্নিবেশ করা হয় এমন ঘরের সারি সংখ্যা খোঁজা হবে। LibreOffice ক্যালক স্বয়ংক্রিয়ভাবে বর্তমান ঘরের রেফারেন্স নির্ধারণ করে।

=ROW(B3) ৩ প্রদান করে, কারণ রেফারেন্সটি টেবিলের তৃতীয় সারিকে উল্লেখ করে।

{=ROW(D5:D8)} একক-কলাম অ্যারে (৫, ৬, ৭, ৮) প্রদান করে, কারণ উল্লেখিত রেফারেন্সে ৫ হতে ৮ পর্যন্ত সারি রয়েছে।

=ROW(D5:D8) ৫ প্রদান করে, কারণ ROW ফাংশনটি অ্যারে সূত্র হিসেবে ব্যবহৃত হয় না এবং শুধুমাত্র রেফারেন্সের প্রথম সারির সংখ্যা প্রদান করা হয়।

{=ROW(A1:E1)} এবং =ROW(A1:E1) উভয়ই 1 প্রদান করে থাকে কারণ রেফারেন্সটি সারণির প্রথম সারি হিসেবে সারি ১ ধারণ করে থাকে। (কারণ একক সারি এলাকার শুধুমাত্র একটি সারি সংখ্যা রয়েছে, সূত্রটি অ্যারে সূত্র হিসেবে ব্যবহার করা হলে বা না হলে কোন পার্থক্য হয় না।)

=ROW() ৩ প্রদান করে, যদি সূত্রটি ৩নং সারিতে সন্নিবেশ করা হয়ে থাকে।

{=ROW(Rabbit)} একক-কলাম অ্যারে (১, ২, ৩) প্রদান করে, যদি এলাকার (C1:D3) নাম "Rabbit" হয়।

ROWS

রেফারেন্স বা অ্যারেতে সারির সংখ্যা প্রদান করে।

ROWS(Array)

Array হলো রেফারেন্স বা নামযুক্ত এলাকা, যার সর্বমোট সারি সংখ্যা নির্ধারণ করা হবে।

=Rows(B5) ১ প্রদান করে, কারণ একটি ঘরে শুধুমাত্র একটি সারি থাকে।

=ROWS(A10:B12) ৩ প্রদান করে।

=ROWS(Rabbit) ৩ প্রদান করে, যদি এলাকার (C1:D3) নাম "Rabbit" হয়।

SHEET

Returns the sheet number of either a reference or a string representing a sheet name. If you do not enter any parameters, the result is the sheet number of the spreadsheet containing the formula.

SHEET([Reference])

Reference হলো ঐচ্ছিক এবং ঘর, এলাকা বা একটি শীট নামের স্ট্রিংয়ের রেফারেন্স।

=SHEET(Sheet2.A1) returns 2 if Sheet2 is the second sheet in the spreadsheet document.

=SHEET("Sheet3") returns 3 if Sheet3 is the third sheet in the spreadsheet document.

SHEETS

রেফারেন্সের শীট সংখ্যা নির্ধারণ করে। যদি আপনি কোনো প্যারামিটার সন্নিবেশ না করান, এটা বর্তমান নথির শীট সংখ্যা প্রদান করে।

SHEETS([Reference])

উল্লেখ হলো একটি শীট বা এলাকার রেফারেন্স। এই প্যারামিটারটি ঐচ্ছিক।

=SHEETS(Sheet1.A1:Sheet3.G12) ৩ প্রদান করে, যদি নির্দেশিত ক্রমে শীট১, শীট২, এবং শীট৩ বিদ্যমান থাকে।

VLOOKUP

Vertical search with reference to adjacent cells to the right. This function checks if a specific value is contained in the first column of an array. The function then returns the value in the same row of the column named by Index. If the Sorted parameter is omitted or set to TRUE or one, it is assumed that the data is sorted in ascending order. In this case, if the exact Lookup is not found, the last value that is smaller than the criterion will be returned. If Sorted is set to FALSE or zero, an exact match must be found, otherwise the error Error: Value Not Available will be the result. Thus with a value of zero the data does not need to be sorted in ascending order.

=VLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

Lookup is the value of any type looked for in the first column of the array.

Array is the reference, which is to comprise at least as many columns as the number passed in Index argument.

Index হলো অ্যারের কলাম নম্বর, যাতে প্রদান করা হবে এমন মান রয়েছে। প্রথম কলামের নম্বর হলো ১।

SortedRangeLookup is an optional parameter that indicates whether the first column in the array contains range boundaries instead of plain values. In this mode, the lookup returns the value in the row with first column having value equal to or less than Lookup. E.g., it could contain dates when some tax value had been changed, and so the values represent starting dates of a period when a specific tax value was effective. Thus, searching for a date that is absent in the first array column, but falls between some existing boundary dates, would give the lower of them, allowing to find out the data being effective to the searched date. Enter the Boolean value FALSE or zero if the first column is not a range boundary list. When this parameter is TRUE or not given, the first column in the array must be sorted in ascending order. Sorted columns can be searched much faster and the function always returns a value, even if the search value was not matched exactly, if it is greater than the lowest value of the sorted list. In unsorted lists, the search value must be matched exactly. Otherwise the function will return #N/A with message: Error: Value Not Available.

You want to enter the number of a dish on the menu in cell A1, and the name of the dish is to appear as text in the neighboring cell (B1) immediately. The Number to Name assignment is contained in the D1:E100 array. D1 contains 100, E1 contains the name Vegetable Soup, and so forth, for 100 menu items. The numbers in column D are sorted in ascending order; thus, the optional Sorted parameter is not necessary.

নিম্নলিখিত সূত্রটি B1 এ সন্নিবেশ করান:

=VLOOKUP(A1;D1:E100;2)

A1 B1 এ একটি ক্রম আপনি সন্নিবেশ করানোর সাথে সাথে D1:E100 reference এর দ্বিতীয় কলামে ধারণকৃত সংশ্লিষ্ট টেক্সট প্রদর্শন করে। অস্তিত্বহীন সংখ্যা সন্নিবেশ নিচের পরবর্তী সংখ্যা সহকারে টেক্সট প্রদর্শন করে। এইটি নিবৃত্ত করার জন্য,সূত্রের শেষ প্যারামিটার হিসেবে FALSE সন্নিবেশ করান যাতে একটি ত্রুটি বার্তা উৎ‍পাদিত হয় যখন একটি অস্তিত্বহীন সংখ্যা সন্নিবেশ করানো হয়।