A párbeszédablak-szerkesztő vezérlőelemeinek példaprogramjai

From LibreOffice Help
Jump to: navigation, search

Az alábbiak egy új „Dialog1” nevű párbeszédablak létrehozására mutatnak példát. A párbeszédablak-szerkesztő Eszközök paneljén található eszközökkel hozza létre a párbeszédablakot, és adja hozzá a következő vezérlőelemeket: egy „CheckBox1” nevű Jelölőnégyzetet, egy „Label1” nevű Címkét, egy „CommandButton1” nevű Gombot és egy „ListBox1” nevű Listamezőt.

Warning.png Legyen következetes a kis- és nagybetűk használatával egy vezérlőelem object (objektum) változóhoz rendelése esetén.

Általános függvény párbeszédablakok betöltéséhez

Function LoadDialog(Libname as String, DialogName as String, Optional oLibContainer)
Dim oLib as Object
Dim oLibDialog as Object
Dim oRuntimeDialog as Object
    If IsMissing(oLibContainer) Then
        oLibContainer = DialogLibraries
    End If
    oLibContainer.LoadLibrary(LibName)
    oLib = oLibContainer.GetByName(Libname)
    oLibDialog = oLib.GetByName(DialogName)
    oRuntimeDialog = CreateUnoDialog(oLibDialog)
    LoadDialog() = oRuntimeDialog
End Function

Párbeszédablak megjelenítése

REM változók globális meghatározása
Dim oDialog1 AS Object
Sub StartDialog1
    BasicLibraries.LoadLibrary("Tools")
    oDialog1 = LoadDialog("Standard", "Dialog1")
    oDialog1.Execute()
End Sub

A programban levő vezérlőelemek tulajdonságainak olvasása vagy szerkesztése

Sub Sample1
    BasicLibraries.LoadLibrary("Tools")
    oDialog1 = LoadDialog("Standard", "Dialog1")
REM a párbeszédablak-modell beolvasása
    oDialog1Model = oDialog1.Model
REM a Label1 szövegének megjelenítése
    oLabel1 = oDialog1.GetControl("Label1")
    MsgBox oLabel1.Text
REM a Label1 vezérlőelem szövegének megváltoztatása
oLabel1.Text = "Új fájlok"
REM a CheckBox1 vezérlőelem modelltulajdonságainak megjelenítése
    oCheckBox1Model = oDialog1Model.CheckBox1
    MsgBox oCheckBox1Model.Dbg_Properties
REM a CheckBox1 vezérlőelem modelljében új állapot beállítása
    oCheckBox1Model.State = 1
REM a CommandButton1 vezérlőelem modelltulajdonságainak megjelenítése
    oCMD1Model = oDialog1Model.CommandButton1
    MsgBox oCMD1Model.Dbg_Properties
REM a CommandButton1 vezérlőelem tulajdonságainak megjelenítése
    oCMD1 = oDialog1.GetControl("CommandButton1")
    MsgBox oCMD1.Dbg_Properties
REM párbeszédablak futtatása
    oDialog1.Execute()
End Sub

Bejegyzés hozzáadása egy listamezőhöz

Sub AddEntry
    BasicLibraries.LoadLibrary("Tools")
    oDialog1 = LoadDialog("Standard", "Dialog1")
REM hozzáad a listamezőhöz egy új bejegyzést
    oDialog1Model = oDialog1.Model
    oListBox = oDialog1.GetControl("ListBox1")
    Dim iCount as integer
    iCount = oListbox.ItemCount
oListbox.additem("New Item" & iCount,0)
End Sub

Bejegyzés eltávolítása egy listamezőből

Sub RemoveEntry
    BasicLibraries.LoadLibrary("Tools")
    oDialog1 = LoadDialog("Standard", "Dialog1")
REM a listamező első bejegyzésének eltávolítása
    oDialog1Model = oDialog1.Model
    oListBox = oDialog1.GetControl("ListBox1")
    oListbox.removeitems(0,1)
End Sub

Related Topics

Vezérlőelemek tulajdonságainak módosítása a párbeszédablak-szerkesztőben

Basic-párbeszédablak létrehozása

Vezérlőelemek létrehozása a párbeszédablak-szerkesztőben

Párbeszédablak megjelenítés programkóddal