Fonctions financières - Deuxième partie

Retour aux fonctions financières - Première partie

Fonctions financières - Troisième partie

CUMUL.PRINCPER_ADD

Calcule le remboursement cumulé d'un emprunt sur une période donnée.

CUMUL.PRINCPER_ADD(taux;NPM;VA;début_période;fin_période;type)

taux définit le taux d'intérêt par période.

NPM représente le nombre total de périodes de paiements. Le taux et NPM doivent se référer à la même unité et tous deux doivent donc être calculés annuellement ou mensuellement.

VA représente la valeur actuelle.

début_période représente la première période de paiement du calcul.

fin_période correspond au dernier paiement de la période du calcul.

type représente l'échéance d'un paiement à la fin de chaque période (type = 0) ou au début de la période (type = 1).

Prêt hypothécaire destiné à financer un achat immobilier :

L'intérêt est de 9,00 pourcent par an (9% / 12 = 0,0075) sur une durée de 30 ans (périodes de remboursement = 30 * 12 = 360) ; VA : 125 000 unités monétaires.

Montant à rembourser au cours de la deuxième année de remboursement du prêt (périodes 13 à 24) ?

=CUMUL.PRINCPER_ADD(0,0075;360;125000;13;24;0) renvoie -934,1071

Somme du remboursement effectué le premier mois :

=CUMUL.PRINCPER_ADD(0,0075;360;125000;1;1;0) renvoie -68,27827

AMORLIN

Calcule l'amortissement linéaire d'un actif pour une période donnée. Le montant de l'amortissement est constant pendant la période d'amortissement.

AMORLIN(coût;valeur_résiduelle;durée)

coût est le coût initial d'un actif.

valeur_résiduelle est la valeur résiduelle de l'actif après amortissement.

durée représente la période d'amortissement déterminant le nombre de périodes dans l'amortissement de l'actif.

Un équipement de bureau d'une valeur d'acquisition de 50 000 unités monétaires doit être amorti sur 7 ans. La valeur résiduelle est estimée à 3 500 unités monétaires.

=AMORLIN(50000;3,500;84) = 553,57 unités monétaires. L'amortissement mensuel périodique de l'équipement de bureau est de 553,57 unités monétaires.

DUREE.MODIFIEE

Calcule la durée de Macauley modifiée d'un titre à revenu fixe en années.

DUREE.MODIFIEE(terme;échéance;coupon;rendement;fréquence;base)

terme est la date d'achat du titre.

échéance est la date à laquelle le titre arrive à échéance (expire).

coupon représente le taux nominal annuel de l'intérêt (taux d'intérêt du coupon)

rendement représente le rendement annuel du titre.

fréquence est le nombre de versements d'intérêts par an (1,2 ou 4).

Un titre a été acquis le 1/1/2001 et le terme de l'échéance a été fixé au 1/1/2006. L'intérêt nominal est de 8%, le rendement s'élève à 9,0% et les intérêts sont versés tous les semestres (fréquence = 2). La base de comptage des jours est réelle (base = 3). Quelle est la durée modifiée ?

=DUREE.MODIFIEE("01/01/2001";"01/01/2006";0,08;0,09;2;3) renvoie 4,02 ans.

VAN

Calcule la valeur actuelle d'un investissement sur la base d'une série de flux de trésorerie périodiques et d'un taux d'escompte. Pour obtenir la valeur actuelle nette, soustrayez le coût du projet (le flux de trésorerie initial, à l'instant zéro) à la valeur retournée.

Si les paiements prennent place à intervalles irréguliers, utilisez la fonction VAN.PAIEMENTS.

VAN(taux;valeur_1;valeur_2;...;valeur_30)

taux représente le taux d'escompte pour une période.

valeur_1;valeur2;...;valeur30 représente jusqu'à 30 valeurs qui représentent les dépôts ou les retraits.

Quelle est la valeur actuelle nette des paiements périodiques de 10, 20 et 30 unités monétaires avec un taux d'escompte de 8,75 %. Au moment zéro, les coûts acquittés s'élevaient à -40 unités monétaires.

=VAN(8,75%;10;20;30) = 49,43 unités monétaires. La valeur actuelle nette est la valeur renvoyée moins le coût initial de 40 unités monétaires, donc 9,43 unités monétaires.

PRIX.TITRE

Calcule la valeur marchande d'un titre à revenu fixe avec une valeur nominale de 100 unités monétaires comme fonction du rendement prévisionnel.

PRIX(terme;échéance;taux;rendement;remboursement;fréquence;base)

terme est la date d'achat du titre.

échéance est la date à laquelle le titre arrive à échéance (expire).

taux (requis) représente le taux nominal annuel de l'intérêt (taux d'intérêt du coupon)

rendement représente le rendement annuel du titre.

remboursement est la valeur de remboursement du titre pour 100 unités monétaires de la valeur nominale.

fréquence est le nombre de versements d'intérêts par an (1,2 ou 4).

Un titre est acheté le 15/02/1999 ; la date d'échéance est le 15/11/2007. Le taux d'intérêt nominal s'élève à 5,75 %. Le rendement s'élève à 6,5 %. La valeur de remboursement est de 100 unités monétaires. Les intérêts sont versés chaque semestre (la fréquence équivaut à 2). Avec un calcul sur une base de 0, le prix est le suivant :

=PRIX.TITRE("15/02/1999";"15/11/2007";0,585;0,065;100;2;0) renvoie 95,04287

DUREE.PERIODE

Calcule le nombre de périodes requises par un investissement pour atteindre la valeur souhaitée.

DUREE.PERIODE(taux;VA;VC)

taux est une constante. Le taux d'intérêt doit être calculé pour toute la durée (période). Le taux d'intérêt par période est calculé en divisant le taux d'intérêt par la durée calculée. Le taux interne pour une annuité doit être saisi taux/12.

VA représente la valeur actuelle. La valeur au comptant est le dépôt d'espèces ou la valeur au comptant actuelle d'une prestation en nature. Une valeur positive doit être saisie pour la valeur de dépôt, le dépôt ne doit pas être 0 ou <0.

VC représente la valeur attendue. La future valeur détermine la (future) valeur de dépôt souhaitée.

Pour un taux d'intérêt de 4,75%, une valeur au comptant actuelle de 25 000 unités monétaires et une valeur future de 1 000 000 d'unités monétaires, il résulte une durée de 79,49 périodes de versement. Le paiement périodique est le quotient obtenu à partir de la valeur future et de la durée, donc : 1 000 000/79,49 = 12 850,20.

PRIX.BON.TRESOR

Calcule le prix d'un bon du Trésor pour 100 unités monétaires.

PRIX.BON.TRESOR(terme;échéance;escompte)

terme est la date d'achat du titre.

échéance est la date à laquelle le titre arrive à échéance (expire).

escompte est le pourcentage d'escompte sur l'acquisition du titre.

La date de liquidation est le 31 mars 1999, le terme de l'échéance a été fixé au 1er juin 1999 et l'escompte s'élève à 9 pour cent.

Calcul du prix du bon du Trésor :

=PRIX.BON.TRESOR("31/03/1999";"01/06/1999") renvoie 98,45.

VALEUR.ENCAISSEMENT

Calcule le prix pour 100 unités monétaires de la valeur nominale d'un titre non productif d'intérêts.

VALEUR.ENCAISSEMENT(terme;échéance;escompte;remboursement;base)

terme est la date d'achat du titre.

échéance est la date à laquelle le titre arrive à échéance (expire).

escompte représente un escompte en pourcentage d'un titre.

remboursement est la valeur de remboursement du titre pour 100 unités monétaires de la valeur nominale.

Un titre a été acquis le 15/2/1999 et le terme de l'échéance a été fixé au 1/3/1999. L'escompte est de 5,25%, la valeur de remboursement est 100 et la base est réelle/360 (2). Lors du calcul en base 2, la valeur de l'escompte est la suivante :

=VALEUR.ENCAISSEMENT("15/02/1999";"01/03/1999";0,0525;100;2) renvoie 99,79583.

PRIX.TITRE.ECHEANCE

Calcule le prix pour 100 unités monétaires de la valeur nominale d'un titre, qui rapporte des intérêts à la date d'échéance.

PRIX.TITRE.ECHEANCE(terme;échéance;émission;taux;rendement;base)

terme est la date d'achat du titre.

échéance est la date à laquelle le titre arrive à échéance (expire).

terme est la date d'achat du titre.

taux représente le taux d'intérêt du titre à la date d'émission.

rendement représente le rendement annuel du titre.

La date de liquidation est le 15 février 1999, le terme de l'échéance est le 13 avril 1999 et la date d'émission est le 11 novembre 1998. Le taux d'intérêt s'élève à 6,1%, le rendement à 6,1% et la base est la méthode américaine 30/360 (2).

Le prix est calculé comme suit :

=PRIX.TITRE.ECHEANCE("15/02/1999";"13/04/1999";"11/11/1998";0,061;0,061;0) renvoie 99,98449888.

TAUX.ESCOMPTE.R

Calcule le rendement annuel d'un bon du trésor. Un bon du trésor est acheté à la date d'émission et vendu à la valeur nominale totale qui doit tomber la même année. Une remise est déduite de prix d'achat.

TAUX.ESCOMPTE.R(terme;échéance;escompte)

terme est la date d'achat du titre.

échéance est la date à laquelle le titre arrive à échéance (expire).

escompte est le pourcentage d'escompte sur l'acquisition du titre.

La date de liquidation est le 31 mars 1999, le terme de l'échéance a été fixé au 1er juin 1999 et l'escompte s'élève à 9,14 pour cent.

Calcul du taux d'intérêt du bon du trésor correspondant au titre :

=TAUX.ESCOMPTE.R("31/03/1999";"01/06/1999";0,0914) renvoie 0,094151 ou 9,4151 pour cent.

RENDEMENT.TITRE.ECHEANCE

Calcule le rendement annuel d'un titre dont les intérêts sont versés à la date d'échéance.

RENDEMENT.TITRE.ECHEANCE(terme;échéance;émission;taux;prix;base)

terme est la date d'achat du titre.

échéance est la date à laquelle le titre arrive à échéance (expire).

terme est la date d'achat du titre.

taux représente le taux d'intérêt du titre à la date d'émission.

prix est le prix du titre pour 100 unités monétaires de la valeur nominale.

Un titre a été acquis le 15/3/1999, le terme de l'échéance a été fixé au 3/11/1999 et la date de l'émission est le 8/11/1998. Le taux d'intérêt est de 6,25%, le prix s'élève à 100,0123 unités et la base de comptage des jours est la méthode américaine (0). Quel est le rendement ?

=RENDEMENT.TITRE.ECHEANCE("15/03/1999";"08/11/1998";0,0625;100,0123;0) renvoie 0,060954 ou 6,0954 pour cent.

RENDEMENT.SIMPLE

Calcule le rendement annuel d'un titre non productif d'intérêts.

TAUX.ESCOMPTE("Terme";"Échéance";prix;remboursement;base)

terme est la date d'achat du titre.

échéance est la date à laquelle le titre arrive à échéance (expire).

prix est le prix du titre pour 100 unités monétaires de la valeur nominale.

remboursement est la valeur de remboursement du titre pour 100 unités monétaires de la valeur nominale.

Un titre non productif a été acquis le 15/2/1999 et le terme de l'échéance a été fixé au 1/3/1999. Le prix s'élève à 99,795 unités monétaires pour une valeur nominale de 100 unités, la valeur de remboursement se situe à 100 unités et la base est réelle/360 (2). Quel est le rendement ?

=RENDEMENT.SIMPLE("15/02/1999";"01/03/1999";99,795;100;2) renvoie 0,052823 ou 5,2823 pour cent.

RENDEMENT.BON.TRESOR

Calcule le rendement d'un bon du Trésor.

RENDEMENT.BON.TRESOR(terme;échéance;prix)

terme est la date d'achat du titre.

échéance est la date à laquelle le titre arrive à échéance (expire).

prix est le prix (prix d'achat) du titre pour 100 unités monétaires de la valeur nominale.

La date de liquidation est le 31 mars 1999, le terme de l'échéance a été fixé au 1er juin 1999 et le prix s'élève à 98,45 unités monétaires.

Calcul du rendement du bon du Trésor :

=RENDEMENT.BON.TRESOR("31/03/1999";"01/06/1999";98,45) renvoie 0,091417 ou 9,1417 pour cent.

RENDEMENT.TITRE

Calcule le rendement d'un titre.

RENDEMENT.TITRE(terme;échéance;taux;prix;remboursement;fréquence;base)

terme est la date d'achat du titre.

échéance est la date à laquelle le titre arrive à échéance (expire).

taux_nominal est le taux nominal annuel de l'intérêt.

prix est le prix du titre pour 100 unités monétaires de la valeur nominale.

remboursement est la valeur de remboursement du titre pour 100 unités monétaires de la valeur nominale.

fréquence est le nombre de versements d'intérêts par an (1,2 ou 4).

Un titre a été acquis le 15/2/1999 et le terme de l'échéance a été fixé au 15/11/2007. Le taux d'intérêt est de 5,75%, le prix s'élève à 95,04287 unités monétaires pour une valeur nominale de 100 unités et la valeur de remboursement se situe à 100 unités. Les intérêts sont versés tous les semestres (fréquence = 2) et la base de comptage des jours est la méthode américaine (0). Quel est le rendement ?

=RENDEMENT.TITRE("15/02/1999";"15/11/2007";0,0575;95,04287;100;2;0) renvoie 0,065 ou 6,50 pour cent.

TAUX.NOMINAL_ADD

Calcule le taux d'intérêt nominal annuel en fonction du taux d'intérêt effectif et du nombre de paiements d'intérêts par an.

TAUX.NOMINAL_ADD(taux_effectif;NPA)

taux_effectif est le taux effectif annuel des intérêts.

NPA représente le nombre de paiements des intérêts périodiques par an.

Calcul du taux nominal pour un taux effectif de 5,3543% et des versements trimestriels.

=TAUX.NOMINAL_ADD(5,3543%;4) renvoie 0,0525 ou 5,25%.

TAUX.NOMINAL

Calcule le taux d'intérêt nominal annuel en fonction du taux d'intérêt effectif et du nombre de périodes par an.

TAUX.NOMINAL(taux_effectif;NPA)

taux_effectif représente le taux d'intérêt effectif

NPA représente le nombre de paiements des intérêts périodiques par an.

Quel est le montant des intérêts nominaux annuels pour un taux d'intérêt effectif de 13,5% et douze paiements d'intérêts par an.

=TAUX.NOMINAL(13,5%;12) = 12,73%. Le taux d'intérêts nominal par an est de 12,73%.

TRIM

Calcule le taux de rentabilité interne modifié pour une série d'investissements.

TRIM(valeurs;investissement;taux_réinvestissement)

valeurs correspond à la matrice ou à la référence de cellule pour les cellules dont le contenu correspond aux paiements.

investissement représente le taux d'intérêt de l'investissement (la valeur négative de la matrice)

taux_réinvestissement représente le taux d'intérêt du réinvestissement (valeur positive de la matrice)

Si A1 = -5, A2 = 10, A3 = 15, et A4 = 8, que la valeur d'investissement est de 0,5 est que la valeur de réinvestissement est de 0,1, alors le résultat est de 94,16%.

CUMUL.INTER_ADD

Calcule les intérêts courus pour une période donnée.

CUMUL.INTER_ADD(taux;NPM;VA;D;F;type)

taux définit le taux d'intérêt par période.

NPM représente le nombre total de périodes de paiements. Le taux et NPM doivent se référer à la même unité et tous deux doivent donc être calculés annuellement ou mensuellement.

VA représente la valeur actuelle.

début_période représente la première période de paiement du calcul.

fin_période correspond au dernier paiement de la période du calcul.

type représente l'échéance d'un paiement à la fin de chaque période (type = 0) ou au début de la période (type = 1).

Prêt hypothécaire destiné à financer un achat immobilier :

Taux : 9,00 pourcent par an (9 % / 12 = 0,0075), Durée : 30 ans (NPM = 30 * 12 = 360), PV : 125 000 unités monétaires.

Montant des intérêts à payer au cours de la deuxième année de remboursement du prêt (périodes 13 à 24) ?

=CUMUL.INTER_ADD(0,0075;360;125000;13;24;0) renvoie -11 135,23.

Intérêts à payer le premier mois ?

=CUMUL.INTER_ADD(0,0075;360;125000;1;1;0) renvoie -937,50.

CUMUL.INTER

Calcule les intérêts cumulés, c'est-à-dire la somme des intérêts d'un investissement réalisé sur la base d'un taux d'intérêt stable.

CUMUL.INTER(taux;NPM;VA;D;F;type)

taux détermine le taux d'intérêt périodique.

NPM représente la période de paiement avec le nombre total de périodes. NPM peut aussi représenter un nombre non entier.

VA représente la valeur actuelle dans la séquence de paiements.

D correspond à la première période.

F correspond à la dernière période.

type représente la date de paiement au début ou à la fin de chaque période.

Que représentent les intérêts avec un taux d'intérêt annuel de 5,5 %, une période de paiement par mensualités de deux ans et une valeur au comptant actuelle de 5 000 unités monétaires ? La période de début est la 4e période et la période de fin la 6e. Le paiement est dû au début de chaque période.

=CUMUL.INTER(5,5%/12;24;5000;4;6;1) = -57,54 unités monétaires. Le paiement des intérêts pendant la 4e et la 6e période est de 57,54 unités monétaires.

PRIX.FRAC

Convertit en fraction décimale mixte une cotation donnée sous forme de nombre décimal.

PRIX.FRAC(nombre_décimal;fraction)

nombre_décimal est un nombre décimal.

fraction est un nombre entier qui est utilisé comme dénominateur de la fraction décimale.

=PRIX.FRAC(1,125;16) convertit en seizièmes. Le résultat est 1,02 pour 1 plus 2/16.

=PRIX.FRAC(1,125;8) convertit en huitièmes. Le résultat est 1,1 pour 1 plus 1/8.

PRIX.DEC

Convertit en nombre décimal une cotation donnée sous forme de fraction décimale.

PRIX.DEC(nombre_fraction;fraction)

nombre_fraction est un nombre donné en fraction décimale.

fraction est un nombre entier qui est utilisé comme dénominateur de la fraction décimale.

=PRIX.DEC(1,02;16) représente 1 et 2/16. Cela renvoie 1,125.

=PRIX.DEC(1,1;8) représente 1 et 1/8. Cela renvoie 1,125.

CUMUL.PRINCPER

Renvoie l'intérêt cumulé payé pour une période d'investissement avec un taux d'intérêt stable.

CUMUL.PRINCPER(taux;NPM;VA;D;F;type)

taux détermine le taux d'intérêt périodique.

NPM représente la période de paiement avec le nombre total de périodes. NPM peut aussi représenter un nombre non entier.

VA représente la valeur actuelle dans la séquence de paiements.

D correspond à la première période.

F correspond à la dernière période.

type représente la date de paiement au début ou à la fin de chaque période.

Quels sont les montants des gains si un taux d'intérêt annuel s'élève à 5,5 % pour 36 mois ? La valeur au comptant est de 15 000 unités monétaires. Le montant des gains est calculé entre la 10ème et la 18ème période. L'échéance est au terme de la période.

=CUMUL.PRINCPER(5,5%/12;36;15000;10;18;0) = -3669,74 unités monétaires. Le montant du paiement entre la 10ème et la 18ème période est de 3669,74 unités monétaires.

VPM

Renvoie le paiement périodique pour une annuité avec des taux d'intérêt stables.

VPM(taux;NPM;VA;VC;type)

taux détermine le taux d'intérêt périodique.

NPM représente le nombre de périodes pour lesquelles l'annuité est versée.

VA représente la valeur actuelle (valeur au comptant) dans une séquence de paiements.

VC (facultatif) est la valeur souhaitée (valeur future) qui doit être atteinte à la fin des paiements périodiques.

type (facultatif) est la date des paiement périodiques. Type = 1 correspond au paiement en début et type = 0 correspond au paiement en fin de chaque période.

Dans les fonctions LibreOffice Calc, les paramètres marqués comme "facultatifs" peuvent être ignorés lorsqu'ils ne sont pas suivis d'autres paramètres. Par exemple, dans une fonction comportant quatre paramètres, où les deux derniers paramètres sont marqués comme "facultatifs", le paramètre 4 ou les paramètres 3 et 4 peuvent être ignorés, mais le paramètre 3 seul ne peut être ignoré.

Que représentent les paiements périodiques avec un taux d'intérêt annuel de 1,99 %, une durée de remboursement de 3 ans et une valeur au comptant de 25 000 unités monétaires ? Il y a 36 mois correspondant à 36 périodes de paiement et le taux d'intérêt par période de paiement est de 1,99 %/12.

=VPM(1,99%/12;36;25000) = -715,96 unités monétaires. Le paiement mensuel périodique est donc de 715,96 unités monétaires.

PRINCPER

Renvoie, pour une période donnée, le paiement sur le capital pour un investissement caractérisé par des paiements réguliers et constants, et un taux d'intérêt stable.

PRINCPER(taux;période;NPM;VA;VC;type)

taux détermine le taux d'intérêt périodique.

période représente la période d'amortissement. Période =1 pour la première et période = NPM pour la dernière période.

NPM est le nombre total de périodes pendant lesquelles l'annuité est payée.

VA représente la valeur actuelle dans une séquence de paiements.

VC (facultatif) est la (future) valeur souhaitée.

type (facultatif) définit la date. V = 1 pour le paiement au début de la période et V = 0 pour la paiement à la fin de la période.

Dans les fonctions LibreOffice Calc, les paramètres marqués comme "facultatifs" peuvent être ignorés lorsqu'ils ne sont pas suivis d'autres paramètres. Par exemple, dans une fonction comportant quatre paramètres, où les deux derniers paramètres sont marqués comme "facultatifs", le paramètre 4 ou les paramètres 3 et 4 peuvent être ignorés, mais le paramètre 3 seul ne peut être ignoré.

Quel est le montant de la mensualité avec un taux d'intérêt annuel de 8,75 % sur une période de trois ans ? La valeur au comptant, qui est de 5 000 unités monétaires, est toujours réglée au début d'une période. La valeur future est de 8 000 unités monétaires.

=PRINCPER(8,75%/12;1;36;5000;8000;1) = -350,99 unités monétaires.

Retour aux fonctions financières - Première partie

Fonctions financières - Troisième partie