Instrução Get

Lê um registro de um arquivo relativo ou uma sequência de bytes de um arquivo binário para uma variável.

Veja também: Instrução PUT

Sintaxe:


Get [#] FileNumber As Integer, [Position], Variable

Parâmetros:

FileNumber: qualquer expressão de número inteiro que determine o número do arquivo.

Position: para arquivos abertos no modo aleatório, Position é o número do registro a ser lido.

Para arquivos abertos no modo Binary, Position é a posição de byte no arquivo onde a leitura é iniciada.

Se Position for omitido, a posição atual ou o registro de dados atual do arquivo será usado.

Variable: Nome da variável a ser lida. À exceção de variáveis de objetos, você pode usar qualquer tipo de variável.

Exemplo:


Sub ExampleRandomAccess
Dim iNumber As Integer
Dim sText As Variant ' Deve ser uma variante
Dim aFile As String
    aFile = "c:\data.txt"
    iNumber = Freefile
    Open aFile For Random As #iNumber Len=32
    Seek #iNumber,1 ' Posição no início
    Put #iNumber,, "Esta é a primeira linha de texto" ' Preenche a linha com texto
    Put #iNumber,, "Esta é a segunda linha de texto"
    Put #iNumber,, "Esta é a terceira linha de texto"
    Seek #iNumber,2
    Get #iNumber,,sText
    Print sText
    Close #iNumber
    iNumber = Freefile
    Open aFile For Random As #iNumber Len=32
    Get #iNumber,2,sText
    Put #iNumber,,"Este é um novo texto"
    Get #iNumber,1,sText
    Get #iNumber,2,sText
    Put #iNumber,20,"Este é o texto no registro 20"
    Print Lof(#iNumber)
    Close #iNumber
End Sub