ŚREDNIA.JEŻELI, funkcja

From LibreOffice Help
Jump to: navigation, search

ŚREDNIA.JEŻELI function

Zwraca średnią arytmetyczną wszystkich komórek w zakresie, które spełniają podaną wielokrotność kryterium. Funkcja ŚREDNIA.JEŻELI sumuje wszystkie wyniki testów logicznych i dzieli ich sumę przez ilość wybranych wartości.

Składnia

ŚREDNIA.JEŻELI(Zakres_średniej; Zakres_kryterium1; Kryterium1 [; Zakres_kryterium2; Kryterium2 [; ...]])

Zakres_średniej – argument wymagany. Zakres komórek, nazwa nazwanego zakresu lub etykieta kolumny, lub wiersz zawierający wartości do obliczenia średniej.

Zakres_kryterium1 – argument wymagany. Zakres komórek, nazwa nazwanego zakresu lub etykieta kolumny, lub wiersz zawierający wartości do znalezienia odpowiadającego kryterium.

Kryterium1 – argument wymagany. Warunek w postaci wyrażenia lub odwołania komórki do wyrażenia, które określa komórki potrzebne do obliczenia średniej. Wyrażenie może zawierać tekst, liczby, wyrażenia regularne (jeśli włączone w opcjach obliczeń) lub symbole wieloznaczne (jeśli włączone w opcjach obliczeń).

Zakres_kryterium2 – opcjonalne. Zakres_kryterium2 i wszystkie następujące oznaczają to samo jak Zakres_kryterium1.

Kryterium2 – opcjonalne. Kryterium2 i wszystkie następujące oznaczają to samo jak Kryterium1.

Note.png Relacja logiczna pomiędzy kryteriami może być zdefiniowana jako logiczne I (duża litera "i"; spójnik). Innymi słowy, jeśli i tylko jeśli wszystkie podane kryteria są spełnione, wartość z odpowiadającą jej komórką z podanego Zakresu_średniej jest użyta do obliczenia średniej.
Kryterium musi być wyrażeniem ciągu, w szczególności Kryterium musi być ujęte w cudzysłów ("Kryterium") z wyjątkiem nazw funkcji, odwołań komórki i operatora ciągu połączeń (&).
Operatory równe do (=), nierówne do (<>), większe niż (>), większy niż lub równe do (>=), mniejsze niż (<) i mniejsze niż lub równe do (<=) mogą być użyte w argumentach kryterium do porównywania liczb.
Funkcja może posiadać do 255 argumentów, co oznacza, że można określić zakresy 127 kryteriów i kryteria dla niego.
Note.png Funkcja ta jest częścią standardu Open Document Format for Office Applications (OpenDocument) w wersji 1.2. (ISO/IEC 26300:2-2015)
Warning.png Jeśli komórka w zakresie wartości do obliczenia średniej jest pusta lub zawiera tekst, funkcja ŚREDNIA.JEŻELI ignoruje tę komórkę.
Jeśli komórka zawiera PRAWDA, jest taktowana jak 1. Jeśli zawiera FAŁSZ – jak 0 (zero).
Jeśli cały zakres jest pusty, zawiera tylko tekst lub wszystkie wartości zakresu nie spełniają warunku (lub dowolna ich kombinacja), funkcja zwraca błąd #DZIEL/0!.
Jeśli zakres wartości do obliczenia średniej i dowolny zakres do znalezienia kryterium mają nierówne wielkości, funkcja zwraca BŁĄD:502.

Przykłady

Poniżej opisano działanie tego pola na tabeli

A B C
1 Nazwa produktu Sprzedaże Przychód
2 ołówek 20 65
3 ołów 35 85
4 notes 20 190
5 książka 17 180
6 piórnik nie nie
Warning.png We wszystkich przykładach poniżej, zakresy dla obliczeń średnich zawierają wiersz #6, który jest ignorowany, ponieważ zawiera tekst.

Proste użycie

=ŚREDNIA.JEŻELI(B2:B6;B2:B6;">=20")

Oblicza średnią dla wartości z zakresu B2:B6, które są większe niż lub równe do 20. Zwraca 25, ponieważ piąty wiersz nie spełnia kryterium.

=ŚREDNIA.JEŻELI(C2:C6;B2:B6;">=20";C2:C6;">70")

Oblicza średnią dla wartości z zakresu C2:C6, które są większe niż 70 i odpowiadają komórkom B2:B6 z wartościami większymi niż lub równymi do 20. Zwraca 137,5, ponieważ drugi i piąty wiersz nie spełniają co najmniej jednego kryterium.

Użycie wyrażeń regularnych i funkcji zagnieżdżonych

=ŚREDNIA.JEŻELI(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAKS(B2:B6))

Oblicza średnią dla wartości z zakresu C2:C6, które odpowiadają wszystkim wartościom z zakresu B2:B6, oprócz jego minimum i maksimum. Zwraca 127,5, ponieważ trzeci i piąty wiersz nie spełniają co najmniej jednego kryterium.

=ŚREDNIA.JEŻELI(C2:C6;A2:A6;"ołów.*";B2:B6;"<"&MAKS(B2:B6))

Oblicza średnią dla wartości z zakresu C2:C6, które odpowiadają wszystkim komórkom z zakresu A2:A6 zaczynającym się od słowa "ołów" i do wszystkich komórek z zakresu B2:B6, oprócz ich maksimum. Zwraca 65, ponieważ tylko drugi wiersz spełnia kryteria.

Odwołanie do komórki jako kryterium

Jeśli chcesz łatwo zmienić kryterium, możesz określić je w osobnej komórce i użyć odwołań do tej komórki w warunku funkcji ŚREDNIA.JEŻELI. Na przykład: powyższa funkcja może być przepisana następująco:

=ŚREDNIA.JEŻELI(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAKS(B2:B6))

Jeśli E2 = ołów, funkcja zwraca 65, ponieważ łącze do komórki jest zastąpione jego treścią.


Related Topics

AVERAGE, AVERAGEA, ŚREDNIA.JEŻELI

, SUMA.WARUNKÓW

, LICZ.WARUNKI

, MAX, MIN

Lista wyrażeń regularnych