Função MÉDIA.SE.S

From LibreOffice Help
Jump to: navigation, search

Função MÉDIA.SE.S

Devolve a média aritmética de um intervalo de células que cumprem um determinado conjunto de condições ou critérios. A função MÉDIA.SE.S soma todos os valores que cumpram o teste e divide essa soma pelo número de valores selecionados.

Sintaxe

MÉDIA.SE.S(intervalo_média;intervalo1;critério1;intervalo2;critério2;...)

intervalo_média - argumento obrigatório. É o intervalo de células, um nome de intervalo ou a etiqueta de uma coluna ou linha que contém os valores para calcular a média.

intervalo1 - argumento obrigatório. É o intervalo de células, um nome de intervalo ou a etiqueta de uma coluna ou linha que contém os valores para avaliar os critérios.

critérios1 - obrigatório. Uma condição na forma de expressão ou referência de célula que define as células a utilizar para calcular a média. A expressão pode conter texto, números, expressões regulares (se ativas nas opções de cálculo) e/ou caracteres universais (se ativos nas opções de cálculo).

intervalo2 - argumento opcional. Intervalo2 e todos os seguintes significam a mesma coisa que o intervalo1, com a exceção de serem opcionais.

critério2 - argumento opcional. Critério2 e todos os seguintes significam a mesma coisa que o critério1, com a exceção de serem opcionais.

Note.png A relação lógica entre diversos critérios pode ser definida como um E lógico. Por outras palavras, apenas e só se todos os critérios forem cumpridos, é que o correspondente valor de intervalo_média será utilizado para calcular a média.
O critério necessita de ser uma expressão, isto é, o critério tem que estar entre aspas ("critério"), com exceção dos nomes de funções, referências a células ou um operador de concatenação (&).
Os operadores (=), (<>), (>), (>=), (<) e (<=) podem ser utilizados como argumentos para comparação de valores.
A função pode ter, no máximo, 255 argumentos o que significa que pode especificar 127 pares de intervalos e critérios.
Note.png Esta função é parte integrante da norma Open Document Format for Office Applications (OpenDocument), versão 1.2 (ISO/IEC 26300:2-2015).
Warning.png Se uma célula do intervalo de valores para calcular a média estiver vazia ou possuir texto, a função MÉDIA.SE.S ignora a célula.
Se a célula contém VERDADEIRO, será tratada como 1 e se a célula contém FALSO, será tratada como 0.
Se todo o intervalo estiver vazio, possuir texto ou nenhum dos valores satisfizerem a condição (ou qualquer combinação destas), a função devolve o erro #DIV/0!
Se o intervalo de valores para o cálculo da média e quaisquer intervalos para encontrar o critério tiverem tamanhos diferentes, a função devolve o erro err:502.

Exemplos

Considere a seguinte tabela

A B C
1 Nome do produto Vendas Rendimento
2 pencil 20 65
3 pen 35 85
4 notebook 20 190
5 book 17 180
6 pencil-case não não
Warning.png Em todos os cálculos abaixo, os intervalos para calcular a média contêm a linha #6, mas esta será ignorada porque contém texto.

Utilização

=MÉDIA.SE.S(B2:B6;B2:B6;">=20")

Calcula a média para os valores do intervalo B2:B6 que são maiores ou iguais a 20. Devolve 25, uma vez que a quinta linha não cumpre o critério.

=MÉDIA.SE.S(C2:C6;B2:B6;">=20";C2:C6;">70")

Calcula a média para os valores do intervalo C2:C6 que são maiores que 70 e que correspondem às células de B2:B6 com valores maiores ou iguais a 20. Devolve 137,50 uma vez que a segunda e a quinta linha não cumprem pelo menos um dos critérios.

Utilizar expressões regulares e funções incorporadas

=MÉDIA.SE.S(C2:C6;B2:B6;">"&MÍNIMO(B2:B6);B2:B6;"<"&MÁXIMOB2:B6))

Calcula a média dos valores no intervalo C2:C6 que coincidam com todos os valores no intervalo B2:B6, exceto os valores máximo e mínimo. Devolve 127,5 uma vez que a terceira e a quinta linha não cumprem, pelo menos, um dos critérios.

=MÉDIA.SE.S(C2:C6;A2:A6;"pen.*";B2:B6;"<"&MÁXIMO(B2:B6))

Calcula a média dos valores do intervalo C2:C6 que correspondem a todos os valores do intervalo A2:A6 que começam com as letras "pen" e todas as células do intervalo B2:B6, exceto seu máximo. Devolve 65 porque apenas a segunda linha cumpre todos os critérios.

Referência a uma célula como critério

Se quiser alterar o critério facilmente, pode especificar o critério numa célula distinta e utilizar uma referência a esta célula como condição da função MÉDIA.SE.S. Por exemplo, a função acima pode ser escrita da seguinte forma:

=MÉDIA.SE.S(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MÁXIMO(B2:B6))

Se E2 = pen, a função devolve 65, uma vez que a ligação à célula é substituída pelo seu conteúdo.


Related Topics

AVERAGE, AVERAGEA, MÉDIA.SE

, Função SOMA.SE.S

, CONTAR.SE.S

, MAX, MIN

Lista de expressões regulares