Rahandusfunktsioonid 1. osa

This category contains the mathematical finance functions of LibreOffice Calc.

ISPMT

Arvutab intressimäära konstantsete osamaksete korral.

ISPMT(määr; periood; kokku_perioode; investeering)

Intressimäär on perioodide intressimäär.

Period is the number of installments for calculation of interest.

TotalPeriods is the total number of installment periods.

Invest is the amount of the investment.

Tahetakse teada, kui suur oleks 120000 rahaühiku suuruse laenu, mille tähtaeg on 2 aastat, aastane intressimäär 12% ja maksed toimuvad kord kuus, intress 1,5 aasta pärast.

=ISPMT(1%;18;24;120000) = -300 currency units. The monthly interest after 1.5 years amounts to 300 currency units.

IRR

Arvutab investeeringu sisemise tulumäära. Väärtused tähistavad regulaarsete intervallidega käibeid, vähemalt üks väärtus peab olema negatiivne (väljaminek) ja vähemalt üks väärtus peab olema positiivne (sissetulek).

If the payments take place at irregular intervals, use the XIRR function.

IRR(väärtused; hinnang)

Values represents an array containing the values.

Guess (optional) is the estimated value. An iterative method is used to calculate the internal rate of return. If you can provide only few values, you should provide an initial guess to enable the iteration.

Under the assumption that cell contents are A1=-10000, A2=3500, A3=7600 and A4=1000, the formula =IRR(A1:A4) gives a result of 11,33%.

DURATION

Arvutab kindla intressiga väärtpaberi kestuse aastates.

DURATION("Settlement"; "Maturity"; Coupon; Yield; Frequency; Basis)

Settlement is the date of purchase of the security.

Tähtaeg on väärtpaberi aegumise kuupäev.

Coupon is the annual coupon interest rate (nominal rate of interest)

Tulusus on väärtpaberi aastane tulusus.

Sagedus on intressimaksete arv aastas (1, 2 või 4).

A security is purchased on 2001-01-01; the maturity date is 2006-01-01. The Coupon rate of interest is 8%. The yield is 9.0%. Interest is paid half-yearly (frequency is 2). Using daily balance interest calculation (basis 3) how long is the duration?

=DURATION("2001-01-01";"2006-01-01";0.08;0.09;2;3)

AMORLINC

Arvutab põhivahendi amortisatsiooni arvestusperioodi kohta lineaarse amortisatsioonina. Kui põhivahend on soetatud arvestusperioodi jooksul, siis leitakse amortisatsiooni võrdeline osa.

AMORLINC(maksumus; soetamiskuupäev; esimene periood; jääkväärtus; periood; määr; alus)

Maksumus on soetusmaksumus.

Soetamiskuupäev on põhivahendi soetamiskuupäev.

Esimene periood on esimese arveldusperioodi lõppkuupäev.

Salvage is the salvage value of the capital asset at the end of the depreciable life.

Periood on arvutuses vaadeldav arveldusperiood.

Määr on amortisatsioonimäär.

AMORDEGRC

Arvutab põhivahendi amortisatsiooni perioodi kohta kahaneva amortisatsioonina. Vastupidiselt funktsioonile AMORLINC on käesoleva funktsiooni juures amortisatsioonikoefitsent elueast sõltumatu.

AMORDEGRC(maksumus; soetamiskuupäev; esimene periood; jääkväärtus; periood; määr; alus)

Maksumus on soetusmaksumus.

Soetamiskuupäev on põhivahendi soetamiskuupäev.

Esimene periood on esimese arveldusperioodi lõppkuupäev.

Salvage is the salvage value of the capital asset at the end of the depreciable life.

Periood on arvutuses vaadeldav arveldusperiood.

Määr on amortisatsioonimäär.

RECEIVED

Arvutab saadava summa, mis makstakse kindla intressiga väärtpaberi eest määratud ajal.

RECEIVED("arvelduspäev"; "tähtaeg"; hind; diskonto; alus)

Settlement is the date of purchase of the security.

Tähtaeg on väärtpaberi aegumise kuupäev.

Hind on ostusumma.

Discount is the percentage discount on acquisition of the security.

Arvelduspäev: 15. veebruar 1999, tähtaeg: 15. mai 1999, ostusumma: 1000 rahaühikut, diskontomäär: 5,75 protsenti, alus: päevane bilanss/360 = 2.

Tähtajal saadav summa arvutatakse järgnevalt:

=RECEIVED("1999-02-15";"1999-05-15";1000;0.0575;2) returns 1014.420266.

DISC

Arvutab väärtpaberi diskontomäära protsentides.

DISC("arvelduspäev"; "tähtaeg"; hind; tagatis; alus)

Settlement is the date of purchase of the security.

Tähtaeg on väärtpaberi aegumise kuupäev.

Price is the price of the security per 100 currency units of par value.

Redemption is the redemption value of the security per 100 currency units of par value.

A security is purchased on 2001-01-25; the maturity date is 2001-11-15. The price (purchase price) is 97, the redemption value is 100. Using daily balance calculation (basis 3) how high is the settlement (discount)?

=DISC("2001-01-25";"2001-11-15";97;100;3) returns about 0.0372 or 3.72 per cent.

ACCRINTM

Arvutab väärtpaberi tekkepõhise intressi arvestades, et kogu summa väärtpaberi eest on makstud arvelduspäeval.

ACCRINTM(emissioon; arvelduspäev; intress; nimiväärtus; alus)

Issue (required) is the issue date of the security.

Settlement (required) is the date at which the interest accrued up until then is to be calculated.

Rate (required) is the annual nominal rate of interest (coupon interest rate).

Par (optional) is the par value of the security.

A security is issued on 2001-04-01. The maturity date is set for 2001-06-15. The Rate is 0.1 or 10% and Par is 1000 currency units. The basis of the daily/annual calculation is the daily balance (3). How much interest has accrued?

=ACCRINTM("2001-04-01";"2001-06-15";0.1;1000;3) returns 20.54795.

DB

Returns the depreciation of an asset for a specified period using the fixed-declining balance method.

Seda amortisatsiooni vormi kasutatakse, kui amortiseerumise alguses soovitakse arvutada kõrgemat amortisatsiooni (vastandina lineaarsele amortisatsioonile). Amortiseeruvat väärtust vähendatakse iga perioodi järel juba arvestatud amortisatsiooni võrra.

DB(maksumus; jääkväärtus; eluiga; periood; kuu)

Maksumus on põhivahendi soetusmaksumus.

Jääkväärtus on põhivahendi väärtus pärast tema eluea lõppu.

Life defines the period over which an asset is depreciated.

Period is the length of each period. The length must be entered in the same date unit as the depreciation period.

Month (optional) denotes the number of months for the first year of depreciation. If an entry is not defined, 12 is used as the default.

Arvutikomplekt ostuhinnaga 25000 rahaühikut amortiseerub 3 aasta jooksul. Väärtus eluea lõpus on 1000 rahaühikut. Perioodi pikkus on 30 päeva.

=DB(25000;1000;36;1;6) = 1075,00 rahaühikut

Arvutikomplekti konstantselt kahanev amortisatsioon on 1075,00 rahaühikut.

SYD

Tagastab lineaarselt kahaneva amortisatsioonimäära.

Selle funktsiooni abil arvutakse objekti eluea ühe perioodi jooksul arvestatavat amortisatsiooni. Lineaarselt kahaneva amortisatsiooni puhul väheneb amortisatsiooni summa iga perioodi jooksul kindla väärtuse võrra.

SYD(maksumus; jääkväärtus; eluiga; periood)

Maksumus on põhivahendi soetusmaksumus.

Salvage is the value of an asset after depreciation.

Life is the period fixing the time span over which an asset is depreciated.

Period defines the period for which the depreciation is to be calculated.

Videosüsteem, mis maksis 50000 rahaühikut, amortiseerub aastakaupa 5 aasta jooksul. Jääkväärtuseks jääb 10000 rahaühikut. Leiame esimese aasta amortisatsiooni.

=SYD(50000;10000;5;1)=13,333.33 currency units. The depreciation amount for the first year is 13,333.33 currency units.

Parema ülevaate saamiseks amortisatsiooni suurusest perioodide lõikes on kasulik koostada amortisatsiooni tabel. Erinevate LibreOffice Calci valemite sisestamisel üksteise järele näeme, milline amortisatsiooni arvutamise viis on kõige mõistlikum. Sisestame tabelisse järgnevad kirjed:

	A	B	C	D	E
1	Soetusmaksumus	Jääkväärtus	Kasulik eluiga	Periood	Amort. SYD
2	50 000 rahaühikut	10 000 rahaühikut	5	1	13 333,33 rahaühikut
3				2	10 666,67 rahaühikut
4				3	8000,00 rahaühikut
5				4	5333,33 rahaühikut
6				5	2666,67 rahaühikut
7				6	0,00 rahaühikut
8				7
9				8
10				9
11				10
12
13	>0			Kokku	40 000,00 rahaühikut

Valem lahtris E2 on järgmine:

=SYD($A$2;$B$2;$C$2;D2)

Valem kogu veerus E on ühesugune lahtrini E11 (vali E2 ja lohista hiirega lahtri alumist parempoolset nurka kuni lahtrini E11).

Lahter E13 sisaldab valemit amortisatsioonide summa kontrolliks. Valemis kasutatakse funktsiooni SUMIF, kuna negatiivseid väärtusi vahemikus E8:E11 ei tohi arvestada. Tingimus >0 on lahtris A13. Lahtris E13 on järgnev valem:

=SUMIF(E2:E11;A13)

Nüüd on võimalik näha amortisatsiooni 10 aasta jooksul, jääkväärtuse 1 rahaühik korral või erineva soetusmaksumuse puhul ja nii edasi.

DDB

Tagastab põhivahendi amortisatsiooni määratud perioodi kohta, kasutades lineaarse kahanemise meetodit.

Seda amortisatsiooni vormi kasutatakse, kui vajatakse suuremat amortisatsiooni põhivahendi eluea alguses. Kulum muutub iga perioodiga väiksemaks ja see juhtub tavaliselt esemetega, mis kaotavad oma väärtusest suure osa kohe pärast ostmist (sõidukid, arvutid). Pane tähele, et sellise arvutusviisi juures ei muutu põhivahendi jääkväärtus kunagi nulliks.

DDB(maksumus; jääkväärtus; eluiga; periood; faktor)

Maksumus on põhivahendi soetusmaksumus.

Salvage fixes the value of an asset at the end of its life.

Life is the number of periods (for example, years or months) defining how long the asset is to be used.

Period states the period for which the value is to be calculated.

Factor (optional) is the factor by which depreciation decreases. If a value is not entered, the default is factor 2.

Arvutikomplekt ostuhinnaga 75000 rahaühikut amortiseerub kuukaupa 5 aasta jooksul. Väärtus eluea lõpus on 1 rahaühik. Faktor on 2.

=DDB(75000;1;60;12;2) = 1,721.81 currency units. Therefore, the double-declining depreciation in the twelfth month after purchase is 1,721.81 currency units.

PV

Tagastab regulaarsete maksete saamiseks tehtud investeeringu nüüdisväärtuse.

See funktsioon arvutab, kui palju raha on kindla intressi korral vaja investeerida praegu, et saada annuiteedina teatud summa mingi arvu perioodide jooksul. Võimalik on ette anda ka summa, mis peab olemas olema perioodi lõpul. Tingimustes saab määrata, kas väljamaksed tehakse perioodi alguses või lõpus.

Sisesta väärtused arvude, avaldiste või viidetena. Näiteks kui intressi makstakse aastas 8%, kuid sa soovid aasta asemel kasutada perioodina kuud, sisesta 8%/12 kohale Intress ja LibreOffice Calc arvutab automaatselt õige intressimäära.

PV(intress; NPer; pmt; FV; tüüp)

Intress määrab intressimäära perioodi kohta.

NPer on perioodide koguarv, mille jooksul makseid sooritatakse (makseperiood).

Pmt on perioodis tehtava regulaarse makse suurus.

FV (optional) defines the future value remaining after the final installment has been made.

Type (optional) denotes due date for payments. Type = 1 means due at the beginning of a period and Type = 0 (default) means due at the end of the period.

LibreOffice Calci funktsioonides võib argumendi, mis on märgitud kui "mittekohustuslik", jätta ära ainult siis, kui talle ei järgne enam teisi argumente. Näiteks, kui nelja argumendiga funktsiooni kaks viimast argumenti omavad märget "mittekohustuslik", võib ära jätta argumendi 4 või argumendid 3 ja 4, kuid mitte argumenti 3 üksinda.

Milline on investeeringu nüüdisväärtus, kui iga kuu makstakse välja 500 rahaühikut ja aastaintress on 8%? Makseperiood on 48 kuud ja lõpuks peab järele jääma 20 000 rahaühikut.

=PV(8%/12;48;500;20000) = -35,019.37 currency units. Under the named conditions, you must deposit 35,019.37 currency units today, if you want to receive 500 currency units per month for 48 months and have 20,000 currency units left over at the end. Cross-checking shows that 48 x 500 currency units + 20,000 currency units = 44,000 currency units. The difference between this amount and the 35,000 currency units deposited represents the interest paid.

Kui sisestada valemisse väärtuste asemel viited lahtritele, siis võib läbi mängida piiramatu hulga "siis kui" stsenaariume. Pane tähele, et viited konstantidele tuleb määrata absoluutviidetena. Seda tüüpi arvutuste näited on toodud amortisatsiooni arvutamise funktsioonide all.

EFFECT_ADD

Tagastab tegeliku aastaintressi määra vastavalt intressimäära nimiväärtusele ja intressimaksete arvule aastas.

EFFECT_ADD(nominaalintress; perioode)

NominalRate is the annual nominal rate of interest.

NPerY is the number of interest payments per year.

Leiame tegeliku aastaintressi määra, kui intressimäära nimiväärtus on 5.25% ja makseid teostatakse kord kvartalis.

=EFFECT_ADD(0.0525;4) returns 0.053543 or 5.3543%.

EFFECT

Tagastab tegeliku aastaintressi määra vastavalt intressimäära nimiväärtusele.

Intressimäära nimiväärtus arvestab intressi summat arvutusperioodi lõpus. Tegelik intressimäär suureneb koos tehtud maksete arvuga. Teiset sõnadega, intressi makstakse sageli osamaksete kaupa (kord kuus või kvartalis) enne arvutusperioodi lõppu.

EFFECT(Nom; P)

Nom is the nominal interest.

P is the number of interest payment periods per year.

Kui aastaintressi määra nimiväärtus on 9.75% ja intressi arvutatakse neli korda aastas, mis on siis tegelik intressimäär (kehtiv intressimäär)?

=EFFECT(9.75%;4) = 10.11% The annual effective rate is therefore 10.11%.

ACCRINT

Tagastab väärtpaberi tekkepõhise intressi perioodiliste maksete korral.

ACCRINT(emissioon; esimene intress; arvelduspäev; intress; nimiväärtus; sagedus; alus)

Issue (required) is the issue date of the security.

FirstInterest (required) is the first interest date of the security.

Settlement (required) is the date at which the interest accrued up until then is to be calculated.

Rate (required) is the annual nominal rate of interest (coupon interest rate)

Par (optional) is the par value of the security.

Frequency (required) is the number of interest payments per year (1, 2 or 4).

A security is issued on 2001-02-28. First interest is set for 2001-08-31. The settlement date is 2001-05-01. The Rate is 0.1 or 10% and Par is 1000 currency units. Interest is paid half-yearly (frequency is 2). The basis is the US method (0). How much interest has accrued?

=ACCRINT("2001-02-28";"2001-08-31";"2001-05-01";0.1;1000;2;0) returns 16.94444.

Rahandusfunktsioonid, 2. osa

Rahandusfunktsioonid, 3. osa