Textové funkce

Tato část popisuje funkce Textu.

ASC

Funkce ASC převede ASCII a katakana znaky plné šířky na poloviční šířku. Vrací textový řetězec.

Viz převodní tabulku na https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions.

ASC("Text")

Text obsahuje znaky pro převod.

Viz též funkce JIS.

JIS

Funkce JIS převede ASCII a katakana znaky poloviční šířky na plnou šířku. Vrací textový řetězec.

Viz převodní tabulku na https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions.

JIS("Text")

Text obsahuje znaky pro převod.

Viz též funkce ASC.

REPLACE

Nahradí část textového řetězce jiným textovým řetězcem. Tuto funkci je možné využít k náhradě znaků i čísel (která se automaticky převedou na text). Výsledek funkce se vždy zobrazí jako text. Pokud chcete s číslem po náhradě provádět další výpočty, musíte jej převést zpět na číslo pomocí funkce VALUE.

Text, který obsahuje čísla, musí být uzavřen v uvozovkách. V opačném případě se interpretuje jako číslo a automaticky převede na text.

REPLACE("Text"; Pozice; Délka; "NovýText")

Text představuje text, jehož část bude nahrazena.

Pozice představuje pozici v textu, od které se začne nahrazovat.

Délka je počet znaků v Textu, který se nahradí.

NovýText představuje text, kterým bude nahrazen Text.

=REPLACE("1234567";1;1;"444") vrátí "444234567". Jeden znak na pozici 1 je nahrazen celým NovýmTextem.

SUBSTITUTE

Nahradí část textu v řetězci jiným textem.

SUBSTITUTE("Text"; "HledanýText"; "NovýText"; Výskyt)

Text je text, jehož části se nahradí.

HledanýText je část textu, která bude nahrazena (vícekrát).

NovýText je text, kterým bude nahrazena část textu.

Výskyt (nepovinné) značí, kolikátý výskyt hledaného textu se nahradí. Není-li tento parametr zadán, nahradí se všechny výskyty.

=SUBSTITUTE("123123123";"3";"abc") vrátí 12abc12abc12abc.

=SUBSTITUTE("123123123";"3";"abc";2) vrátí 12312abc123.

TRIM

Odstraní mezery z řetězce a ponechá mezi slovy jen jednoznakovou mezeru.

TRIM("Text")

Text je text, ve kterém mají být odstraněny mezery.

=TRIM(" ahoj světe ") vrátí ahoj světe bez úvodních a koncových mezer a s jedinou mezerou mezi slovy.

REPT

Opakuje textový řetězec tolikrát, kolikrát je uvedeno v parametru počet.

REPT("Text"; Počet)

Text je text, který se bude opakovat.

Číslo udává počet opakování.

Výsledek funkce může mít maximálně 255 znaků.

=REPT("Dobré ráno";2) vrátí Dobré ránoDobré ráno.

EXACT

Porovná dva řetězce a vrátí PRAVDA, pokud jsou stejné. Tato funkce rozlišuje velikost písmen.

EXACT("Text1"; "Text2")

Text1 představuje první text na porovnání.

Text2 je druhý text na porovnání.

=EXACT("mikrosystémy";"Mikrosystémy") vrátí NEPRAVDA.

BASE

Převede kladné číslo na text v číselné soustavě o určeném základu. Použijí se číslice 0-9 a písmena A-Z.

BASE(Číslo; Základ; [MinimálníDélka])

Číslo je kladné číslo pro převod.

Základ označuje základ číselné soustavy. Může se jednat o kladné číslo mezi 2 a 36.

MinimálníDélka (nepovinné) určuje minimální délku řady znaků, která se vytvoří. Pokud bude text kratší než stanovená minimální délka, na levou stranu řetězce se přidají nuly.

=BASE(17;10;4) vrátí 0017 v desítkové soustavě.

=BASE(17;2) vrátí 10001 ve dvojkové soustavě.

=BASE(255;16;4) vrátí 00FF v šestnáctkové soustavě.

DECIMAL

Převede text se znaky z číselné soustavy na kladné číslo v soustavě s určeným základem. Základ této soustavy musí být v rozsahu 2 až 36. Mezery a tabulátory jsou ignorovány. U pole text nezáleží na velikosti znaků.

Pokud použijete šestnáctkovou soustavu, ignoruje se počáteční x, X, 0x nebo 0X a koncové h nebo H. Pokud použijete dvojkovou soustavu, ignoruje se koncové b nebo B. Jiné znaky, které nepatří do číselné soustavy, vyvolají chybu.

DECIMAL("Text"; Základ)

Text je text, který se převede. Abyste odlišili číslo v šestnáctkové soustavě, například A1, od odkazu na buňku A1, musíte číslo zapsat do uvozovek, například "A1" nebo "FACE".

Základ označuje základ číselné soustavy. Může se jednat o kladné číslo mezi 2 a 36.

=DECIMAL("17";10) vrátí 17.

=DECIMAL("FACE";16) vrátí 64206.

=DECIMAL("0101";2) vrátí 5.

VALUE

Převede textový řetězec na číslo.

VALUE("Text")

Text je text, který se převede na číslo.

=VALUE("4321") vrátí 4321.

LOWER

Převede všechna velká písmena v textovém řetězci na malá.

LOWER("Text")

Text představuje text, který se převede.

=LOWER("Slunce") vrátí slunce.

UNICHAR

Převede číselný kód na znak nebo písmeno Unicode.

UNICHAR(číslo)

=UNICHAR(169) vrátí znak copyright - ©.

DOLLAR

Převede číslo na hodnotu s jednotkou měny a zaokrouhlí na určený počet desetinných míst. Jako parametr Hodnota zadejte číslo, které chcete převést na měnu. Volitelně je také možné zadat počet desetinných míst parametrem Desetinná místa. Pokud tento počet neurčíte, zobrazí se výsledek na dvě desetinná místa.

Formát měny je nastaven podle vašeho systému.

DOLLAR(Hodnota; Desetinná místa)

Hodnota je číslo, odkaz na buňku s číslem nebo vzorec, který vrací číslo.

Desetinná místa je nepovinný počet desetinných míst.

=DOLLAR(255) vrátí $255.00.

=DOLLAR(367.456;2) vrátí $367.46. Použijte oddělovač desetinných míst, který odpovídá aktuálnímu národnímu prostředí.

TEXT

Převede číslo na text podle určeného formátu.

TEXT(číslo; formát)

Číslo je číselná hodnota, která se převede.

Formát je text, který určuje formát. Použijte oddělovače desetinných míst a tisíců v souladu s tím, jaký jazyk je nastaven ve formátu buňky.

=TEXT(12.34567;"###.##") vrátí text 12.35

=TEXT(12.34567;"000.00") vrátí text 012.35

BAHTTEXT

Převede číslo na thajský text, včetně názvů thajské měny.

BAHTTEXT(Číslo)

Číslo je jakékoliv číslo. K celé části čísla se přidá "Baht" a k desetinné části se přidá "Satang".

=BAHTTEXT(12.65) vrátí řetězec v thajských znacích s významem "dvanáct bahtů a šedesát pět satangů".

CHAR

Převede číslo na znak podle aktuální převodní tabulky. Číslo může být dvou- nebo tříciferné celé číslo.

CHAR(Číslo)

Číslo mezi 1 a 255 představuje hodnotu kódu znaku.

=CHAR(100) vrátí znak d.

="abc" & CHAR(10) & "def" vrátí řetězec se znakem konce řádku.

ROMAN

Převede číslo na římské číslice. Hodnota musí být v rozsahu 0 až 3999, režim může být celé číslo od 0 do 4.

ROMAN(číslo; režim)

Číslo je číslo, které se převede na římské číslice.

Režim (nepovinné) značí stupeň zjednodušení. Čím vyšší je hodnota, tím jednodušší bude zápis v římských číslicích.

=ROMAN(999) vrátí CMXCIX

=ROMAN(999;0) vrátí CMXCIX

=ROMAN (999;1) vrátí LMVLIV

=ROMAN(999;2) vrátí XMIX

=ROMAN(999;3) vrátí VMIV

=ROMAN(999;4) vrátí IM

UPPER

Převede řetězec v parametru text na velká písmena.

UPPER("Text")

Text představuje malá písmena, která chcete převést na velká písmena.

=UPPER("Dobré ráno") vrátí DOBRÉ RÁNO.

CONCATENATE

Spojí několik řetězců do jednoho.

CONCATENATE("Text1"; ...; "Text30")

Text 1; Text 2; ... představuje až 30 částí textů, které se spojí do jednoho řetězce.

=CONCATENATE("Dobré ";"ráno, ";"paní ";"Nováková") vrátí: Dobré ráno, paní Nováková.

ARABIC

Spočítá hodnotu římského čísla. Hodnota musí být v rozmezí od 0 do 3999.

ARABIC("Text")

Text představuje římské číslo.

=ARABIC("MXIV") vrátí 1014

=ARABIC("MMII") vrátí 2002

T

Tato funkce vrátí cílový text nebo prázdný řetězec, pokud cíl není text.

T(Hodnota)

Pokud je Hodnota textový řetězec nebo odkaz na textový řetězec, T vrátí tento řetězec; jinak vrátí prázdný textový řetězec.

=T(12345) vrátí prázdný řetězec.

=T("12345") vrátí řetězec 12345.

LENB

U jazyků s dvoubajtovou znakovou sadou (DBCS) vrátí počet bajtů použitých pro reprezentaci znaků textového řetězce.

LENB("Text")

Text je text, jehož délka se má zjistit.

LENB("中") vrátí 2 (1 znak DBCS tvořený 2 bajty).

LENB("中国") vrátí 4 (2 znaky DBCS, z nichž je každý tvořen 2 bajty).

LENB("office") vrátí 6 (6 znaků bez DBCS, z nichž je každý tvořen 1 bajtem).

=LENB("Dobré odpoledne") vrátí 15.

=LENB(12345.67) vrátí 8.

PROPER

Upraví první písmeno ve všech slovech textového řetězce na velké.

PROPER("Text")

Text představuje text, který se převede.

=PROPER("open office") vrátí Open Office.

LEN

Vrátí délku řetězce včetně mezer.

LEN("Text")

Text je text, jehož délka se zjistí.

=LEN("Dobré odpoledne") vrátí 15.

=LEN(12345.67) vrátí 8.

UNICODE

Vrátí numerický kód prvního Unicode znaku řetězce.

UNICODE("Text")

=UNICODE("©") vrátí číslo Unicode 169 pro znak copyrightu.

CODE

Vrátí numerický kód prvního znaku řetězce.

CODE("Text")

Text je text, pro který se nalezne kód jeho prvního znaku.

=CODE("Hieronymus") vrátí 72, =CODE("hieroglyfický") vrátí 104.

MIDB

Vrátí podřetězec textu s DBCS. Parametry určují počáteční pozici a počet znaků.

MIDB("Text"; Začátek; Počet_bajtů)

Text obsahuje znaky, které se vyčlení.

Začátek je pozice v textu, na které se vyčlení první znak.

Počet_bajtů udává počet znaků vráceného textu v bajtech.

MIDB("中国";1;0) vrátí "" (0 bajtů vždy představuje prázdný řetězec).

MIDB("中国";1;1) vrátí " " (1 bajt je pouze polovina znaku DBCS, a proto je výsledkem znak mezery).

MIDB("中国";1;2) vrátí "中" (2 bajty představují jeden úplný znak DBCS).

MIDB("中国";1;3) vrátí "中 " (3 bajty představují jeden a půl znaku DBCS; místo posledního znaku se proto vrátí znak mezery).

MIDB("中国";1;4) vrátí "中国" (4 bajty představují dva úplné znaky DBCS).

MIDB("中国";2;1) vrátí " " (bajt na pozici 2 není na začátku znaku řetězce DBCS; vrátí se 1 znak mezery).

MIDB("中国";2;2) vrátí " " (bajt na pozici 2 představuje druhou polovinu prvního znaku řetězce DBCS; požadované 2 bajty proto představují druhou polovinu prvního znaku a první polovinu druhého znaku řetězce; vrátí se tudíž 2 znaky mezery).

MIDB("中国";2;3) vrátí " 国" (bajt na pozici 2 není na začátku znaku řetězce DBCS; vrátí se pro něj proto znak mezery).

MIDB("中国";3;1) vrátí " " (bajt na pozici 3 je na začátku znaku řetězce DBCS, ale 1 bajt představuje pouze polovinu znaku DBCS, a proto se místo ní vrátí znak mezery).

MIDB("中国";3;2) vrátí "国" (bajt na pozici 3 je na začátku znaku řetězce DBCS a 2 bajty představují jeden znak DBCS).

MIDB("office";2;3) vrátí "ffi" (bajt na pozici 2 je na začátku znaku řetězce bez DBCS a 3 bajty řetězce bez DBCS představují 3 znaky).

MID

Vrátí podřetězec textu. Parametry určují počáteční pozici a počet znaků.

MID("Text"; Začátek; Počet)

Text obsahuje znaky, které se vyčlení.

Začátek je pozice v textu, na které se vyčlení první znak.

Počet udává počet znaků ve vyčleněné části textu.

=MID("office";2;2) vrátí ff.

RIGHTB

Vrátí poslední znak nebo znaky textu s dvoubajtovou znakovou sadou (DBCS).

RIGHTB("Text"; Počet_bajtů)

Text je text, jehož pravá část se má zjistit.

Počet_bajtů (nepovinné) udává počet znaků vyčleněného textu založený na bajtech.

RIGHTB("中国";1) vrátí " " (1 bajt představuje pouze polovinu znaku DBCS a místo ní se vrátí znak mezery).

RIGHTB("中国";2) vrátí "国" (2 bajty představují jeden úplný znak DBCS).

RIGHTB("中国";3) vrátí " 国" (3 bajty představují půl a jeden úplný znak DBCS; místo první poloviny se vrátí mezera).

RIGHTB("中国";4) vrátí "中国" (4 bajty představují dva úplné znaky DBCS).

RIGHTB("office";3) vrátí "ice" (3 znaky bez DBCS, z nichž je každý tvořen 1 bajtem).

RIGHT

Vrátí poslední znak nebo znaky textu.

RIGHT("Text"; Počet)

Text je text, jehož pravá část se má zjistit.

Počet (nepovinné) je počet znaků z pravé části textu.

=RIGHT("Slunce";2) vrátí ce.

SEARCH

Vrátí pozici části textu v řetězci. Možné je také nastavit začátek hledání. Hledaný text může být číslo nebo sekvence znaků. U hledání nezávisí na velikosti písmen. Pokud text nebyl nalezen, vrátí chybu 519 (#VALUE).

SEARCH("HledanýText"; "Text"; Pozice)

HledanýText je text, který se bude hledat.

Text je text, ve kterém se bude hledat.

Pozice (nepovinné) je pozice v textu, od které hledání začne.

=SEARCH(54;998877665544) vrátí 10.

FIND

Vrátí pozici řetězce v jiném řetězci. Také je možné určit, kde začne hledání. Hledaný termín může být číslo nebo libovolný řetězec. Při hledání záleží na velikosti znaků.

FIND("HledanýText"; "Text"; Pozice)

HledanýText představuje hledaný text.

Text je text, ve kterém se bude vyhledávat.

Pozice (volitelné) je pozice v textu, na které hledání začne.

=FIND(76;998877665544) vrátí 6.

LEFTB

Vrátí první znak nebo znaky textu s DBCS.

LEFTB("Text"; Počet_bajtů)

Text je text, u nějž se určí počáteční část.

Počet_bajtů (nepovinné) udává na základě bajtů počet znaků počátečního textu. Není-li tento parametr zadán, vrátí se jeden znak.

LEFTB("中国";1) vrátí " " (1 bajt je pouze polovina znaku DBCS a místo ní se vrátí znak mezery).

LEFTB("中国";2) vrátí "中" (2 bajty představují jeden úplný znak DBCS).

LEFTB("中国";3) vrátí "中 " (3 bajty představují jeden a půl znaku DBCS; místo posledního znaku se proto vrátí znak mezery).

LEFTB("中国";4) vrátí "中国" (4 bajty představují dva úplné znaky DBCS).

LEFTB("office";3) vrátí "off" (3 znaky bez DBCS, z nichž je každý tvořen 1 bajtem).

LEFT

Vrátí první znak nebo znaky textu.

LEFT("Text"; Počet)

Text je text, u nějž se určí počáteční část.

Počet (volitelné) počet znaků počátečního textu. Není-li tento parametr zadán, vrátí se jeden znak.

=LEFT("výstup";3) vrátí “výs”.

FIXED

Vrátí číslo jako text s určeným počtem desetinných míst a volitelným oddělovačem tisíců.

FIXED(Číslo; Desetinná místa; Nerozdělovat tisíce)

Číslo představuje číslo, které se bude formátovat.

Desetinná místa udává, kolik desetinných míst se zobrazí.

Nerozdělovat tisíce (volitelné) určuje, zda se použije oddělovač tisíců. Pokud je tento parametr číslo různé od 0, oddělovač tisíců se neobjeví. Pokud je tento parametr 0 nebo není-li zadán, zobrazí se oddělovač tisíců podle aktuálního národního prostředí.

=FIXED(1234567.89;3) vrátí 1,234,567.890 jako textový řetězec.

=FIXED(1234567.89;3;1) vrátí 1234567.890 jako textový řetězec.

CLEAN

Všechny netisknutelné znaky jsou z řetězce odstraněny.

CLEAN("Text")

Text představuje text, ze kterého budou všechny netisknutelné znaky odstraněny.