Função CONT.SES

From LibreOffice Help
Jump to: navigation, search

Função CONT.SES

Retorna a contagem de linhas e colunas que conferem critérios em vários intervalos.

Sintaxe

CONT.SES(Intervalo1; Criterio1 [; Intervalo2; Criterio2 [; ...]])

Intervalo – argumento obrigatório. Um intervalo, um nome de intervalo ou um rótulo de coluna ou linha contendo os números a contar e a achar o critério correspondente.

critério1 – obrigatório. Uma condição na forma de expressão ou referência de célula que define quais células devem ser usadas para calcular a contagem. A expressão pode conter texto, números, expressões regulares (se ativadas nas opções do Calc) ou caracteres coringa (se ativado nas opções do Calc).

Range2 – Optional. Range2 and all the following mean the same as Range1.

criterio2 – Opcional. Idem a criterio1.

Note.png A relação lógica ente os diversos critérios deve ser entendida como um E lógico. Em outras palavras, se e somente se todos os critérios são conferidos para a linha ou coluna ser contada.
O Criterio deve ser uma expressão em texto.
Os operadores =, <>, >, >=, <= e < podem ser usados para comparação de números.
A função pode ter até 500 argumentos, significando que pode ter até 250 pares de Intervalo_criterio e Criterio.
Note.png Esta função é parte integrante da norma Open Document Format for Office Applications (OpenDocument), versão 1.2 (ISO/IEC 26300:2-2015).
Warning.png Se a célula contém VERDADEIRO, será tratada como 1 e se a célula contém FALSO será tratada como 0.
Se o intervalo para os argumentos Intervalo e Critério tiverem tamanhos diferentes, a função retorna o erro 502.

Exemplos

Considere a seguinte tabela

A B C
1 Nome do produto Vendas Renda
2 canudo 20 65
3 caneta 35 85
4 caderno 20 190
5 mochila 17 180
6 caneta tinteiro nao não

Utilização simples

=CONT.SES(B2:B6;">=20")

Conta o número de linhas no intervalo B2:B6 com valores maiores ou iguais a 20. Retorna 3 por que a 5ª e 6ª linhas não atendem ao critério.

=CONT.SES(B2:B6;">=20";C2:C6;">70")

Conta o número de linhas que contém simultaneamente valores maiores de 70 no intervalo C2:C6 e valores maiores que 20 no intervalo B2:B6. Retorna 2 por que a segunda e a 6ª linhas não conferem pelo menos uma das condições.

Usar expressões regulares e funções incorporadas

=CONT.SES(B2:B6;"[:alpha:]*")

Conta o número de linhas do intervalo B2:B6 que contém somente símbolos do alfabeto. Retorna 1 por que somente a 6ª linha atende ao critério.

=CONT.SES(B2:B6;">"&MÍNIMO(B2:B6);B2:B6;"<"&MÁXIMO(B2:B6))

Conta o número de linhas no intervalo B2:B6 excluindo as linhas de máximo e mínimo. Retorna 2 por que a 3ª, 5ª e 6ª linhas não atendem pelo menos um dos critérios.

=CONT.SES(A2:A6;"can.*";B2:B6;"<"&MÁXIMO(B2:B6))

Conta número de linhas que correspondem a todas as células do intervalo A2:A6 que começam com as letras "can" e todas as células do intervalo B2:B6 exceto seu máximo. Retorna 1 por que somente a segunda linha atende a todos os critérios.

Critério como referência

Se precisar mudar o critério mais facilmente, você pode especificar uma célula em separado e usar sua referência na condição para a função CONT.SES. Por exemplo, a função acima pode ser reescrita como:

=CONT.SES(A2:A6;E2&".*";B2:B6;"<"&MÁXIMO(B2:B6))

Se E2="can", a função retorna 1.


Related Topics

CONTAR, CONT.SE, CONTARA, Função SOMASES

, Função MÉDIASES

, MÁXIMO, MÍNIMO

Lista de expressões regulares