GEMIDDELDE.ALS-functie
Geeft het rekenkundig gemiddelde van alle cellen in een bereik die aan een bepaalde voorwaarde voldoen. De GEMIDDELDE.ALS-functie telt alle resultaten op die overeenkomen met de logische test en deelt dit totaal door het aantal geselecteerde waarden.
GEMIDDELDE.ALS(Bereik; Criterium [; Gemiddeld_Bereik])
Bereik – vereist argument. Een matrix, een naam van een benoemd bereik of een label van een kolom of een rij met getallen voor het bepalen van een gemiddelde of getallen of tekst voor de conditie.
Criterium1 – vereist argument. Een voorwaarde in de vorm van expressie of een verwijzing naar een cel met een expressie, die bepaalt welke cellen worden gebruikt om het gemiddelde te berekenen. De expressie kan tekst, cijfers of reguliere expressies bevatten (als dit in de rekenopties is aangezet) of jokertekens (als dit in de rekenopties is aangezet).
The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in .
When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".
Gemiddeld_Bereik – optioneel. Het is een reeks waarden voor de berekening van het gemiddelde.
If the Average_Range is not specified, Range is used for both, the calculation of the mean and the search according to the condition. If Average_Range is specified, the Range is used only for the condition test, while Average_Range is used for the average calculation.
Deze functie maakt deel uit van het Open Document Format voor Office Applications (OpenDocument) standaard versie 1.2. (ISO/IEC 26300: 2-2015)
Als een cel in een bereik van waarden voor het berekenen van het gemiddelde leeg is of tekst bevat, negeert de functie GEMIDDELDE.ALS deze cel.
Als de hele reeks leeg is, alleen tekst bevat of alle waarden van de reeks voldoen niet aan de voorwaarde (of een combinatie hiervan), geeft de functie de fout #DIV/0!.
Overweeg de volgende tabel
|
A |
B |
C |
|
|
1 |
Productnaam |
Verkopen |
Ontvangsten |
|
2 |
potlood |
20 |
65 |
|
3 |
pen |
35 |
85 |
|
4 |
kladblok |
20 |
190 |
|
5 |
boek |
17 |
180 |
|
6 |
etui |
niet |
niet |
In alle onderstaande voorbeelden, bevatten bereiken voor berekening de rij # 6, die genegeerd wordt omdat deze tekst bevat.
In alle onderstaande berekeningen, bevat het bereik voor de berekening van gemiddelden de rij #6, maar deze wordt genegeerd, omdat deze tekst bevat.
Eenvoudig gebruik
=GEMIDDELDE.ALS(B2:B6;"<35")
Berekent het gemiddelde van de waarden van het bereik B2:B6 dat er minder dan 35 zijn. Dit geeft 19, omdat de tweede rij niet deelneemt in de berekening.
=GEMIDDELDE.ALS(B2:B6;"<"&MAX(B2:B6))
Berekent het gemiddelde van waarden van hetzelfde bereik, dat kleiner is dan de maximale waarde van dit bereik. Geeft 19, omdat de grootste waarde (tweede rij) niet deelneemt aan de berekening.
=GEMIDDELDE.ALS(B2:B6;">"&SMALL(B2:B6;1))
Berekent het gemiddelde van waarden van hetzelfde bereik, dat groter is dan de kleinste waarde van dit bereik. Geeft 25, omdat de kleinste waarde (vierde rij) niet deelneemt aan de berekening.
Gebruik het Gemiddelde_Bereik
=GEMIDDELDE.ALS(B2:B6;"<35";C2:C6)
De functie zoekt uit welke waarden minder dan 35 zijn in het bereik B2:B6 en berekent het gemiddelde van corresponderende waarden van et bereik C2:C6. Geeft 145, omdat de tweede rij niet deelneemt in de berekening.
=GEMIDDELDE.ALS(B2:B6;">"&MIN(B2:B6);C2:C6)
De functie zoekt uit welke waarden uit het bereik B2:B6 groter zijn dan de kleinste waarde in het bereik B2:B6 en berekent het gemiddelde van corresponderende waarden in het bereik C2:C6. Geeft 113,3, omdat de vierde rij (waar de minste waarde in het bereik B2: B6 in staat) niet deelneemt aan de berekening.
=GEMIDDELDE.ALS(B2:B6;"<"&LARGE(B2:B6;2);C2:C6)
De functie zoekt uit welke waarden uit het bereik B2:B6 kleiner zijn dan de tweede grote waarde in het bereik B2:B6 en berekent het gemiddelde van corresponderende waarden in het bereik C2: C6. Geeft 180, omdat alleen de vierde rij deelneemt in de berekening.
Reguliere uitdrukkingen gebruiken
=GEMIDDELDE.ALS(A2:A6);"pen";B2:B6
De functie zoekt uit welke cellen van het bereik A2:A6 alleen het woord "pen" bevatten en berekent het gemiddelde van de overeenkomstige waarden uit het bereik B2:B6. Dit geeft 35, omdat alleen de tweede rij aan de berekening deelneemt. De zoekopdracht wordt uitgevoerd in het bereik A2:A6, maar de waarden worden berekend van het bereik B2:B6.
=GEMIDDELDE.ALS(A2:A6;"pen.*";B2:B6)
De functie zoekt uit welke van de cellen van het bereik A2:A6 die beginnen met "pen", eindigen met elke hoeveelheid andere symbolen en berekent het gemiddelde van de overeenkomstige waarden uit het bereik B2:B6. Dit geeft 27,5, want ook "pencil" voldoet nu aan de voorwaarde en zowel de eerste en tweede rij nemen deel aan de berekening.
=GEMIDDELDE.ALS(A2:A6;".*boek.*";B2:B6)
De functie zoekt uit welke van de cellen van het bereik A2: A6 die "boek" bevatten, beginnen en eindigend met elke hoeveelheid van andere symbolen en berekent het gemiddelde van de overeenkomstige waarden van het bereik B2:B6. Dit geeft 18,5, omdat alleen de derde en vierde rij deelnemen aan de berekening.
Refereer naar een cel als een criterium
Als u een criterium gemakkelijk moet kunnen veranderen, kunt u deze in een aparte cel opvoeren en gebruik maken van een verwijzing naar deze cel in de conditie van de GEMIDDELDE.ALS-functie.
=GEMIDDELDE.ALS(A2:A6;".*"&E2&".*";B2:B6)
De functie zoekt uit welke van de cellen van het bereik A2:A6 een combinatie van symbolen bevat die wordt aangegeven in E2, beginnend en eindigend met elke hoeveelheid van andere symbolen en berekent het gemiddelde van de overeenkomstige waarden van het bereik B2:B. Als E2 = boek, geeft de functie 18,5 terug.
=GEMIDDELDE.ALS(B2:B6;"<"&E2;C2:C6)
De functie zoekt uit welke van de cellen van het bereik A2:A6 kleiner zijn dan de waarden in E2 en berekent het gemiddelde van de overeenkomstige waarden uit het bereik B2:B6. Als E2 = 35, geeft de functie 145 terug.