ScriptForge.String service

The String service provides a collection of methods for string processing. These methods can be used to:

• Validate the contents of strings

• Format strings by trimming, justifying or wrapping their contents

• Use regular expressions to search and replace substrings

• Apply hash algorithms on strings, etc.

Definitions

Line breaks

The String service recognizes the following line breaks:

Whitespaces

The String service recognizes the following whitespaces:

Escape sequences

Below is a list of escape sequences that can be used in strings.

To have the escape sequence "\n" interpreted as an actual string, simply use "\\n" instead of "\" & Chr(10).

Non-printable characters:

Characters defined in the Unicode Character Database as “Other” or “Separator” are considered as non-printable characters.

Control characters (ascii code <= 0x1F) are also considered as non-printable.

Quotes inside strings:

To add quotes in strings use \' (single quote) or \" (double quote). For example:

• The string [str\'i\'ng] is interpreted as [str'i'ng]

• The string [str\"i\"ng] is interpreted as [str"i"ng]

Service invocation

Before using the ScriptForge.String service the ScriptForge library needs to be loaded using:

      GlobalScope.BasicLibraries.LoadLibrary("ScriptForge")
  

The following code snippets show the three ways to call methods in the String service (the ExpandTabs method is used as an example):

        SF_String.ExpandTabs(...)
    

        Dim s : s = SF_String
        s.ExpandTabs(...)
    

        Dim s : s = CreateScriptService("String")
        s.ExpandTabs(...)
    

Properties

The SF_String object provides the following properties:

You can use the properties above to identify or insert the corresponding characters inside strings. For example, the Linefeed can be replaced by SF_String.sfLF.

The first argument of most methods is the string to be considered. It is always passed by reference and left unchanged. Methods such as Capitalize, Escape, etc return a new string after their execution.

Capitalize

Capitalizes the first character from each word in the input string.

Syntax:

       SF_String.Capitalize(InputStr As String) As String
     

Parameters:

InputStr: The string to be capitalized.

Example:

       Dim sName as String : sName = "john smith"
       Dim sCapitalizedName as String
       sCapitalizedName = SF_String.Capitalize(sName)
       MsgBox sCapitalizedName 'John Smith
     

Count

Counts the number of occurrences of a substring or a regular expression within a string.

Syntax:

        SF_String.Count(InputStr As String, Substring As String[, IsRegex As Boolean][, CaseSensitive As Boolean]) As Long
      

Parameters:

InputStr: The input string to be examined

Substring: The substring or the regular expression to be used during search

IsRegex: Use True if the substring is a regular expression (default = False)

CaseSensitive: Default = False

Example:

        'Counts the occurrences of the substring "or" inside the input string (returns 2)
        MsgBox SF_String.Count("Lorem ipsum dolor sit amet, consectetur adipiscing elit.", "or", CaseSensitive := False)
        'Counts the number of words with only lowercase letters (returns 7)
        MsgBox SF_String.Count("Lorem ipsum dolor sit amet, consectetur adipiscing elit.", "\b[a-z]+\b", IsRegex := True, CaseSensitive := True)
      

To learn more about regular expressions, refer to the Python's documentation on Regular Expression Operations.

EndsWith

Returns True if a string ends with a specified substring.

The function returns False when either the string or the substring have a length = 0 or when the substring is longer than the string.

Syntax:

       SF_String.EndsWith(InputStr As String, Substring As String[, CaseSensitive As Boolean]) As Boolean
     

Parameters:

InputStr: The string to be tested.

Substring: The substring to be searched at the end of InputStr.

CaseSensitive: The comparison can be case sensitive or not (default = False).

Example:

        'Returns True because the method was called with the default CaseSensitive = False
        MsgBox SF_String.EndsWith("abcdefg", "EFG")
        'Returns False due to the CaseSensitive parameter
        MsgBox SF_String.EndsWith("abcdefg", "EFG", CaseSensitive := True)
      

Escape

Converts linebreaks and tabs contained in the input string to their equivalent escaped sequence (\\, \n, \r, \t).

Syntax:

          SF_String.Escape(InputStr As String) As String
      

Parameters:

InputStr: The string to be converted.

Example:

          'Returns the string "abc\n\tdef\\n"
          MsgBox SF_String.Escape("abc" & Chr(10) & Chr(9) & "def\n")
        

ExpandTabs

Replaces Tab characters Chr(9) by space characters to replicate the behavior of tab stops.

If a line break is found, a new line is started and the character counter is reset.

Syntax:

        SF_String.ExpandTabs(InputStr As String[, TabSize As Integer]) As String
      

Parameters:

InputStr: The string to be expanded

TabSize: This parameter is used to determine the Tab stops using the formula: TabSize + 1, 2 * TabSize + 1 , ... N * TabSize + 1 (default = 8)

Example:

        Dim myText as String
        myText = "100" & SF_String.sfTAB & "200" & SF_String.sfTAB & "300" & SF_String.sfNEWLINE & _
                 "X"  & SF_String.sfTAB & "Y" & SF_String.sfTAB & "Z"
        MsgBox SF_String.ExpandTabs(myText)
        '100     200     300
        'X       Y       Z
      

FilterNotPrintable

Replaces all non-printable characters in the input string by a given character.

Syntax:

        SF_String.FilterNotPrintable(InputStr As String[, ReplacedBy As String]) As String
      

Parameters:

InputStr: The string to be searched

ReplacedBy: Zero, one or more characters that will replace all non-printable characters in InputStr (Default = "")

Example:

        Dim LF : LF = Chr(10)
        Dim myText as String
        myText = "àén ΣlPµ" & LF & " Русский" & "\n"
        MsgBox SF_String.FilterNotPrintable(myText)
        ' "àén ΣlPµ Русский\n"
      

FindRegex

Finds in a string a substring matching a given regular expression.

Syntax:

        SF_String.FindRegex(InputStr As String, Regex As String[, Start As Long[, CaseSensitive As Boolean[, Forward As Boolean]]]) As String
      

Parameters:

InputStr: The string to be searched

Regex: The regular expression

Start: The position in the string where the search will begin. This parameter is passed by reference, so after execution the value of Start will point to the first character of the found substring. If no matching substring is found, Start will be set to 0.

CaseSensitive: Default = False

Forward: Determines the direction of the search. If True, search moves forward. If False search moves backwards (Default = True)

At the first iteration, if Forward = True, then Start should be equal to 1, whereas if Forward = False then Start should be equal to Len(InputStr)

Example:

        Dim lStart As Long : lStart = 1
        Dim result as String
        result = SF_String.FindRegex("abCcdefghHij", "C.*H", lStart, CaseSensitive := True)
        MsgBox lStart & ": " & result
        '3: CcdefghH
      

In the example above, the new value of lStart can be used to keep searching the same input string by setting the Start parameter to lStart + Len(result) at the next iteration.

HashStr

Hash functions are used inside some cryptographic algorithms, in digital signatures, message authentication codes, manipulation detection, fingerprints, checksums (message integrity check), hash tables, password storage and much more.

The HashStr method returns the result of a hash function applied on a given string and using a specified algorithm, as a string of lowercase hexadecimal digits.

The hash algorithms supported are: MD5, SHA1, SHA224, SHA256, SHA384 and SHA512.

Syntax:

          SF_String.HashStr(InputStr As String, Algorithm As String) As String
      

Parameters:

InputStr : The string to hash. It is presumed to be encoded in UTF-8. The hashing algorithm will consider the string as a stream of bytes.

Algorithm : One of the supported algorithms listed above, passed as a string.

Example:

          MsgBox SF_String.HashStr("œ∑¡™£¢∞§¶•ªº–≠œ∑´®†¥¨ˆøπ‘åß∂ƒ©˙∆˚¬", "MD5")
          ' c740ccc2e201df4b2e2b4aa086f35d8a
      

HtmlEncode

Encodes the input string into the HTML character codes, replacing special characters by their & counterparts.

For example, the character é would be replaced by &eacute; or an equivalent numerical HTML code.

Syntax:

        SF_String.HtmlEncode(InputStr) As String
      

Parameters:

InputStr: The string to encode

Example:

        MsgBox SF_String.HtmlEncode("<a href=""https://a.b.com"">From α to ω</a>")
        ' "&lt;a href=&quot;https://a.b.com&quot;&gt;From &#945; to &#969;&lt;/a&gt;"
      

IsADate

Returns True if the input string is a valid date according to a specified date format.

Syntax:

        SF_String.IsADate(InputStr As String[, DateFormat As String]) As Boolean
      

Parameters:

InputStr: The string to be checked. If empty, the method returns False

DateFormat: The date format, as a string. It can be either "YYYY-MM-DD" (default), "DD-MM-YYYY" or "MM-DD-YYYY"

The dash (-) may be replaced by a dot (.), a slash (/) or a space.

If the format is invalid, the method returns False.

Example:

        MsgBox SF_String.IsADate("2020-12-31", "YYYY-MM-DD") ' True
      

This method checks the format of the input string without performing any calendar-specific checks. Hence it does not test the input string for leap years or months with 30 or 31 days. For that, refer to the IsDate built-in function.

The example below shows the difference between the methods IsADate (ScriptForge) and the IsDate (built-in) function.

    Dim myDate as String : myDate = "2020-02-30"
    MsgBox SF_String.IsADate(myDate, "YYYY-MM-DD") 'True
    MsgBox IsDate(myDate) 'False
  

IsAlpha

Returns True if all characters in the string are alphabetic.

Alphabetic characters are those characters defined in the Unicode Character Database as Letter.

Syntax:

        SF_String.IsAlpha(InputStr As String) As Boolean
      

Parameters:

InputStr: The string to be checked. If empty, the method returns False.

Example:

        MsgBox SF_String.IsAlpha("àénΣlPµ") 'True
        MsgBox SF_String.IsAlpha("myVar3") 'False
      

IsAlphaNum

Returns True if all characters in the string are alphabetic, digits or "_" (underscore). The first character must not be a digit.

Syntax:

        SF_String.IsAlphaNum(InputStr As String) As Boolean
      

Parameters:

InputStr: The string to be checked. If empty, the method returns False.

Example:

        MsgBox SF_String.IsAlphaNum("_ABC_123456_abcàénΣlPµ") 'True
        MsgBox SF_String.IsAlphaNum("123ABC") 'False
      

IsAscii

Returns True if all characters in the string are Ascii characters.

Syntax:

        SF_String.IsAscii(InputStr As String) As Boolean
      

Parameters:

InputStr: The string to be checked. If empty, the method returns False.

Example:

        MsgBox SF_String.IsAscii("a%?,25") 'True
        MsgBox SF_String.IsAscii("abcàénΣlPµ") 'False
      

IsDigit

Returns True if all characters in the string are digits.

Syntax:

        SF_String.IsDigit(InputStr As String) As Boolean
      

Parameters:

InputStr: The string to be checked. If empty, the method returns False.

Example:

        MsgBox SF_String.IsDigit("123456") 'True
        MsgBox SF_String.IsDigit("_12a") 'False
      

IsEmail

Returns True if the string is a valid email address.

Syntax:

        SF_String.IsEmail(InputStr As String) As Boolean
      

Parameters:

InputStr: The string to be checked. If empty, the method returns False.

Example:

        MsgBox SF_String.IsEmail("first.last@something.org") 'True
        MsgBox SF_String.IsEmail("first.last@something.com.br") 'True
        MsgBox SF_String.IsEmail("first.last@something.123") 'False
      

IsFileName

Returns True if the string is a valid filename in a given operating system.

Syntax:

        SF_String.IsFileName(InputStr As String[, OSName As String]) As Boolean
      

Parameters:

InputStr: The string to be checked. If empty, the method returns False.

OSName: The operating system name, as a string. It can be WINDOWS, LINUX, MACOSX or SOLARIS.

The default value is the current operating system on which the script is running.

Example:

        MsgBox SF_String.IsFileName("~/Documents/a file name.odt", "LINUX") 'True
        MsgBox SF_String.IsFileName("C:\home\a file name.odt", "LINUX") 'False
        MsgBox SF_String.IsFileName("C:\home\a file name.odt", "WINDOWS") 'True
      

IsHexDigit

Returns True if all characters in the string are hexadecimal digits.

Syntax:

        SF_String.IsHexDigit(InputStr As String) As Boolean
      

Parameters:

InputStr: The string to be checked. If empty, the method returns False.

The hexadecimal digits may be prefixed with "0x" or "&H".

Example:

        MsgBox SF_String.IsHexDigit("&H00FF") 'True
        MsgBox SF_String.IsHexDigit("08AAFF10") 'True
        MsgBox SF_String.IsHexDigit("0x18LA22") 'False
      

IsIBAN

Returns True if the string is a valid International Bank Account Number (IBAN). The comparison is not case-sensitive.

This method is available from LibreOffice 7.2 onwards.

Syntax:

        SF_String.IsIBAN(InputStr As String) As Boolean
      

Parameters:

InputStr: The string to be checked. If empty, the method returns False.

Return value:

True if the string contains a valid IBAN number.

Example:

        MsgBox SF_String.IsIBAN("BR15 0000 0000 0000 1093 2840 814 P2") 'returns True
      

IsIPv4

Returns True if the string is a valid IP(v4) address.

Syntax:

        SF_String.IsIPv4(InputStr As String) As Boolean
      

Parameters:

InputStr: The string to be checked. If empty, the method returns False.

Example:

        MsgBox SF_String.IsIPv4("192.168.1.50") 'True
        MsgBox SF_String.IsIPv4("192.168.50") 'False
        MsgBox SF_String.IsIPv4("255.255.255.256") 'False
      

IsLike

Returns True if the whole input string matches a given pattern containing wildcards.

Syntax:

        SF_String.IsLike(InputStr As String, Pattern As String[, CaseSensitive As Boolean) As Boolean
      

Parameters:

InputStr: The string to be checked. If empty, the method returns False.

Pattern: The pattern as a string. Wildcard are:

• "?" represents any single character;

• "*" represents zero, one, or multiple characters.

CaseSensitive: Default = False.

Example:

        MsgBox SF_String.IsLike("aAbB", "?A*") 'True
        MsgBox SF_String.IsLike("C:\a\b\c\f.odb", "?:*.*") 'True
        MsgBox SF_String.IsLike("name:host", "?*@?*") 'False
        MsgBox SF_String.IsLike("@host", "?*@?*") 'False
      

IsLower

Returns True if all characters in the string are in lowercase. Non-alphabetic characters are ignored.

Syntax:

        SF_String.IsLower(InputStr As String) As Boolean
      

Parameters:

InputStr: The string to be checked. If empty, the method returns False.

Example:

        MsgBox SF_String.IsLower("abc'(-xy4z") 'True
        MsgBox SF_String.IsLower("1234") ' True
        MsgBox SF_String.IsLower("abcDefg") 'False
      

IsPrintable

Returns True if all characters in the string are printable.

Syntax:

        SF_String.IsPrintable(InputStr As String) As Boolean
      

Parameters:

InputStr: The string to be checked. If empty, the method returns False.

Example:

        MsgBox SF_String.IsPrintable("àén ΣlPµ Русский") 'True
        MsgBox SF_String.IsPrintable("First line." & Chr(10) & "Second Line.") 'False
      

IsRegex

Returns True if the whole input string matches a given regular expression.

Syntax:

        SF_String.IsRegex(InputStr As String, Regex As String[, CaseSensitive As Boolean) As Boolean
      

Parameters:

InputStr: The string to be checked. If empty, the method returns False.

Regex: The regular expression. If empty, the method returns False.

CaseSensitive: Default = False.

Example:

        MsgBox SF_String.IsRegex("aAbB", "[A-Za-z]+") ' True
        MsgBox SF_String.IsRegex("John;100", "[A-Za-z]+;[0-9]+") 'True
        MsgBox SF_String.IsRegex("John;100;150", "[A-Za-z]+;[0-9]+") 'False
      

IsSheetName

Returns True if the input string is a valid Calc sheet name.

Syntax:

          SF_String.IsSheetName(InputStr As String) As Boolean
      

Parameters:

InputStr: The string to be checked. If empty, the method returns False.

Example:

          MsgBox SF_String.IsSheetName("1àbc + ""déf""") 'True
          MsgBox SF_String.IsSheetName("[MySheet]") 'False
      

A sheet name must not contain the characters [ ] * ? : / \ or the character ' (apostrophe) as first or last character.

IsTitle

Returns True if the first character of every word is in uppercase and the other characters are in lowercase.

Syntax:

        SF_String.IsTitle(InputStr As String) As Boolean
      

Parameters:

InputStr: The string to be checked. If empty, the method returns False.

Example:

        MsgBox SF_String.IsTitle("This Is The Title Of My Book") 'True
        MsgBox SF_String.IsTitle("This is the Title of my Book") 'False
        MsgBox SF_String.IsTitle("Result Number 100") 'True
      

IsUpper

Returns True if all characters in the string are in uppercase. Non alphabetic characters are ignored.

Syntax:

        SF_String.IsUpper(InputStr As String) As Boolean
      

Parameters:

InputStr: The string to be checked. If empty, the method returns False.

Example:

        MsgBox SF_String.IsUpper("ABC'(-XYZ") 'True
        MsgBox SF_String.IsUpper("A Title") 'False
      

IsUrl

Returns True if the string is a valid absolute URL (Uniform Resource Locator) address. Only the http, https and ftp protocols are supported.

Syntax:

        SF_String.IsUrl(InputStr As String) As Boolean
      

Parameters:

InputStr: The string to be checked. If empty, the method returns False.

Example:

        MsgBox SF_String.IsUrl("http://foo.bar/?q=Test%20URL-encoded%20stuff") 'True
        MsgBox SF_String.IsUrl("www.somesite.org") 'False
      

IsWhitespace

Returns True if all characters in the string are whitespaces

Syntax:

        SF_String.IsWhitespace(InputStr As String) As Boolean
      

Parameters:

InputStr: The string to be checked. If empty, the method returns False.

Example:

        MsgBox SF_String.IsWhitespace("    ") 'True
        MsgBox SF_String.IsWhitespace(" " & Chr(9) & Chr(10)) 'True
        MsgBox SF_String.IsWhitespace("") 'False
      

JustifyCenter

Returns the input string center-justified.

The leading and trailing white spaces are stripped and the remaining characters are completed left and right up to a specified total Length with the character Padding.

Syntax:

        SF_String.JustifyCenter(InputStr As String[, Length As Long[, Padding As String]]) As String
      

Parameters:

InputStr: The string to be center-justified. If empty, the method returns an empty string.

Length: The length of the resulting string (default = the length of the input string).

If the specified length is shorter than the center-justified input string, then the returned string is truncated.

Padding: The single character to be used as padding (default = the Ascii space " ").

Example:

        MsgBox SF_String.JustifyCenter("Title", Length := 11) ' "   Title   "
        MsgBox SF_String.JustifyCenter("    ABCDE", Padding := "_") ' "__ABCDEF__"
        MsgBox SF_String.JustifyCenter("A Long Title", Length := 5) ' "ong T"
      

JustifyLeft

Returns the input string left-justified.

The leading white spaces are stripped and the remaining characters are completed to the right up to a specified total Length with the character Padding.

Syntax:

        SF_String.JustifyLeft(InputStr As String[, Length As Long[, Padding As String]]) As String
      

Parameters:

InputStr: The string to be left-justified. If empty, the method returns an empty string.

Length: The length of the resulting string (default = the length of the input string).

If the specified length is shorter than the left-justified input string, then the returned string is truncated.

Padding: The single character to be used as padding (default = the Ascii space " ").

Example:

        MsgBox SF_String.JustifyLeft("Title", Length := 10) ' "Title     "
        MsgBox SF_String.JustifyLeft("    ABCDE", Padding := "_") ' "ABCDEF____"
        MsgBox SF_String.JustifyLeft("A Long Title", Length := 5) ' "A Lon"
      

JustifyRight

Returns the input string right-justified.

The leading white spaces are stripped and the remaining characters are completed to the left up to a specified total Length with the character Padding.

Syntax:

        SF_String.JustifyRight(InputStr As String[, Length As Long[, Padding As String]]) As String
      

Parameters:

InputStr: The string to be right-justified. If empty, the method returns an empty string.

Length: The length of the resulting string (default = the length of the input string).

If the specified length is shorter than the right-justified input string, then the returned string is truncated.

Padding: The single character to be used as padding (default = the Ascii space " ").

Example:

        MsgBox SF_String.JustifyRight("Title", Length := 10) ' "     Title"
        MsgBox SF_String.JustifyRight("  ABCDE  ", Padding := "_") ' "____ABCDEF"
        MsgBox SF_String.JustifyRight("A Long Title", Length := 5) ' "Title"
      

Quote

Returns the input string enclosed in single or double quotes. Existing quotes are left unchanged, including leading and/or trailing quotes.

Syntax:

        SF_String.Quote(InputStr As String, [QuoteChar As String]) As String
      

Parameters:

InputStr: the string to quote.

QuoteChar : Either the single (') or (default) double (") quote.

Example:

        MsgBox SF_String.Quote("Text Value")
        ' "Text Value"
        MsgBox SF_String.Quote("Book Title: ""The Arabian Nights""", "'")
        ' 'Book Title: "The Arabian Nights"'
      

This method can be useful while preparing a string field to be stored in a csv-like file, which requires that text values be enclosed with single or double quotes.

ReplaceChar

Replaces all occurrences of the characters specified in the Before parameter by the corresponding characters specified in After.

If the length of Before is greater than the length of After, the residual characters in Before are replaced by the last character in After.

Syntax:

        SF_String.ReplaceChar(InputStr As String, Before As String, After As String) As String
      

Parameters:

InputStr: The input string on which replacements will occur.

Before: A string with the characters that will be searched in the input string for replacement.

After: A string with the new characters that will replace those defined in Before.

Example:

        ' Replaces accented characters
        MsgBox SF_String.ReplaceChar("Protégez votre vie privée", "àâãçèéêëîïôöûüýÿ", "aaaceeeeiioouuyy")
        ' "Protegez votre vie privee"
        MsgBox SF_String.ReplaceChar("Protégez votre vie privée", "àâãçèéêëîïôöûüýÿ", "")
        ' "Protgez votre vie prive"
        MsgBox SF_String.ReplaceChar("àâãçèéêëîïôöûüýÿ", "àâãçèéêëîïôöûüýÿ", "aaaceeeeiioouuyy")
        ' "aaaceeeeiioouuyy"
    

The SF_String service provides useful public constants for the Latin character sets, as shown in the example below:

        MsgBox SF_String.ReplaceChar("Protégez votre vie privée", SF_String.CHARSWITHACCENT, SF_String.CHARSWITHOUTACCENT)
        ' "Protegez votre vie privee"
      

ReplaceRegex

Replaces all occurrences of a given regular expression by a new string.

Syntax:

        SF_String.ReplaceRegex(InputStr As String, Regex As String, NewStr As String[, CaseSensitive As Boolean]) As String
      

Parameters:

InputStr: The input string on which replacements will occur.

Regex: The regular expression.

NewStr: The replacing string.

CaseSensitive: Default = False.

Example:

          MsgBox SF_String.ReplaceRegex("Lorem ipsum dolor sit amet, consectetur adipiscing elit.", "[a-z]", "x", CaseSensitive := True)
          ' "Lxxxx xxxxx xxxxx xxx xxxx, xxxxxxxxxxx xxxxxxxxxx xxxx." (each lowercase letter is replaced by "x")
          MsgBox SF_String.ReplaceRegex("Lorem ipsum dolor sit amet, consectetur adipiscing elit.", "\b[a-z]+\b", "x", CaseSensitive := False)
          ' "x x x x x, x x x." (each word is replaced by "x")
      

ReplaceStr

Replaces in a string some or all occurrences of an array of strings by an array of new strings.

Syntax:

        SF_String.ReplaceStr(InputStr As String, OldStr As Variant, NewStr As Variant[, Occurrences As Long[, CaseSensitive As Boolean]]) As String
      

Parameters:

InputStr: The input string on which replacements will occur.

OldStr: A single string or an array of strings. Zero-length strings are ignored.

NewStr: The replacing string or the array of replacing strings.

If OldStr is an array, each occurrence of any of the items in OldStr is replaced by NewStr.

If OldStr and NewStr are arrays, replacements occur one by one up to the UBound(NewStr).

If OldStr has more entries than NewStr, then the residual elements in OldStr are replaced by the last element in NewStr.

Occurrences: The maximum number of replacements. The default value is 0, meaning that all occurrences will be replaced.

When OldStr is an array, the Occurrence parameter is computed separately for each item in the array.

CaseSensitive: Default = False.

Example:

        MsgBox SF_String.ReplaceStr("100 xxx 200 yyy", Array("xxx", "yyy"), Array("(1)", "(2)"), CaseSensitive := False)
        ' "100 (1) 200 (2)"
        MsgBox SF_String.ReplaceStr("abCcdefghHij", Array("c", "h"), Array("Y", "Z"), CaseSensitive := False)
        ' "abYYdefgZZij"
      

Represent

Returns a string with a readable representation of the argument, truncated at a given length. This is useful mainly for debugging or logging purposes.

If the AnyValue parameter is an object, it will be enclosed with square brackets "[" and "]".

In strings, tabs and line breaks are replaced by \t, \n or \r.

If the final length exceeds the MaxLength parameter, the latter part of the string is replaced by " ... (N)" where N is the total length of the original string before truncation.

Syntax:

        SF_String.Represent(AnyValue As Variant[, MaxLength As Long]) As String
      

Parameters:

AnyValue: The input value to be represented. It can be any value, such as a string, an array, a Basic object, a UNO object, etc.

MaxLength: The maximum length of the resulting string. The default value is 0, meaning there is no limit to the length of the resulting representation.

Example:

        MsgBox SF_String.Represent("this is a usual string") ' "this is a usual string"
        MsgBox SF_String.Represent("this is a usual string", 15) ' "this i ... (22)"
        MsgBox SF_String.Represent("this is a" & Chr(10) & " 2-lines string") ' "this is a\n 2-lines string"
        MsgBox SF_String.Represent(Empty) ' "[EMPTY]"
        MsgBox SF_String.Represent(Null) ' "[NULL]"
        MsgBox SF_String.Represent(Pi) ' "3.142"
        MsgBox SF_String.Represent(CreateUnoService("com.sun.star.util.PathSettings")) ' "[com.sun.star.comp.framework.PathSettings]"
      

Note that the representation of data types such as Arrays and ScriptForge.Dictionary object instances include both the data type and their values:

    ' An example with a Basic built-in Array
    MsgBox SF_String.Represent(Array(1, 2, "Text" & Chr(9) & "here"))
    ' "[ARRAY] (0:2) (1, 2, Text\there)"
    ' An example with a ScriptForge Array
    Dim aValues as Variant
    aValues = SF_Array.RangeInit(1, 5)
    MsgBox SF_String.Represent(aValues)
    ' "[ARRAY] (0:4) (1.0, 2.0, 3.0, 4.0, 5.0)"
    ' An example with a ScriptForge Dictionary
    Dim myDict As Variant : myDict = CreateScriptService("Dictionary")
    myDict.Add("A", 1) : myDict.Add("B", 2)
    MsgBox SF_String.Represent(myDict)
    ' "[Dictionary] ("A":1, "B":2)"
  

Reverse

Returns the input string in reversed order.

This method is equivalent to the built-in StrReverse Basic function, however with better performance.

To use the StrReverse function, the statement OpTion VBASupport 1 must be present in the module.

Syntax:

        SF_String.Reverse(InputStr As String) As String
      

Parameters:

InputStr: The string to be reversed.

Example:

        MsgBox SF_String.Reverse("abcdefghij") ' "jihgfedcba"
      

SplitLines

Returns a zero-based array of strings with the lines in the input string. Each item in the array is obtained by splitting the input string at newline characters.

Syntax:

        SF_String.SplitLines(InputStr As String[, KeepBreaks As Long]) As Variant
      

Parameters:

InputStr: The string to be split.

KeepBreaks: When True, line breaks are preserved in the output array (default = False).

Example:

        Dim a as Variant
        a = SF_String.SplitLines("Line1" & Chr(10) & "Line2" & Chr(13) & "Line3")
        ' a = Array("Line1", "Line2", "Line3")
        a = SF_String.SplitLines("Line1" & Chr(10) & "Line2" & Chr(13) & "Line3" & Chr(10))
        ' a = Array("Line1", "Line2", "Line3", "")
        a = SF_String.SplitLines("Line1" & Chr(10) & "Line2" & Chr(13) & "Line3" & Chr(10), KeepBreaks := True)
        ' a = Array("Line1\n", "Line2\r", "Line3\n", "")
      

SplitNotQuoted

Splits a string into an array of elements using a specified delimiter.

If a quoted substring contains a delimiter, it is ignored. This is useful when parsing CSV-like records that contain quoted strings.

Syntax:

        SF_String.SplitNotQuoted(InputStr As String[, Delimiter As String], [Occurrences As Long], [QuoteChar As String]) As Variant
      

Parameters:

InputStr: The string to be split.

Delimiter: A string of one or more characters that will be used as delimiter. The default delimiter is the space character.

Occurrences: The maximum number of substrings to return. The default value is 0, meaning that there is no limit to the number of returned strings.

QuoteChar : Either the single (') or double (") quote.

Example:

        a = SF_String.SplitNotQuoted("abc def ghi")
        ' a = Array("abc", "def", "ghi")
        a = SF_String.SplitNotQuoted("abc,""def,ghi""", ",")
        ' a = Array("abc", """def,ghi""")
        a = SF_String.SplitNotQuoted("abc,""def\"",ghi""", ",")
         ' a = Array("abc", """def\"",ghi""")
        a = SF_String.SplitNotQuoted("abc,""def\"",ghi"""",", ",")
        ' a = Array("abc", """def\"",ghi""", "")
      

StartsWith

Returns True if the first characters of a string are identical to a given substring.

This method returns False if either the input string or the substring have a length = 0 or when the substring is longer than the input string.

Syntax:

        SF_String.StartsWith(InputStr As String, Substring As String[, CaseSensitive As Boolean]) As Boolean
      

Parameters:

InputStr: The string to be tested.

Substring: The substring to be searched at the start of InputStr.

CaseSensitive: Default = False.

Example:

        MsgBox SF_String.StartsWith("abcdefg", "ABC") 'True
        MsgBox SF_String.StartsWith("abcdefg", "ABC", CaseSensitive := True) 'False
      

TrimExt

Returns the input string without its leading and trailing whitespaces.

Syntax:

        SF_String.TrimExt(InputStr As String) As String
      

Parameters:

InputStr: The string to trimmed.

Example:

        MsgBox SF_String.TrimExt(" Some text.  ") ' "Some text."
        MsgBox SF_String.TrimExt("   ABCDE" & Chr(9) & Chr(10) & Chr(13) & " ") ' "ABCDEF"
      

Unescape

Converts any escaped sequence (\\, \n, \r, \t) in the input string to their corresponding Ascii character.

Syntax:

        SF_String.Unescape(InputStr As String) As String
      

Parameters:

InputStr: The string to be converted.

Example:

        MsgBox SF_String.Unescape("abc\n\tdef\\n")
        ' "abc" & Chr(10) & Chr(9) & "def\n"
      

Unquote

Removes the single or double quotes enclosing the input string.

This is useful when parsing CSV-like records that contain quoted strings.

Syntax:

        SF_String.Unquote(InputStr As String, [QuoteChar As String]) As String
      

Parameters:

InputStr : The string to unquote.

QuoteChar : Either the single (') or double (") quote (default).

Example:

        Dim s as String
        s = SF_String.Unquote("""Some text""") ' s = "Some text" (without enclosing quotes)
        ' The string below does not have enclosing quotes, so it remains unchanged
        s = SF_String.Unquote("Some text") ' s = "Some text" (unchanged)
        ' Quotes inside the string are not removed
        s = SF_String.Unquote("The ""true"" meaning") ' s = "The ""true"" meaning"
      

Wrap

Converts the input string into an array of substrings so that each item in the array has at most a given number of characters.

In practice, this method returns a zero-based array of output lines, without newlines at the end, except for the pre-existing line-breaks.

Tabs are expanded using the same procedure performed by the ExpandTabs method.

Symbolic line breaks are replaced by their equivalent Ascii characters.

If the wrapped output has no content, the returned array is empty.

Syntax:

          SF_String.Wrap(InputStr As String, [Width As Long], [TabSize As Integer]) As String
      

Parameters:

InputStr: The string to wrap.

Width : The maximum number of characters in each line (default = 70).

TabSize : Before wrapping the text, the existing TAB Chr(9) characters are replaced with spaces. TabSize defines the TAB stops at TabSize + 1, 2 * TabSize + 1 , ... N * TabSize + 1 (default = 8).

Example:

          a = "Neque porro quisquam est qui dolorem ipsum quia dolor sit amet, consectetur, adipisci velit..."
          b = SF_String.Wrap(a, 20)
          ' Array("Neque porro ", "quisquam est qui ", "dolorem ipsum quia ", "dolor sit amet, ", "consectetur, ", "adipisci velit...")
        

All ScriptForge Basic routines or identifiers that are prefixed with an underscore character "_" are reserved for internal use. They are not meant be used in Basic macros.