functie GEMIDDELDE.ALS

From LibreOffice Help
Jump to: navigation, search

GEMIDDELDE.ALS-functie

Geeft het rekenkundig gemiddelde van alle cellen in een bereik die voldoen aan meerdere opgegeven criteria . De GEMIDDELDEN.ALS-functie telt alle resultaten die overeenkomen met de logische tests op en deelt dit totaal door het aantal geselecteerde waarden.

Syntaxis

GEMIDDELDE.ALS(Gemiddelde_bereik; Criterium_bereik1; Criterium1 [; Criterium_bereik2; Criterium2 [; ...]])

Gemiddelde_bereik – vereist argument. Het is een reeks cellen, een naam van een benoemd bereik of een label van een kolom of een rij met waarden, voor de berekening van het gemiddelde.

Criterium_bereik1 – vereist argument. Het is een reeks cellen, een naam van een benoemd bereik of een label van een kolom of een rij met waarden, voor het vinden van het bijbehorende criterium.

Criterion1 – vereist argument. Een voorwaarde in de vorm van expressie of een verwijzing naar een cel met een expressie, die bepaalt welke cellen worden gebruikt om het gemiddelde te berekenen. De expressie kan tekst, cijfers of reguliere expressies bevatten (als dit in de rekenopties is aangezet) of jokertekens (als dit in de rekenopties is aangezet).

Criterium_bereik2 – Optioneel. Criterium_bereik2 en alle volgende hebben dezelfde betekenis als Criterium_bereik1.

Criterium2 – Optioneel. Criterium2 en alle volgende hebben dezelfde betekenis als Criterium1.

Note.png De logische relatie tussen criteria kunnen gedefinieerd worden als een logische EN (combinatie). Met andere woorden, als en alleen als aan alle opgegeven criteria wordt voldaan, wordt een waarde van de corresponderende cel van een opgegeven Gemiddelde_bereik in de berekening van het gemiddelde opgenomen.
Het Criterium moet een tekenreeks-expressie zijn, en het Criterium moet tussen aanhalingstekens worden geplaatst ("Criterium"), met uitzondering van de namen van de functies, celverwijzingen en het teken van een samenvoegingsoperator (&).
De operatoren gelijk aan (=), niet gelijk aan (<>) groter dan (>), groter dan of gelijk aan (> =), kleiner dan (<) en kleiner dan of gelijk aan (<=) kunnen worden gebruikt in criterium-argumenten voor de vergelijking van getallen.
De functie kan maximaal 255 argumenten hebben, wat betekent dat u 127 criteria-bereiken en criteria ervoor kunt opgeven.
Note.png Deze functie maakt deel uit van het Open Document Format voor Office Applications (OpenDocument) standaard versie 1.2. (ISO/IEC 26300: 2-2015)
Warning.png Als een cel in een bereik van waarden voor het berekenen van het gemiddelde leeg of tekst bevat, negeert de functie GEMIDDELDE.ALS deze cel.
Als een cel WAAR bevat, wordt deze als 1 behandeld, als een cel ONWAAR bevat - als 0 (nul).
Als het hele bereik leeg is, alleen tekst bevat of alle waarden van het bereik niet de voorwaarde (of een combinatie hiervan) voldoen, geeft de functie de fout #DIV/0!.
Als het bereik van de waarden voor het berekenen van het gemiddelde en een bereik voor het zoeken van criteria ongelijke afmetingen hebben, geeft de functie FOUT:502.

Voorbeelden

Overweeg de volgende tabel

A B C
1 Productnaam Verkopen Ontvangsten
2 potlood 20 65
3 pen 35 85
4 kladblok 20 190
5 boek 17 180
6 etui niet niet
Warning.png In alle onderstaande voorbeelden, bevatten de bereiken voor de berekening van gemiddelden de rij #6, maar deze wordt genegeerd, omdat deze tekst bevat.

Eenvoudig gebruik

=GEMIDDELDE.ALS(B2:B6;B2:B6;">=20")

Berekent het gemiddelde van de waarden van het bereik B2:B6 die groter of gelijk zijn aan 20. Dit geeft 25, omdat de vijfde rij niet aan het criterium voldoet.

=GEMIDDELDE.ALS(C2:C6;B2:B6;">=20";C2:C6;">70")

Berekent het gemiddelde van de waarden van het bereik C2:C6, die groter zijn dan 70 en overeenkomen met cellen van B2:B6 met waarden groter dan of gelijk aan 20. Dit geeft 137,5, omdat de tweede en vijfde rij niet voldoen aan tenminste één criterium.

Met behulp van reguliere expressies en geneste functies

=GEMIDDELDE.ALS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Berekent het gemiddelde van de waarden van het bereik C2:C6, die overeenkomen met alle waarden van het bereik B2 B6 behalve de kleinste en de grootste. Dit geeft 127,5, omdat de derde en vijfde rij niet voldoen aan tenminste één criterium.

=GEMIDDELDE.ALS(C2:C6;A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Berekent het gemiddelde van de waarden van het bereik C2:C6, die overeenkomen met alle cellen van het bereik A2: A6, die beginnen met "pen" en alle cellen van het bereik B2:B6 behalve de grootste. Dit geeft 65, want alleen tweede rij voldoet aan alle criteria.

Refereer naar een cel als een criterium

Als u een criterium gemakkelijk moet kunnen veranderen, kunt u dit in een aparte cel opvoeren en gebruik maken van een verwijzing naar deze cel in de voorwaarde van de GEMIDDELDE.ALS-functie. De bovenstaande functie kan bijvoorbeeld als volgt worden herschreven:

=GEMIDDELDE.ALS(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Als E2 = pen, geeft de functie 65, omdat de koppeling naar de cel wordt vervangen met de inhoud ervan.


Related Topics

AVERAGE, AVERAGEA, GEMIDDELDE.ALS-functie

, SOM.ALS

, AANTAL.ALS

, MAX, MIN

Lijst met reguliere expressies