Услуга ScriptForge.Array

Предоставя набор от методи за манипулиране и трансформиране на едномерни масиви (вектори) и двумерни масиви (матрици). Това включва операции с множества, сортиране, импортиране и експортиране от текстови файлове.

Масиви с повече от две измерения не могат да се използват с методите в тази услуга, с изключение само на метода CountDims, който приема масиви с произволен брой измерения.

Елементите на масивите могат да съдържат стойности от всякакъв тип, включително (под)масиви.

Извикване на услугата

Преди да използвате услугата Array, библиотеката ScriptForge трябва да бъде заредена чрез:


      GlobalScope.BasicLibraries.LoadLibrary("ScriptForge")
   

Зареждането на библиотеката ще създаде обекта SF_Array, който може да бъде използван за извикване на методите на услугата Array.

Следващите откъси код показват различни начини за извикване на методите в услугата Array (методът Append е използван като пример):


      SF_Array.Append(...)
   

      Dim arr    :    arr = SF_Array
      arr.Append(...)
   

      Dim arr    :    arr = CreateScriptService("Array")
      arr.Append(...)
   
note

Методът CreateScriptService е наличен само след като сте заредили библиотеката ScriptForge.


Методи

Append
AppendColumn
AppendRow
Contains
ConvertToDictionary
CountDims
Difference
ExportToTextFile
ExtractColumn
ExtractRow

Flatten
ImportFromCSVFile
IndexOf
Insert
InsertSorted
Intersection
Join2D
Prepend
PrependColumn
PrependRow

RangeInit
Reverse
Shuffle
Slice
Sort
SortColumns
SortRows
Transpose
TrimArray
Union
Unique


tip

Първият аргумент на повечето методи е разглежданият обект масив. Той винаги се предава по адрес и остава непроменен. Методите като Append, Prepend и т.н. връщат нов обект масив след изпълнението си.


Append

Добавя елементите, изброени като аргументи, в края на входния масив.

Синтаксис:


      SF_Array.Append(Array_1D As Variant, arg0 As Variant, [arg1 As Variant], ...) As Variant
   

Параметри:

Array_1D: съществуващият масив, може да е празен.

arg0, ...: списък от елементи, които да бъдат добавени към Array_1D.

Пример:


      Sub Example_Append()
      Dim a As Variant
          a = SF_Array.Append(Array(1, 2, 3), 4, 5)
              ' (1, 2, 3, 4, 5)
      End Sub
   

AppendColumn

Добавя нова колона към дясната страна на двумерен масив. Полученият масив има същите долни граници като началния двумерен масив.

Синтаксис:


      SF_Array.AppendColumn(Array_2D As Variant, New_Column As Variant) As Variant
   

Параметри:

Array_2D: съществуващият масив, може да е празен. Ако масивът има само едно измерение, той се смята за първа колона на получения двумерен масив.

New_Column: едномерен масив с толкова елементи, колкото са редовете в Array_2D.

Пример:


      Sub Example_AppendColumn()
      Dim a As Variant, b As variant
          a = SF_Array.AppendColumn(Array(1, 2, 3), Array(4, 5, 6))
              ' ((1, 4), (2, 5), (3, 6))
          b = SF_Array.AppendColumn(a, Array(7, 8, 9))
              ' ((1, 4, 7), (2, 5, 8), (3, 6, 9))
          c = SF_Array.AppendColumn(Array(), Array(1, 2, 3))
              ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i
      End Sub
   

AppendRow

Добавя нов ред към долната страна на двумерен масив. Полученият масив има същите долни граници като началния двумерен масив.

Синтаксис:


      SF_Array.AppendRow(Array_2D As Variant, Row As Variant) As Variant
   

Параметри:

Array_2D: съществуващият масив, може да е празен. Ако масивът има само едно измерение, той се смята за първи ред на получения двумерен масив.

Row: едномерен масив с толкова елементи, колкото са колоните в Array_2D.

Пример:


      Sub Example_AppendRow()
      Dim a As Variant, b As variant
          a = SF_Array.AppendRow(Array(1, 2, 3), Array(4, 5, 6))
              '  ((1, 2, 3), (4, 5, 6))
          b = SF_Array..AppendRow(Array(), Array(1, 2, 3))
              ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i
      End Sub
   

Contains

Проверява дали едномерен масив съдържа определено число, текст или дата. Сравняването на текст може да бъде или да не бъде чувствително към регистъра.
Сортираните входни масиви трябва да бъдат запълнени хомогенно, тоест всички елементи трябва да са скалари от един и същ тип (елементи със стойност Empty и Null са забранени).
Резултатът от метода е непредсказуем, когато масивът е обявен като сортиран, но в действителност не е такъв.
Ако масивът е сортиран, се извършва двоично търсене, в противен случай той просто се обхожда от началото до края и елементите Empty и Null се игнорират.

Синтаксис:


      SF_Array.Contains(Array_1D, ToFind As Variant, [CaseSensitive As Boolean], [SortOrder As String]) As Boolean
   

Параметри:

Array_1D: масивът за обхождане.

ToFind: търсено число, дата или низ.

CaseSensitive: само за сравняване на низове, подразбира се False.

SortOrder: "ASC" (възходящо сортиран), "DESC" (низходящо сортиран) или "" (= несортиран, подразбира се)

Пример:


      Sub Example_Contains()
      Dim a As Variant
          a = SF_Array.Contains(Array("A","B","c","D"), "C", SortOrder := "ASC") ' True
          SF_Array.Contains(Array("A","B","c","D"), "C", CaseSensitive := True) ' False
      End Sub
   

ConvertToDictionary

Съхранява съдържанието на масив с две колони в обект от тип ScriptForge.Dictionary.
Ключът се извлича от първата колона, а елементът – от втората.

Синтаксис:


      SF_Array.ConvertToDictionary(Array_2D As Variant) As Variant
   

Параметри:

Array_1D: първата колона трябва да съдържа само низове с ненулева дължина, в произволен ред.

Пример:


      Sub Example_ConvertToDictionary()
      Dim a As Variant, b As Variant
          a = SF_Array.AppendColumn(Array("a", "b", "c"), Array(1, 2, 3))
          b = SF_Array.ConvertToDictionary(a)
          MsgBox b.Item("c") ' 3
      End Sub
   

CountDims

Преброява измеренията на масив. Резултатът може да е по-голям от две.
Ако аргументът не е масив, връща -1.
Ако масивът не е инициализиран, връща 0.

Синтаксис:


      SF_Array.CountDims(Array_ND As Variant) As Integer
   

Параметри:

Array_ND: разглежданият масив.

Пример:


      Sub Example_CountDims()
      Dim a(1 To 10, -3 To 12, 5)
          MsgBox SF_Array.CountDims(a) ' 3
      End Sub
   

Difference

Конструира множество във вид на индексиран от нула масив, като прилага операцията разлика върху двата входни масива. Резултатът включва елементите, които присъстват в първия масив, но не и във втория.
Резултатният масив е сортиран във възходящ ред.
Двата входни масива трябва да са попълнени хомогенно, елементите им трябва да са скалари от един и същ тип. Елементи със стойност Empty и Null са забранени.
Сравняването на текст може да бъде чувствително или нечувствително към регистъра.

Синтаксис:


      SF_Array.Difference(Array1_1D As Variant, Array2_1D As Variant[, CaseSensitive As Boolean]) As Variant
   

Параметри:

Array1_1D: едномерен отправен масив, чиито елементи се преглеждат за премахване.

Array2_1D: едномерен масив, чиито елементи се изваждат от първия входен масив.

CaseSensitive: само ако масивите са попълнени с низове, подразбира се False.

Пример:


      Sub Example_Difference()
      Dim a As Variant
          a = SF_Array.Difference(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
              ' ("A", "B")
      End Sub
   

ExportToTextFile

Записва всички елементи на масива последователно в текстов файл. Ако файлът вече съществува, той ще бъде заменен без предупреждение.

Синтаксис:


      SF_Array.ExportToTextFile(Array_1D As Variant, FileName As String, [Encoding As String]) As Boolean
   

Параметри:

Array_1D: масивът за експортиране. Той трябва да съдържа само низове.

FileName: името на текстовия файл с данните. Името се изразява според текущото свойство FileNaming на услугата SF_FileSystem. Подразбира се any (приемат се и форматът URL, и собственият формат на операционната система).

Encoding: знаковият набор, който трябва да се използва. Използвайте име от списъка със знакови набори на IANA. Имайте предвид, че LibreOffice може да не поддържа всички съществуващи знакови набори. Подразбира се "UTF-8".

Пример:


      Sub Example_ExportToTextFile()
          SF_Array.ExportToTextFile(Array("A","B","C","D"), "C:\Temp\A short file.txt")
      End Sub
   

ExtractColumn

Извлича указана колона от двуизмерен масив като нов масив.
Долната и горната му граница, LBound и UBound, са идентични на тези на първото измерение на входния масив.

Синтаксис:


      SF_Array.ExtractColumn(Array_2D As Variant, ColumnIndex As Long) As Variant
   

Параметри:

Array_2D: масивът, от който се извлича.

ColumnIndex: номерът на колоната за извличане – трябва да е в интервала [LBound, UBound].

Пример:


      Sub Example_ExtractColumn
         'Създава матрица 3x3: |1, 2, 3|
         '                      |4, 5, 6|
         '                      |7, 8, 9|
         Dim mat as Variant, col as Variant
         mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
         mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
         mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
         'Извлича третата колона: |3, 6, 9|
         col = SF_Array.ExtractColumn(mat, 2)
      End Sub
   

ExtractRow

Извлича указан ред от двуизмерен масив като нов масив.
Долната и горната му граница, LBound и UBound, са идентични на тези на второто измерение на входния масив.

Синтаксис:


      SF_Array.ExtractRow(Array_2D As Variant, RowIndex As Long) As Variant
   

Параметри:

Array_2D: масивът, от който се извлича.

RowIndex: номерът на реда за извличане – трябва да е в интервала [LBound, UBound].

Пример:


      Sub Example_ExtractRow
         'Създава матрица 3x3: |1, 2, 3|
         '                      |4, 5, 6|
         '                      |7, 8, 9|
         Dim mat as Variant, row as Variant
         mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
         mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
         mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
         'Извлича първия ред: |1, 2, 3|
         row = SF_Array.ExtractRow(mat, 0)
      End Sub
   

Flatten

Подрежда всички единични елементи на масив и всички елементи на подмасивите му в един нов масив без подмасиви. Празните подмасиви се игнорират, а подмасивите с повече от едно измерение не се изравняват.

Синтаксис:


      SF_Array.Flatten(Array_1D As Variant) As Variant
   

Параметри:

Array_1D: съществуващият масив, може да е празен.

Пример:


      Sub Example_Flatten()
      Dim a As Variant
          a = SF_Array.Flatten(Array(Array(1, 2, 3), 4, 5))
              ' (1, 2, 3, 4, 5)
      End Sub
   
tip

Можете да използвате метода Flatten заедно с други методи, като Append или Prepend, за да конкатенирате съвкупност от едномерни масиви в един едномерен масив.


Пример:

Следва пример как методите Flatten и Append могат да се комбинират за конкатениране на три масива.


      Sub Concatenate_Example
         'Създава три масива за този пример
         Dim a as Variant, b as Variant, c as Variant
         a = Array(1, 2, 3)
         b = Array(4, 5)
         c = Array(6, 7, 8, 9)
         'Конкатенира трите масива в един едномерен масив
         Dim arr as Variant
         arr = SF_Array.Flatten(SF_Array.Append(a, b, c))
         '(1, 2, 3, 4, 5, 6, 7, 8, 9)
      End Sub
   

ImportFromCSVFile

Импортира данните от файл със стойности, разделени със запетая (CSV). Запетаята може да бъде заменена с произволен друг знак.

Приложимият формат CSV е описан в документа IETF Common Format and MIME Type for CSV Files.

Всеки ред във файла съдържа по един пълен запис (не се разрешава разделяне на редове на части).
Последователности от рода на \n, \t, ... остават непроменени. За тяхната обработка използвайте метода SF_String.Unescape().

Методът връща двуизмерен масив, чиито редове съответстват на записите, прочетени от файла, а колоните – на полета от записите. Не се проверява дали типовете на полетата са съгласувани в рамките на колоните. Прави се опит за разпознаване на числа и дати.

Ако някой ред съдържа повече или по-малко полета от първия ред във файла, ще възникне изключение. Празните редове обаче просто се игнорират. Ако размерът на файла надхвърля ограничението за брой на елементите (вижте в кода), ще бъде издадено предупреждение и масивът ще бъде съкратен.

Синтаксис:


      SF_Array.ImportFromCSVFile(FileName As String, [Delimiter As String], [DateFormat As String]) As Variant
   

Параметри:

FileName: името на текстовия файл с данните. Името се изразява според текущото свойство FileNaming на услугата SF_FileSystem. Подразбира се any (приемат се и форматът URL, и собственият формат на операционната система).

Delimiter: единичен знак, обикновено, запетая, точка и запетая или знак за табулация. Подразбира се ",".

DateFormat: когато DateFormat е "YYYY-MM-DD", "DD-MM-YYYY" или "MM-DD-YYYY", датите се обработват по специален начин. Тирето (-) може да е заменено с точка (.), наклонена черта (/) или интервал. Другите формати на дати се игнорират. Датите с подразбирана стойност "" се смятат за обикновен текст.

Пример:

Нека е даден следният CSV файл:


      Name,DateOfBirth,Address,City
      Anna,2002/03/31,"Rue de l'église, 21",Toulouse
      Fred,1998/05/04,"Rue Albert Einstein, 113A",Carcassonne
   

      Sub Example_ImportFromCSVFile()
      Dim a As Variant
          a = SF_Array.ImportFromCSVFile("C:\Temp\myFile.csv", DateFormat := "YYYY/MM/DD")
          MsgBox a(0, 3)    ' City
          MsgBox TypeName(a(1, 2))    ' Date
          MsgBox a(2, 2)    ' Rue Albert Einstein, 113A
      End Sub
   

IndexOf

Претърсва едномерен масив за число, низ или дата. Сравняването на текст може да бъде или да не бъде чувствително към регистъра.
Ако масивът е сортиран, той трябва да е запълнен хомогенно, тоест всички елементи трябва да са скалари от един и същ тип (елементи със стойност Empty и Null са забранени).
Резултатът от метода е непредсказуем, когато масивът е обявен като сортиран, но в действителност не е такъв.
Ако масивът е сортиран, се извършва двоично търсене. В противен случай той просто се обхожда от началото до края и елементите Empty и Null се игнорират.

Ако търсенето е неуспешно, методът връща LBound(input array) - 1.

Синтаксис:


      SF_Array.IndexOf(Array_1D, ToFind As Variant, [CaseSensitive As Boolean], [SortOrder As String]) As Long
   

Параметри:

Array_1D: масивът за обхождане.

ToFind: търсено число, дата или низ.

CaseSensitive: само за сравняване на низове, подразбира се False.

SortOrder: "ASC", "DESC" или "" (= несортиран, подразбира се).

Пример:


      Sub Example_IndexOf()
          MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", SortOrder := "ASC") ' 2
          MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", CaseSensitive := True) ' -1
      End Sub
   

Insert

Вмъква преди даден индекс на входния масив елементите, изброени като аргументи.
Аргументите се вмъкват без проверка. Всеки от тях може да бъде или скалар от произволен тип, или подмасив.

Синтаксис:


      SF_Array.Insert(Array_1D As Variant, Before As Long, arg0 As Variant, [arg1 As Variant], ...) As Variant
   

Параметри:

Array_1D: съществуващият масив, може да е празен.

Before: индексът, преди който да се вмъква; трябва да е в интервала [LBound, UBound + 1].

arg0, ...: списък от елементи, които да бъдат вмъкнати в Array_1D.

Пример:


      Sub Example_Insert()
      Dim a As Variant
          a = SF_Array.Insert(Array(1, 2, 3), 2, "a", "b")
              ' (1, 2, "a", "b", 3)
      End Sub
   

InsertSorted

Вмъква нов елемент на правилното място в сортиран масив.
Масивът трябва да е попълнен хомогенно, тоест всичките му елементи трябва да са скалари от един и същ тип.
Забранени са елементи Empty and Null.

Синтаксис:


      SF_Array.InsertSorted(Array_1D As Variant, Item As Variant, SortOrder As String, CaseSensitive As Boolean) As Variant
   

Параметри:

Array_1D: масивът, който да бъде сортиран.

Item: скаларната стойност, която да бъде вмъкната, от същия тип като съществуващите елементи на масива.

SortOrder: "ASC" (подразбира се) или "DESC".

CaseSensitive: само за сравняване на низове, подразбира се False.

Пример:


      Sub Example_InsertSorted()
      Dim a As Variant
          a = SF_Array.InsertSorted(Array("A", "C", "a", "b"), "B", CaseSensitive := True)
              ' ("A", "B", "C", "a", "b")
      End Sub
   

Intersection

Конструира множество във вид на индексиран от нула масив, като прилага операцията сечение върху двата входни масива. Резултатът включва елементите, които присъстват и в двата масива.
Резултатният масив е сортиран във възходящ ред.
Двата входни масива трябва да са попълнени хомогенно, с други думи, елементите им трябва да са скалари от един и същ тип. Елементи със стойност Empty и Null са забранени.
Сравняването на текст може да бъде чувствително или нечувствително към регистъра.

Синтаксис:


      SF_Array.Intersection(Array1_1D As Variant, Array2_1D As Variant[, CaseSensitive As Boolean]) As Variant
   

Параметри:

Array1_1D: първият входен масив.

Array2_1D: вторият входен масив.

CaseSensitive: отнася се само за масиви, попълнени с текстови елементи, подразбира се False.

Пример:


      Sub Example_Intersection()
      Dim a As Variant
          a = SF_Array.Intersection(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
              ' ("C", "b")
      End Sub
   

Join2D

Обединява двумерен масив с два разделителя, един за колоните и един за редовете.

Синтаксис:


      SF_Array.Join2D(Array_2D As Variant, ColumnDelimiter As String, RowDelimiter As String, Quote As Boolean) As String
   

Параметри:

Array_2D: всеки елемент трябва да е текст, число, дата или булева стойност.
Датите се преобразуват във формата YYYY-MM-DD hh:mm:ss.
Невалидните елементи се заместват с низ с нулева дължина.

ColumnDelimiter: разделя колоните (подразбира се Tab/Chr(9)).

RowDelimiter: разделя редовете (подразбира се LineFeed/Chr(10)).

Quote: ако е True, низовете се защитават с двойни кавички. Подразбира се False.

Пример:


      Sub Example_Join2D()
      -                     | 1, 2, "A", [2020-02-29], 5      |
      -    SF_Array.Join_2D(| 6, 7, "this is a string", 9, 10 |, ",", "/")
      -            ' "1,2,A,2020-02-29 00:00:00,5/6,7,this is a string,9,10"
      End Sub
   

Prepend

Добавя в началото на входния масив елементите, изброени като аргументи.

Синтаксис:


      SF_Array.Prepend(Array_1D As Variant, arg0 As Variant, [arg1 As Variant], ...) As Variant
   

Параметри:

Array_1D: съществуващият масив, може да е празен.

arg0, ...: списък от елементи, които да бъдат добавени в началото на Array_1D.

Пример:


      Sub Example_Prepend()
      Dim a As Variant
          a = SF_Array.Prepend(Array(1, 2, 3), 4, 5)
              ' (4, 5, 1, 2, 3)
      End Sub
   

PrependColumn

Добавя нова колона към лявата страна на двумерен масив. Полученият масив има същите долни граници като началния двумерен масив.

Синтаксис:


      SF_Array.PrependColumn(Array_2D As Variant, Column As Variant) As Variant
   

Параметри:

Array_2D: съществуващият масив, може да е празен. Ако масивът има само едно измерение, той се смята за последна колона на получения двумерен масив.

Column: едномерен масив с толкова елементи, колкото са редовете в Array_2D.

Пример:


      Sub Example_PrependColumn()
      Dim a As Variant, b As variant
          a = SF_Array.PrependColumn(Array(1, 2, 3), Array(4, 5, 6))
              ' ((4, 1), (5, 2), (6, 3))
          b = SF_Array.PrependColumn(Array(), Array(1, 2, 3))
              ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i
      End Sub
   

PrependRow

Добавя нов ред в началото на двумерен масив. Полученият масив има същите долни граници като началния двумерен масив.

Синтаксис:


      SF_Array.PrependRow(Array_2D As Variant, Row As Variant) As Variant
   

Параметри:

Array_2D: съществуващият масив, може да е празен. Ако масивът има само едно измерение, той се смята за последен ред на получения двумерен масив.

Row: едномерен масив с толкова елементи, колкото са редовете в Array_2D.

Пример:


      Sub Example_PrependRow()
      Dim a As Variant, b As variant
          a = SF_Array.PrependRow(Array(1, 2, 3), Array(4, 5, 6))
              ' ((4, 5, 6), (1, 2, 3))
          b = SF_Array.PrependRow(Array(), Array(1, 2, 3))
              ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i
      End Sub
   

RangeInit

Инициализира нов индексиран от нула масив с числови стойности.

Синтаксис:


      SF_Array.RangeInit(From As [number], UpTo As [number] [, ByStep As [number]]) As Variant
   

Параметри:

From: стойност на първия елемент.

UpTo: последният елемент не трябва да надвишава UpTo.

ByStep: разликата между първите два последователни елемента (подразбира се 1).

Пример:


      Sub Example_RangeInit()
      Dim a As Variant
          a = SF_Array.RangeInit(10, 1, -1)
              ' (10, 9, 8, 7, 6, 5, 4, 3, 2, 1)
      End Sub
   

Reverse

Връща обърнатия едномерен входен масив.

Синтаксис:


      SF_Array.Reverse(Array_1D As Variant) As Variant
   

Параметри:

Array_1D: масивът, който да бъде обърнат.

Пример:


      Sub Example_Reverse()
      Dim a As Variant
          a = SF_Array.Reverse(Array("a", 2, 3, 4))
              ' (4, 3, 2, "a")
      End Sub
   

Shuffle

Връща случайна пермутация на едномерен масив.

Синтаксис:


      SF_Array.Shuffle(Array_1D As Variant) As Variant
   

Параметри:

Array_1D: масивът, който да бъде разбъркан.

Пример:


      Sub Example_Shuffle()
      Dim a As Variant
          a = SF_Array.Shuffle(Array(1, 2, 3, 4))
              ' Непредсказуемо
      End Sub
   

Slice

Връща подмножество на едномерен масив.

Синтаксис:


      SF_Array.Slice(Array_1D As Variant, From As Long, [UpTo As Long]) As Variant
   

Параметри:

Array_1D: масивът, който да бъде разрязан.

From: долният индекс в Array_1D на подмасива, който да бъде извлечен (включително From).

UpTo: горният индекс в Array_1D на подмасива, който да бъде извлечен (включително UpTo). Подразбира се горната граница на Array_1D. Ако UpTo < From, върнатият масив е празен.

Пример:


      Sub Example_Slice()
      Dim a As Variant
          a = SF_Array.Slice(Array(1, 2, 3, 4, 5), 1, 3) ' (2, 3, 4)
      End Sub
   

Sort

Сортира едномерен масив във възходящ или низходящ ред. Сравняването на текст може да бъде чувствително или нечувствително към регистъра.
Масивът трябва да бъде запълнен хомогенно, тоест всички елементи трябва да бъдат скалари от един и същ тип.
Не се допускат елементи Empty и Null. По конвенция Empty < Null < всяка друга скаларна стойност.

Синтаксис:


      SF_Array.Sort(Array_1D As Variant, SortOrder As String, CaseSensitive As Boolean) As Variant
   

Параметри:

Array_1D: масивът, който да бъде сортиран.

SortOrder: "ASC" (подразбира се) или "DESC".

CaseSensitive: само за сравняване на низове, подразбира се False.

Пример:


      Sub Example_Sort()
      Dim a As Variant
          a = SF_Array.Sort(Array("a", "A", "b", "B", "C"), CaseSensitive := True)
              ' ("A", "B", "C", "a", "b")
      End Sub
   

SortColumns

Връща пермутация на колоните на двумерен масив, сортирани според стойностите на даден ред.
Редът трябва да бъде запълнен хомогенно, тоест всички елементи трябва да бъдат скалари от един и същ тип.
Не се допускат елементи Empty и Null. По конвенция Empty < Null < всяка друга скаларна стойност.

Синтаксис:


      SF_Array.SortColumns(Array_1D As Variant, RowIndex As Long, SortOrder As String, CaseSensitive As Boolean) As Variant
   

Параметри:

Array_1D: масивът, който да бъде сортиран.

RowIndex: индексът на реда, по който да се сортират колоните.

SortOrder: "ASC" (подразбира се) или "DESC".

CaseSensitive: само за сравняване на низове, подразбира се False.

Пример:


      Sub Example_SortColumns()
      -                         | 5, 7, 3 |            ' | 7, 5, 3 |
      -    SF_Array.SortColumns(| 1, 9, 5 |, 2, "ASC") ' | 9, 1, 5 |
      -                         | 6, 1, 8 |            ' | 1, 6, 8 |
      End Sub
   

SortRows

Връща пермутация на редовете на двумерен масив, сортирани според стойностите на дадена колона.
Колоната трябва да бъде запълнена хомогенно, тоест всички елементи трябва да бъдат скалари от един и същ тип.
Не се допускат елементи Empty и Null. По конвенция Empty < Null < всяка друга скаларна стойност.

Синтаксис:


      SF_Array.SortRows(Array_1D As Variant, ColumnIndex As Long, SortOrder As String, CaseSensitive As Boolean) As Variant
   

Параметри:

Array_1D: масивът, който да бъде сортиран.

RowIndex: индексът на колоната, по която да се сортират редовете.

SortOrder: "ASC" (подразбира се) или "DESC".

CaseSensitive: само за сравняване на низове, подразбира се False.

Пример:


      Sub Example_SortRows()
      -                      | 5, 7, 3 |            ' | 1, 9, 5 |
      -    SF_Array.SortRows(| 1, 9, 5 |, 2, "ASC") ' | 5, 7, 3 |
      -                      | 6, 1, 8 |            ' | 6, 1, 8 |
      End Sub
   

Transpose

Разменя редовете и колоните в двумерен масив.

Синтаксис:


      SF_Array.Transpose(Array_2D As Variant) As Variant
   

Параметри:

Array_2D: масивът, който да бъде транспониран.

Пример:


      Sub Example_Transpose()
      -                       | 1, 2 |  ' | 1, 3, 5 |
      -    SF_Array.Transpose(| 3, 4 |) ' | 2, 4, 6 |
      -                       | 5, 6 |
      End Sub
   

TrimArray

Премахва от едномерен масив всички елементи Null, Empty и с нулева дължина.
Елементите низове се подрязват с функцията на LibreOffice Basic Trim().

Синтаксис:


      SF_Array.TrimArray(Array_1D As Variant) As Variant
   

Параметри:

Array_1D: масивът за обхождане.

Пример:


      Sub Example_TrimArray()
      Dim a As Variant
          a = SF_Array.TrimArray(Array("A","B",Null," D "))
              ' ("A","B","D")
      End Sub
   

Union

Конструира множество във вид на индексиран от нула масив, като прилага операцията обединение върху двата входни масива. Резултатът включва елементите, които присъстват в поне един от двата масива.
Резултатният масив е сортиран във възходящ ред.
Двата входни масива трябва да са попълнени хомогенно, с други думи, елементите им трябва да са скалари от един и същ тип. Елементи със стойност Empty и Null са забранени.
Сравняването на текст може да бъде чувствително или нечувствително към регистъра.

Синтаксис:


      SF_Array.Union(Array1_1D As Variant, Array2_1D As Variant[, CaseSensitive As Boolean]) As Variant
   

Параметри:

Array1_1D: първият входен масив.

Array2_1D: вторият входен масив.

CaseSensitive: само ако масивите са попълнени с низове, подразбира се False.

Пример:


      Sub Example_Union()
      Dim a As Variant
          a = SF_Array.Union(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
              ' ("A", "B", "C", "Z", "b")
      End Sub
   

Unique

Конструира множество от уникални стойности на базата на входния масив.
Входният масив трябва да е запълнен хомогенно, тоест елементите му трябва да са скалари от един и същ тип. Елементи Empty и Null са забранени.
Сравняването на текстове може да бъде чувствително или нечувствително към регистъра.

Синтаксис:


      SF_Array.Unique(Array_1D As Variant, CaseSensitive As Boolean]) As Variant
   

Параметри:

Array_1D: входният масив.

CaseSensitive: само ако масивът е попълнен с текстове, подразбира се False.

Пример:


      Sub Example_Unique()
      Dim a As Variant
          a = SF_Array.Unique(Array("A", "C", "A", "b", "B"), CaseSensitive := True)
              '  ("A", "B", "C", "b")
      End Sub
   
warning

В ScriptForge всички подпрограми или идентификатори на Basic с префикс „_“ са запазени за вътрешна употреба. Те не са предназначени за използване в макроси на Basic.


Моля, подкрепете ни!