Text Functions

This section contains descriptions of the Text functions.

Π—Π° Π΄Π° пристапитС Π΄ΠΎ ΠΎΠ²Π°Π° Π½Π°Ρ€Π΅Π΄Π±Π°...

Π’ΠΌΠ΅Ρ‚Π½ΠΈ - Π€ΡƒΠ½ΠΊΡ†ΠΈΡ˜Π° - ΠšΠ°Ρ‚Π΅Π³ΠΎΡ€ΠΈΡ˜Π° ВСкстуални


REGEX

Matches and extracts or optionally replaces text using regular expressions.

WEBSERVICE

Get some web content from a URI.

FILTERXML

Apply a XPath expression to a XML document.

ENCODEURL

Returns a URL-encoded string.

CLEAN

All non-printing characters are removed from the string.

Syntax

CLEAN(text)

text refers to the text from which to remove all non-printable characters.

ARABIC

Calculates the value of a Roman number. The value range must be between 0 and 3999.

Syntax

ARABIC (Text)

Text is the text that represents a Roman number.

Example

ARABIC("MXIV") returns 1014

ARABIC("MMII") returns 2002

PROPER

Capitalizes the first letter in all words of a text string.

Syntax

PROPER(text)

text refers to the text to be converted.

Example

PROPER("sun microsystems") returns Sun Microsystems.

CONCATENATE

Combines several text strings into one string.

Syntax

CONCATENATE(Text 1;...;Text 30)

Text 1; text 2; ... represent up to 30 text passages which are to be combined into one string.

Example

CONCATENATE("Good ";"Morning ";"Mrs. ";"Doe") returns Good Morning Mrs. Doe.

EXACT

Compares two text strings and returns TRUE if they are identical. This function is case-sensitive.

Syntax

EXACT(text_1;text_2)

text_1 refers to the first text to compare.

text_2 is the second text to compare.

Example

EXACT("Sun microsystems";"Sun Microsystems") returns FALSE.

UNICHAR

Converts a code number into a Unicode character or letter.

Syntax

UNICHAR(number)

Example

=UNICHAR(169) returns the Copyright character Β©.

tip

See also the UNICODE() function.


ROMAN

Converts a number into a Roman numeral. The value range must be between 0 and 3999, the modes can be integers from 0 to 4.

Syntax

ROMAN(Number; Mode)

Number is the number that is to be converted into a Roman numeral.

Mode (optional) indicates the degree of simplification. The higher the value, the greater is the simplification of the Roman number.

Example

ROMAN(999) returns CMXCIX

ROMAN(999;0) returns CMXCIX

ROMAN (999;1) returns LMVLIV

ROMAN(999;2) returns XMIX

ROMAN(999;3) returns VMIV

ROMAN(999;4) returns IM

CHAR

Converts a number into a character according to the current code table. The number can be a two-digit or three-digit integer number.

ΠšΠΎΠ΄ΠΎΠ²ΠΈΡ‚Π΅ ΠΏΠΎΠ³ΠΎΠ»Π΅ΠΌΠΈ ΠΎΠ΄ 127 ΠΌΠΎΠΆΠ΅ Π΄Π° зависат ΠΌΠ°ΠΏΠΈΡ€Π°ΡšΠ΅Ρ‚ΠΎ Π½Π° Π·Π½Π°Ρ†ΠΈΡ‚Π΅ Π½Π° Π²Π°ΡˆΠΈΠΎΡ‚ систСм (Π½Π° ΠΏΡ€ΠΈΠΌΠ΅Ρ€ iso-8859-1, iso-8859-2, Windows-1252, Windows-1250), ΠΈ Π·Π°Ρ‚ΠΎΠ° ΠΌΠΎΠΆΠ΅ Π΄Π° Π½Π΅ сС ΠΏΠΎΡ€Ρ‚Π°Π±ΠΈΠ»Π½ΠΈ.

Syntax

CHAR(number)

number is a number between 1 and 255 representing the code value for the character.

Example

CHAR(100) returns the character "d".

="abc" & CHAR(10) & "def" inserts a newline character into the string.

TEXT

Converts a number into text according to a given format.

Syntax

TEXT(Number; Format)

Number is the numerical value to be converted.

Format is the text which defines the format. Use decimal and thousands separators according to the language set in the cell format.

Example

=TEXT(12.34567;"###.##") returns the text 12.35

=TEXT(12.34567;"000.00") returns the text 012.35

tip

See also Number format codes: custom format codes defined by the user.


BAHTTEXT

Converts a number to Thai text, including the Thai currency names.

Syntax

BAHTTEXT(Number)

Number is any number. "Baht" is appended to the integral part of the number, and "Satang" is appended to the decimal part of the number.

Example

BAHTTEXT(12.65) returns a string in Thai characters with the meaning of "Twelve Baht and sixty five Satang".

Π”ΠžΠ›ΠΠ 

Converts a number to an amount in the currency format, rounded to a specified decimal place. In the value field enter the number to be converted to currency. Optionally, you may enter the number of decimal places in the decimals field. If no value is specified, all numbers in currency format will be displayed with two decimal places.

You set the currency format in your system settings.

Syntax

DOLLAR(value; decimals)

value is a number, a reference to a cell containing a number, or a formula which returns a number.

decimals is the optional number of decimal places.

Example

DOLLAR(255) returns $255.00.

DOLLAR(367.456;2) returns $367.46. Use the decimal separator that corresponds to the current locale setting.

BASE

Converts a positive integer to a specified base into a text from the numbering system. The digits 0-9 and the letters A-Z are used.

Syntax

BASE(Number; Radix; [Minimum length])

number is the positive integer to be converted.

radix indicates the base of the number system. It may be any positive integer between 2 and 36.

Minimum length (optional) determines the minimum length of the character sequence that has been created. If the text is shorter than the indicated minimum length, zeros are added to the left of the string.

Example

BASE(17;10;4) returns 0017 in the decimal system.

BASE(17;2) returns 10001 in the binary system.

BASE(255;16;4) returns 00FF in the hexadecimal system.

VALUE

Converts a text string into a number.

Syntax

VALUE(text)

text is the text to be converted to a number.

Example

VALUE("4321") returns 4321.

LOWER

Converts all uppercase letters in a text string to lowercase.

Syntax

LOWER(text)

text refers to the text to be converted.

Example

LOWER("Sun") returns sun.

DECIMAL

Converts text with characters from a number system to a positive integer in the base radix given. The radix must be in the range 2 to 36. Spaces and tabs are ignored. The text field is not case-sensitive.

If the radix is 16, a leading x or X or 0x or 0X, and an appended h or H, is disregarded. If the radix is 2, an appended b or B is disregarded. Other characters that do not belong to the number system generate an error.

Syntax

DECIMAL(Text; Radix)

text is the text to be converted. To differentiate between a hexadecimal number, such as A1 and the reference to cell A1, you must place the number in quotation marks, for example, "A1" or "FACE".

radix indicates the base of the number system. It may be any positive integer between 2 and 36.

Example

DECIMAL("17";10) returns 17.

DECIMAL("FACE";16) returns 64206.

DECIMAL("0101";2) returns 5.

UPPER

Converts the string specified in the text field to uppercase.

Syntax

UPPER(text)

text refers to the lower case letters you want to convert to upper case.

Example

UPPER("Good Morning") returns GOOD MORNING.

LENB

For double-byte character set (DBCS) languages, returns the number of bytes used to represent the characters in a text string.

tip

This function is available since LibreOffice 4.2


Syntax

LENB("Text")

text is the text whose length is to be determined.

Example

LENB("δΈ­") returns 2 (1 DBCS character consisting of 2 bytes).

LENB("δΈ­ε›½") returns 4 (2 DBCS characters each consisting of 2 bytes).

LENB("office") returns 6 (6 non-DBCS characters each consisting of 1 byte).

=LENB("Good Afternoon") returns 14.

=LENB(12345.67) returns 8.

TRIM

Removes spaces from a string, leaving only a single space character between words.

Syntax

TRIM(Text)

Text refers to text in which spaces are to be removed.

Example

=TRIM(" hello world ") returns hello world without leading and trailing spaces and with single space between words.

REPT

Repeats a character string by the given number of copies.

Syntax

REPT(text; number)

text is the text to be repeated.

number is the number of repetitions.

The result can be a maximum of 255 characters.

Example

REPT("Good morning"; 2) returns Good morningGood morning.

REPLACE

Replaces part of a text string with a different text string. This function can be used to replace both characters and numbers (which are automatically converted to text). The result of the function is always displayed as text. If you intend to perform further calculations with a number which has been replaced by text, you will need to convert it back to a number using the VALUE function.

Any text containing numbers must be enclosed in quotation marks if you do not want it to be interpreted as a number and automatically converted to text.

Syntax

REPLACE(text; position; length; new text)

Text refers to text of which a part will be replaced.

position refers to the position within the text where the replacement will begin.

length is the number of characters in text to be replaced.

new text refers to the text which replaces text.

Example

REPLACE("1234567";1;1;"444") returns "444234567". One character at position 1 is replaced by the complete new text.

CODE

Returns a numeric code for the first character in a text string.

Syntax

CODE(Text)

Text is the text for which the code of the first character is to be found.

ΠšΠΎΠ΄ΠΎΠ²ΠΈΡ‚Π΅ ΠΏΠΎΠ³ΠΎΠ»Π΅ΠΌΠΈ ΠΎΠ΄ 127 ΠΌΠΎΠΆΠ΅ Π΄Π° зависат ΠΌΠ°ΠΏΠΈΡ€Π°ΡšΠ΅Ρ‚ΠΎ Π½Π° Π·Π½Π°Ρ†ΠΈΡ‚Π΅ Π½Π° Π²Π°ΡˆΠΈΠΎΡ‚ систСм (Π½Π° ΠΏΡ€ΠΈΠΌΠ΅Ρ€ iso-8859-1, iso-8859-2, Windows-1252, Windows-1250), ΠΈ Π·Π°Ρ‚ΠΎΠ° ΠΌΠΎΠΆΠ΅ Π΄Π° Π½Π΅ сС ΠΏΠΎΡ€Ρ‚Π°Π±ΠΈΠ»Π½ΠΈ.

Example

CODE("Hieronymus") returns 72, CODE("hieroglyphic") returns 104.

note

The code used here does not refer to ASCII, but to the code table currently loaded.


UNICODE

Returns a numeric code for the first character in a text string.

Syntax

UNICODE("Text")

Example

=UNICODE("Β©") returns the Unicode number 169 for the Copyright character.

tip

See also the UNICHAR() function.


MID

Returns a text segment of a character string. The parameters specify the starting position and the number of characters.

Syntax

MID(text; start; number)

text is the text containing the characters to extract.

start is the position of the first character in the text to extract.

number specifies the number of characters in the part of the text.

Example

MID("Sun Microsystems";5;5) returns Micro.

MIDB

Returns a text string of a DBCS text. The parameters specify the starting position and the number of characters.

tip

This function is available since LibreOffice 4.2


Syntax

MIDB("Text"; Start; Number_bytes)

text is the text containing the characters to extract.

Start is the position of the first character in the text to extract.

Number_bytes specifies the number of characters MIDB will return from text, in bytes.

Example

MIDB("δΈ­ε›½";1;0) returns "" (0 bytes is always an empty string).

MIDB("δΈ­ε›½";1;1) returns " " (1 byte is only half a DBCS character and therefore the result is a space character).

MIDB("δΈ­ε›½";1;2) returns "δΈ­" (2 bytes constitute one complete DBCS character).

MIDB("δΈ­ε›½";1;3) returns "δΈ­ " (3 bytes constitute one and a half DBCS character; the last byte results in a space character).

MIDB("δΈ­ε›½";1;4) returns "δΈ­ε›½" (4 bytes constitute two complete DBCS characters).

MIDB("δΈ­ε›½";2;1) returns " " (byte position 2 is not at the beginning of a character in a DBCS string; 1 space character is returned).

MIDB("δΈ­ε›½";2;2) returns " " (byte position 2 points to the last half of the first character in the DBCS string; the 2 bytes asked for therefore constitutes the last half of the first character and the first half of the second character in the string; 2 space characters are therefore returned).

MIDB("δΈ­ε›½";2;3) returns " ε›½" (byte position 2 is not at the beginning of a character in a DBCS string; a space character is returned for byte position 2).

MIDB("δΈ­ε›½";3;1) returns " " (byte position 3 is at the beginning of a character in a DBCS string, but 1 byte is only half a DBCS character and a space character is therefore returned instead).

MIDB("δΈ­ε›½";3;2) returns "ε›½" (byte position 3 is at the beginning of a character in a DBCS string, and 2 bytes constitute one DBCS character).

MIDB("office";2;3) returns "ffi" (byte position 2 is at the beginning of a character in a non-DBCS string, and 3 bytes of a non-DBCS string constitute 3 characters).

LEFTB

Returns the first characters of a DBCS text.

tip

This function is available since LibreOffice 4.2


Syntax

LEFTB("Text"; Number_bytes)

Text is the text where the initial partial words are to be determined.

Number_bytes (optional) specifies the number of characters you want LEFTB to extract, based on bytes. If this parameter is not defined, one character is returned.

Example

LEFTB("δΈ­ε›½";1) returns " " (1 byte is only half a DBCS character and a space character is returned instead).

LEFTB("δΈ­ε›½";2) returns "δΈ­" (2 bytes constitute one complete DBCS character).

LEFTB("δΈ­ε›½";3) returns "δΈ­ " (3 bytes constitute one DBCS character and a half; the last character returned is therefore a space character).

LEFTB("δΈ­ε›½";4) returns "δΈ­ε›½" (4 bytes constitute two complete DBCS characters).

LEFTB("office";3) returns "off" (3 non-DBCS characters each consisting of 1 byte).

RIGHTB

Returns the last character or characters of a text with double bytes characters sets (DBCS).

tip

This function is available since LibreOffice 4.2


Syntax

RIGHTB("Text"; Number_bytes)

Text is the text of which the right part is to be determined.

Number_bytes (optional) specifies the number of characters you want RIGHTB to extract, based on bytes.

Example

RIGHTB("δΈ­ε›½";1) returns " " (1 byte is only half a DBCS character and a space character is returned instead).

RIGHTB("δΈ­ε›½";2) returns "ε›½" (2 bytes constitute one complete DBCS character).

RIGHTB("δΈ­ε›½";3) returns " ε›½" (3 bytes constitute one half DBCS character and one whole DBCS character; a space is returned for the first half).

RIGHTB("δΈ­ε›½";4) returns "δΈ­ε›½" (4 bytes constitute two complete DBCS characters).

RIGHTB("office";3) returns "ice" (3 non-DBCS characters each consisting of 1 byte).

LEN

Returns the length of a string including spaces.

Syntax

LEN(text)

text is the text whose length is to be determined.

Example

LEN("Good Afternoon") returns 14.

LEN(12345.67) returns 8.

FIND

Returns the position of a string of text within another string.You can also define where to begin the search. The search term can be a number or any string of characters. The search is case-sensitive.

Syntax

FIND(find_text; text; position)

find_text refers to the text to be found.

text is the text where the search takes place.

position (optional) is the position in the text from which the search starts.

Example

FIND(76;998877665544) returns 6.

SEARCH

Returns the position of a text segment within a character string. You can set the start of the search as an option. The search text can be a number or any sequence of characters. The search is not case-sensitive. If the text is not found, returns error 519 (#VALUE).

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in - LibreOffice Calc - Calculate.

warning

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".


Syntax

SEARCH(find_text; text; position)

find_text is the text to be searched for.

text is the text where the search will take place.

position (optional) is the position in the text where the search is to start.

Example

SEARCH(54;998877665544) returns 10.

FIXED

Specifies that a number be displayed with a fixed number of decimal places and with or without a thousands separator. This function can be used to apply a uniform format to a column of numbers.

Syntax

FIXED(Number; decimals; no thousands separators)

Number refers to the number to be formatted.

Decimals refers to the number of decimal places to be displayed.

No thousands separators (optional) determines whether the thousands separator is used. If the parameter is a number not equal to 0, the thousands separator is suppressed. If the parameter is equal to 0 or if it is missing altogether, the thousands separators of your current locale setting are displayed.

Example

FIXED(1234567.89;3) returns 1,234,567.890. FIXED(1234567.89;3;1) returns 1234567.890.

FIXED(1234567.89;3) returns 1,234,567.890. FIXED(1234567.89;3;1) returns 1234567.890.

SUBSTITUTE

Substitutes new text for old text in a string.

Syntax

SUBSTITUTE(text; search_text; new text; occurrence)

text is the text in which text segments are to be exchanged.

search_text is the text segment that is to be replaced (a number of times).

new text is the text that is to replace the text segment.

occurrence (optional) indicates which occurrence of the search text is to be replaced. If this parameter is missing the search text is replaced throughout.

Example

SUBSTITUTE("123123123"; "3"; "abc") returns 12abc12abc12abc.

SUBSTITUTE("123123123"; "3"; "abc"; 2) returns 12312abc123.

ASC

The ASC function converts full-width to half-width ASCII and katakana characters. Returns a text string.

See https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions for a conversion table.

Syntax

ASC("Text")

Text is the text that contains characters to be converted.

See also JIS function.

JIS

The JIS function converts half-width to full-width ASCII and katakana characters. Returns a text string.

See https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions for a conversion table.

Syntax

TRIM(Text)

Text is the text that contains characters to be converted.

See also ASC function.

T

This function converts a number to a blank text string.

Syntax

T(value)

value is the value to be converted. Also, a reference can be used as a parameter. If the referenced cell includes a number or a formula containing a numerical result, the result will be an empty string.

Example

T(12345) becomes an empty string "", if 12345 is formatted as a number. T("12345") returns 12345.

T(12345) becomes an empty string "", if 12345 is formatted as a number. T("12345") returns 12345.

RIGHT

Π“ΠΎ Π²Ρ€Π°ΡœΠ° послСдниот Π·Π½Π°ΠΊ ΠΈΠ»ΠΈ Π·Π½Π°Ρ†ΠΈ ΠΎΠ΄ тСкстот.

Syntax

RIGHT(text; number)

text is the text of which the right part is to be determined.

number (optional) is the number of characters from the right part of the text.

Example

RIGHT("Sun";2) returns un.

LEFT

Π“ΠΎ Π΄Π°Π²Π° ΠΏΡ€Π²ΠΈΠΎΡ‚ Π·Π½Π°ΠΊ ΠΈΠ»ΠΈ Π·Π½Π°Ρ†ΠΈ ΠΎΠ΄ тСкстот.

Syntax

LEFT(text; number)

text is the text where the initial partial words are to be determined.

Number (optional) specifies the number of characters for the start text. If this parameter is not defined, one character is returned.

Example

LEFT("output";3) returns out.

Please support us!