財務関数 2

From LibreOffice Help
Jump to: navigation, search

挿入 → 関数 → 分類項目 財務

財務関数 1 へ

財務関数3へ

YIELDMAT

満期日に利息が支払われる証券の利回りを返します。

構文

YIELDMAT(受領日; 満期日; 発行; 利率; 取得価額; 基準)

受領日 は、証券の購入日です。

満期日 は、証券が満期になる (満了する) 日付です。

発行 は、証券の発行日です。

利率 は、発行日の証券の利率です。

取得価額 は、額面の 100 通貨単位あたりの証券の取得価額 (購入価額) です。

基準 はオプションのリストから選択され、どのように年が計算されるかを示します。

基準 計算
0 または指定なし US 方式 (NASD) 、30日×12ヶ月
1 ひと月または1年の正確な日数
2 ひと月の正確な日数、1年は 360 日
3 ひと月の正確な日数、1年は 365 日
4 ヨーロッパ方式、30日×12ヶ月

証券を 1999 年 3 月 15 日に購入しました。満期日は 1999 年 11 月 3 日です。発行日は 1998 年 11 月 8 日です。利率は 6.25% で、取得価額は 100.0123 単位です。基準は 0 です。利回りを求めます。

=YIELDMAT("1999-03-15"; "1999-11-03"; "1998-11-08"; 0.0625; 100.0123; 0) は、0.060954、つまり 6.0954 パーセントを返します。

YIELDDISC

割引債の年利回りを返します。

構文

YIELDDISC(受領日; 満期日; 取得価額; 償還価額; 基準)

受領日 は、証券の購入日です。

満期日 は、証券が満期になる (満了する) 日付です。

取得価額 は、額面の 100 通貨単位あたりの証券の取得価額 (購入価額) です。

償還価額 は、額面の 100 通貨単位あたりの償還価値です。

基準 はオプションのリストから選択され、どのように年が計算されるかを示します。

基準 計算
0 または指定なし US 方式 (NASD) 、30日×12ヶ月
1 ひと月または1年の正確な日数
2 ひと月の正確な日数、1年は 360 日
3 ひと月の正確な日数、1年は 365 日
4 ヨーロッパ方式、30日×12ヶ月

割引債を 1999 年 2 月 15 日に購入しました。満期日は 1999 年 3 月 1 日です。取得価額は、額面 100 単位あたり 99.795 通貨単位で、償還価値は 100 単位です。基準は 2 です。利回りを求めます。

=YIELDDISC("1999-02-15"; "1999-03-01"; 99.795; 100; 2) は、0.052823、つまり 5.2823 パーセントを返します。

YIELD

利息が定期的に支払われる証券の利回りを返します。

構文

YIELD(受領日; 満期; 利率; 取得価額; 償還価額; 利息支払回数; 基準)

受領日 は、証券の購入日です。

満期日 は、証券が満期になる (満了する) 日付です。

利率 は、年利率です。

取得価額 は、額面の 100 通貨単位あたりの証券の取得価額 (購入価額) です。

償還価額 は、額面の 100 通貨単位あたりの償還価値です。

利息支払回数 は、年間の利息支払回数です。1、2、または 4 になります。

基準 はオプションのリストから選択され、どのように年が計算されるかを示します。

基準 計算
0 または指定なし US 方式 (NASD) 、30日×12ヶ月
1 ひと月または1年の正確な日数
2 ひと月の正確な日数、1年は 360 日
3 ひと月の正確な日数、1年は 365 日
4 ヨーロッパ方式、30日×12ヶ月

証券を 1999 年 02 月 15 日に購入し、満期日は 2007 年 11 月 15 日です。利率は 5.75% です。取得価額は、額面 100 単位あたり 95.04287 通貨単位で、償還価値は 100 単位です。利息は半年に一度支払われ (年間の利息支払回数は 2 回)、基準は 0 です。利回りを求めます。

=YIELD("1999-02-15"; "2007-11-15"; 0.0575 ;95.04287; 100; 2; 0) は、0.065、つまり 6.50 パーセントを返します。

TBILLYIELD

米国財務省短期証券 (TB) の利回りを返します。

構文

TBILLYIELD(受領日; 満期日; 取得価額)

受領日 は、証券の購入日です。

満期日 は、証券が満期になる (満了する) 日付です。

取得価額 は、額面の 100 通貨単位あたりの米国財務省短期証券 (TB) の取得価額 (購入価額) です。

受領日: 1999年3月31日、満期日: 1999年6月1日、 現在価値: $98.45

証券の利回り計算は次のようになります:

=TBILLYIELD("1999-03-31";"1999-06-01"; 98.45) は、0.091417、つまり 9.1417 パーセントを返します。

TBILLPRICE

米国財務省短期証券 (TB) の額面 100 貨幣単位当たりの価格を返します。

構文

TBILLPRICE(受領日; 満期日; 割引)

受領日 は、証券の購入日です。

満期日 は、証券が満期になる (満了する) 日付です。

割引 は、証券購入時の割引率です。

受領日: 1999年3月31日、満期日: 1999年6月1日、 割引率: 9 パーセント。

証券の価格計算は次のようになります:

=TBILLPRICE("1999-03-31";"1999-06-01"; 0.09) は、98.45 を返します。

TBILLEQ

Calculates the annual return on a treasury bill. A treasury bill is purchased on the settlement date and sold at the full par value on the maturity date, that must fall within the same year. A discount is deducted from the purchase price.

構文

TBILLEQ(受領日; 満期日; 割引)

受領日 は、証券の購入日です。

満期日 は、証券が満期になる (満了する) 日付です。

割引 は、証券購入時の割引率です。

受領日: 1999年3月31日、満期日: 1999年6月1日、割引率: 9.14 パーセント。

計算は次のようになります。:

=TBILLEQ("1999-03-31";"1999-06-01"; 0.0914) は、0.094151、つまり 9.4151 パーセントを返します。

SLN

資産の 1 期間あたりの定額減価償却費を計算します。償却期間中の減価償却費は一定です。

構文

SLN(取得価額; 残存; 耐用年数)

取得価額 は、資産を購入した時点での価格です。

残存価額 は、減価償却後の資産の価格です。

耐用年数 は、資産の償却期間数を決定する償却期間です。

取得価格 50,000 貨幣単位の事務所設備を7年間で償却するとします。残存価格の見積もりは 3,500 貨幣単位です。

=SLN(50000;3,500;84) = 553.57 通貨単位。このオフィス機器の定期月額減価償却費は、553.57 通貨単位になります。

PRICEMAT

満期日に利息が支払われる証券に対して、額面 100 貨幣単位当たりの価格を返します。

構文

PRICEMAT(受領日; 満期日; 発行; 利率; 利回り; 基準)

受領日 は、証券の購入日です。

満期日 は、証券が満期になる (満了する) 日付です。

発行 は、証券の発行日です。

利率 は、発行日の証券の利率です。

利回り は、証券の年利回りです。

基準 はオプションのリストから選択され、どのように年が計算されるかを示します。

基準 計算
0 または指定なし US 方式 (NASD) 、30日×12ヶ月
1 ひと月または1年の正確な日数
2 ひと月の正確な日数、1年は 360 日
3 ひと月の正確な日数、1年は 365 日
4 ヨーロッパ方式、30日×12ヶ月

受領日: 1999年2月15日、満期日: 1999年4月13日、 発行日: 1998年11月11日。利率: 6.1 パーセント、 利回り: 6.1 パーセント、基準: 30/360 = 0。

価格の計算は次のようになります:

=PRICEMAT("1999-02-15";"1999-04-13";"1998-11-11"; 0.061; 0.061;0) は、99.98449888 を返します。

PRICEDISC

無利息証券に対して、額面 100 貨幣単位当たりの価格を返します。

構文

PRICEDISC(受領日; 満期日; 割引; 償還価額; 基準)

受領日 は、証券の購入日です。

満期日 は、証券が満期になる (満了する) 日付です。

割引 は、証券の割引率です。

償還価額 は、額面の 100 通貨単位あたりの償還価値です。

基準 はオプションのリストから選択され、どのように年が計算されるかを示します。

基準 計算
0 または指定なし US 方式 (NASD) 、30日×12ヶ月
1 ひと月または1年の正確な日数
2 ひと月の正確な日数、1年は 360 日
3 ひと月の正確な日数、1年は 365 日
4 ヨーロッパ方式、30日×12ヶ月

証券を 1999 年 02 月 15 日に購入し、満期日は 1999 年 3 月 1 日です。割引率は、5.25% です。償還価値は 100 です。基準 2 を基に計算すると、取得価額の割引率は次のようになります。

=PRICEDISC("1999-02-15"; "1999-03-01"; 0.0525; 100; 2) は、99.79583 を返します。

PRICE

定期的に利息が支払われる証券に対して、100 貨幣単位当たりの価格を予測利回りの関数として返します。

構文

PRICE(受領日; 満期; 利率; 利回り; 償還価額; 利息支払回数; 基準)

受領日 は、証券の購入日です。

満期日 は、証券が満期になる (満了する) 日付です。

利率 は、名目年利率 (利札利率) です

利回り は、証券の年利回りです。

償還価額 は、額面の 100 通貨単位あたりの償還価値です。

利息支払回数 は、年間の利息支払回数です。1、2、または 4 になります。

基準 はオプションのリストから選択され、どのように年が計算されるかを示します。

基準 計算
0 または指定なし US 方式 (NASD) 、30日×12ヶ月
1 ひと月または1年の正確な日数
2 ひと月の正確な日数、1年は 360 日
3 ひと月の正確な日数、1年は 365 日
4 ヨーロッパ方式、30日×12ヶ月

証券を 1999 年 02 月 15 日に購入し、満期日は 2007 年 11 月 15 日です。名目利率は 5.75% です。利回りは 6.5% です。償還価値は 100 通貨単位です。利息は半年に一度支払われます (年間の利息支払回数は 2 回)。基準 0 を基に計算すると、取得価額は次のようになります。

=PRICE("1999-02-15"; "2007-11-15"; 0.0575; 0.065; 100; 2; 0) は、95.04287 を返します。

PPMT

定額の支払いが定期的に行われ、利率が一定である場合に、指定された期間において、投資に支払われる元金を返します。

構文

PPMT(利率; 期間; NPer; PV; FV; タイプ)

利率 は期間の利率を指定します。

期間 は、償却期間です。P = 1 は最初、P = NPer は最後の期間を示します。

NPer は、年金が支払われる期間の合計です。

PV は、一連の支払いの中での現在の価額です。

FV (オプション) は、希望の (将来) 価値です。

タイプ (オプション) は、支払期日を定義します。F = 1 は期間の最初での支払い、F = 0 は期間の最後での支払いです。

LibreOffice Calc の関数では、「オプション」としてマークされているパラメーターを省略できるのは、その後にパラメーターが続かない場合のみです。たとえば、4 つのパラメーターがあり、その最後 2 つのパラメーターが「オプション」としてマークされている関数では、パラメーター 4 を省略したり、パラメーター 3 と 4 を省略することはできますが、パラメーター 3 のみを省略することはできません。

現在価値 5,000 貨幣単位を 年間 8.75% の利率で 3 年間続けて月ごとに支払う場合の、1 回の支払金額を求めます。支払は期首に行い、最終残存額は 8,000 貨幣単位とします。

=PPMT(8.75%/12;1;36;5000;8000;1) = -350.99 通貨単位。

PMT

利率が一定な投資の定期支払額 (年賦) を計算します。

構文

PMT(利率; NPer; PV; FV; タイプ)

利率 は期間の利率を指定します。

NPer は、年金が支払われる期間数です。

PV は、一連の支払いの現在の価額 (現金額) です。

FV (オプション) は、定期支払いの終了時に達成される目標価値 (将来価値) です。

タイプ (オプション) は、定期的に行われる支払いの期日を指定します。タイプ = 1 は各期の最初の支払い、タイプ = 0 は各期の最後の支払いです。

LibreOffice Calc の関数では、「オプション」としてマークされているパラメーターを省略できるのは、その後にパラメーターが続かない場合のみです。たとえば、4 つのパラメーターがあり、その最後 2 つのパラメーターが「オプション」としてマークされている関数では、パラメーター 4 を省略したり、パラメーター 3 と 4 を省略することはできますが、パラメーター 3 のみを省略することはできません。

3 年間で現在価値 25,000 貨幣単位を 1.99% の利率で支払う場合の、1 回の支払額を求めます。36 ヶ月、つまり 36 回支払いがあり、各支払い期間の利率は 1.99%/12 です。

=PMT(1.99%/12;36;25000) = -715.96 通貨単位。したがって、月ごとに支払う場合の 1 回の支払金額は、715.96 通貨単位です。

NPV

Returns the present value of an investment based on a series of periodic cash flows and a discount rate. To get the net present value, subtract the cost of the project (the initial cash flow at time zero) from the returned value.

If the payments take place at irregular intervals, use the XNPV function.

構文

NPV(利率; 値 1; 値 2; ...)

利率 は、期間の割引率です。

値 1;... は最高 30 個で、預け入れまたは引き出しを表します。

割引率 8.75% で定期的に 10、20、30 貨幣単位を支払う場合の正味現在価値を求めます。時間 0 のとき、-40 貨幣単位で費用が支払われます。

=NPV(8.75%;10;20;30) = 49.43 通貨単位。現在の正味価値は、戻り値から 40 通貨単位の初期コストを引いた値なので、9.43 通貨単位です。

NOMINAL_ADD

指定された実効年利率と、1 年当たりの複利計算回数を元に、名目年利率を返します。

Note.png The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.

構文

NOMINAL_ADD(実質利率; NPerY)

実効利率 は、実効年利率です。

NPerY は、年間の利息支払回数です。

実効利率 5.3543%、四半期ごとの利息支払の場合の名目年利率を求めます。

=NOMINAL_ADD(5.3543%;4) は、0.0525、つまり 5.25% を返します。

NOMINAL

開始日と 1 年あたりの複利計算期の回数が指定されている場合に、 1 年あたりの名目年利率を計算します。

構文

NOMINAL(実質利率; NPerY)

実効利率 は、実効利率です。

NPerY は、年間の利息定期支払回数です。

1年に利息が12回支払われ、実効年利率が 13.5% の場合の1年あたりの名目利率を求めます。

=NOMINAL(13.5%;12) = 12.73%。名目年利率は 12.73% です。

MIRR

一連の投資額に対する、修正内部利益率を返します。

構文

MIRR(値; 投資; 再投資率)

は、行列または内容が支払いに対応するセルのセル参照に対応します。

支払額 は、投資額 (行列の負の値) に対する利率です。

再投資率 は、再投資 (行列の正の値) に対する利率です。

セルの内容を A1 = -5、A2 = 10、A3 = 15、および A4 = 8、投資価値を 0.5、再投資価値 0.1 とすると、結果は 94.16% です。

MDURATION

固定金利証券に対する修正マコーレー係数を返します。

構文

MDURATION(受領日; 満期日; 利札; 利回り; 利息支払回数; 基準)

受領日 は、証券の購入日です。

満期日 は、証券が満期になる (満了する) 日付です。

利札 は、名目年利率 (利札利率) です

利回り は、証券の年利回りです。

利息支払回数 は、年間の利息支払回数です。1、2、または 4 になります。

基準 はオプションのリストから選択され、どのように年が計算されるかを示します。

基準 計算
0 または指定なし US 方式 (NASD) 、30日×12ヶ月
1 ひと月または1年の正確な日数
2 ひと月の正確な日数、1年は 360 日
3 ひと月の正確な日数、1年は 365 日
4 ヨーロッパ方式、30日×12ヶ月

証券を 2001 年 1 月 1 日に購入し、満期日は 2006 年 1 月 1 日です。名目利率は 8% です。利回りは 9.0% です。利息は半年に一度支払われます (年間の利息支払回数は 2 回)。1 日単位の未払い利息計算 (基準 3) を使用して、修正された期間を求めます。

=MDURATION("2001-01-01"; "2006-01-01"; 0.08; 0.09; 2; 3) は、4.02 年を返します。

DURATION

この関数は、積立ての期間の回数を計算し、特定の値を得ることができます。

構文

DURATION(利率; PV; FV)

利率 は、定数です。利率は、期間全体に対して計算されます。期間ごとの利率は、計算される期間で利率を割って計算します。年金の利率は、利率/12 として入力されます。

PV は、現在の価値です。現金値は、現金の預け入れまたは現物支給の現在の現金価値です。預金額として正の値を入力します。預金額は、0 未満にしないでください。

FV は、予想価値です。将来価値は、預金の希望の (将来) 価値を決定します。

利率 4.75%、現在の価値 25,000 貨幣単位、将来価値 1,000,000 貨幣単位の場合、支払期間は 79.49 回になります。一回の支払額は、見積もられた将来価値と支払期間から次のように計算されます: 1,000,000/79.49=12,580.20

DOLLARFR

小数で表された数値を分数表示に変換します。

構文

DOLLARFR(10 進法ドル; 分数)

10 進法ドル は、10 進数です。

分数 は、小数の分母として使用される整数です。

=DOLLARFR(1.125;16) は、16 分の 1 に変換します。2 と 1/16 の場合、値は 1.02 です。

=DOLLARFR(1.125;8) は、8 分の 1 に変換します。1 と 1/8 の場合、値は 1.1 です。

DOLLARDE

分数で表された数値を小数に変換します。

構文

DOLLARDE(分数ドル; 分数)

分数ドル は、小数として指定される数値です。

分数 は、小数の分母として使用される整数です。

=DOLLARDE(1.02;16) は、1 と 2/16 を表します。この式は、1.125 を返します。

=DOLLARDE(1.1;8) は、1 と 1/8 を表します。この式は、1.125 を返します。

CUMPRINC_ADD

指定された期間の貸付金の累積償還額を計算します。

Note.png The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.

構文

CUMPRINC_ADD(利率; NPer; PV; 開始期間; 終了期間; タイプ)

利率 は、各期の利率です。

NPer は、支払い期間の合計です。利率と NPER は同じ単位を指し、そのため、どちらも年または月単位のいずれかで計算されます。

PV は、現在の価値です。

最初の利札 は、計算用の最初の支払い期間です。

最後の期間 は、計算用の最後の支払い期間です。

タイプ は、各期間の最後 (タイプ = 0) または期間の最初 (タイプ = 1) の支払いの満期です。

次のような住宅ローンがあります:

利率: 年利 9.00 パーセント (9% / 12 = 0.0075) 、 返済期間: 30 年 (支払回数 = 30 * 12 = 360) 、現在価値: ¥125000000

2年目 (支払回数 = 13 ~ 24) に返済する元金の合計を求めます。

=CUMPRINC_ADD(0.0075;360;125000;13;24;0) は、-934.1071 を返します。

最初の月に返済する元金を求めます。

=CUMPRINC_ADD(0.0075;360;125000;1;1;0) は、-68.27827 を返します。

CUMPRINC

指定された投資期間に対して支払われる利息の累計を返します。

構文

CUMPRINC(利率; NPer; PV; S; E; タイプ)

利率 は期間の利率を指定します。

NPer は、期間の合計を含む支払い期間です。NPER は、整数値でなくてもかまいません。

PV は、一連の支払いの現在の価額です。

S は、最初の期間です。

E は、最後の期間です。

タイプ は、各期間の最初または最後の支払い期日です。

5.5% の利率で 36 期間に返済する元金の額を求めます。価額は 15,000 通貨単位です。返済する元金は、第 10 期から第 18 期までの期間で計算します。支払期日は期末に指定します。

=CUMPRINC(5.5%/12;36;15000;10;18;0) = -3669.74 通貨単位。10 期と 18 期の間の期間の支払い額は、3669.74 通貨単位です。

CUMIPMT_ADD

指定された期間に、貸付金に対して支払われる利息の累計を返します。

Note.png The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.

構文

CUMIPMT_ADD(利率; NPer; PV; 開始期間; 終了期間; タイプ)

利率 は、各期の利率です。

NPer は、支払い期間の合計です。利率と NPER は同じ単位を指し、そのため、どちらも年または月単位のいずれかで計算されます。

PV は、現在の価値です。

最初の利札 は、計算用の最初の支払い期間です。

最後の期間 は、計算用の最後の支払い期間です。

タイプ は、各期間の最後 (タイプ = 0) または期間の最初 (タイプ = 1) の支払いの満期です。

次のような住宅ローンがあります:

利率: 年利 9.00 パーセント (9% / 12 = 0.0075)、 返済期間: 30 年 (支払い回数 = 30 * 12 = 360)、 現在価値: 125,000,000 貨幣単位

2年目 (支払回数 = 13 ~ 24) に返済する利息の合計を求めます。

=CUMIPMT_ADD(0.0075;360;125000;13;24;0) は、-11135.23 を返します。

最初の月に返済する利息を求めます。

=CUMIPMT_ADD(0.0075;360;125000;1;1;0) は、-937.50 を返します。

CUMIPMT

複利の累計、すなわちある期間の投資に対する全利息の合計を計算します。利率は一定です。

構文

CUMIPMT(利率; NPer; PV; S; E; タイプ)

利率 は期間の利率を指定します。

NPer は、期間の合計を含む支払い期間です。NPER は、整数値でなくてもかまいません。

PV は、一連の支払いの現在の価額です。

S は、最初の期間です。

E は、最後の期間です。

タイプ は、各期間の最初または最後の支払い期日です。

5.5% の期間利率で現在価格 5000 貨幣単位から 2 年間に得られる利息の合計を求めます。計算期間の始まりは第 4 期で、終わりが第 6 期、支払期日は各期間の期首とします。

=CUMIPMT(5.5%/12;24;5000;4;6;1) = -57.54 通貨単位。4 期と 6 期の間の利息支払いは、57.54 通貨単位です。

財務関数 1 へ

財務関数3へ

Functions by Category