Математически функции

Тази категория съдържа математическите функции в Calc. За да отворите помощника за функции, изберете Вмъкване - Функция.

AGGREGATE

Тази функция връща агрегиран резултат от изчисление върху диапазона от клетки. Допустимите агрегатни функции са изброени по-долу. Функцията AGGREGATE ви позволява да пропускате скритите редове, грешките и резултатите от SUBTOTAL и други срещания на AGGREGATE.

RAWSUBTRACT

Изважда съвкупност от числа и дава резултат без елиминиране на малките грешки от закръгляване.

COLOR

Връща числова стойност, изчислена чрез комбиниране на три цвята (червено, зелено и синьо) и алфа-канал по цветовата система RGBA. Резултатът зависи от цветовата система, използвана от компютъра ви.

SUMIFS

Връща сумата от стойностите на клетките в даден диапазон, които удовлетворяват няколко условия в няколко диапазона.

SUMSQ

Ако искате да изчислите сумата на квадратите на числа, подадени като аргументи, въведете ги в текстовите полета.

Синтаксис

SUMSQ(Число1; Число2; …; Число30)

Число1…30 са не повече от 30 аргумента, сумата на чиито квадрати да бъде изчислена.

Пример

Ако въведете числата 2, 3 и 4 в текстовите полета Число 1, 2 и 3 ще получите резултат 29.

PI

Връща 3,14159265358979, стойността на математическата константа пи с точност до 14 дробни позиции.

Синтаксис

PI()

Пример

=PI() връща 3,14159265358979.

EXP

Връща e на степен дадено число. Константата e е приблизително равна на 2,71828182845904.

Синтаксис

EXP(Число)

Число е степента, на която да бъде повдигнато e.

Пример

=EXP(1) връща 2,71828182845904, математическата константа e с точността на Calc.

ABS

Връща абсолютната стойност на число.

Синтаксис

ABS(Число)

Число е числото, чиято абсолютна стойност да бъде изчислена. Абсолютната стойност на число е стойността му без знака +/-.

Пример

=ABS(-56) връща 56.

=ABS(12) връща 12.

=ABS(0) връща 0.

ACOS

Връща аркускосинуса (обратния косинус) на число.

Синтаксис

ACOS(Число)

Тази функция връща аркускосинуса на Число, т.е. ъгъла (в радиани), чийто косинус е числото. Връщаният ъгъл е между 0 и π.

За да получите ъгъла в градуси, използвайте функцията DEGREES.

Пример

=ACOS(-1) връща 3,14159265358979 (пи радиана)

=DEGREES(ACOS(0,5)) връща 60. Косинусът на 60 градуса е 0,5.

Отваряне на файл с пример:

ACOT

Връща аркускотангенса (обратния котангенс) на даденото число.

Синтаксис

ACOT(Число)

Тази функция връща аркускотангенса на Число, т.е. ъгъла (в радиани), чийто котангенс е числото. Връщаният ъгъл е между 0 и π.

За да получите ъгъла в градуси, използвайте функцията DEGREES.

Пример

=ACOT(1) връща 0,785398163397448 (PI/4 радиана).

=DEGREES(ACOT(1)) връща 45. Тангенсът на 45 градуса е 1.

Отваряне на файл с пример:

ASIN

Връща аркуссинуса (обратния синус) на число.

Синтаксис

ASIN(Число)

Тази функция връща аркуссинуса на Число, т.е. ъгъла (в радиани), чийто синус е числото. Връщаният ъгъл е между -π/2 и +π/2.

За да получите ъгъла в градуси, използвайте функцията DEGREES.

Пример

=ASIN(0) връща 0.

=ASIN(1) връща 1,5707963267949 (PI/2 радиана).

=DEGREES(ASIN(0.5)) връща 30. Синусът на 30 градуса е 0,5.

Отваряне на файл с пример:

ATAN

Връща аркустангенса (обратния тангенс) на число.

Синтаксис

ATAN(Число)

Тази функция връща аркустангенса на Число, т.е. ъгъла (в радиани), чийто тангенс е числото. Връщаният ъгъл е между -π/2 и π/2.

За да получите ъгъла в градуси, използвайте функцията DEGREES.

Пример

=ATAN(1) връща 0,785398163397448 (PI/4 радиана).

=DEGREES(ATAN(1)) връща 45. Тангенсът на 45 градуса е 1.

Отваряне на файл с пример:

COMBIN

Връща броя на комбинациите за елементи без повторение.

Синтаксис

COMBIN(Брой1; Брой2)

Брой1 е броят на елементите в множеството.

Брой2 е броят избирани елементи от множеството.

COMBIN връща броя на начините, по които могат да се изберат даден брой елементи. Например, ако множеството се състои от трите елемента А, Б и В, можете да изберете два елемента по три различни начина: АБ, БВ и АВ.

COMBIN реализира формулата Брой1! / (Брой2! * (Брой1 - Брой2)!)

Пример

=COMBIN(3;2) връща 3.

COMBINA

Връща броя на комбинациите от избрани елементи с повторения.

Синтаксис

COMBINA(Брой1; Брой2)

Брой1 е броят на елементите в множеството.

Брой2 е броят избирани елементи от множеството.

COMBINA връща броя различни начини да се изберат даден брой елементи независимо от реда им, като е разрешено повтаряне на елементи. Например за множество от трите елемента А, Б и В можете да изберете два елемента по шест различни начина: АА, АБ, ББ, БВ, ВВ, и АВ.

COMBINA реализира формулата (Брой1 + Брой2 - 1)! / (Брой2! (Брой1 - 1)!)

Пример

=COMBINA(3;2) връща 6.

LOG10

Връща десетичния логаритъм на число.

Синтаксис

LOG10(Число)

Връща десетичния логаритъм на Число.

Пример

=LOG10(5) връща десетичния логаритъм на 5 (приблизително 0,69897).

SIGN

Връща знака на число: 1, ако числото е положително, -1, ако е отрицателно, и 0, ако е нула.

Синтаксис

SIGN(Число)

Число е числото, чийто знак да бъде определен.

Пример

=SIGN(3,4) връща 1.

=SIGN(-4,5) връща -1.

SQRTPI

Връща квадратния корен на пи, умножено по число.

Синтаксис

SQRTPI(Число)

Връща положителния квадратен корен на произведението на пи с Число.

Това е еквивалентно на SQRT(PI()*Число).

Пример

=SQRTPI(2) връща квадратния корен на 2*пи, приблизително 2,506628.

CSC

Връща косеканса на дадения ъгъл в радиани. Косекансът на ъгъл е равен на единица върху синуса му.

tip

Тази функция е налична от LibreOffice 3.5


Синтаксис

CSC(Число)

Връща косеканса на Число, ъгълът трябва да е в радиани.

За да получите косеканса на ъгъл в градуси, използвайте функцията RADIANS.

Пример

=CSC(PI()/4) връща приблизително 1,4142135624, реципрочното на синус от PI/4 радиана.

=CSC(RADIANS(30)) връща 2, косекансът на 30 градуса.

Отваряне на файл с пример:

COS

Връща косинуса на дадения ъгъл в радиани.

Синтаксис

COS(Число)

Връща косинуса на Число, ъгълът трябва да е в радиани.

За да получите косинуса на ъгъл в градуси, използвайте функцията RADIANS.

Пример

=COS(PI()*2) връща 1, косинусът на 2*PI радиана.

=COS(RADIANS(60)) връща 0,5, косинусът на 60 градуса.

Отваряне на файл с пример:

COT

Връща котангенса на дадения ъгъл в радиани.

Синтаксис

COT(Число)

Връща котангенса на Число, ъгълът трябва да е в радиани.

За да получите котангенса на ъгъл в градуси, използвайте функцията RADIANS.

Котангенсът на ъгъл е равен на единица върху тангенса му.

Примери:

=COT(PI()/4) връща 1, котангенсът на PI/4 радиана.

=COT(RADIANS(45)) връща 1, котангенсът на 45 градуса.

Отваряне на файл с пример:

LOG

Връща логаритъма на число при зададена основа.

Синтаксис

LOG(Число; Основа)

Число е стойността, чийто логаритъм да се изчисли.

Основа е основата на логаритъма.

Пример

=LOG(10;3) връща логаритъма на 10 при основа 3 (приблизително 2,0959).

=LOG(7^4;7) връща 4.

GCD

Връща най-големия общ делител на две или повече цели числа.

Най-големият общ делител е най-голямото положително цяло число, което дели без остатък всяко от дадените цели числа.

Синтаксис

GCD(ЦялоЧисло1; ЦялоЧисло2; …; ЦялоЧисло30)

ЦялоЧисло1…30 са не повече от 30 цели числа, чийто най-голям общ делител да бъде изчислен.

Пример

=GCD(16;32;24) дава резултат 8, тъй като 8 е най-голямото число, делящо 16, 24 и 32 без остатък.

=GCD(B1:B3), ако клетките B1, B2 и B3 съдържат9, 12 и 9, дава 3.

LCM

Връща най-малкото общо кратно на едно или няколко цели числа.

Синтаксис

LCM(ЦялоЧисло1; ЦялоЧисло2; …; ЦялоЧисло30)

ЦялоЧисло1…30 са не повече от 30 цели числа, чието най-малко общо кратно да бъде изчислено.

Пример

Ако въведете числата 512, 1024 и 2000 в полетата ЦялоЧисло 1, 2 и 3, ще получите резултат 128000.

LN

Връща натуралния логаритъм (с основа e) на число. Константата e има стойност приблизително 2,71828182845904.

Синтаксис

LN(Число)

Число е стойността, чийто натурален логаритъм да се изчисли.

Пример

=LN(3) връща натуралния логаритъм на 3 (приблизително 1,0986).

=LN(EXP(321)) връща 321.

ACOSH

Връща обратния хиперболичен косинус на число.

Синтаксис

ACOSH(Число)

Тази функция връща обратния хиперболичен косинус на Число, т.е. числото, чийто хиперболичен косинус е даденото число.

Числото трябва да е по-голямо или равно на 1.

Пример

=DELTA(1;2) връща 0.

=ACOSH(COSH(4)) връща 4.

Отваряне на файл с пример:

ACOTH

Връща обратния хиперболичен котангенс на даденото число.

Синтаксис

ACOTH(Число)

Тази функция връща обратния хиперболичен котангенс на Число, т.е. числото, чийто хиперболичен котангенс е даденото число.

Ако числото е между -1 и 1 включително, възниква грешка.

Пример

=ACOTH(1,1) връща обратния хиперболичен котангенс на 1,1, приблизително 1,52226.

Отваряне на файл с пример:

ASINH

Връща обратния хиперболичен синус на число.

Синтаксис

ASINH(Число)

Тази функция връща обратния хиперболичен синус на Число, т.е. числото, чийто хиперболичен синус е даденото число.

Пример

=ASINH(-90) връща приблизително -5,1929877.

=ASINH(SINH(4)) връща 4.

Отваряне на файл с пример:

ATANH

Връща обратния хиперболичен тангенс на число.

Синтаксис

ATANH(Число)

Тази функция връща обратния хиперболичен тангенс на Число, т.е. числото, чийто хиперболичен тангенс е даденото число.

Числото трябва да бъде в отворения интервал (-1; 1).

Пример

=ATANH(0) връща 0.

Отваряне на файл с пример:

MOD

Връща остатъка от деление на едно цяло число на друго.

Синтаксис

MOD(Делимо; Делител)

За целочислени аргументи тази функция връща остатъка от делението на Делимо на Делител.

Тази функция е реализирана като Делимо - Делител * INT(Делимо / Делител) и формулата дава резултат и ако аргументите не са цели числа.

Пример

=MOD(22;3) връща 1, остатъкът при деление на 22 на 3.

=MOD(11,25;2,5) връща 1,25.

SQRT

Връща положителния квадратен корен на число.

Синтаксис

SQRT(Число)

Връща положителния квадратен корен на Число.

Числото трябва да е положително.

Пример

=SQRT(16) връща 4.

=SQRT(-16) връща грешка от типа невалиден аргумент.

SEC

Връща секанса на дадения ъгъл в радиани. Секансът на ъгъл е равен на единица върху косинуса му.

tip

Тази функция е налична от LibreOffice 3.5


Синтаксис

SEC(Число)

Връща секанса на Число, ъгълът трябва да е в радиани.

За да получите секанса на ъгъл в градуси, използвайте функцията RADIANS.

Пример

=SEC(PI()/4) връща приблизително 1,4142135624, реципрочното на косинус от PI/4 радиана.

=SEC(RADIANS(60)) връща 2, секансът на 60 градуса.

Отваряне на файл с пример:

SIN

Връща синуса на дадения ъгъл в радиани.

Синтаксис

SIN(Число)

Връща синуса на Число, ъгълът трябва да е в радиани.

За да получите синуса на ъгъл в градуси, използвайте функцията RADIANS.

Пример

=SIN(PI()/2) връща 1, синусът на пи/2 радиана.

=SIN(RADIANS(30)) връща 0,5, синусът на 30 градуса.

Отваряне на файл с пример:

RANDBETWEEN

Връща случайно цяло число в зададен диапазон.

Синтаксис

RANDBETWEEN(ДолнаГраница; ГорнаГраница)

Връща случайно цяло число между целите числа ДолнаГраница и ГорнаГраница (включително).

Тази функция дава ново случайно число всеки път, когато Calc преизчислява. За да предизвикате преизчисляване ръчно, натиснете F9.

За да се генерират случайни числа, които никога не се преизчисляват, копирайте клетките, съдържащи тази функция, и използвайте Редактиране - Специално поставяне (като Поставяне - всичко и Формули не са отметнати, а Числа е отметнато).

Пример

=RANDBETWEEN(20;30) връща цяло число между 20 и 30.

RAND

Връща случайно число между 0 и 1.

Синтаксис

RAND()

Тази функция дава ново случайно число всеки път, когато Calc преизчислява. За да предизвикате преизчисляване ръчно, натиснете F9.

За да се генерират случайни числа, които никога не се преизчисляват, копирайте клетките, съдържащи =RAND(), и използвайте Редактиране - Специално поставяне (като Поставяне - всичко и Формули не са отметнати, а Числа е отметнато).

Пример

=RAND() връща случайно число между 0 и 1.

TAN

Връща тангенса на дадения ъгъл в радиани.

Синтаксис

TAN(Число)

Връща тангенса на Число, ъгълът трябва да е в радиани.

За да получите тангенса на ъгъл в градуси, използвайте функцията RADIANS.

Пример

=TAN(PI()/4) връща 1, тангенсът на пи/4 радиана.

=TAN(RADIANS(45)) връща 1, тангенсът на 45 градуса.

Отваряне на файл с пример:

MULTINOMIAL

Връща факториела на сумата на аргументите, разделен на произведението от факториелите на аргументите.

Синтаксис

MULTINOMIAL(Числа)

Числа е списък от не повече от 30 числа.

Пример

=MULTINOMIAL(F11:H11) връща 1260, ако клетките от F11 до H11 съдържат стойностите 2, 3 и 4. Това съответства на формулата =(2+3+4)! / (2!*3!*4!).

FACT

Връща факториела на число.

Синтаксис

FACT(Число)

Връща Число!, факториела на Число, който е равен на 1*2*3*4*…*Число.

=FACT(0) връща 1 по дефиниция.

Факториел от отрицателно число предизвиква грешка от типа „невалиден аргумент“.

Пример

=FACT(3) връща 6.

=FACT(0) връща 1.

CSCH

Връща хиперболичния косеканс на число.

tip

Тази функция е налична от LibreOffice 3.5


Синтаксис

CSCH(Число)

Връща хиперболичния косеканс на Число.

Пример

=CSCH(1) връща приблизително 0,8509181282, хиперболичният косеканс на 1.

Отваряне на файл с пример:

COSH

Връща хиперболичния косинус на число.

Синтаксис

COSH(Число)

Връща хиперболичния косинус на Число.

Пример

=COSH(0) връща 1, хиперболичния косинус на 0.

Отваряне на файл с пример:

COTGH

Връща хиперболичния котангенс на дадено число (ъгъл).

Синтаксис

COTH(Число)

Връща хипербличния котангенс на Число.

Пример

=COTH(1) връща хиперболичния котангенс на 1, приблизително 1,3130.

Отваряне на файл с пример:

SECH

Връща хиперболичния секанс на число.

tip

Тази функция е налична от LibreOffice 3.5


Синтаксис

SECH(Число)

Връща хиперболичния секанс на Число.

Пример

=SECH(0) връща 1, хиперболичният секанс на 0.

Отваряне на файл с пример:

SINH

Връща хиперболичния синус на число.

Синтаксис

SINH(Число)

Връща хиперболичния синус на Число.

Пример

=SINH(0) връща 0, хиперболичният синус на 0.

Отваряне на файл с пример:

TANH

Връща хиперболичния тангенс на число.

Синтаксис

TANH(Число)

Връща хиперболичния тангенс на Число.

Пример

=TANH(0) връща 0, хиперболичният тангенс на 0.

Отваряне на файл с пример:

QUOTIENT

Връща целочислената част от резултата при деление.

Синтаксис

QUOTIENT(Числител; Знаменател)

Връща цялата част от частното на Числител и Знаменател.

QUOTIENT е еквивалентна на INT(числител/знаменател) при еднакъв знак на числителя и знаменателя, но може да отчита грешките с различни кодове за грешка. По-общо тя е еквивалентна на INT(числител/знаменател/SIGN(числител/знаменател))*SIGN(числител/знаменател).

Пример

=QUOTIENT(11;3) връща 3. Остатъкът 2 се загубва.

MROUND

Връща число, закръглено до най-близкото кратно на друго число.

Синтаксис

MROUND(Число; Стъпка)

Връща Число, закръглено до най-близкото кратно на Стъпка.

Алтернативна реализация на същото изчисление е Стъпка * ROUND(Число / Стъпка).

Пример

=MROUND(15,5;3) връща 15, тъй като 15,5 е по-близо до 15 (= 3*5), отколкото до 18 (= 3*6).

=MROUND(1,4;0,5) връща 1,5 (= 0,5*3).

POWER

Връща число, повдигнато на степен.

Синтаксис

POWER(Основа; Степен)

Връща Основа, повдигната на Степен.

Същият резултат може да се постигне чрез операцията степенуване ^:

Основа^Степен

Пример

=POWER(4;3) връща 64, което е 4 на степен 3.

=4^3 също връща 4 на степен 3.

ATAN2

Връща ъгъла (в радиани) между оста x и права през началото до точката (ЧислоX|ЧислоY).

Икона Бележка

Тази функция е от стандарта Open Document Format for Office Applications (OpenDocument) версия 1.2. (ISO/IEC 26300:2-2015)


Синтаксис

ATAN2(X; Y)

ЧислоX е стойността на координатата x.

ЧислоY е стойността на координатата y.

tip

В езиците за програмиране редът на аргументите на функцията atan2() обикновено е обратен.


ATAN2 връща ъгъла (в радиани) между оста x и права през началото до точката (ЧислоX|ЧислоY).

Пример

=ATAN2(-5;9) връща 2,07789 радиана.

За да получите ъгъла в градуси, приложете функцията DEGREES върху резултата.

=DEGREES(ATAN2(12,3;12,3)) връща 45. Тангенсът на 45 градуса е 1.

note

LibreOffice връща 0 за ATAN2(0;0).


Функцията може да се използва за преобразуване от декартови в полярни координати.

=DEGREES(ATAN2(-8;5)) връща φ = 147,9 градуса.

Пример за преобразуване от декартови в полярни координати

Отваряне на файл с пример:

ODD

Закръглява положително число нагоре до най-близкото нечетно цяло число, а отрицателно – надолу към най-близкото нечетно цяло число.

Синтаксис

ODD(Число)

Връща Число, закръглено до следващото нечетно цяло число в посока обратно на нулата.

Пример

=ODD(1,2) връща 3.

=ODD(1) връща 1.

=ODD(0) връща 1.

=ODD(-3,1) връща -5.

EVEN

Закръглява положително число нагоре до следващото четно цяло число и отрицателно число – надолу до следващото четно цяло число.

Синтаксис

EVEN(Число)

Връща Число, закръглено нагоре до следващото четно цяло число, в посока обратно на нулата.

Пример

=EVEN(2,3) връща 4.

=EVEN(2) връща 2.

=EVEN(0) връща 0.

=EVEN(-0,5) връща -2.

ROUNDDOWN

Закръглява число в посока надолу към нулата до зададена точност.

Синтаксис

ROUNDDOWN(Число; Брой)

Връща Число, закръглено надолу (към нулата) до Брой дробни позиции. Ако броят е пропуснат или нула, функцията закръглява надолу до цяло число. Ако броят е отрицателен, функцията закръглява надолу до следващото кратно на 10, 100, 1000 и т.н.

Тази функция закръглява към нулата. За алтернативи вижте ROUNDUP и ROUND.

Пример

=ROUNDDOWN(1,234;2) връща 1,23.

=ROUNDDOWN(45,67;0) връща 45.

=ROUNDDOWN(-45,67) връща -45.

=ROUNDDOWN(987,65;-2) връща 900.

CEILING.XCL

Закръглява число в посока обратно на нулата до най-близкото кратно на „Стъпка“.

tip

Тази функция е налична от LibreOffice 5.0


Синтаксис

CEILING.XCL(Число; Стъпка)

Число е числото, което да бъде закръглено.

Стъпка е числото, до чието кратно трябва да бъде закръглена стойността.

warning

Тази функция съществува за съвместимост с Microsoft Excel 2007 и по-стари версии.


Пример

=CEILING.XCL(1;3) връща 3

=CEILING.XCL(7;4) връща 8

=CEILING.XCL(-10;-3) връща -12

ROUND

Закръглява число до зададен брой дробни позиции.

Синтаксис

ROUND(Число; Брой)

Връща Число, закръглено до Брой дробни позиции. Ако броят е пропуснат или нула, функцията закръглява до най-близкото цяло число. Ако броят е отрицателен, функцията закръглява до най-близкото кратно на 10, 100, 1000 и т.н.

Тази функция закръглява до най-близкото число. За алтернативи вижте ROUNDDOWN и ROUNDUP.

Пример

=ROUND(2,348;2) връща 2,35

=ROUND(-32,4834;3) връща -32,483. Променете формата на клетката, за да видите всички дробни позиции.

=ROUND(2,348;0) връща 2.

=ROUND(2,5) връща 3.

=ROUND(987,65;-2) връща 1000.

CEILING.PRECISE

Закръглява число нагоре до най-близкото кратно на Стъпка, независимо от знака на Стъпка

tip

Тази функция е налична от LibreOffice 4.3


Синтаксис

CEILING.PRECISE(Число; Стъпка)

Число (задължителен) е числото, което да бъде закръглено нагоре.

Стъпка (незадължителен) е числото, до чието кратно трябва да бъде закръглена стойността.

Пример

=CEILING.PRECISE(-11;-2) връща -10

ISO.CEILING

Закръглява число нагоре до най-близкото кратно на Стъпка, независимо от знака на Стъпка

Синтаксис

ISO.CEILING(Число; Стъпка; Режим)

Число (задължителен) е числото, което да бъде закръглено нагоре.

Стъпка (незадължителен) е числото, до чието кратно трябва да бъде закръглена стойността.

Пример

=ISO.CEILING(-11;-2) връща -10

FLOOR.PRECISE

Закръглява число нагоре до най-близкото кратно на Стъпка, независимо от знака на Стъпка

tip

Тази функция е налична от LibreOffice 4.3


Синтаксис

FLOOR.PRECISE(Число; Стъпка)

Число е числото, което да бъде закръглено надолу.

Стъпка е стойността, до чието кратно трябва да се закръгли числото.

warning

Ако електронната таблица се експортира към Microsoft Excel, функцията FLOOR се експортира като еквивалентната FLOOR.MATH, която съществува от Excel 2013. Ако планирате да използвате файла с по-ранни версии на Excel, използвайте или FLOOR.PRECISE, която съществува от Excel 2010, или FLOOR.XCL, която се експортира към функцията FLOOR, съвместима с всички версии на Excel. Имайте предвид, че FLOOR.XCL винаги закръглява в посока към нулата.


Пример

=FLOOR.PRECISE(-11;-2) връща -12

CEILING

Закръглява число нагоре до най-близкото кратно на дадено число.

Синтаксис

CEILING(Число; Стъпка; Режим)

Число е числото, което да бъде закръглено нагоре.

Стъпка е числото, до чието кратно трябва да бъде закръглена стойността.

Режим е незадължителна стойност. Ако тя е зададена и различна от нула и ако „Число“ и „Стъпка“ са отрицателни, закръгляването се извършва на базата на абсолютната стойност на числото, т.е. отрицателните числа се закръгляват в посока, обратна на нулата. Ако „Режим“ е нула или не е зададено, отрицателните числа се закръгляват към нулата.

warning

Ако електронната таблица се експортира към Microsoft Excel, функцията CEILING се експортира като еквивалентната CEILING.MATH, която съществува от Excel 2013. Ако планирате да използвате файла с по-ранни версии на Excel, използвайте или CEILING.PRECISE, която съществува от Excel 2010, или CEILING.XCL, която се експортира към функцията CEILING, съвместима с всички версии на Excel. Имайте предвид, че CEILING.XCL винаги закръглява в посока, обратна на нулата.


Пример

=CEILING(-11;-2) връща -10

=CEILING(-11;-2;0) връща -10

=CEILING(-11;-2;1) връща -12

CEILING.MATH

Закръглява число нагоре до най-близкото кратно на „Стъпка“.

Синтаксис

CEILING.MATH(Число; Стъпка; Режим)

Число е числото, което да бъде закръглено нагоре.

Стъпка е числото, до чието кратно трябва да бъде закръглена стойността.

Режим е незадължителна стойност. Ако тя е зададена и различна от нула и ако „Число“ и „Стъпка“ са отрицателни, закръгляването се извършва на базата на абсолютната стойност на числото, т.е. отрицателните числа се закръгляват в посока, обратна на нулата. Ако „Режим“ е нула или не е зададено, отрицателните числа се закръгляват към нулата.

warning

Тази функция съществува за съвместимост с Microsoft Excel 2013 или по-нова версия.


Пример

=CEILING.MATH(-10;-3) връща -9

=CEILING.MATH(-10;-3;0) връща -9

=CEILING.MATH(-10;-3;1) връща -12

ROUNDUP

Закръглява число нагоре, в посока обратна на нулата, до зададена точност.

Синтаксис

ROUNDUP(Число; Брой)

Връща Число, закръглено нагоре (в посока обратно на нулата) до Брой дробни позиции. Ако броят е пропуснат или нула, функцията закръглява нагоре до цяло число. Ако броят е отрицателен, функцията закръглява нагоре до следващото кратно на 10, 100, 1000 и т.н.

Тази функция закръглява в посока, обратна на нулата. За алтернативи вижте ROUNDDOWN и ROUND.

Пример

=ROUNDUP(1,1111;2) връща 1,12.

=ROUNDUP(1,2345;1) връща 1,3.

=ROUNDUP(45,67;0) връща 46.

=ROUNDUP(-45,67) връща -46.

=ROUNDUP(987,65;-2) връща 1000.

FLOOR

Закръглява число надолу до най-близкото кратно на дадено число.

Синтаксис

FLOOR(Число; Стъпка; Режим)

Число е числото, което да бъде закръглено надолу.

Стъпка е стойността, до чието кратно трябва да се закръгли числото.

Режим е незадължителна стойност. Ако тя е зададена и различна от нула и ако „Число“ и „Стъпка“ са отрицателни, закръгляването се извършва на базата на абсолютната стойност на числото, т.е. отрицателните числа се закръгляват към нулата. Ако „Режим“ е нула или не е зададено, отрицателните числа се закръгляват в посока, обратна на нулата.

warning

Ако електронната таблица се експортира към Microsoft Excel, функцията FLOOR се експортира като еквивалентната FLOOR.MATH, която съществува от Excel 2013. Ако планирате да използвате файла с по-ранни версии на Excel, използвайте или FLOOR.PRECISE, която съществува от Excel 2010, или FLOOR.XCL, която се експортира към функцията FLOOR, съвместима с всички версии на Excel. Имайте предвид, че FLOOR.XCL винаги закръглява в посока към нулата.


Пример

=FLOOR(-11;-2) връща -12

=FLOOR(-11;-2;0) връща -12

=FLOOR(-11;-2;1) връща -10

INT

Закръглява число надолу до най-близкото цяло число.

Синтаксис

INT(Число)

Връща Число, закръглено надолу до най-близкото цяло число.

Отрицателните числа се закръгляват надолу до съответните цели числа под тях.

Пример

=INT(5,7) връща 5.

=INT(-1,3) връща -2.

SUBTOTAL

Изчислява междинни суми. Ако областта вече съдържа междинни суми, те не се включват в по-нататъшните изчисления. Използвайте тази функция заедно с автофилтър, за да обработите само филтрираните записи.

Синтаксис

SUBTOTAL(Функция; Област)

Функция е число, което означава една от следващите функции:

Индекс

(включва скритите стойности)

Индекс

(игнорира скритите стойности)

Функция

1

101

AVERAGE

2

102

COUNT

3

103

COUNTA

4

104

MAX

5

105

MIN

6

106

PRODUCT

7

107

STDEV

8

108

STDEVP

9

109

SUM

10

110

VAR

11

111

VARP


Използвайте числата от 1–11, за да включите ръчно скритите редове, или 101–111, за да ги изключите; невидимите заради филтриране клетки винаги се изключват.

Област е областта, чиито клетки са включени.

Пример

Имате таблица в диапазона от клетки A1:B6, съдържаща цените на принадлежности за 10 ученици. Ред 2 (Писалка) е скрит ръчно. Може да искате да видите сумата на показаните числа, т.е. междинната сума за филтрираните редове. В този случай правилната формула би била:

A

B

1

АРТИКУЛ

КОЛИЧЕСТВО

2

Писалка

10

3

Молив

10

4

Бележник

10

5

Гумичка

10

6

Острилка

10


=SUBTOTAL(9;B2:B6) връща 50.

=SUBTOTAL(109;B2:B6) връща 40.

TRUNC

Отрязва число, премахвайки дробни позиции.

Синтаксис

TRUNC(Число; Брой)

Връща Число с не повече от Брой дробни позиции. Излишните разреди се премахват независимо от знака.

TRUNC(Число; 0) се държи като INT(Число) за положителни числа, но закръгля в посока към нулата за отрицателни числа.

warning

Видимите дробни позиции в резултата се задават в - LibreOffice Calc - Изчисляване.


Пример

=TRUNC(1,239;2) връща 1,23. Разредът със стойност 9 се изгубва.

=TRUNC(-1,234999;3) връща -1,234. Всички деветки се изгубват.

RADIANS

Преобразува градуси в радиани.

Синтаксис

RADIANS(Число)

Число е ъгълът в градуси, който да бъде преобразуван в радиани.

Пример

=RADIANS(90) връща 1,5707963267949, което е пи/2 с точността на Calc.

EUROCONVERT

Преобразува между стари европейски парични единици и евро и обратно.

Синтаксис

EUROCONVERT(Стойност; "Валута1"; "Валута2", ПълнаТочност, МеждТочност)

Стойност е паричната сума, която да бъде преобразувана.

От_валута и Към_валута са паричните единици, между които да се преобразува. Те трябва да представляват текстове – официалните обозначения на валутите (например "EUR"). Курсовете (спрямо евро) са определени от Европейската комисия.

Пълна_точност не е задължителен. Ако се пропусне или има стойност False, резултатът се закръгля според дробните позиции за Валута2. Ако е True, резултатът не се закръгля.

Межд_точност не е задължителен. Ако е зададен и има стойност >=3, междинният резултат при двойно преобразуване (Валута1, EUR, Валута2) се закръглява до тази точност. Ако е пропуснат, междинният резултат не се закръглява. Освен това, ако Валута2 е "EUR", МеждТочност се използва все едно, че е необходимо двойно преобразуване и се прилага преобразуване от EUR към EUR.

Примери

=EUROCONVERT(100;"ATS";"EUR") преобразува 100 австрийски шилинга в евро.

=EUROCONVERT(100;"EUR";"DEM") преобразува 100 евро в германски марки.

DEGREES

Преобразува радиани в градуси.

Синтаксис

DEGREES(Число)

Число е ъгълът в радиани, който да бъде преобразуван в градуси.

Пример

=DEGREES(PI()) връща 180 градуса.

CONVERT_OOO

Преобразува стойност от една мерна единица в друга. Коефициентите за преобразуване са дадени в списък в конфигурацията.

До определен момент списъкът с коефициенти за преобразуване включваше старите европейски валути и еврото (вижте долните примери). Препоръчваме ви за преобразуване на тези валути да използвате новата функция EUROCONVERT.

Синтаксис

CONVERT_OOO(стойност; "текст"; "текст")

Пример

=CONVERT_OOO(100;"ATS";"EUR") преобразува 100 австрийски шилинга в евро.

=CONVERT_OOO(100;"EUR";"DEM") преобразува 100 евро в германски марки.

GCD_EXCEL2003

Резултатът е най-големият общ делител на списък от числа.

note

Функциите, чиито имена завършват с _ADD или _EXCEL2003, връщат същите резултати като съответните функции на Microsoft Excel 2003 без този суфикс. Функциите без суфикс връщат резултати, базирани на международните стандарти.


Синтаксис

GCD_EXCEL2003(Числа)

Числа е списък от не повече от 30 числа.

Пример

=GCD_EXCEL2003(5;15;25) връща 5.

LCM_EXCEL2003

Резултатът е най-малкото общо кратно на списък от числа.

note

Функциите, чиито имена завършват с _ADD или _EXCEL2003, връщат същите резултати като съответните функции на Microsoft Excel 2003 без този суфикс. Функциите без суфикс връщат резултати, базирани на международните стандарти.


Синтаксис

LCM_EXCEL2003(Числа)

Числа е списък от не повече от 30 числа.

Пример

=LCM_EXCEL2003(5;15;25) връща 75.

SUM

Сумира всички числа в област от клетки.

Синтаксис

SUM(Число1; Число2; …; Число30)

Число1…Число30 са не повече от 30 аргумента – клетки или диапазони, – чиято сума да бъде изчислена.

tip

SUM пропуска текстовете и празните клетки в диапазон или масив. Ако подозирате, че функцията SUM дава погрешен резултат, потърсете текст в диапазоните с данни. Използвайте функционалността за осветяване на стойности, за да осветите текстовете в диапазона, които може да представляват числа.


Пример

Ако въведете числата 2, 3 и 4 в полетата Число 1, 2 и 3, ще получите резултат 9.

=SUM(A1;A3;B5) изчислява сумата на три клетки. =SUM (A1:E10) изчислява сумата на всички клетки в областта от A1 до E10.

Условия, свързани с AND, могат да се използват с функцията SUM() по следния начин:

Да приемем, че сте въвели фактури в таблица. Колоната A съдържа датата, а B – количествата. Необходима ви е формула, с която да изчислите общата сума на количествата за даден месец, например само в периода от >=2008-01-01 до <2008-02-01. Областта с датите е A1:A40, а с количествата за сумиране – B1:B40. Клетката C1 съдържа най-ранната дата на желаните фактури, 2008-01-01, а C2 – най-късната дата, 2008-02-01.

Въведете следната формула като формула за масив:

=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

За да въведете формула за масив, трябва да натиснете комбинацията Shift+ Enter вместо просто Enter, когато завършвате формулата. След това формулата ще се покаже оградена с фигурни скоби в лентата Формула.

{=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

Формулата се базира на факта, че резултатът от сравнение е 1, ако условието е изпълнено, и 0 в противен случай. Отделните резултати от сравненията се третират като масив и се използват в матрично умножение. Накрая отделните стойности се сумират, за да се получи резултатната матрица.

SUMIF

Сумира клетките, отговарящи на зададен критерий. Чрез тази функция можете да пресеете областта, търсейки конкретни стойности.

Търсенето поддържа заместващи знаци или регулярни изрази. Ако са разрешени регулярните изрази, можете да въведете например „всички.*“, за да намерите първото срещане на „всички“, последвано от произволни знаци. Ако искате да търсите текст, който сам представлява регулярен израз, трябва или да поставите наклонена черта „\“ пред всеки знак, или да оградите текста с \Q...\E. Можете да превключвате автоматичното изчисляване на заместващи знаци или регулярни изрази в - PRODUCTNAME Calc - Изчисляване.

warning

Когато се използват функции, в които един или няколко аргумента са низове с критерии за търсене – регулярни изрази, първо се прави опит низовете с критерии да се преобразуват в числа. Например ".0" ще се преобразува в 0.0 и т.н. При успех няма да се използва сравняване по регулярен израз, а сравняване на числа. Ако обаче се превключи към локал, в който десетичният разделител не е точка, ще сработи преобразуването към регулярен израз. За да наложите изчисляване на регулярен израз вместо числов, използвайте израз, който не може да бъде изтълкуван като число, например ".[0]", ".\0" или "(?i).0".


Синтаксис

SUMIF(Област; Критерии; ОблСум)

Диапазон е диапазонът, върху който да се приложат критериите.

Критерии е самото условие за търсене или клетката, която го съдържа. Ако критериите са изписани във формулата, трябва да бъдат заградени с двойни кавички.

ДиапазонЗаСумиране е диапазонът, от който се сумират стойности. Ако този параметър е пропуснат, се сумират стойностите от параметъра „Диапазон“.

note

SUMIF поддържа операцията слепване на обръщения (~) само в параметъра „Критерии“ и само ако незадължителният параметър „ДиапазонЗаСумиране“ е пропуснат.


Пример

За да сумирате само отрицателни числа: =SUMIF(A1:A10; "<0")

=SUMIF(A1:A10;">0";B1:B10) – сумира стойностите от диапазона B1:B10 само ако съответните стойности от диапазона A1:A10 са по-големи от 0.

При COUNTIF() ще намерите още примери за синтаксиса, който може да се използва със SUMIF().

SERIESSUM

Сумира първите членове на степенен ред.

SERIESSUM(x; n; m; коефициенти) = коефициент_1*x^n + коефициент_2*x^(n+m) + коефициент_3*x^(n+2m) +...+ коефициент_i*x^(n+(i-1)m)

Синтаксис

SERIESSUM(X; N; M; Коефициенти)

X е стойността, за която се изчислява степенният ред.

N е началната степен.

M е стъпката за увеличаване на N.

Коефициенти е редица от коефициенти. На всеки коефициент съответства по един член в сумата на реда.

PRODUCT

Умножава всички подадени като аргументи числа и връща произведението.

Синтаксис

PRODUCT(Число1; Число2; …; Число30)

Число1…30 са не повече от 30 аргумента, чието произведение да бъде изчислено.

PRODUCT връща число1 * число2 * число3 * ...

Пример

=PRODUCT(2;3;4) връща 24.

Моля, подкрепете ни!