Fonction MOYENNE.SI.ENS

Renvoie la moyenne arithmétique de toutes les cellules dans une plage qui satisfont à des critères multiples donnés. La fonction MOYENNE.SI.ENS totalise tous les résultats qui correspondent aux tests logiques et divise cette somme par la quantité de valeurs sélectionnées.

Cette fonction est disponible depuis LibreOffice 4.0

Syntaxe

MOYENNESIS(Plage_Fonction;Plage1;Critère1 [;Plage2;Critère2 [;...]]))

plage_fonction – argument requis. C'est une plage de cellules, un nom d'une plage nommée ou une étiquette de colonne ou de ligne contenant les valeurs pour le calcul de la moyenne.

Critère1 - argument requis. Une expression de chaîne représentant une condition logique ou une référence de cellule à une telle expression de chaîne. L'expression peut contenir du texte, des nombres, des expressions régulières ou des caractères génériques ( si activé dans les options de calcul).

Plage2 – Facultatif. Plage2 et tous les arguments suivants ont la même signification que Plage1.

critère2 – facultatif. Critère2 et tous les autres ont la même signification que critère1.

La recherche prend en charge les caractères génériques ou les expressions régulières . Lorsque les expressions régulières sont activées, vous pouvez saisir "tous. *", Par exemple pour trouver le premier emplacement de "tous" suivi de n'importe quel caractère. Si vous souhaitez rechercher un texte qui est également une expression régulière, vous devez soit précéder chaque caractère d'un caractère "\", soit placer le texte dans \Q ...\E. Vous pouvez activer ou désactiver l'évaluation automatique des caractères génériques ou des expressions régulières dans - LibreOffice Calc - Calculer .

Lorsque vous utilisez des fonctions où un ou plusieurs arguments sont des chaînes de critères de recherche qui représentent une expression régulière, la première tentative consiste à convertir les critères de chaîne en nombres. Par exemple, ".0" se convertira en 0.0 et ainsi de suite. En cas de succès, la correspondance ne sera pas une correspondance d'expression régulière mais une correspondance numérique. Cependant, lorsque vous passez à un environnement local où le séparateur décimal n'est pas le point, la conversion d'expression régulière fonctionne. Pour forcer l'évaluation de l'expression régulière au lieu d'une expression numérique, utilisez une expression qui ne peut pas être mal interprétée comme numérique, telle que ". [0]" ou ".\0" ou "(?I) .0".

Plage_Fonction et Plage1, Plage2... doivent avoir la même taille, sinon la fonction renvoie une err502 - argument incorrecte.

La relation logique entre les critères peut être définie comme ET logique (conjonction). En d'autres termes, si et seulement si tous les critères donnés sont satisfaits, une valeur de la cellule correspondante de la plage donnée Plage_Fonction est prise en compte dans le calcul.

La fonction peut avoir jusqu'à 255 arguments, ce qui signifie que 127 plages de critères et critères peuvent leur être spécifié

Si une cellule contient VRAI, elle est traitée comme 1, si une cellule contient FAUX - comme 0 (zéro)

Cette fonction fait partie du standard Open Document Format for Office Applications (Open Document) Version 1.2 (ISO/IEC 26300:2-2015)

Exemple

Examinez le tableau suivant

	A	B	C
1	Nom du produit	Ventes	Chiffre d'affaires
2	crayon	20	65
3	stylo	35	85
4	bloc-notes	20	190
5	livre	17	180
6	trousse	non	non

Dans tous les exemples ci-dessous, les plages de calcul contiennent la ligne #6, qui est ignorée parce qu'elle contient du texte.

Usage simple

=MOYENNE.SI.ENS(B2:B6;B2:B6;">=20")

Calcule la moyenne des valeurs de la plage B2:B6 qui sont supérieures ou égales à 20. Renvoie 25, parce que la cinquième ligne ne correspond pas au critère.

=MOYENNE.SI.ENS(C2:C6;B2:B6;">=20";C2:C6;">70")

Calcule la moyenne des valeurs de la plage C2:C6 qui sont supérieures à 70 et correspondent aux cellules de B2:B6 avec des valeurs supérieures ou égales à 20. Renvoie 137,5 parce que les seconde et cinquième lignes ne correspondent pas à au moins un critère.

Utilisation des expressions régulières et des fonctions imbriquées

=MOYENNE.SI.ENS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Calcule la moyenne pour les valeurs de la plage C2:C6 qui correspondent à toutes les valeurs de la plage B2:B6 à l'exception des minimum et maximum. Renvoie 127,5 parce que les troisième et cinquième lignes ne correspondent pas à au moins un critère.

=MOYENNE.SI.ENS(C2:C6;A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Calcule la moyenne pour les valeurs de la plage C2:C6 qui correspondent à toutes les cellules de la plage A2:A6 commençant par "crayon" et à toutes les cellules de la plage B2:B6 excepté son maximum. Renvoie 65, parce que uniquement la seconde ligne correspond à tous les critères.

Référence à une cellule comme critère

Si vous avez besoin de modifier facilement un critère, vous le spécifiez dans une cellule séparée et utilisez une référence à cette cellule dans la condition de la fonction MOYENNE.SI.ENS. Par exemple, la fonction ci-dessous peut être réécrite de la façon suivante :

=MOYENNE.SI.ENS(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Si E2=crayon, la fonction renvoie 65 parce que le lien à la cellule est substitué par son contenu.

Ouvrir un fichier avec un exemple :

MOYENNE, MOYENNEA, ECART.MOYEN, MOYENNE.SI

NB.SI.ENS, MIN.SI, MAX.SI, MOYENNE.SI.ENS, SOMME.SI.ENS

Liste des expressions régulières