ANTAL.OMF funktion

EN
AST
BG
BN
BN-IN
CA
CS
DA
DE
EL
ES
EU
FI
FR
HU
IT
JA
KM
KO
NB
NL
OM
PL
PT
PT-BR
RU
SL
SV
TR
VI
ZH-CN
ZH-TW

ANTAL.OMF funktion

Ger antal rader eller kolumner som uppfyller kriterierna i flera områden.

Syntax

ANTAL.OMF(Område1; Kriterium1 [; Område2; Kriterium2 [; ...]])

Range1 – required argument. It is a range of cells, a name of a named range or a label of a column or a row containing values for counting and finding the corresponding criterion.

Criterion1 – required argument. A condition in the form of expression or a cell reference to expression that defines what cells should be used for counting. The expression can contain text, numbers, regular expressions (if enabled in calculation options) or wildcards (if enabled in calculation options).

Range2 – Optional. Range2 and all the following mean the same as Range1.

Criterion2 – Optional. Criterion2 and all the following mean the same as Criterion1.

The logical relation between criteria can be defined as logical AND (conjunction). In other words, if and only if all given criteria are met, a row or a column is taken into counting.

The Criterion needs to be a string expression, in particular, the Criterion needs to be enclosed in quotation marks ("Criterion") with the exception of the names of functions, cell references and the operator of a string concatenation (&).
The operators equal to (=), not equal to (<>), greater than (>), greater than or equal to (>=), less than (<), and less than or equal to (<=) can be used in criterion arguments for comparison of numbers.
The function can have up to 500 arguments, meaning that you can specify 250 pairs of ranges and criteria.

This function is part of the Open Document Format for Office Applications (OpenDocument) standard Version 1.2. (ISO/IEC 26300:2-2015)

If a cell contains TRUE, it is treated as 1, if a cell contains FALSE – as 0 (zero).

If ranges for arguments Range and Criterion have unequal sizes, the function returns err:502.

Exempel

Consider the following table

	A	B	C
1	Product Name	Sales	Revenue
2	pencil	20	65
3	pen	35	85
4	notebook	20	190
5	book	17	180
6	pencil-case	not	not

Simple usage

=ANTAL.OMF(B2:B6;">=20")

Counts the amount of rows of the range B2:B6 with values greater than or equal to 20. Returns 3, because the fifth and the sixth rows do not meet the criterion.

=ANTAL.OMF(B2:B6;">=20";C2:C6;">70")

Counts the amount of rows that contain simultaneously values greater than 70 in the C2:C6 range and values greater than or equal to 20 in the B2:B6 range. Returns 2, because the second, the fifth and the sixth rows do not meet at least one criterion.

Using regular expressions and nested functions

=ANTAL.OMF(B2:B6;"[:alpha:]*")

Counts the amount of rows of the B2:B6 range that contain only alphabet symbols. Returns 1, because only sixth row meets the criterion.

=ANTAL.OMF(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Counts the amount of rows of the B2:B6 range excluding rows with minimum and maximum values of this range. Returns 2, because the third, the fifth and the sixth rows do not meet at least one criterion.

=ANTAL.OMF(A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Counts the amount of rows that correspond to all cells of the A2:A6 range starting with "pen" and to all cells of the B2:B6 range with exception of its maximum. Returns 1, because only second row meets all criteria.

Reference to a cell as a criterion

Om du vill göra det enklare att ändra ett kriterium, så kan du ange det i en separat cell och sedan referera till den cellen ifrån funktionen ANTAL.OMF. Exempelvis kan ovanstående funktion skrivas så här:

=ANTAL.OMF(A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

If E2 = pen, the function returns 1, because the link to the cell is substituted with its content and it works as a function above.

ANTAL.OMF funktion

Contents