Συνάρτηση COUNTIFS

From LibreOffice Help
Jump to: navigation, search

Συνάρτηση COUNTIFS

Επιστρέφει τον αριθμό των γραμμών ή στηλών που ικανοποιούν τα κριτήρια σε πολλαπλές περιοχές.

Σύνταξη

COUNTIFS(περιοχή1; κριτήριο1 [; περιοχή2; κριτήριο2 [; ...]])

Περιοχή1 – απαιτούμενο όρισμα. Είναι μια περιοχή κελιών, ένα όνομα μιας ονοματισμένης περιοχής, ή μια ετικέτα μιας στήλης ή μιας γραμμής που περιέχουν τιμές για τη μέτρηση και την εύρεση του αντίστοιχου κριτηρίου.

Κριτήριο1 – απαιτούμενο όρισμα. Μια συνθήκη με τη μορφή παράστασης ή αναφοράς κελιού σε παράσταση που καθορίζει ποια κελιά πρέπει να χρησιμοποιηθούν για καταμέτρηση. Η παράσταση μπορεί να περιέχει κείμενο, αριθμούς, κανονικές εκφράσεις (αν είναι ενεργές στις επιλογές υπολογισμού) ή σύμβολα υποκατάστασης (αν είναι ενεργά στις επιλογές υπολογισμού).

Range2 – Optional. Range2 and all the following mean the same as Range1.

Κριτήριο2 – Προαιρετικό. Το Κριτήριο2 και όλα τα επόμενα σημαίνουν τα ίδια όπως το Κριτήριο1.

Note.png Η λογική σχέση μεταξύ κριτηρίων μπορεί να καθοριστεί ως λογικό AND (σύζευξη). Με άλλα λόγια, αν και μόνο αν όλα τα δεδομένα κριτήρια πληρούνται, λαμβάνεται υπόψη μια γραμμή ή μία στήλη.
Το Κριτήριο πρέπει να είναι μια παράσταση συμβολοσειράς, ειδικά, το Κριτήριο πρέπει να περικλείεται σε εισαγωγικά ("Κριτήριο") με την εξαίρεση των ονομάτων των συναρτήσεων, των αναφορών κελιού και του τελεστή συνένωσης συμβολοσειράς (&).
Οι τελεστές ίσον (=), όχι ίσο (<>), μεγαλύτερο από (>), μεγαλύτερο από ή ίσο με (>=), μικρότερο από (<) και μικρότερο από ή ίσο με (<=) μπορούν να χρησιμοποιηθούν σε ορίσματα κριτηρίου για τη σύγκριση αριθμών.
Η συνάρτηση μπορεί να δεχτεί μέχρι 500 ορίσματα, που σημαίνει ότι μπορείτε να ορίσετε 250 ζεύγη περιοχών και κριτηρίων.
Note.png Αυτή η συνάρτηση είναι τμήμα του προτύπου της μορφής Open Document για εφαρμογές γραφείου (OpenDocument) έκδοσης 1.2. (ISO/IEC 26300:2-2015)
Warning.png Αν ένα κελί περιέχει TRUE, αντιμετωπίζεται ως 1, αν ένα κελί περιέχει FALSE – ως 0 (μηδέν).
Αν οι περιοχές για τα ορίσματα Περιοχή και Κριτήριο έχουν άνισα μεγέθη, η συνάρτηση επιστρέφει err:502.

Παραδείγματα

Θεωρήστε τον ακόλουθο πίνακα

A B C
1 Όνομα προϊόντος Πωλήσεις Έσοδα
2 μολύβι 20 65
3 στυλό 35 85
4 σημειωματάριο 20 190
5 βιβλίο 17 180
6 κασετίνα όχι όχι

Απλή χρήση

=COUNTIFS(B2:B6;">=20")

Μετρά τον αριθμό των γραμμών στην περιοχή B2:B6 με τιμές μεγαλύτερες από ή ίσες με 20. Επιστρέφει 3, επειδή η πέμπτη και η έκτη γραμμή δεν ικανοποιούν το κριτήριο.

=COUNTIFS(B2:B6;">=20";C2:C6;">70")

Μετρά τον αριθμό των γραμμών που περιέχουν ταυτόχρονα τιμές μεγαλύτερες από 70 στην περιοχή C2:C6 και τιμές μεγαλύτερες από ή ίσες με 20 στην περιοχή B2:B6. Επιστρέφει 2, επειδή η δεύτερη, η πέμπτη και η έκτη γραμμή δεν πληρούν τουλάχιστον ένα κριτήριο.

Χρήση κανονικών παραστάσεων και ένθετων συναρτήσεων

=COUNTIFS(B2:B6;"[:alpha:]*")

Μετρά τον αριθμό των γραμμών στην περιοχή B2:B6 που περιέχει μόνο αλφαβητικά σύμβολα. Επιστρέφει 1, επειδή μόνο η έκτη γραμμή πληρεί το κριτήριο.

=COUNTIFS(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Μετρά τον αριθμό των γραμμών στην περιοχή B2:B6 αποκλείοντας τις γραμμές με ελάχιστες και μέγιστες τιμές αυτής της περιοχής. Επιστρέφει 2, επειδή η τρίτη, η πέμπτη και η έκτη γραμμή δεν πληρούν τουλάχιστον ένα κριτήριο.

=COUNTIFS(A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Υπολογίζει τον αριθμό των γραμμών που αντιστοιχούν σε όλα τα κελιά της περιοχής A2:A6 που ξεκινούν με "pen" και όλα τα κελιά της περιοχής B2:B6 με εξαίρεση του μεγίστου του. Επιστρέφει 1, επειδή μόνο η δεύτερη γραμμή καλύπτει όλα τα κριτήρια.

Αναφορά σε ένα κελί ως ένα κριτήριο

Αν χρειάζεται να αλλάξετε ένα κριτήριο εύκολα, μπορεί να θέλετε να το ορίσετε σε ένα ξεχωριστό κελί και να χρησιμοποιήσετε μια αναφορά σε αυτό το κελί στη συνθήκη της συνάρτησης COUNTIFS. Παραδείγματος χάρη, η παραπάνω συνάρτηση μπορεί να ξαναγραφτεί ως εξής:

=COUNTIFS(A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Αν E2 = pen, η συνάρτηση επιστρέφει 1, επειδή ο σύνδεσμος στο κελί αντικαθίσταται με το περιεχόμενό του και δουλεύει όπως η παραπάνω συνάρτηση.


Related Topics

COUNT, COUNTIF, COUNTA, SUMIFS

, AVERAGEIFS

, MAX, MIN

Κατάλογος κανονικών εκφράσεων