Funktion SUMMEWENNS
Ergibt die Summe der Werte der Zellen in einem Bereich, die mehrere Bedingungen in mehreren Bereichen erfĂĽllen.
SUMMEWENNS(Funktionsbereich; Bereich 1; Kriterium 1 [ ; Bereich 2; Kriterium 2 [;...]]))
Funktionsbereich – erforderliches Argument. Ist ein Zellbereich, der Name eines benannten Bereichs oder eine Spalten-/Zeilenüberschrift, der/die Werte enthält, für die die Summe berechnet wird.
Die Suche unterstützt Platzhalter oder reguläre Ausdrücke. Wenn reguläre Ausdrücke aktiviert sind, können Sie "alle.*" Eingeben, um beispielsweise die erste Position von „alle“ gefolgt von beliebigen Zeichen zu finden. Wenn Sie nach einem Text suchen möchten, der auch ein regulärer Ausdruck ist, müssen Sie entweder jedem Zeichen ein "\" voranstellen oder den Text in "\Q…\E" einschließen. Um die automatische Auswertung von Platzhaltern oder regulären Ausdrücken in ein- und auszuschalten, wählen Sie .
Wenn Sie Funktionen verwenden, bei denen ein oder mehrere Argumente Zeichenfolgen für Suchkriterien sind, die einen regulären Ausdruck darstellen, besteht ein erste Versuch darin, die Kriterien für Zeichenfolgen in Zahlen zu konvertieren. Zum Beispiel wird ",0" in 0,0 konvertiert und so weiter. Bei Erfolg ist die Übereinstimmung keine Übereinstimmung mit regulären Ausdrücken, sondern eine numerische Übereinstimmung. Wenn Sie jedoch zu einem Gebietsschema wechseln, bei dem das Dezimaltrennzeichen nicht das Komma ist, funktioniert die Konvertierung des regulären Ausdrucks. Um die Auswertung des regulären Ausdrucks anstelle eines numerischen Ausdrucks zu erzwingen, verwenden Sie einen Ausdruck, der nicht als numerisch falsch interpretiert werden kann, beispielsweise ",[0]" oder ",\0" oder "(?i),0".
Die logische Beziehung zwischen Bedingungen kann als logisches UND (Konjunktion) definiert werden. In anderen Worten, wenn und nur wenn alle angegebenen Bedingungen zutreffen, wird ein Wert von der zugehörigen Zelle aus dem angegebenen Funktionsbereich in der Berechnung berücksichtigt.
Diese Funktion ist Teil des OpenDocument-Standards (Open Document Format for Office Applications) Version 1.2. (ISO/IEC 26300:2-2015)
Betrachten Sie folgende Tabelle
|
A |
B |
C |
|
|
1 |
Produktname |
Absatz |
Einnahmen |
|
2 |
Buntstift |
20 |
65 |
|
3 |
Stift |
35 |
85 |
|
4 |
Schulbuch |
20 |
190 |
|
5 |
Buch |
17 |
180 |
|
6 |
Buntstift-Set |
nicht |
nicht |
In allen unten stehenden Beispielen enthält der Bereich für die Berechnung der Summe die Zeile 6, diese wird aber ignoriert, da sie Text enthält.
Einfache Verwendung
=SUMMEWENNS(B2:B6;B2:B6;">=20")
Berechnet die Summe der Werte im Bereich B2:B6, die größer oder gleich 20 sind. Ergibt 75, da die fünfte Zeile die Bedingung nicht erfüllt.
=SUMMEWENNS(C2:C6;B2:B6;">=20";C2:C6;">70")
Berechnet die Summe der Werte im Bereich C2:C6, die größer als 70 und deren entsprechende Zellwerte im Bereich B2:B6 größer oder gleich 20 sind. Ergibt 275, da die zweite und fünfte Zeile je mindestens eine Bedingung nicht erfüllen.
Verwendung mit regulären Ausdrücken und verschachtelten Funktionen
=SUMMEWENNS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))
Berechnet die Summe der Werte im Bereich C2:C6, die allen Werten im Bereich B2:B6, auĂźer dem Minimum und dem Maximum, entsprechen. Ergibt 255, da die dritte und fĂĽnfte Zeile je mindestens eine Bedingung nicht erfĂĽllen.
=SUMMEWENNS(C2:C6;A2:A6;".*stift";B2:B6;"<"&MAX(B2:B6))
Berechnet die Summe der Werte im Bereich C2:C6, die allen Zellen im Bereich A2:A6, die auf "stift" enden, und allen Zellen im Bereich B2:B6, auĂźer dem Maximum, entsprechen. Ergibt 65, da nur die zweite Zeile alle Bedingungen erfĂĽllt.
BezĂĽge zu einer Zelle mit einer Bedingung
Um eine Bedingung einfach zu ändern, bietet es sich an, diese in einer separaten Zelle festzulegen und für die Bedingung der Funktion SUMMEWENNS einen Bezug zur Zelle anzugeben. Beispielsweise kann obige Funktion geschrieben werden als:
=SUMMEWENNS(C2:C6;A2:A6;".*"&E2;B2:B6;"<"&MAX(B2:B6))
Wenn E2 = stift ist, ergibt die Funktion 65, da der Bezug zur Zelle derem Inhalt entspricht.
