Programmbeispiele für Kontrollfelder im Dialog-Editor

From LibreOffice Help
Jump to: navigation, search

Um diese Beispiele ausprobieren zu können, müssen Sie einen neuen Dialog mit dem Namen "Dialog1" anlegen. Im Dialogeditor legen Sie mithilfe der Schaltflächen in der Werkzeugleiste folgende Kontrollfelder an: ein Markierfeld mit dem Namen "CheckBox1", ein Beschriftungsfeld mit dem Namen "Label1", eine Schaltfläche mit dem Namen "CommandButton1" und ein Listenfeld mit dem Namen "ListBox1".

Warning.png Beim Zuweisen des Kontrollfeldes an eine Objektvariable ist die Schreibweise wichtig. Wenn der Name des Kontrollfeldes klein geschrieben wurde, muss dieser auch mit der selben Schreibweise abgefragt werden.

Globale Funktion zum Laden von Dialogen

Function LoadDialog(Libname as String, DialogName as String, Optional oLibContainer)
Dim oLib as Object
Dim oLibDialog as Object
Dim oRuntimeDialog as Object
    If IsMissing(oLibContainer) Then
        oLibContainer = DialogLibraries
    End If
    oLibContainer.LoadLibrary(LibName)
    oLib = oLibContainer.GetByName(Libname)
    oLibDialog = oLib.GetByName(DialogName)
    oRuntimeDialog = CreateUnoDialog(oLibDialog)
    LoadDialog() = oRuntimeDialog
End Function

Dialog anzeigen

REM globale Variablendefiniton
Dim oDialog1 AS Object
Sub StartDialog1
    BasicLibraries.LoadLibrary("Tools")
    oDialog1 = LoadDialog("Standard", "Dialog1")
    oDialog1.Execute()
End Sub

Eigenschaften von Kontrollfeldern im Programm abfragen oder ändern

Sub Sample1
    BasicLibraries.LoadLibrary("Tools")
    oDialog1 = LoadDialog("Standard", "Dialog1")
REM Model des Dialogs holen
    oDialog1Model = oDialog1.Model
REM Beschriftung des Kontrollfelds Label1 anzeigen
    oLabel1 = oDialog1.GetControl("Label1")
    MsgBox oLabel1.Text
REM Neuen Text am Kontrollfeld Label1 setzen
oLabel1.Text = "New Files"
REM Anzeigen der Model-Eigenschaften für das Kontrollfeld CheckBox1
    oCheckBox1Model = oDialog1Model.CheckBox1
    MsgBox oCheckBox1Model.Dbg_Properties
REM Neuen State für CheckBox1 am Model des Kontrollfelds setzen
    oCheckBox1Model.State = 1
REM Anzeigen der Model-Eigenschaften für das Kontrollfeld CommandButton1
    oCMD1Model = oDialog1Model.CommandButton1
    MsgBox oCMD1Model.Dbg_Properties
REM Anzeigen der Eigenschaften des Kontrollfelds CommandButton1
    oCMD1 = oDialog1.GetControl("CommandButton1")
    MsgBox oCMD1.Dbg_Properties
REM Dialog ausführen
    oDialog1.Execute()
End Sub

Eintrag in einer ListBox hinzufügen

Sub AddEntry
    BasicLibraries.LoadLibrary("Tools")
    oDialog1 = LoadDialog("Standard", "Dialog1")
REM setzt einen neuen Eintrag in die Listbox
    oDialog1Model = oDialog1.Model
    oListBox = oDialog1.GetControl("ListBox1")
    Dim iCount as integer
    iCount = oListbox.ItemCount
oListbox.additem("New Item" & iCount,0)
End Sub

Eintrag in eines Listenfeldes löschen

Sub RemoveEntry
    BasicLibraries.LoadLibrary("Tools")
    oDialog1 = LoadDialog("Standard", "Dialog1")
REM löscht den ersten Eintrag aus der Listbox
    oDialog1Model = oDialog1.Model
    oListBox = oDialog1.GetControl("ListBox1")
    oListbox.removeitems(0,1)
End Sub

Related Topics

Eigenschaften für Kontrollfelder im Dialog-Editor

Erstellen eines Basic-Dialogs

Erstellen von Kontrollfeldern im Dialog-Editor

Aufruf eines Dialogs vom Programmcode aus