AVERAGEIFS

From LibreOffice Help
Jump to: navigation, search

AVERAGEIFS

Vrátí aritmetický průměr všech buněk oblasti, které splňují více kritérií. Funkce AVERAGEIFS sečte všechny výsledky, které vyhovují daným logickým testům, a součet vydělí počtem vybraných hodnot.

Syntaxe

AVERAGEIFS(Oblast_pro_průměr; Oblast_kritéria1; Kritérium1 [; Oblast_kritéria2; Kritérium2 [; ...]])

Oblast_pro_průměr – povinný argument. Jedná se o oblast buněk, název pojmenované oblasti nebo popisek sloupce nebo řádku obsahujícího hodnoty pro výpočet průměru.

Oblast_kritéria1 – povinný argument. Jedná se o oblast buněk, název pojmenované oblasti nebo popisek sloupce nebo řádku obsahujícího hodnoty pro vyhledávání pomocí odpovídajícího kritéria.

Kritérium1 – povinný argument. Podmínka v podobě výrazu nebo odkaz na buňku s výrazem, jenž určuje, které buňky se mají pro výpočet průměru použít. Výraz může obsahovat text, čísla, regulární výrazy nebo zástupné znaky (podle toho, jsou-li povoleny v možnostech výpočtu).

Oblast_kritéria2 – nepovinný. Oblast_kritéria2 a následující mají stejný význam jako Oblast_kritéria1.

Kritérium2 – nepovinný. Kritérium2 a následující mají stejný význam jako Kritérium1.

Note.png Logický vztah mezi kritérii lze definovat jako logické AND (konjunkce). Jinak řečeno, hodnota z odpovídající buňky dané Oblasti_pro_průměr je použita při výpočtu průměru právě tehdy, když jsou splněna všechna kritéria.
Kritérium musí být řetězec, tedy uzavřeno v uvozovkách ("Kritérium") s výjimkou názvů funkcí, odkazů na buňku a operátoru spojování řetězců (&).
V argumentech s kritérii mohou být pro porovnávání čísel použity operátory je rovno (=), není rovno (<>), větší než (>), větší nebo rovno (>=), menší než (<) a menší nebo rovno (<=).
Funkce může mít až 255 argumentů, je tedy možné určit 127 oblastí a kritérií pro ně.
Note.png Tato funkce je součástí standardu Open Document Format for Office Applications (OpenDocument) verze 1.2 (ISO/IEC 26300:2-2015).
Warning.png Pokud je buňka v oblasti hodnot pro výpočet průměru prázdná nebo obsahuje text, funkce AVERAGEIFS ji ignoruje.
Obsahuje-li buňka hodnotu PRAVDA, je považována za číslo 1, obsahuje-li hodnotu NEPRAVDA, je považována za 0.
Pokud je celá oblast prázdná, obsahuje pouze text nebo žádná z hodnot oblasti nesplňuje podmínku (nebo jejich kombinaci), funkce vrátí chybu #DIV/0!
Pokud mají oblast hodnot pro výpočet průměru a jakákoliv oblast kritéria pro vyhledávání různé velikosti, funkce vrátí chybu Chyba:502.

Příklady

Uvažujme následující tabulku

A B C
1 Název zboží Prodeje Tržby
2 nůžky 20 65
3 nůž 35 85
4 poznámkový blok 20 190
5 známka 17 180
6 nůž na papír ne ne
Warning.png Ve všech následujících příkladech je v oblasti pro výpočet průměru zahrnut řádek číslo 6, který se ale ignoruje, protože obsahuje text.

Základní použití

=AVERAGEIFS(B2:B6;B2:B6;">=20")

Vypočítá průměr hodnot z oblasti B2:B6, které jsou větší nebo rovny 20. Vrátí 25, protože pátý řádek kritérium nesplňuje.

=AVERAGEIFS(C2:C6;B2:B6;">=20";C2:C6;">70")

Vypočítá průměr hodnot z oblasti C2:C6, které jsou větší než 70 a odpovídají buňkám oblasti B2:B6 s hodnotami většími nebo rovnými 20. Vrátí 137,5, protože druhý a pátý řádek aspoň jedno z kritérií nesplňují.

Použití regulárních výrazů a vnořených funkcí

=AVERAGEIFS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Vypočítá průměr hodnot z oblasti C2:C6, které odpovídají všem hodnotám z oblasti B2:B6 kromě jejich minima a maxima. Vrátí 127,5, protože třetí a pátý řádek aspoň jedno z kritérií nesplňují.

=AVERAGEIFS(C2:C6;A2:A6;"nůž.*";B2:B6;"<"&MAX(B2:B6))

Vrátí průměr hodnot z oblasti C2:C6, které odpovídají všem buňkám z oblasti A2:A6 začínajícím na "nůž" a všem buňkám z oblasti B2:B6 s výjimkou jejich maxima. Vrátí 65, protože všechna kritéria splňuje pouze druhý řádek.

Odkaz na buňku jako kritérium

Potřebujete-li kritérium snadno změnit, můžete jej zadat do samostatné buňky, na kterou odkážete v podmínce funkce AVERAGEIFS. Například výše uvedenou funkci lze přepsat následovně:

=AVERAGEIFS(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Pokud E2 = nůž, funkce vrátí 65, protože odkaz na buňku je nahrazen jejím obsahem.


Related Topics

AVERAGE, AVERAGEA, AVERAGEIF

, SUMIFS

, COUNTIFS

, MAX, MIN

Seznam regulárních výrazů