Text Functions

This section contains descriptions of the Text functions.

要访问此命令...

插入 - 函数 - 类别 文字


ARABIC

计算罗马数字的值。值的范围必须介于 0 和 3999 之间。

语法

ARABIC("Text")

Text 是一个表示罗马数字的文字。

示例

=ARABIC("MXIV") 返回 1014

=ARABIC("MMII") 返回 2002

ASC

ASC 函数将全角转换为半角 ASCII 码和片假名字符。返回字符串。

See https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions for a conversion table.

语法

ASC("Text")

Text 是包含要转换的字符的文本。

另请参见 JIS 函数。

BAHTTEXT

将数字转换为泰语文本,包括泰国货币名称。

语法

BAHTTEXT(Number)

Number 为任意数字。"Baht" 将被附加到该数字的整数部分,而 "Satang" 将被附加到该数字的小数部分。

示例

=BAHTTEXT(12.65) 返回一个以泰语字符表示的字符串,该字符串的含义为“12 铢和 65 萨当”。

BASE

将以指定基数为底数的正整数通过编号系统转换成文本。 可以使用数字 0-9 和字母 A-Z。

语法

BASE(Number; Radix; [MinimumLength])

Number 是要转换的正整数。

Radix 指数字系统的基数,是一个介于 2 和 36 之间的正整数。

MinimumLength(可选)用于确定已创建的字符序列的最小长度。如果文字长度小于设置的最小长度,则会在字符串左边加零。

示例

=BASE(17;10;4) 返回十进制系统中的 0017。

=BASE(17;2) 返回二进制系统中的 10001。

=BASE(255;16;4) 返回十六进制系统中的 00FF。

CHAR

根据当前代码表将数字转换成字符。数字可以是两位或三位的整数。

大于 127 的代码会依赖于您系统的字符映射(例如 iso-8859-1、iso-8859-2、Windows-1252、Windows-1250),因此可能不能移植。

语法

CHAR(Number)

Number 是一个表示字符代码值的介于 1 和 255 之间的数字。

示例

=CHAR(100) 返回字符 d。

="abc" & CHAR(10) & "def" 在字符串中插入换行符。

CLEAN

所有非打印字符都被从字符串中删除。

语法

CLEAN("Text")

Text 要从中删除所有不能打印的字符的文本。

CODE

返回文本字符串中第一个字符的数字代码。

语法

CODE("Text")

Text 要获得第一个字符编码的文字。

大于 127 的代码会依赖于您系统的字符映射(例如 iso-8859-1、iso-8859-2、Windows-1252、Windows-1250),因此可能不能移植。

示例

=CODE("Hieronymus") 返回 72,=CODE("hieroglyphic") 返回 104。

批注图标

在这里使用的编码并不是ASCII编码,而是当前编码表的编码。


CONCATENATE

将多个文本字符串合并为一个字符串。

语法

CONCATENATE("Text1"; ...; "Text30")

Text 1; Text 2; ... 是 1 至 30 个要合并成一个字符串的文本段落。

示例

=CONCATENATE("Good ";"Morning ";"Mrs. ";"Doe") 返回:Good Morning Mrs. Doe。

DECIMAL

数字系统中将带有字符的文本按给定的基数转换为正整数。基数必须介于 2 到 36 之间。空格和制表符会被忽略。Text 字段不区分大小写。

如果 Radix 为 16,则开头的 x、X、0x 或 0X,以及结尾的 h 或 H 会被忽略。如果 Radix 为 2,则结尾的 b 或 B 会被忽略。采用其他不属于数字系统的字符将产生错误。

语法

DECIMAL("Text"; Radix)

Text 是要转换的文字。为了将十六进制数与单元格引用(如 A1 与引用的单元格 A1)区分开来,必须在数字前后加上引号,例如 "A1" 或 "FACE"。

Radix 指数字系统的基数,是一个介于 2 和 36 之间的正整数。

示例

=DECIMAL("17";10) 返回 17。

=DECIMAL("FACE";16) 返回 64206。

=DECIMAL("0101";2) 返回 5。

DOLLAR

将数字转换为货币格式,舍入到指定的小数位。数值字段输入要转换为货币的数字。也可在小数字段输入小数位数。如果没有指定数值,则所有货币格式的数字都显示两位小数。

在系统设置中设置货币格式。

语法

DOLLAR(Value; Decimals)

Value 是一个数值,一个含有数值的单元格引用,或一个返回数值的公式。

Decimals 是小数的可选位数。

示例

=DOLLAR(255) 返回 $255.00。

=DOLLAR(367.456;2) 返回 $367.46。请使用与当前语言环境设置相对应的小数点分隔符。

EXACT

比较两个文本字符串,如果二者相同,则返回 TRUE。此函数区分大小写。

语法

EXACT("Text1"; "Text2")

Text1 是要比较的第一个文本。

Text2 是要比较的第二个文本。

示例

=EXACT("microsystems";"Microsystems") 返回 FALSE。

FIND

Returns the position of a string of text within another string.You can also define where to begin the search. The search term can be a number or any string of characters. The search is case-sensitive.

语法

FIND("FindText"; "Text"; Position)

FindText 是要查找的文字。

Text 是要进行搜索的文本。

Position(可选)是文字中开始搜索的位置。

示例

=FIND(76;998877665544) 返回 6。

FIXED

以文本方式返回数字,该文本具有指定数量的小数位数以及可选的千位分隔符。

语法

FIXED(Number; Decimals; NoThousandsSeparators)

Number 是要格式化的数字。

Decimals 是要显示的小数位数。

NoThousandsSeparators(可选)用于指定是否使用千位分隔符。如果该参数是一个不等于 0 的数字,则不显示千位分隔符。如果该参数等于 0 或没有指定,则显示当前语言环境设置指定的千位分隔符。

示例

=FIXED(1234567.89;3) 将 1,234,567.890 作为文本字符串返回。

=FIXED(1234567.89;3;1) 将 1234567.890 作为文本字符串返回。

JIS

JIS 函数将半角转换为全角 ASCII 码和片假名字符。返回字符串。

See https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions for a conversion table.

语法

JIS("Text")

Text 是包含要转换的字符的文本。

另请参见 ASC 函数。

LEFT

返回文本中第一个或前几个字符。

语法

LEFT("Text"; Number)

Text 是确定初始部分字符的文本。

Number(可选)指定开始文字的字符数。如果不定义此参数,则返回一个字符。

示例

=LEFT("output";3) 返回 。

LEFTB

返回 DBCS 文本的第一个字符。

语法

LEFTB("文本", 字节数)

文本 是需要确定其部分字节的原始文本,

字节数(可选)指定您需要用LEFTB截取的字符长度,单位为字节。如果该参数未指定,则返回1个字节。

示例

LEFTB("中国";1) returns " " (1 byte is only half a DBCS character and a space character is returned instead).

LEFTB("中国";2) returns "中" (2 bytes constitute one complete DBCS character).

LEFTB("中国";3) returns "中 " (3 bytes constitute one DBCS character and a half; the last character returned is therefore a space character).

LEFTB("中国";4) returns "中国" (4 bytes constitute two complete DBCS characters).

LEFTB("office";3) returns "off" (3 non-DBCS characters each consisting of 1 byte).

LEN

返回字符串的长度(包括空格)。

语法

LEN("Text")

Text 是需要确定长度的文本。

示例

=LEN("Good Afternoon") 返回 14。

=LEN(12345.67) 返回 8。

LENB

对于双字节字符集 (DBCS) 语言,返回用于表示文本字符串中的字符所使用的字节数。

语法

LENB("文本")

Text 是需要确定长度的文本。

示例

LENB("中") 返回 2 (1 个 DBCS 字符为 2 字节)。

LENB("中国") returns 4 (2 DBCS characters each consisting of 2 bytes).

LENB("office") 返回 6 (6 个非-DBCS 字符串,每个均为 1 字节)。

=LENB("Good Afternoon") 返回 14.

=LENB(12345.67) 返回 8.

LOWER

将文本字符串中的所有大写字母转换为小写字母。

语法

LOWER("Text")

Text 是要转换的文字。

示例

=LOWER("Sun") 返回 sun。

MID

返回文本的文本字符串。参数用于指定起始位置和字符数。

语法

MID("Text"; Start; Number)

Text 是包含要提取的字符的文本。

Start 是要从文字字符串中提取字符的起始位置。

Number 指定文字中字符的数目。

示例

=MID("office",2,2) 返回 ff。

MIDB

返回DBCS文本的一个文本字符串。参数用于指定起始位置以及要返回的字节数。

语法

MIDB("文本", 起始, 字节数)

文本 是包含有要提取的字符的文本。

起始 要提取的文本中第一个字符的位置。

字节数 指定了 MIDB 将要返回的字符数,以字节为单位。

示例

MIDB("中国";1;0) returns "" (0 bytes is always an empty string).

MIDB("中国";1;1) returns " " (1 byte is only half a DBCS character and therefore the result is a space character).

MIDB("中国";1;2) returns "中" (2 bytes constitute one complete DBCS character).

MIDB("中国";1;3) returns "中 " (3 bytes constitute one and a half DBCS character; the last byte results in a space character).

MIDB("中国";1;4) returns "中国" (4 bytes constitute two complete DBCS characters).

MIDB("中国";2;1) returns " " (byte position 2 is not at the beginning of a character in a DBCS string; 1 space character is returned).

MIDB("中国";2;2) returns " " (byte position 2 points to the last half of the first character in the DBCS string; the 2 bytes asked for therefore constitutes the last half of the first character and the first half of the second character in the string; 2 space characters are therefore returned).

MIDB("中国";2;3) returns " 国" (byte position 2 is not at the beginning of a character in a DBCS string; a space character is returned for byte position 2).

MIDB("中国";3;1) 返回 " " (字节位置3处于DBCS字符串中每个字符的开始位置,但是1字节只代表了DBCS字符的一半,因此返回一个空格字符)。

MIDB("中国";3;2) returns "国" (byte position 3 is at the beginning of a character in a DBCS string, and 2 bytes constitute one DBCS character).

MIDB("office";2;3) returns "ffi" (byte position 2 is at the beginning of a character in a non-DBCS string, and 3 bytes of a non-DBCS string constitute 3 characters).

PROPER

将文本字符串的所有单词的首字母转换成大写。

语法

PROPER("文本")

文本 要转换的文字。

示例

=PROPER("open office") 返回 Open Office。

REPLACE

将文本字符串的一部分用其他文本字符串替换。 此函数可用于替换字符和数字(将自动转换为文本)。函数的结果将始终显示为文本类型。如果想对已经替换成文本的数字执行进一步的计算,必须使用VALUE 函数将其转换回数字。

输入含有数字的文字时,如果您希望输入的信息不被解释为数字并自动转换成文字,则需要在文字前后加上引号。

语法

REPLACE("文本", 位置, 长度, "新文本")

文本 要将其部分内容替换掉的文本。

位置 是要替换的文本的起始位置。

长度 是要在文本 中替换掉的字符数目。

新文本 是用来替换文本 的文字。

示例

=REPLACE("1234567",1,1,"444") 返回 "444234567"。位于位置1的一个字符整个被新文本 替代。

REPT

根据给定的重复次数 重复字符串。

语法

REPT("文本", 数量)

文本 是要重复的文字。

次数 是重复的次数。

函数 REPT 的结果不能多于 255 个字符。

示例

=REPT("Good morning",2) 返回 Good morningGood morning。

RIGHT

返回文本中最后一个或多个字符。

语法

RIGHT("文本", 字符数)

文本 是指要确定其右侧部分字符的文字。

字符数(可选)是文本右侧的字符数。

示例

=RIGHT("Sun",2) 返回 un。

RIGHTB

返回双字节字符集 (DBCS) 文本的最后一个或几个字符

语法

RIGHTB("文本"; 字节数)

文本 是需要确定其右侧字符的文本。

字节数 (可选) 指定RIGHTB函数需要提取多少个字符,以“字节”为单位。

示例

RIGHTB("中国";1) returns " " (1 byte is only half a DBCS character and a space character is returned instead).

RIGHTB("中国";2) returns "国" (2 bytes constitute one complete DBCS character).

RIGHTB("中国";3) returns " 国" (3 bytes constitute one half DBCS character and one whole DBCS character; a space is returned for the first half).

RIGHTB("中国";4) returns "中国" (4 bytes constitute two complete DBCS characters).

RIGHTB("office";3) returns "ice" (3 non-DBCS characters each consisting of 1 byte).

ROMAN

将数字转换成罗马数字。数字必须介于 0 到 3999 之间,Mode 的值可以是 0 到 4 之间的整数。

语法

ROMAN(Number; Mode)

Number 是要转换成罗马数字的数字。

Mode(可选)指示简化的级别。值越高,转换成的罗马数字就越简单。

示例

=ROMAN(999) 返回 CMXCIX

=ROMAN(999;0) 返回 CMXCIX

=ROMAN (999;1) 返回 LMVLIV

=ROMAN(999;2) 返回 XMIX

=ROMAN(999;3) 返回 VMIV

=ROMAN(999;4) 返回 IM

SEARCH

返回字符串中某个文本段的位置。您可以设置搜索的起始位置。搜索的文字可以是数字或任意的字符序列。搜索不区分大小写。

查找支持正则表达式。例如,您可以输入 "all.*" 来查找起始部分为 "all" 且后跟任意字符的内容首次出现的位置。如果您想要查找一个同时也是正则表达式的文本,则您必须在每个字符前面加上一个 \ 字符。您能够在 - LibreOffice Calc - 计算中切换正则表达式自动求值功能的打开和关闭状态。

语法

SEARCH("FindText"; "Text"; Position)

FindText 是要搜索的文本。

Text 是要在其中进行搜索的文本。

Position(可选)是开始搜索的起始字符位置。

示例

=SEARCH(54;998877665544) 返回 10。

SUBSTITUTE

用新文字替换字符串中的旧文字。

语法

SUBSTITUTE("Text"; "SearchText"; "NewText"; Occurrence)

Text 是需要交换部分文字的文本。

SearchText 是要(多次)替换的文本段。

NewText 是用于替换文本段的文本。

Occurrence(可选)指出要替换第几次出现的搜索文本。如果不指定此参数,则所有搜索文本都将被替换。

示例

=SUBSTITUTE("123123123";"3";"abc") 返回 12abc12abc12abc。

=SUBSTITUTE("123123123";"3";"abc";2) 返回 12312abc123。

T

此函数返回目标文本,或者在目标不是文本时返回空白文本字符串。

语法

T(Value)

如果 Value 是(或表示)文本字符串,则 T 返回文本字符串;否则返回空文本字符串。

示例

=T(12345) 返回空字符串。

=T("12345") 返回字符串 12345。

TEXT

根据给定的格式将数字转换成文字。

语法

TEXT(value; format_text)

Number 是要转换的数值。

Format 是定义格式的文字。根据单元格格式中的语言设置来使用小数点和千位分隔符。

示例

=TEXT(12.34567;"###.##") 返回文本 12.35

=TEXT(12.34567;"000.00") 返回文本 012.35

TRIM

删除字符串中的空格,在字词之间只留一个空格。

语法

TRIM("Text")

文本 是指想要去除其中空格的文本。

示例

=TRIM(" hello world ") returns hello world without leading and trailing spaces and with single space between words.

UNICHAR

将代码数字转换为 Unicode 字符或字母。

语法

UNICHAR(number)

示例

=UNICHAR(169) 返回版权字符 ©

提示图标

See also the UNICODE() function.


UNICODE

返回文本字符串中第一个 Unicode 字符的数字代码。

语法

UNICODE("Text")

示例

=UNICODE("©") 返回版权字符的 Unicode 数字 169。

提示图标

See also the UNICHAR() function.


UPPER

文本字段中指定的字符串转换为大写形式。

语法

UPPER("Text")

Text 是要将其转换为大写的小写字母。

示例

=UPPER("Good Morning") 返回 GOOD MORNING。

VALUE

将文本字符串转换为数字。

语法

VALUE("Text")

Text 是被转换为数字的文本。

示例

=VALUE("4321") 返回 4321。