Elkarrizketa-koadroen editoreko kontrolak programatzeko adibideak

From LibreOffice Help
Jump to: navigation, search

Ondorengo adibideak "1.elkarrizketa-koadroa" izeneko elkarrizketa-koadro berriarentzat dira. Erabili elkarrizketa-koadroen editoreko Tresna-koadroa barrako tresnak elkarrizketa-koadroa sortzeko, eta gehitu kontrol hauek: "CheckBox1" izeneko Kontrol-laukia, "Label1" izeneko Etiketa-eremua, "CommandButton1" izeneko Botoia, eta "ListBox1" izeneko Zerrenda-koadroa.

Warning.png Maiuskulak eta minuskulak mantendu kontrolak objektu-aldagaiei eranstean.

Elkarrizketa-koadroak kargatzeko funtzio globala

Function LoadDialog(Libname as String, DialogName as String, Optional oLibContainer)
Dim oLib as Object
Dim oLibDialog as Object
Dim oRuntimeDialog as Object
    If IsMissing(oLibContainer) Then
        oLibContainer = DialogLibraries
    End If
    oLibContainer.LoadLibrary(LibName)
    oLib = oLibContainer.GetByName(Libname)
    oLibDialog = oLib.GetByName(DialogName)
    oRuntimeDialog = CreateUnoDialog(oLibDialog)
    LoadDialog() = oRuntimeDialog
End Function

Elkarrizketa-koadroak bistaratzea

rem aldagaien definizio orokorra
Dim oDialog1 AS Object
Sub StartDialog1
    BasicLibraries.LoadLibrary("Tools")
    oDialog1 = LoadDialog("Standard", "Dialog1")
    oDialog1.Execute()
End Sub

Kontrolen propietateak programan irakurtzea edo editatzea

Sub Sample1
    BasicLibraries.LoadLibrary("Tools")
    oDialog1 = LoadDialog("Standard", "Dialog1")
REM lortu elkarrizketa-koadroaren eredua
    oDialog1Model = oDialog1.Model
REM bistaratu Label1en testua
    oLabel1 = oDialog1.GetControl("Label1")
    MsgBox oLabel1.Text
REM ezarri testu berria Label1 kontrolarentzat
oLabel1.Text = "Fitxategi berriak"
REM bistaratu eredu-propietateak CheckBox1 kontrolarentzat
    oCheckBox1Model = oDialog1Model.CheckBox1
    MsgBox oCheckBox1Model.Dbg_Properties
REM ezarri egoera berria CheckBox1entzat kontrol-eredurako
    oCheckBox1Model.State = 1
REM bistaratu eredu-propietateak CommandButton1 kontrolarentzat
    oCMD1Model = oDialog1Model.CommandButton1
    MsgBox oCMD1Model.Dbg_Properties
REM bistaratu CommandButton1 kontrolaren propietateak
    oCMD1 = oDialog1.GetControl("CommandButton1")
    MsgBox oCMD1.Dbg_Properties
REM exekutatu elkarrizketa-koadroa
    oDialog1.Execute()
End Sub

Zerrenda-koadroari sarrera bat gehitzea

Sub AddEntry
    BasicLibraries.LoadLibrary("Tools")
    oDialog1 = LoadDialog("Standard", "Dialog1")
REM sarrera berria gehitzen dio ListBox-i
    oDialog1Model = oDialog1.Model
    oListBox = oDialog1.GetControl("ListBox1")
    Dim iCount as integer
    iCount = oListbox.ItemCount
oListbox.additem("Elementu berria" & iCount,0)
End Sub

Zerrenda-koadrotik sarrera bat kentzea

Sub RemoveEntry
    BasicLibraries.LoadLibrary("Tools")
    oDialog1 = LoadDialog("Standard", "Dialog1")
REM kendu lehen sarrera ListBox-etik
    oDialog1Model = oDialog1.Model
    oListBox = oDialog1.GetControl("ListBox1")
    oListbox.removeitems(0,1)
End Sub

Related Topics

Elkarrizketa-koadroen editoreko kontrolen propietateak aldatzea

Basic elkarrizketa-koadroa sortzea

Elkarrizketa-koadroen editorean kontrolak sortzea

Elkarrizketa-koadroak programa-kodea erabiliz irekitzea