Función AGREGAR

Esta función devuelve el resultado totalizado de los cálculos de un intervalo. Puede utilizar una de las funciones de totalización mostradas a continuación. La función AGREGAR le permite ignorar las filas ocultas, los errores y los resultados de otras fórmulas SUBTOTALES y AGREGAR.

Icono de nota

La función AGREGAR se aplica a rangos verticales de datos con AutoFiltro activado. Si AutoFiltro no está áctivado el recálculo automático del resultado de la función no funciona para columnas ocultadas recientemente. No se supone que funcione con rangos horizontales, de todos modo se puede aplicar a esos rangos también pero con limitaciones. En particular, la función AGREGAR aplicada a un rango horizontal de datos no reconoce columnas ocultas aunque omite correctamente errores y resultados de SUBTOTALES y otras funciones AGREGAR incrustadas en la fila.


tip

Esta función está disponible desde LibreOffice 4.4


Sintaxis

AGREGAR(Función; Opción; Ref1 [; Ref2 [; …]])

o

AGREGAR(Función; Opción; Matriz[; k])

Función (argumento obligatorio): un índice de función o una referencia a una celda cuyo valor esté entre 1 y 19, conforme a la tabla siguiente.

Índice de funciones

Función aplicada

1

PROMEDIO

2

CONTAR

3

CONTARA

4

MAX

5

MIN

6

PRODUCTO

7

DESVEST.M

8

DESVEST.P

9

SUMA

10

VAR.S

11

VAR.P

12

MEDIANA

13

MODA.UNO

14

K.ESIMO.MAYOR

15

K.ESIMO.MENOR

16

PERCENTIL.INC

17

CUARTIL.INC

18

PERCENTIL.EXC

19

CUARTIL.EXC


Opción – argumento obligatorio. Un índice de opciones o referencia a una celda con valores de 0 a 7 determina que ignorar en el rango de la función.

Índice de opción

Opción aplicada

0

Ignora solo SUBTOTALES anidados y funciones AGREGAR

1

Ignora solo filas ocultas, SUBTOTALES anidados y funciones AGREGAR

2

Ignoara solo errores, SUBTOTALES anidados y funciones AGREGAR

3

Ignorar filas ocultas, errores, SUBTOTALES anidados y funciones AGREGAR

4

No ignorar nada

5

Ignorar solos filas ocultas

6

Ignorar solo los errores

7

Ignorar solo filas ocultas y errores


Ref1 – argumento obligatorio. El primer argumento numérico (si el rango se establece mediante una lista de valores dentro de la función) o la referencia a una celda que lo contiene.

Ref2, 3… (opcional). Un valor numérico o una referencia a una celda (hasta 253 argumentos) cuyo valor totalizado se quiere obtener.

Matriz – Argumento obligatorio. La matriz se puede especificar mediante los límites del rango, el nombre de un rango con nombre o la etiqueta de la columna.

Icono de nota

Para utilizar etiquetas de columnas debe activar la función «Buscar automáticamente etiquetas de columnas y filas».


k – argumento obligatorio para las siguientes funciones: K.ESIMO.MAYOR, K.ESIMO.MENOR, PERCENTIL.INC, CUARTIL.INC, PERCENTIL.EXC, CUARTIL.EXC. Es un argumento numérico que debe corresponder al segundo argumento de estas funciones.

Ejemplo

A

B

C

1

ColumnaUno

ColumnaDos

ColumnaTres

2

34

11

12

3

10

56

35

4

#¡DIV/0!

5

3

5

20

8

1

6

0

8

9

7

#¡VALOR!

20

21

8

5

7

8

9

14

0

5


=AGREGAR(4;2;A2:A9)
Devuelve el valor mayor del intervalo A2:A9 = 34, donde =MAX(A2:A9) devuelve el error Err:511.

=AGREGAR(9;5;A5:C5)
Devuelve la suma del intervalo A5:C5 = 29, incluso si algunas de las columnas están ocultas.

=AGREGAR(9;5;B2:B9)
Devuelve la suma de la columna B = 115. Si alguna fila estuviere oculta, la función omitirá su valor; por ejemplo, si la séptima fila está oculta, la función devuelve 95.

Si necesita aplicar la función en un intervalo 3D, este ejemplo muestra cómo hacerlo.

=AGREGAR(13;3;Hoja1.B2:B9:Hoja3.B2:B9)
La función devuelve la moda de los valores de la segunda columna a través de las hojas 1:3 (que tienen los mismos datos) = 8.

Es posible emplear referencias a celdas o a intervalos para cada argumento de la fórmula. El ejemplo siguiente muestra cómo funciona esta técnica. Además, muestra cómo se pueden utilizar etiquetas de columnas para especificar una matriz.

=AGREGAR(E3;E5;'ColumnaUno')
Si E3 = 13 y E5 = 5, la función devuelve la moda de la primera columna = 10.

¡Necesitamos su ayuda!