信息函数

此类别包含统计函数。

要访问此命令...

插入 - 函数 - 类别 信息


以下列表中数据是函数说明的一些示例:

C

D

2

x

y

3

-5

-3

4

-2

0

5

-1

1

6

0

3

7

2

4

8

4

6

9

6

8


CELL

返回单元格地址、格式或内容等信息。

语法

CELL("InfoType"; Reference)

InfoType 为一个字符串,指定信息类型。这个字符串始终是英语。可以任意选择大小写。

InfoType

含义

COL

返回引用列的编号。

=CELL("COL";D2) 返回 4。

ROW

返回引用行的编号。

=CELL("ROW";D2) 返回 2。

SHEET

返回引用工作表的编号。

=CELL("Sheet";Sheet3.D2) 返回 3。

ADDRESS

返回引用单元格的绝对地址。

=CELL("ADDRESS";D2) 返回 $D$2。

=CELL("ADDRESS";Sheet3.D2) 返回 $Sheet3.$D$2。

=CELL("ADDRESS";'X:\dr\test.ods'#$Sheet1.D2) returns 'file:///X:/dr/test.ods'#$Sheet1.$D$2.

FILENAME

返回引用单元格的文件名称和工作表名称。

=CELL("FILENAME";D2) returns 'file:///X:/dr/own.ods'#$Sheet1, if the formula in the current document X:\dr\own.ods is located in Sheet1.

=CELL("FILENAME";'X:\dr\test.ods'#$Sheet1.D2) returns 'file:///X:/dr/test.ods'#$Sheet1.

COORD

Returns the complete cell address in Lotus™ notation.

=CELL("COORD"; D2) 返回 $A:$D$2。

=CELL("COORD"; Sheet3.D2) 返回 $C:$D$2。

CONTENTS

返回引用单元格的内容,无格式化。

TYPE

返回单元格内容的类型。

b=blank。空单元格

l=label。文字,公式的结果作为文字

v=value。数值,一个公式的结果作为数值

WIDTH

返回引用列的宽度。度量单位是插入列内的 0 的数目,0 为默认大小的默认字体。

PREFIX

返回引用单元格的对齐方式。

'=左对齐或左右对齐

"= 右对齐

^= 居中

\ = 重复(目前不能使用)

PROTECT

返回单元格保护状态。

1 =单元格受保护

0 =单元格未受保护

FORMAT

返回说明数字格式的的字符串。

, = 带有千位分隔符的数字

F = 不带有千位分隔符的数字

C =货币格式

S =科学计数法,比如 1.234+E56

P = 百分数

在上面的格式中,小数点后面的小数位作为数字给出。示例:数字格式 #,##0.0 返回“,1”,数字格式 00.000% 返回“P3”

D1 =D-MMM-YY、D-MM-YY 和类似格式

D2 =DD-MM

D3 =MM-YY

D4 =DD-MM-YYYY HH:MM:SS

D5 =MM-DD

D6 =HH:MM:SS AM/PM

D7 =HH:MM AM/PM

D8 =HH:MM:SS

D9 =HH:MM

G =全部其他格式

-(负号)在结束位置=负数会用颜色标出

()(括号)在结束位置 = 在格式码中会出现一个前括号

COLOR

如果负数用颜色格式化,结果为 1,否则为 0。

PARENTHESES

当格式码中包含一个左括号时,结果为1,否则为0。


引用(可选)是要检查的单元格的位置。如果引用是一个区域,那么单元格移至该区域内左上方。如果没有引用,LibreOffice Calc 就使用含有这个公式的单元格的位置。Microsoft Excel 使用光标所在的单元格的引用。

CURRENT

该函数返回直到计算公式时的结果,该公式是函数的一部分(也就是说已经得到的计算结果)。它主要用途是与函数 STYLE() 一同应用到由单元格内容决定所选的样式中。

语法

CURRENT()。

示例

=1+2+CURRENT()

该示例返回 6。公式从左到右计算:1 + 2 等于 3,这是遇到 CURRENT() 时得到的结果;因此 CURRENT() 为 3,加上最初的 3 后得到 6。

=A2+B2+STYLE(IF(CURRENT()>10;”Red”;”Default”))

该示例返回 A2 + B2(STYLE 返回 0)。如果和大于 10,样式 Red 应用到此单元格。请参见函数 STYLE 获得更多信息。

="choo"&CURRENT()

该示例返回 choochoo。

FORMULA

将公式单元格的公式显示为文本字符串。

语法

FORMULA(Reference)

Reference 是对包含公式的单元格的引用。

无效引用或对无公式单元格的引用将导致错误值 #N/A。

示例

如果单元格 A8 包含公式 =SUM(1;2;3),则

=FORMULA(A8) 返回文本 =SUM(1;2;3)。

IFERROR

Returns the value if the cell does not contains an error value, or the alternative value if it does.

语法

IFERROR(值, 备选值)

Value

备选值:前面一个参数()的返回结果为错误的情况下,返回这个备选值。

示例

=ISERROR(C8) 返回 TRUE,其中单元格 C8 包含 =1/0,因为 1/0 是错误值。

=ISERROR(C8) 返回 TRUE,其中单元格 C8 包含 =1/0,因为 1/0 是错误值。

IFNA

当单元格的结果不是 #N/A (“值不可用”) 错误的情况下,返回单元格结果,否则返回备选值。

语法

IFNA(值, 备选值)

:表达式的返回结果不是 #N/A 值的情况下,返回该值。

备选值:前面一个参数()的返回结果为 #N/A 错误的情况下,返回这个备选值。

示例

=IFNA(D3, D4) 如果 D3 不是 #N/A 错误的情况下,返回 D3,否则返回 D4.

INFO

返回有关当前工作环境的特定信息。该函数接收单个文本参数,并根据该参数返回数据。

语法

INFO("Type")

下表列出了文本参数 Type 的值以及 INFO 函数的返回值。

"Type" 的值

返回值

"osversion"

由于兼容性原因,始终为 "Windows (32-bit) NT 5.01"

"system"

操作系统的类型。
"WNT" 代表 Microsoft Windows
"LINUX" 代表 Linux
"SOLARIS" 代表 Solaris

"release"

产品版本标识符,例如

"numfile"

由于兼容性原因,始终为 1

"recalc"

当前的公式重新计算模式,可以为“自动”或“手动”(已本地化为 LibreOffice 语言)


批注图标

其他电子表格应用程序可能会接受 Type 参数的本地化值,但 LibreOffice Calc 只接受英文值。


示例

=INFO("release") 返回当前使用的 LibreOffice 的产品版本号。

单元格 D5 包含一个文本字符串 system 时,=INFO(D5) 返回操作系统的类型。

ISBLANK

如果引用的单元格是空白的,则返回 TRUE。此函数用于确定单元格内容是否为空。含有公式的单元格不为空。

如果发生错误,此函数将返回一个逻辑值或数字值。

语法

ISBLANK(Value)

value 是要测试的内容。

示例

=ISBLANK(D2) 返回 FALSE 作为结果。

ISERR

测试错误条件(#N/A 错误值除外),并返回 TRUE 或 FALSE。

如果发生错误,此函数将返回一个逻辑值或数字值。

语法

ISERR(Value)

Value 是任意值或表达式,将对其进行测试以确定是否存在 #N/A 以外的错误值。

示例

=ISERR(C8) 返回 TRUE,其中单元格 C8 包含 =1/0,因为 1/0 是错误值。

=ISERR(C9) 返回 FALSE,其中单元格 C9 包含 =NA(),因为 ISERR() 忽略 #N/A 错误。

ISERROR

测试错误条件(包括 #N/A 错误值),并返回 TRUE 或 FALSE。

如果发生错误,此函数将返回一个逻辑值或数字值。

语法

ISERROR(Value)

Value 是(或表示)要测试的值。如果存在错误,则 ISERROR() 返回 TRUE,否则返回 FALSE。

示例

=ISERROR(C8) 返回 TRUE,其中单元格 C8 包含 =1/0,因为 1/0 是错误值。

=ISERROR(C9) 返回 TRUE,其中单元格 C9 包含 =NA()

ISEVEN

如果数值是偶数,则返回 TRUE;如果是奇数,则返回 FALSE。

语法

ISEVEN(Value)

Value 是要检查的数值。

如果 Value 不是一个整数,那么小数点后的所有数字都将被忽略。Value 的正负符号也将被忽略。

示例

=ISEVEN(48) 返回 TRUE

=ISEVEN(33) 返回 FALSE

=ISEVEN(0) 返回 TRUE

=ISEVEN(-2.1) 返回 TRUE

=ISEVEN(3.999) 返回 FALSE

ISEVEN_ADD

用于测试偶数。如果接受测试的数字能被 2 整除,则返回 1。

批注图标

The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.


语法

ISEVEN_ADD(Number)

Number 是被检验的值。

示例

=ISEVEN_ADD(5) 返回 0。

如果单元格 A1 包含数字 2,则 =ISEVEN_ADD(A1) 返回 1。

ISFORMULA

如果单元格含有公式,返回 TRUE。

如果发生错误,此函数将返回一个逻辑值或数字值。

语法

ISFORMULA(Reference)

引用指示对某个单元格的引用,将在该单元格中执行测试以确定它是否包含公式。

示例

如果单元格 C4 包含数字 5,则 =ISFORMULA(C4) 返回 FALSE。

ISLOGICAL

测试逻辑值(TRUE 或 FALSE)。

如果发生错误,函数返回 FALSE。

语法

ISLOGICAL(Value)

如果 Value 为逻辑值(TRUE 或 FALSE),则返回 TRUE,否则将返回 FALSE。

示例

=ISLOGICAL(99) 返回 FALSE,因为 99 是数字,而不是逻辑值。

=ISLOGICAL(ISNA(D4)) 返回 TRUE,而不考虑单元格 D4 的内容,因为 ISNA() 返回逻辑值。

ISNA

如果单元格含有错误值 #NA(值不可用),返回逻辑值 TRUE 。

如果发生错误,函数返回 FALSE。

语法

ISNA(Value)

数值是指一个要检查的数值或一个表达式。

示例

=ISNA(D3) 返回 FALSE 作为结果。

ISNONTEXT

测试单元格内容是文字还是数字,如果内容是文字,则返回 FALSE。

如果发生错误,函数返回 TRUE。

语法

ISNONTEXT(Value)

数值是指一个数值或一个表达式。检查它是文字还是数字(或逻辑值)。

示例

如果单元格 D2 包含文本 abcdef,则 =ISNONTEXT(D2) 返回 FALSE。

如果单元格 D9 包含数字 8,则 =ISNONTEXT(D9) 返回 TRUE。

ISNUMBER

如果值是一个数字,则返回逻辑值 TRUE。

如果发生错误,此函数将返回一个逻辑值或数字值。

语法

ISNUMBER(Value)

value 是要测试的表达式,将确定它是数字还是文字。

示例

如果单元格 C3 包含数字 4,则 =ISNUMBER(C3) 返回 TRUE。

如果单元格 C2 包含文本 abcdef,则 =ISNUMBER(C2) 返回 FALSE。

ISODD

如果数值是奇数,则返回 TRUE;如果是偶数,则返回 FALSE。

语法

ISODD(value)

Value 是要检查的数值。

如果 Value 不是一个整数,那么小数点后的所有数字都将被忽略。Value 的正负符号也将被忽略。

示例

=ISODD(33) 返回 TRUE

=ISODD(48) 返回 FALSE

=ISODD(3.999) 返回 TRUE

=ISODD(-3.1) 返回 TRUE

ISODD_ADD

如果数字不能被 2 整除,则返回 TRUE (1)。

批注图标

The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.


语法

ISODD_ADD(number)

Number 是被检验的值。

示例

=ISODD_ADD(5) 返回 1。

ISREF

测试参数是否为引用。如果参数为引用,则返回 TRUE,否则返回 FALSE。当所给参数是个引用时,函数不检查正被引用的值。

如果发生错误,此函数将返回一个逻辑值或数字值。

语法

ISREF(Value)

value 是要测试的值,将确定它是否是引用。

示例

=ISREF(C5) 返回结果 TRUE,因为 C5 是一个有效的引用。

=ISREF("abcdef") 总是返回 FALSE,因为文本永远不可能是引用。

=ISREF(4) 返回 FALSE。

=ISREF(INDIRECT("A6")) 返回 TRUE,因为 INDIRECT 是返回引用的函数。

=ISREF(ADDRESS(1; 1; 2;"Sheet2")) 返回 FALSE,因为 ADDRESS 是返回文本的函数,尽管它看起来像引用。

ISTEXT

如果单元格内容是文本,则返回逻辑值 TRUE。

如果发生错误,函数返回 FALSE。

语法

ISTEXT(Value)

数值是指一个要检查的数值,一个数字,一个逻辑值或一个错误值。识别它们是文字还是数字。

示例

如果单元格 D9 包含文本 abcdef,则 =ISTEXT(D9) 返回 TRUE。

如果单元格 C3 包含数字 3,则 =ISTEXT(C3) 返回 FALSE。

N

返回给定参数数值化后的值。如果参数为文本或 FALSE 则返回 0。

如果发生错误,则函数将返回错误值。

语法

N(Value)

Value 是要转换成数字的参数。N() 会在可行的情况下返回数值。对于逻辑值 TRUE 和 FALSE,N() 将分别返回 1 和 0。对于文本将返回 0。

示例

=N(123) 返回 123

=N(TRUE) 返回 1

=N(FALSE) 返回 0

=N("abc") 返回 0

=N(1/0) returns #DIV/0!

NA

返回错误值 #NA。

语法

NA()

示例

=NA() 转换当前单元格内容为 #N/A。

TYPE

Returns the type of value, where 1 = number, 2 = text, 4 = Boolean value, 8 = formula, 16 = error value, 64 = array.

如果发生错误,此函数将返回一个逻辑值或数字值。

语法

TYPE(Value)

Value is a specific value for which the data type is determined.

示例(请您参考以上的示例表格)

=TYPE(C2) 返回 2 作为结果。

=TYPE(D9) 返回 1 作为结果。