Financiële functies - deel één
Deze categorie bevat de wiskundige financiële functies van LibreOffice Calc.
DB
Berekent de afschrijving van een object over een bepaalde termijn met behulp van de vaste degressieve afschrijvingsmethode.
Deze vorm van afwaardering kunt u gebruiken als u een hogere afwaarderingswaarde wilt aan het begin van de afschrijving (in tegenstelling tot lineaire afwaardering). De afwaarderingswaarde wordt iedere afwaarderingsperiode verkleind door de afschrijving af te trekken van de initiële kosten.
DB(Aanschafwaarde; Restwaarde; Levensduur; Periode; Maand)
Aanschafwaarde is de aanschafprijs van een goed.
Restwaarde is de waarde van een goed aan het eind van de afschrijving.
Levensduur definieert de periode waarover een goed wordt afgeschreven.
Periode is de lengte van elke termijn. De lengte moet worden ingevoerd in dezelfde tijdseenheid als de afschrijvingsperiode.
Maand (optioneel) geeft het aantal maanden aan voor het eerste jaar van afwaardering. Als dit item niet gedefinieerd is wordt de standaardwaarde 12 gebruikt.
Een computersysteem met een initiële waarde van 25.000 valuta-eenheden moet worden afgeschreven over een periode van drie jaar. De restwaarde bedraagt 1.000 valuta-eenheden. Een periode is 30 dagen.
=DB(25000;1000;36;1;6) = 1.075,00 valutaeenheden
De constant afnemende afwaardering van het computersysteem is 1.075,00 valuta-eenheden.
DDB
Berekent de afwaardering van een goed voor een opgegeven periode gebruik makend van de rekenkundig-degressieve afwaarderingsmethode.
Gebruik deze manier van afwaarderen als u een hogere initiële afwaarderingswaarde nodig hebt in tegenstelling tot lineaire afwaardering. De afwaarderingswaarde wordt met elke termijn kleiner. Deze methode wordt doorgaans gebruikt voor goederen waarvan het waardeverlies hoger is kort na de aankoop (bijv. voertuigen, computers). Merk op dat de boekwaarde nooit nul zal bereiken met deze berekeningsmethode.
DDB(Aanschafwaarde; Restwaarde; Levensduur; Periode; Factor)
Aanschafwaarde duidt de initiële kosten van een goed aan.
Restwaarde geeft de waarde van een goed aan het eind van zijn levensduur aan.
Levensduur is het aantal termijnen (bijvoorbeeld jaren of maanden) dat het goed moet worden gebruikt.
Periode definieert de periode waarvoor de waarde moet worden berekend.
Factor (optioneel) is de factor waarmee de afwaardering afneemt. Als er geen waarde wordt opgegeven wordt standaard factor 2 gebruikt.
Een computersysteem met een initiële waarde van 75.000 valuta-eenheden moet maandelijks worden afgeschreven gedurende 5 jaar. De waarde aan het eind van de afschrijving is 1 valuta-eenheid. De factor is 2.
=DDB(75000;1;60;12;2) = 1.721,81 valuta-eenheden. Derhalve is de dubbele verouderingsafschrijving gedurende de eerste maand na de aankoop 1.721,81 valuta-eenheden.
LOOPTIJD
Berekent de duur van een obligatie in jaren.
De functies waarvan de namen eindigen op _ADD of Excel2003 leveren dezelfde resultaten op als de overeenkomende functies in Microsoft Excel 2003. Gebruik de functies zonder toevoeging om resultaten te verkrijgen die op internationale standaarden gebaseerd zijn.
DURATION("Settlement"; "Maturity"; Coupon; Yield; Frequency; Basis)
Aankoopdatum is de datum van aankoop van het waardepapier.
Vervaldatum is de datum waarop het waardepapier afloopt (verloopt).
Coupon is het jaarlijkse rentebewijs (nominale rentekoers)
Opbrengst is de jaarlijkse opbrengst van het waardepapier.
Frequentie is het aantal rentebetalingen per jaar (1, 2 of 4).
Een waardepapier wordt gekocht op 01-01-2001; de vervaldatum is 01-01-2006. Het nominale rentepercentage is 8%. Het rendement is 9,0%. De rente wordt halfjaarlijks betaald (frequentie is 2). Indien gebruik gemaakt wordt van de berekeningsmethode met dagelijkse balansrente (basis 3) hoe lang is dan de tijdsduur?
=LOOPTIJD("2001-01-01";"2006-01-01";0.08;0.09;2;3)
EFFECT.RENTE_ADD
Berekent de effectieve jaarlijkse rentevoet op basis van de nominale rentevoet en het aantal rentebetalingen per jaar.
De functies waarvan de namen eindigen op _ADD of Excel2003 leveren dezelfde resultaten op als de overeenkomende functies in Microsoft Excel 2003. Gebruik de functies zonder toevoeging om resultaten te verkrijgen die op internationale standaarden gebaseerd zijn.
EFFECT_RENTE_ADD(Nominale rente; NPerJ)
Nominale rente is het jaarlijkse nominale rentepercentage.
NPerJ is het aantal rentebetalingen per jaar.
Wat is de effectieve jaarlijkse rente voor een nominale rente van 5,25% en bij viermaandelijkse betaling.
=EFFECT.RENTE_ADD(0,0525;4) geeft als resultaat 0,053543 of 5,3534%.
IR
Berekent de interne rentabiliteit van een investering. De waarden stellen de cashstromen voor op regelmatige basis, tenminste één waarde moet negatief zijn (betaling) en tenminste één waarde moet positief zijn (inkomsten).
Gebruik de functie IR.SCHEMA, als de betalingen op onregelmatige basis plaatsvinden.
IR(Waarden; Schatting)
Waarden stelt een verwijzing voor naar een cel of naar een reeks cellen die de betalingsbedragen bevatten.
Schatting (optioneel) is de geschatte waarde. Een iteratieve methode wordt gebruikt om de interne teruggavekoers te berekenen. Indien u slechts een paar waarden kan invullen, zou u een initiële schatting moeten opgeven om de iteratie te kunnen laten uitvoeren.
Met de aanname dat de celinhoud is: A1=-10000, A2=3500, A3=7600 en A4=1000 geeft de formule =IR(A1:A4) het resultaat 11,33%.
Vanwege de gebruikte iteratieve methode is het mogelijk dat IR faalt en terugkeert met Fout 523, met "Fout: De berekening zal niet uitkomen" in de statusbalk. In dat geval kunt u een andere waarde voor Schat proberen.
OPBRENGST
Berekent de ontvangen hoeveelheid die is betaald voor een obligatie op een bepaald tijdstip.
OPBRENGST("Aankoopdatum"; "Vervaldatum"; Investering; Korting; Basis)
Aankoopdatum is de datum van aankoop van het waardepapier.
Vervaldatum is de datum waarop het waardepapier afloopt (verloopt).
Investering is de aankoopsom.
Korting is het kortingspercentage bij het verkrijgen van het waardepapier.
Afrekeningsdatum: 15 februari 1999, vervaldatum: 15 mei 1999, investeringsbedrag: 1000 valutaeenheden, disconto: 5,75 procent, basis: Dagelijkse balans/360 = 2.
De opbrengst op de vervaldatum wordt als volgt berekend:
=OPBRENGST("15-02-1999";"15-05-1999";1000;0,0575;2) geeft als resultaat 1014,420266.
SAMENG.RENTE.V
Berekent de opgebouwde rente van een waardepapier bij een eenmalige betaling op de aankoopdatum.
SAMENG.RENTE.V(Uitgiftedatum; Afrekeningsdatum; Nominale rente;Nominale waarde; Frequentie;Basis)
Uitgiftedatum (verplicht) is de datum van uitgifte van het waardepapier.
Afrekeningsdatum (verplicht) is de datum tot waarop de totaal aangegroeide rente moet worden berekend.
Koers (verplicht) is de jaarlijkse nominale rentekoers (coupon rentekoers).
Nom (optioneel) is de nominale waarde van het waardepapier.
Een waardepapier wordt uitgegeven op 01-04-2001. De vervaldatum is 15-06-2001. De rente is 0,1 of 10% en Par is 1000 valutaeenheden. De basis voor de dagelijkse/jaarlijkse berekening is de dagelijkse balans (3). Hoeveel rente heeft het opgebracht?
=SAMENG.RENTE.V("01-04-2001";"15-06-2001";0,1;1000;3) geeft als resultaat 20,54795.
SAMENG.RENTE
Berekent de opgebouwde rente van een waardepapier bij periodieke betalingen.
SAMENG.RENTE(Uitgiftedatum; Eerste rente; Aankoopdatum; Koers; Nominale waarde; Frequentie; Basis)
Uitgiftedatum (verplicht) is de datum van uitgifte van het waardepapier.
Eerste rente (verplicht) is de eerste rentedatum van het waardepapier.
Afrekeningsdatum (verplicht) is de datum tot waarop de totaal aangegroeide rente moet worden berekend.
Koers (verplicht) is de jaarlijkse nominale rentekoers (coupon rentekoers)
Nom (optioneel) is de nominale waarde van het waardepapier.
Frequentie (verplicht) is het aantal rentebetalingen per jaar (1, 2 of 4).
Een waardepapier wordt uitgegeven op 28-02-2001. De eerste rentedatum is op 31-08-2001. De datum van overeenkomst is 01-05-2001. De rente is 0,1 of 10% en Par is 1000 valuta-eenheden. De rente wordt halfjaarlijks betaald (frequentie is 2). De basis is de US-methode (0). Hoeveel rente heeft het opgebracht?
=SAMENG.RENTE("28-02-2001";"31-08-2001";"01-05-2001";0,1;1000;2;0) geeft 16,94444 terug.
DISCONTO
Berekent de vermindering (korting) van een waardepapier als een percentage.
DISCONTO("Aankoopdatum"; "Vervaldatum"; Prijs; Aflossingsbedrag; Basis)
Aankoopdatum is de datum van aankoop van het waardepapier.
Vervaldatum is de datum waarop het waardepapier afloopt (verloopt).
Prijs is de prijs van het waardepapier per 100 valutaeenheden van de nominale waarde.
Aflossingsbeddrag is de aflossingsbedrag van de waardepapieren per 100 valuta-eenheden van gelijke waarde.
Een waardepapier wordt gekocht op 25-01-2001; de vervaldatum is 15-11-2001. De koers (aankoopprijs) is 97, het aflossingsbedrag is 100. Hoe hoog is de disconto indien de dagelijkse balans-berekening (basis 3) gebruikt wordt?
=DISCONTO("25-01-2001";"15-11-2001";97;100;3) geeft 0,03720 of 3,72 procent.
AMORDEGRC
Berekent het afschrijvingsbedrag voor een vereffeningsperiode als degressieve afschrijving. In tegenstelling tot AMORLINC wordt hier een afschrijvingscoëfficiënt gebruikt die niet afhankelijk is van de afschrijvingsperiode.
AMORDEGRC(Kosten; Aankoopdatum; Eerste periode; Restwaarde; Periode; Percentage; Basis)
Kosten zijn de kosten van aankoop.
Aankoopdatum is de aankoopdatum.
Eerste periode is de einddatum van de eerste aflossingsperiode.
Restwaarde is de restwaarde van het kapitaalgoed aan het einde van de afschrijvingstermijn.
Periode is de aflossingsperiode waarmee moet worden gerekend.
Koers is de koers van de afschrijving.
AMORLINC
Berekent het afschrijvingsbedrag voor een vereffeningsperiode als lineaire afschrijving. Als het kapitaalgoed gekocht wordt tijdens de vereffeningsperiode, wordt het proportionele afschrijvingsbedrag in aanmerking genomen.
AMORLINC(Kosten; Aankoopdatum; Eerste periode; Restwaarde; Periode; Percentage; Basis)
Kosten zijn de kosten van aankoop.
Aankoopdatum is de aankoopdatum.
Eerste periode is de einddatum van de eerste aflossingsperiode.
Restwaarde is de restwaarde van het kapitaalgoed aan het einde van de afschrijvingstermijn.
Periode is de aflossingsperiode waarmee moet worden gerekend.
Koers is de koers van de afschrijving.
EFFECT.RENTE_ADD
Berekent het netto jaarlijks rentepercentage uit een nominaal rentepercentage.
Aangezien de nominale rente verwijst naar het rentebedrag dat verschuldigd is aan het eind van een berekeningsperiode, neemt de effectieve rente toe met het aantal uitgevoerde betalingen. Met andere woorden de rente wordt vaak in verschillende keren betaald (bijvoorbeeld maandelijks of driemaandelijks) vóór het einde van de berekeningsperiode.
EFFECT.RENTE_ADD(Nominale rente; Aperj)
NR is de nominale rente.
T is het aantal termijnen met rentebetalingen per jaar.
Als het jaarlijks nominale rentepercentage 9,75% is en er zijn vier termijnen met renteberekening gedefinieerd, wat is dan het eigenlijke rentepercentage (effectieve rente)?
=EFFECT.RENTE_ADD(9.75%;4) = 10.11% Het jaarlijkse effectieve percentage is daarom 10,11%.
SYD
Geeft als resultaat het meetkundig-degressief afwaarderingspercentage.
Gebruik deze functie om het afschrijvingsbedrag te berekenen voor één periode in de totale afwaarderingstermijn van een goed. Meetkundig-degressieve afwaardering vermindert iedere periode het afwaarderingsbedrag met een vast bedrag.
SYD(Aanschafwaarde; Restwaarde; Levensduur; Periode)
Aanschafwaarde is de aanschafprijs van een goed.
Restwaarde is de waarde van een goed na afwaardering.
Levensduur is de termijn waarin een goed wordt afgeschreven.
Periode definieert de periode waarvoor de afwaardering moet worden berekend.
Een videosysteem dat aanvankelijk 50.000 valuta-eenheden kost moet jaarlijks worden afgeschreven gedurende de volgende 5 jaar. De restwaarde bedraagt 10.000 valuta-eenheden. U wilt de afwaardering berekenen voor het eerste jaar.
=SYD(50000;10000;5;1)=13.333,33 valuta-eenheden. De afschrijving voor het eerste jaar is 13.333,33 valuta-eenheden.
Teneinde een overzicht te hebben van de afwaarderingspercentages per periode, is het het beste om een afwaarderingstabel te definiëren. Door de verschillende afwaarderingsformules die beschikbaar zijn in LibreOffice Calc naast elkaar in te voeren, kunt u zien welke wijze van afwaarderen het meest toepasselijk is. Voer de tabel als volgt in:
|
A |
B |
C |
D |
E |
|
|
1 |
Aankoopkosten |
Restwaarde |
Levensduur |
Tijdperiode |
Verval. SYD |
|
2 |
50.000 valuta-eenheden |
10.000 valuta-eenheden |
5 |
1 |
13.333,33 valuta-eenheden |
|
3 |
2 |
10.666,67 valutaeenheden |
|||
|
4 |
3 |
8.000,00 valuta-eenheden |
|||
|
5 |
4 |
5.333,33 valuta-eenheden |
|||
|
6 |
5 |
2.666,67 valuta-eenheden |
|||
|
7 |
6 |
0,00 valuta-eenheden |
|||
|
8 |
7 |
||||
|
9 |
8 |
||||
|
10 |
9 |
||||
|
11 |
10 |
||||
|
12 |
|||||
|
13 |
>0 |
Totaal |
40.000,00 valuta-eenheden |
De formule in E2 is als volgt:
=SYD($A$2;$B$2;$C$2;D2)
Deze formule wordt naar beneden gekopieerd in kolom E tot cel E11 (selecteer E2, sleep dan de rechter benedenhoek met de muis naar beneden).
Cel E13 bevat de formule die gebruikt wordt om na te gaan wat het totaal is van de afschrijvingsbedragen. Daarbij wordt de functie SOM.ALS gebruikt gezien de negatieve waarden in E8:E11 niet in beschouwing mogen worden genomen. De voorwaarde >0 is in cel A13 opgenomen. De formule in E13 luidt als volgt:
=SOM.ALS(E2:E11;A13)
Ga nu na wat de waardeverminderingen zouden zijn voor een periode van 10 jaar, of bij een restwaarde van 1 valutaeenheid, of voer een andere initiële kostprijs in, enz..
HW
Geeft de huidige waarde van een investering die ontstaan is uit een reeks van regelmatige betalingen.
Gebruik deze functie om het bedrag te berekenen dat vandaag geïnvesteerd zou moeten worden tegen een vaste rente, teneinde een bepaald bedrag, een annuïteit, te ontvangen gedurende een bepaald aantal periodes. U kunt ook bepalen welk bedrag nog moet overblijven na het verlopen van de periode. Bepaal eveneens of het bedrag wordt uitbetaald aan het begin of aan het einde van elke periode.
Voer deze waarden in als getallen, als uitdrukkingen of als verwijzingen. Als er bijvoorbeeld een jaarlijkse rente wordt betaald van 8%, maar u wilt een periode van een maand gebruiken, voer dan 8%/12 in bij Rente en LibreOffice Calc zal automatisch de correcte factor berekenen.
HW(Rente; NPER; Betaling; TW; Type)
Rente bepaalt het rentepercentage per periode.
NPer is het totale aantal perioden (betalingsperioden).
Betaling is het te betalen bedrag per periode.
TW (optioneel) bepaalt de toekomstige waarde die overblijft nadat de laatste uitbetaling is gedaan.
Type (optioneel) is de datum waarop de periodieke betalingen voldaan moeten worden. Type = 1 betekent aan het begin van een periode en Type = 0 (standaard) betekent aan het eind van de periode.
In de functies van LibreOffice Calc kunnen "optionele" parameters alleen weggelaten worden wanneer er geen parameter volgt. In een functie met vier parameters waarvan de laatste twee als "optioneel" gemarkeerd zijn, kunt u bijvoorbeeld parameter 4 of parameter 3 en 4 weglaten, maar niet alleen parameter 3.
Wat is de huidige waarde van een investering indien maandelijks 500 valuta-eenheden worden uitbetaald en het jaarlijkse rentepercentage 8% bedraagt? De betalingsperiode is 48 maanden en er moeten 20.000 valuta-eenheden overblijven aan het eind van de betalingsperiode.
=HW(8%/12;48;500;20000) = -35.019,37 valuta-eenheden. Onder de genoemde voorwaarden moet u vandaag 35.019,37 valuta-eenheden storten als u 500 valuta-eenheden per maand gedurende 48 maanden wilt ontvangen en aan het einde nog 20.000 valuta-eenheden over wilt hebben. Narekenen bewijst dat 48 x 500 valuta-eenheden + 20.000 valuta-eenheden = 44.000 valuta-eenheden. Het verschil tussen dit bedrag en de gestorte 35.000 valuta-eenheden vertegenwoordigt de betaalde rente.
Als u in de formule verwijzingen invoert in plaats van deze waarden, kunt u een willekeurige aantal "Als-dan" scenario's berekenen. Merk op: verwijzingen naar constanten moet worden gedefinieerd als absolute verwijzingen. Voorbeelden van dit soort toepassing zijn te vinden onder de afschrijvingsfuncties.
ISPMT
Met behulp van deze functie kunt u het renteniveau berekenen bij gelijkblijvende aflossingstermijnen.
ISPMT(Rente; Termijn; Aantal perioden; Investering)
Rente bepaalt het periodieke rentepercentage.
Termijn is het aantal aflossingstermijnen voor de berekening van de rente.
Aantal perioden is het totale aantal aflossingstermijnen.
Investering is het investeringsbedrag.
Voor een krediet van 120.000 valuta-eenheden met een twee-jarige looptijd en maandelijkse aflossingen tegen een jaarlijkse rente van 12%, zoeken we het renteniveau na 1,5 jaar.
=ISPMT(1%;18;24;120000) = -300 valuta-eenheden. De maandelijkse rente na 1,5 jaar bedraagt 300 valuta-eenheden.