Identificazione del sistema operativo

L'identificazione del sistema operativo si può eseguire col linguaggio Python o Basic.

La proprietà ComputerName è disponibile solo per Windows. Le chiamate Basic alle macro Python aiutano a superare le limitazioni di LibreOffice Basic.

Uso di una classe Python:


        import os, platform
        class Platform():
            @property
            def ComputerName(self): return platform.node()
            @property
            def DirSeparator(self): return os.sep
            @property
            def isLinux(self): return (self.OSName=='Linux')
            @property
            def isMacOSX(self): return (self.OSName=='Darwin')
            @property
            def isWindows(self): return (self.OSName=='Windows')
            @property
            def OSName(self): return platform.system()
            @property
            def PathDelimiter(self): return os.pathsep

Uso di un modulo di classe Basic:

LibreOffice Basic difetta del riconoscimento nativo per MacOS X. L'identificazione della piattaforma è possibile utilizzando l'API (Application Programming Interface) di LibreOffice.


        Option Compatible
        Option ClassModule
        Option Explicit
        
        Public Property Get ComputerName As String
            If isWindows Then ComputerName = Environ("ComputerName")
        End Property ' Platform.ComputerName
        
        Public Property Get DirSeparator As String
            DirSeparator = GetPathSeparator()
        End Property ' Platform.DirSeparator
        
        Public Property Get IsLinux As Boolean
            isLinux = ( GetGUIType()=4 ) ' Applies to macOS as well 
        End Property ' Platform.isLinux
        
        Public Property Get IsMacOSX As Boolean
            isMacOSX = ( OSName="MAC" )
        End Property ' Platform.isMacOSX
        
        Public Property Get IsWindows As Boolean
            isWindows = ( GetGUIType()=1 )
        End Property ' Platform.isWindows
        
        Public Property Get OSName As String
            ' Restituisce il nome della piattaforma come "MAC", "UNIX", "WIN"
            ' Dedotta dalla funzione "Tools.UCB.ShowHelperDialog"
            With GlobalScope.Basiclibraries
                If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
            End With
            Dim keyNode As Object ' com.sun.star.configuration.ConfigurationAccess
            keyNode = Tools.Misc.GetRegistryKeyContent("org.openoffice.Office.Common/Help")
            OSName = keyNode.GetByName("System")
        End Property ' Platform.OSName
        
        Public Property Get PathDelimiter As String
            Select Case OSName
                Case "MAC", "UNIX" : PathDelimiter = ":"
                Case "WIN" : PathDelimiter = ";"
             End Select
        End Property ' Platform.PathDelimiter

Esempi:

Con Python

>>> from <the_module> import Platform

>>> print(Platform().isMacOSX) # proprietà dell'oggetto

True

>>> input(Platform().OSName) # proprietà dell'oggetto

Darwin

Dal menu Strumenti – Macro - Esegui macro....


        from <the_module> import Platform
        import screen_io as ui
        p = Platform()
        ui.MsgBox(''.join(['isMacOS: ',str(p.isMacOSX)]),0,p.OSName)

Con LibreOffice Basic


        Sub Platform_example()
            Dim p As New Platform ' istanza di classe di piattaforma
            MsgBox p.isLinux ' proprietà dell'oggetto
            Print p.isWindows, p.OSName ' proprietà dell'oggetto
        End Sub ' Platform_example

Input/output su schermo

Funzione GetGuiType

Funzione GetPathSeparator

Esempi di programmazione in Python

Guida agli script Python di LibreOffice