Funzione CONTA.PIÙ.SE

From LibreOffice Help
Jump to: navigation, search

Funzione CONTA.PIÙ.SE

Restituisce il conteggio delle righe o delle colonne che soddisfano i criteri in più intervalli.

Sintassi

CONTA.PIÙ.SE(Intervallo1; Criterio1 [; Intervallo2; Criterio2 [; ...]])

Intervallo1 – argomento obbligatorio. È un intervallo di celle, il nome di un'area indicata, la dicitura di una colonna o di una riga che contiene valori per il conteggio e per trovare il criterio corrispondente.

Criterio1 – argomento obbligatorio. È una condizione nella forma di un'espressione o un riferimento di cella a un'espressione che definisce quali celle devono essere utilizzate per il conteggio. L'espressione può contenere testo, numeri, espressioni regolari (se abilitate nelle opzioni di calcolo) o caratteri jolly (se abilitati nelle opzioni di calcolo).

Range2 – Optional. Range2 and all the following mean the same as Range1.

Criterio2 – opzionale. Criterio2 e tutto ciò che segue hanno lo stesso significato di Criterio1.

Note.png La relazione logica tra criteri può essere definita come E logico (congiunzione). In altri termini, se, e solo se, tutti i criteri indicati sono soddisfatti, viene considerata nel conteggio una riga o una colonna.
L'opzione Criterio necessita di un'espressione di stringa; in particolare, Criterio deve essere incluso tra virgolette doppie ("Criterio"). Le virgolette non sono necessarie per i nomi delle funzioni, i riferimenti di cella e le operazioni con concatenazione di stringa (&).
Gli operatori uguale a (=), non uguale a (<>), maggiore di (>), maggiore di o uguale a (>=), minore di (<) e minore di o uguale a (<=) possono essere utilizzati negli argomenti del criterio per il confronto di numeri.
La funzione può contenere fino a 500 argomenti, ossia potete specificare 250 coppie di intervalli e criteri.
Note.png Questa funzione appartiene all'Open Document Format for Office Applications (OpenDocument), versione standard 1.2 (ISO/IEC 26300:2-2015).
Warning.png Se una cella contenesse VERO, sarebbe considerata 1; se contenesse FALSO, sarebbe considerata 0 (zero).
Se gli intervalli per gli argomenti Intervallo e Criterio avessero dimensioni diseguali, la funzione restituirebbe err:502.

Esempi

Considerate la tabella seguente

A B C
1 Nome prodotto Vendite Ricavo
2 matita 20 65
3 penna 35 85
4 notebook 20 190
5 libro 17 180
6 astuccio non non

Uso semplice

=CONTA.PIÙ.SE(B2:B6;">=20")

Conta la quantità di righe dell'intervallo B2:B6 con valori maggiori o uguali a 20. Restituisce 3, perché la quinta e la sesta riga non soddisfano il criterio.

=CONTA.PIÙ.SE(B2:B6;">=20";C2:C6;">70")

Conta la quantità di righe che contengono contemporaneamente valori maggiori di 70 nell'intervallo C2:C6 e valori maggiori o uguali a 20 nell'intervallo B2:B6. Restituisce 2, perché la seconda, la quinta e la sesta riga non soddisfano almeno un criterio.

Uso delle espressioni regolari e delle funzioni annidate

=CONTA.PIÙ.SE(B2:B6;"[:alpha:]*")

Conta la quantità di righe dell'intervallo B2:B6 che contengono solo simboli alfabetici. Restituisce 1, perché solo la sesta riga soddisfa il criterio.

=CONTA.PIÙ.SE(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Conta la quantità di righe dell'intervallo B2:B6 escludendo le righe con valori minimi e massimi dello stesso intervallo. Restituisce 2, perché la terza, la quinta e la sesta riga non soddisfano almeno un criterio.

=CONTA.PIÙ.SE(A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Conta la quantità di righe che corrispondono a tutte le celle dell'intervallo A2:A6 che iniziano con "pen" e a tutte le celle dell'intervallo B2:B6, eccetto il suo massimo. Restituisce 1, perché solo la seconda riga soddisfa tutti i criteri.

Fare riferimento a una cella come criterio

Per cambiare in modo facile un criterio, potete specificarlo in una cella separata, utilizzando un riferimento alla cella all'interno della condizione della funzione CONTA.PIÙ.SE. Per esempio, la funzione sopra citata può essere riscritta nel modo seguente:

=CONTA.PIÙ.SE(A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Se E2 = pen, la funzione restituisce 1, perché il collegamento alla cella è sostituito dal suo contenuto e agisce come la funzione sopra citata.


Related Topics

CONTA, CONTA.SE, CONTA.VALORI, SOMMA.PIÙ.SE

, MEDIA.PIÙ.SE

, MAX, MIN

Elenco delle espressioni regolari