খালি ঘরের হ্যান্ডলিং

সফটওয়্যারটির পুরোনো সংস্করণগুলোতে, কিছু জায়গায় ফাঁকা ঘরগুলো সংখ্যাসূচক ০ ধরা হয়েছে এবং অন্যান্য জায়গায় ফাঁকা স্ট্রিং হিসেবে ধরা হয়েছে, ব্যতিক্রম, সরাসরি তুলনা যেখানে =A1=0 এবং =A1="" উভয়ের ফলাফলই TRUE হয় যদি A1 ফাঁকা থাকে। ব্যবহার না করা পর্যন্ত ফাঁকাকরণ পরবর্তী ধাপে সঞ্চারিত হতে থাকবে, সুতরাং =VLOOKUP(...)=0 এবং =VLOOKUP(...)="" উভয়ই TRUE মান দেয় যদি ফাঁকা ঘরের ফলাফলকৃত লুকআপ প্রদান করা হয়।

একটি খালি ঘরে একটি সরল রেফারেন্স এখনও ০ সংখ্যা হিসেবে দেখানো হয় কিন্তু এটি numeric ধরনের নাও হতে পারে, কাজেই রেফারেন্স ঘরের সাথে তুলনা করা হলে এটি প্রত্যাশিতভাবেই কাজ করে।

নিম্নের উদাহরনের জন্য, A1 একটি সংখ্যা ধারণ করে, B1 খালি, C1 B1এর প্রতি রেফারেন্স ধারণ করে:

Case	Formula	Results and comments
A1: 1 B1: <Empty>	C1: =B1	Displays 0
	=B1=0	TRUE
	=B1=""	TRUE
	=C1=0	TRUE
	=C1=""	TRUE (previously was FALSE)
	=ISNUMBER(B1)	FALSE
	=ISNUMBER(C1)	FALSE (previously was TRUE)
	=ISNUMBER(VLOOKUP(1;A1:C1;2))	FALSE (B1)
	=ISNUMBER(VLOOKUP(1;A1:C1;3))	FALSE (C1, previously was TRUE)
	=ISTEXT(B1)	FALSE
	=ISTEXT(C1)	TRUE
	=ISTEXT(VLOOKUP(1;A1:C1;2))	FALSE (B1, previously was TRUE)
	=ISTEXT(VLOOKUP(1;A1:C1;3))	FALSE (C1)
	=ISBLANK(B1)	TRUE
	=ISBLANK(C1)	TRUE
	=ISBLANK(VLOOKUP(1;A1:C1;2))	TRUE (B1, previously was FALSE)
	=ISBLANK(VLOOKUP(1;A1:C1;3))	FALSE (C1)

মনে রাখবেন যে মাইক্রোসফট এক্সেল ভিন্ন আচরন করে এবং সবসময় একটি খালি ঘরের রেফারেন্স বা একটি খালি ঘরের ফলাফলের সাথে সূত্র ঘর হিসেবে একটি সংখ্যা ফেরত পাঠায়। উদাহরনস্বরূপ:

Case	Formula	Results and comments
A1: <Empty>	B1: =A1	Displays 0, but is just a reference to an empty cell.
	=ISNUMBER(A1)	FALSE
	=ISTEXT(A1)	FALSE
	=A1=0	TRUE
	=A1=""	TRUE
	=ISNUMBER(B1)	FALSE (Microsoft Excel: TRUE)
	=ISTEXT(B1)	FALSE
	=B1=0	TRUE
	=B1=""	TRUE (Microsoft Excel: FALSE)
	C1: =VLOOKUP(...) with empty cell result	displays empty (Microsoft Excel: displays 0)
	=ISNUMBER(VLOOKUP(...))	FALSE
	=ISTEXT(VLOOKUP(...))	FALSE
	=ISNUMBER(C1)	FALSE (Microsoft Excel: TRUE)
	=ISTEXT(C1)	FALSE