Funzione MEDIA.PIÙ.SE

From LibreOffice Help
Jump to: navigation, search

Funzione MEDIA.PIÙ.SE

Restituisce la media aritmetica di tutte le celle all'interno di un intervallo che soddisfi più condizioni determinate. La funzione MEDIA.PIÙ.SE somma tutti i risultati che corrispondono ai test logici e divide per la quantità dei valori selezionati.

Sintassi

MEDIA.PIÙ.SE(intervallo_media; Criterio_intervallo1; Criterio1 [; Criterio_intervallo2; Criterio2 [; ...]])

intervallo_media – argomento obbligatorio. È un intervallo di celle, il nome di un'area indicata, la dicitura di una colonna o di una riga che contiene valori per il calcolo della media.

Criterio_intervallo1 – argomento obbligatorio. È un intervallo di celle, il nome di un'area indicata, la dicitura di una colonna o di una riga che contiene valori per trovare il criterio corrispondente.

Criterio1 – argomento obbligatorio. È una condizione nella forma di un'espressione o un riferimento di cella a un'espressione che definisce quali celle devono essere utilizzate per calcolare la media. L'espressione può contenere testo, numeri, espressioni regolari (se abilitate nelle opzioni di calcolo) o caratteri jolly (se abilitati nelle opzioni di calcolo).

Criterio_intervallo2 – opzionale. Criterio_intervallo2 e tutto ciò che segue hanno lo stesso significato di Criterio_intervallo1.

Criterio2 – opzionale. Criterio2 e tutto ciò che segue hanno lo stesso significato di Criterio1.

Note.png La relazione logica tra criteri può essere definita come E logico (congiunzione). In altri termini, se, e solo se, tutti i criteri indicati sono soddisfatti, viene considerato nel calcolo della media un valore proveniente dalla cella corrispondente dell'intervallo_media indicato.
L'opzione Criterio necessita di un'espressione di stringa; in particolare, Criterio deve essere incluso tra virgolette doppie ("Criterio"). Le virgolette non sono necessarie per i nomi delle funzioni, i riferimenti di cella e le operazioni con concatenazione di stringa (&).
Gli operatori uguale a (=), non uguale a (<>), maggiore di (>), maggiore di o uguale a (>=), minore di (<) e minore di o uguale a (<=) possono essere utilizzati negli argomenti del criterio per il confronto di numeri.
La funzione può contenere fino a 255 argomenti, ossia potete specificare 127 intervalli di criteri e i criteri per essa.
Note.png Questa funzione appartiene all'Open Document Format for Office Applications (OpenDocument), versione standard 1.2 (ISO/IEC 26300:2-2015).
Warning.png Se all'interno di un intervallo di valori per il calcolo della media, una cella fosse vuota o contenesse del testo, la funzione MEDIA.PIÙ.SE ignorerebbe tale cella.
Se una cella contenesse VERO, sarebbe considerata 1; se contenesse FALSO, sarebbe considerata 0 (zero)
Se l'intero intervallo fosse vuoto, contenesse solo testo o tutti i valori al suo interno non soddisfassero la condizione (o qualsiasi loro combinazione), la funzione restituirebbe l'errore #DIV/0!.
Se l'intervallo di valori per il calcolo della media e qualsiasi altro intervallo per la ricerca del criterio avessero dimensioni diseguali, la funzione restituirebbe err:502.

Esempi

Considerate la tabella seguente

A B C
1 Nome prodotto Vendite Ricavo
2 matita 20 65
3 penna 35 85
4 notebook 20 190
5 libro 17 180
6 astuccio non non
Warning.png In tutti gli esempi sotto riportati, gli intervalli per il calcolo della media includono la riga #6, ma essa è ignorata poiché contiene del testo.

Uso semplice

=MEDIA.PIÙ.SE(B2:B6;B2:B6;">=20")

Calcola la media per i valori dell'intervallo B2:B6, maggiori o uguali a 20. Restituisce 25, perché la quinta riga non soddisfa il criterio.

=MEDIA.PIÙ.SE(C2:C6;B2:B6;">=20";C2:C6;">70")

Calcola la media per i valori dell'intervallo C2:C6 maggiori di 70 e che corrispondono alle celle B2:B6 con valori maggiori o uguali a 20. Restituisce 137,5, perché la seconda e la quinta riga non soddisfano almeno un criterio.

Uso delle espressioni regolari e delle funzioni annidate

=MEDIA.PIÙ.SE(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Calcola la media per i valori dell'intervallo C2:C6 che corrispondono a tutti i valori dell'intervallo B2:B6, eccetto il suo minimo e massimo. Restituisce 127,5, perché la terza e la quinta riga non soddisfano almeno un criterio.

=MEDIA.PIÙ.SE(C2:C6;A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Calcola la media per i valori dell'intervallo C2:C6 che corrispondono a tutte le celle dell'intervallo A2:B6 che iniziano con "pen" e a tutte le celle dell'intervallo B2:B6, eccetto il suo massimo. Restituisce 65, perché solo la seconda riga soddisfa tutti i criteri.

Fare riferimento a una cella come criterio

Per cambiare in modo facile un criterio, potete specificarlo in una cella separata, utilizzando un riferimento alla cella all'interno della condizione della funzione MEDIA.PIÙ.SE. Per esempio, la funzione sopra citata può essere riscritta nel modo seguente:

=MEDIA.PIÙ.SE(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Se E2 = pen, la funzione restituisce 65, perché il collegamento alla cella è sostituito dal suo contenuto.


Related Topics

AVERAGE, AVERAGEA, MEDIA.SE

, SOMMA.PIÙ.SE

, CONTA.PIÙ.SE

, MAX, MIN

Elenco delle espressioni regolari