财务函数第一部分
此类别包含 LibreOffice Calc 的数学财务函数。
ACCRINT
计算定期支付情况下的有价证券的应付利息。
语法
ACCRINT(Issue; FirstInterest; Settlement; Rate; Par; Frequency; Basis)
Issue 指有价证券的发行日期。
FirstInterest 指有价证券首次支付利息的日期。
Settlement 指计算到该日为止累积利息的日期。
Rate 指年名义利率(息票利率)
Par 指有价证券的面额。
Frequency 指每年支付利息的次数(1、2 或 4)。
示例
一有价证券于 2001 年 2 月 28 日发行。首次支付利息的日期定在 2001 年 8 月 31 日。结算日期为 2001 年 5 月 1 日。年息票利率为 0.1 或 10%,面额为 1000 货币单位。利息每半年支付一次(年付息的次数为 2)。基数应用美国方法计算 (0)。 累积利息为多少?
=ACCRINT("2001-02-28";"2001-08-31";"2001-05-01";0.1;1000;2;0) 返回 16.94444。
ACCRINTM
计算在结算日期一次性支付的有价证券的应付利息。
语法
ACCRINTM(Issue; Settlement; Rate; Par; Basis)
Issue 指有价证券的发行日期。
Settlement 指计算到该日为止累积利息的日期。
Rate 指年名义利率(息票利率)。
Par 指有价证券的面额。
示例
一有价证券于 1.4.2001 发行。到期日期定于 15.6.2001。利率为 0.1 或 10%,面额为 1000 个货币单位。每日/每年计算的基础是每日余额 (3)。累积的利息为多少?
=ACCRINTM("2001-04-01";"2001-06-15";0.1;1000;3) 返回 20.54795。
AMORDEGRC
计算一个结算周期内递减分摊的折旧金额。与 AMORLINC 不同的是,这里使用了与折旧年限无关的折旧系数。
语法
AMORDEGRC(Cost; DatePurchased; FirstPeriod; Salvage; Period; Rate; Basis)
Cost 是购买成本。
DatePurchased 指购买日期。
FirstPeriod 指第一个结算期间的结束日期。
Salvage 指资产在使用期限终止时的残值。
Period 指结算期间。
Rate 指折旧率。
AMORLINC
计算一个结算周期内线性分摊的折旧额。如果资产在结算周期内买入,则按比例考虑部分折旧额。
语法
AMORLINC(Cost; DatePurchased; FirstPeriod; Salvage; Period; Rate; Basis)
Cost 指购买成本。
DatePurchased 指购买日期。
FirstPeriod 指第一个结算期间的结束日期。
Salvage 指资产在使用期限终止时的残值。
Period 指结算期间。
Rate 指折旧率。
DB
返回采用固定余额递减法计算的某项资产在给定期间的折旧额。
与直线法不同,固定余额递减法在开始期间的折旧额更高,并在折旧期间内依次递减。
语法
DB(成本; 残值; 折旧期限; 期间; 首年月数)
成本 是指资产的初始成本。
残值 是指资产使用寿命终止时的剩余价值。
折旧期限 定义资产将要被折旧的期间。
期间 是每个期间的长度。该长度必须输入与折旧周期相同的时间单位。
首年月数(可选)折旧计算时首年的月份数。若省略,则使用默认值,即 首年月数 = 12。
示例
初始成本为25,000的计算机,折旧期限为三年,残值为1,000,每个期间为30天。
=DB(25000;1000;36;1;6) = 1,075.00
该计算机的固定余额递减折额为1,075.00 .
DDB
使用算术递减法,计算指定期限内资产的折旧额。
如果希望获得比线性折旧法高的初始折旧额,请采用这种资产折旧方式。采用此折旧方式时,折旧金额按折旧周期依次递减,这种方式通常用于在使用初期价值损失非常快的资产(例如汽车、计算机)。值得注意的是,采用这种折旧方式计算的帐面价值永远不可能为零。
语法
DDB(Cost; Salvage; Life; Period; Factor)
Cost 处输入的是资产的购入价。
Salvage 栏位输入的是资产在使用期限终止时的残值。
Life 定义资产使用的时间长度(如年或月)。
Period 表示计算该值的周期。
Factor(可选择的)是一个用于折旧计算的余额递减因子。若省略这个参数,程序便会采用默认设定,即 factor = 2。
示例
初始成本为 75,000 个货币单位的计算机系统在 5 年内按月折旧。折旧后的最终价值为 1 个货币单位。系数为 2。
=DDB(75000;1;60;12;2) = 1,721.81 个货币单位。因此,在购买后第一个月,双倍递减折旧后为 1,721.81 个货币单位。
DISC
计算有价证券的贴现(折扣)百分比。
语法
DISC("Settlement"; "Maturity"; Price; Redemption; Basis)
Settlement 指有价证券的购买日期。
Maturity 该有价证券的到期日(期满)。
Price 面额为 100 个货币单位的有价证券的实际价格。
Redemption 面额为 100 个货币单位的有价证券的赎回价格。
示例
一有价证券购于 25.1.2001;到期日期为 15.11.2001。购买价格为 97,偿还价格为 100。使用每日余额计算 (basis 3),则贴现率为多高?
=DISC("2001-01-25";"2001-11-15";97;100;3) 返回近似值 0.0372 或 3.72%。
DURATION_ADD
计算固定利率的有价证券的年周期。
语法
DURATION_ADD("Settlement"; "Maturity"; Coupon; Yield; Frequency; Basis)
Settlement 指有价证券的购买日期。
Maturity 该有价证券的到期日(期满)。
Coupon 年息票利率(名义利率)
Yield 有价证券的年收益率。
Frequency 指每年支付利息的次数(1、2 或 4)。
示例
一有价证券于 2001 年 1 月 1 日买入;有效期截止到 2006 年 1 月 1 日。年息票利率为 8%。年收益率为 9.0%。利息每半年支付一次(年付息的次数为 2)。如果使用日余额利息(基数为 3)计算,修正后周期为多长?
=DURATION_ADD("2001-01-01";"2006-01-01";0.08;0.09;2;3)
EFFECTIVE
返回名义利率的净年利率。
由于名义利率涉及的是在计算期限结束时到期的利率。而利率通常以月利率,季度利率等等计算且在计算期限结束之前分别到期。也就是说,利率通常是应该预支付的。这样实际利率便会随分期支付利率次数的增加而变化。
语法
EFFECTIVE(Nom; P)
Nom 是名义利率。
P 指定的是每年支付利息的次数。
示例
假设年名义利率为9.75%,且每年支付利息的次数设定为4次,那么实际利率应该是多少呢?
=EFFECTIVE(9.75%;4) = 10.11% 也就是说,年实际利率为 10.11%。
EFFECT_ADD
根据名义年利率和年付息次数计算实际年利率。
语法
EFFECT_ADD(NominalRate; NPerY)
NominalRate 年名义利率。
NPerY 是每年支付利息的次数。
示例
名义利率为 5.25%,且每季度支付,实际年利率为多少?
=EFFECT_ADD(0.0525;4) 返回 0.053543 或 5.3534%。
IRR
计算投资回报的内部收益率。这些数值表示一段时间内的现金流金额,其中至少有一个数值必须为负(支出),至少有一个数值必须为正(收入)。
If the payments take place at irregular intervals, use the XIRR function.
语法
IRR(Values; Guess)
Values 代表含有数值的数组。
Guess(可选择的)是估计值。使用迭代的方法计算回报的内部收益率。如果只能提供少量数值,则应该提供一个初始估计值以启用迭代。
示例
假设单元格内容是 A1=-10000、A2=3500、 A3=7600 and A4=1000,公式 =IRR(A1:A4) 的结果为 11,33%。
Because of the iterative method used, it is possible for IRR to fail and return Error 523, with "Error: Calculation does not converge" in the status bar. In that case, try another value for Guess.
ISPMT
计算分期偿还额恒定时的利率。
语法
ISPMT(Rate; Period; TotalPeriods; Invest)
Rate 指定每个周期的利率。
Period 是用于计算利息的分期付款周期。
TotalPeriods 是分期付款周期的总数。
Invest 是一项投资的金额。
示例
一笔按月偿还的总额为 120,000 货币单位的贷款,偿还期限为两年,计算利率为 12% 时 1.5 年后的利息总额。
=ISPMT(1%;18;24;120000) = -300 个货币单位。1.5 年后每月利息总额为 300 个货币单位。
PV
返回一项投资在一系列定期支付后的现值。
借助这个函数您能够计算为了在各个周期内(周期总数确定)获得预定的分期支付金额(年金),目前必须投资的金额数值。在此您既可以指定在完成最后一次支付后还剩余的应支付金额数,又可以指定支付是在周期开始还是周期结束时到期。
您既可以往参数栏内键入数字或表达式,又可以键入引用。例如:假设年利率为8%,且支付按月进行,那么请您在 rate 栏内键入 8%/12 。这样,LibreOffice Calc 便会自动计算出利率值。
语法
PV(Rate; NPer; Pmt; FV; Type)
Rate 指定每个周期的利率。
NPer 是周期总数(支付周期)。
Pmt 指定的是在每个周期应支付的固定金额。
FV(可选择的)指定的完成最后一次支付后计算的未来值。
Type(可选择的)指定支付到期类型。Type = 1 指在周期开始时到期,Type = 0 (默认设定)指在周期结束时到期。
In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.
示例
假设每月分期支付金额为 500 货币单位且年利率设定为8%,那么这项投资的现金值是多少呢?支付周期设定为 48 个月且完成最后一次支付后的剩余金额应为 20,000 货币单位。
=PV(8%/12;48;500;20000) = -35,019.37 个货币单位。也就是说,要想在 48 个月期间每月获得 500 个货币单位且在完成最后一次支付后的剩余金额为 20,000 个货币单位,那么您目前必须投资 35,019.37 个货币单位。通过一个对比计算:48 x 500 个货币单位 + 20,000 个货币单位 = 44,000 个货币单位。您可以见到计算结果 44,000 个货币单位与投资金额 35,019.37 个货币单位的差额是您获得的利息。
如果您在公式中输入引用来代替这些数值,那么您可以计算 "If-then" 方案中的任意数字。请注意:对常数的引用必须定义为绝对引用。这种应用类型的示例可以在折旧函数中找到。
RECEIVED
计算在特定时间接收到的为固定利率有价证券支付的总金额。
语法
RECEIVED("Settlement"; "Maturity"; Investment; Discount; Basis)
Settlement 指有价证券的购买日期。
Maturity 该有价证券的到期日(期满)。
Investment 指购买总量。
Discount 指有价证券的贴现率。
示例
成交日:1999年2月15日,到期日期:1999年5月15日,投资额:1000个货币单位,贴现率:5.75%,基数:每日余额/360=2。
计息日期的总支付金额计算如下:
=RECEIVED("1999-02-15";"1999-05-15";1000;0.0575;2) 返回 1014.420266。
SYD
返回算术递减的折旧率。
借助这个函数功能您能够计算一项资产在指定周期内的折旧额。采用数字型折旧方法时在每个周期内折旧金额的递减值是恒定的。
语法
SYD(Cost; Salvage; Life; Period)
Cost 是资产的购入价。
Salvage 指的是折旧期限终止时资产的残值。
Life 指的是资产的使用寿命,即资产的折旧期限。
Period 指定要计算其折旧金额的周期数。
示例
一台录象设备的购买价为¥50,000,希望以一年为一个周期在五年使用期限内进行折旧计算。折旧期限终止时资产的残值应为¥10,000。要计算的是第一年的资产折旧金额。
=SYD(50000;10000;5;1)=13,333.33 个货币单位。第一年的折旧金额为 13,333.33 个货币单位。
建议您制作一个资产折旧表,以便能够清楚地了解各个周期的折旧金额。如果您在此并排列出 LibreOffice Calc 中不同的资产折旧公式,便可针对示例情况找出资产折旧的最佳方法。请如下制作表格:
A |
B |
C |
D |
E |
|
1 |
初始成本 |
残值 |
有效期 |
期间 |
折旧 SYD |
2 |
50,000 个货币单位 |
10,000 个货币单位 |
5 |
1 |
13,333.33 个货币单位 |
3 |
2 |
10,666.67 个货币单位 |
|||
4 |
3 |
8,000.00 个货币单位 |
|||
5 |
4 |
5,333.33 个货币单位 |
|||
6 |
5 |
2,666.67 个货币单位 |
|||
7 |
6 |
0.00 个货币单位 |
|||
8 |
7 |
||||
9 |
8 |
||||
10 |
9 |
||||
11 |
10 |
||||
12 |
|||||
13 |
>0 |
总数 |
40,000.00 个货币单位 |
E2 中的公式为以下公式:
=SYD($A$2;$B$2;$C$2;D2)
将单元格 E2 内的公式复制到列 E 中单元格 E3 至 E11 位置(标记单元格 E2 后,鼠标往下拖拉单元格右下角的矩形)。
在单元格E13处的公式是用来核对折旧金额总计的。它采用的是函数SUMIF,因为单元格E8至E11之间的负值不予考虑。条件 >0 位于单元格A13处。单元格E13处的公式如下:
=SUMIF(E2:E11;A13)
您也可以设定资产折旧期限为 10 年,或者折旧期限终止时资产的残值为 1 元,或者另外设定资产的购买价等等来重新进行折旧计算。