NETWORKDAYS.INTL

Връща броя работни дни между начална и крайна дата. Възможно е задаване на ежеседмични почивни дни и празници. Незадължителният параметър „Уикенд“ (число или низ) служи за задаване на неработните дни. Може да се зададе и списък с дати на празници. Седмичните неработни дни и зададените от потребителя празници се изключват от броя на работните дни.

Синтаксис

NETWORKDAYS.INTL(НачалнаДата; КрайнаДата [; [ Уикенд ] [; Празници ] ])

НачалнаДата е датата, от която започва изчислението. Ако началната дата е работен ден, той се включва в изчислението.

КрайнаДата е датата, до която завършва изчислението. Ако крайната дата е работен ден, той се включва в изчислението.

Уикенд е незадължителен параметър – число или низ, – който указва кои дни от седмицата се считат за почивни. Числовите стойности обозначават следните почивни дни:

Числата от 1 до 7 обозначават двудневни уикенди, а от 11 до 17 – еднодневни.

Число

Уикенд

1 или пропуснат

Събота и неделя

2

Неделя и понеделник

3

Понеделник и вторник

4

Вторник и сряда

5

Сряда и четвъртък

6

Четвъртък и петък

7

Петък и събота

11

Само неделя

12

Само понеделник

13

Само вторник

14

Само сряда

15

Само четвъртък

16

Само петък

17

Само събота


Низовете за „Уикенд“ позволяват друг начин за задаване на седмичните почивни дни. Низът трябва да съдържа седем знака: нули (0) за работните дни и единици (1) за почивните. Всеки знак отговаря на един ден, започвайки с понеделник. Допустими са само 1 и 0. "1111111" е невалиден низ и не трябва да се използва. Пример: низът "0000011" задава събота и неделя като почивни дни.

Празници е незадължителен списък с дати, които трябва да се смятат за неработни дни. Той може да бъде зададен в диапазон от клетки.

note

Ако въведете дата като част от формула, наклонените черти и тиретата, използвани като разделители, се интерпретират като аритметични операции. Затова датите, въведени по такъв начин, не се разпознават като дати и причиняват погрешни изчисления. За да предотвратите тълкуване на датите като части от формули, използвайте функцията DATE, например DATE(1954;7;20), или ограждайте датата в кавички и я изписвайте по стандарта ISO 8601, например "1954-07-20". Избягвайте зависими от локала формати като "07/20/54", защото може да се получи грешка в изчисленията, ако документът бъде зареден при различни настройки за локал.


tip

Еднозначно преобразуване е възможно за дати и часове по стандарта ISO 8601 в разширените им формати с разделители. Ако възникне грешка #VALUE!, изчистете полето Генериране на грешка #VALUE! в - LibreOffice Calc - Формула, бутон Подробности... под „Подробни настройки за изчисляване“, списъчно поле Преобразуване от текст в число.


note

Тази функция игнорира текстовете и празните клетки в диапазон с данни. Ако подозирате, че резултатът ѝ е погрешен, потърсете текст в диапазоните с данни. За да осветите текстовото съдържание в диапазон с данни, използвайте функционалността за осветяване на стойности.


Примери

Колко работни дни има между 15 декември 2016 г. и 14 януари 2017 г.? Нека началната дата се намира в C3, а крайната – в D3. Клетките от F3 до J3 съдържат 5 празнични дни за Коледа и Нова година във формат за дати: 24 декември 2016 г., 25 декември 2016 г., 26 декември 2016 г., 31 декември 2016 г. и 1 януари 2017 г.

=NETWORKDAYS.INTL(C3;D3;;F3:J3) връща 21 работни дни с подразбираната настройка за уикенд.

=NETWORKDAYS.INTL(C3;D3;11;F3:J3) връща 24 работни дни, като за седмични почивни дни се вземат само неделите.

Друг начин да зададете неделята като единствен седмичен почивен ден е низът "0000001" за „Уикенд“.

=NETWORKDAYS.INTL(C3;D3;"0000001";F3:J3) връща 24 работни дни, като за седмични почивни дни се вземат само неделите.

Функцията може да се използва без двата задължителни параметъра – седмични почивни дни и празници, – като те бъдат пропуснати:

=NETWORKDAYS.INTL(C3;D3) дава 22 работни дни.

Техническа информация

tip

Тази функция е налична от LibreOffice 4.3.


Тази функция не е част от стандарта Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format. Пространството от имена е

COM.MICROSOFT.NETWORKDAYS.INTL

Моля, подкрепете ни!