سۆزلىشىش رامكا تەھرىرلىگۈچتىكى كونترولنىڭ پروگرامما تۈزۈش مىسالى

Function LoadDialog(Libname as String, DialogName as String, Optional oLibContainer)

Dim oLib as Object

Dim oLibDialog as Object

Dim oRuntimeDialog as Object

    If IsMissing(oLibContainer) Then

        oLibContainer = DialogLibraries

    End If

    oLibContainer.LoadLibrary(LibName)

    oLib = oLibContainer.GetByName(Libname)

    oLibDialog = oLib.GetByName(DialogName)

    oRuntimeDialog = CreateUnoDialog(oLibDialog)

    LoadDialog() = oRuntimeDialog

End Function

rem ئومۇمىي ئۆزگەرگۈچى مىقدارنىڭ ئېنىقلىمىسى

Dim oDialog1 AS Object

Sub StartDialog1

    BasicLibraries.LoadLibrary("Tools")

    oDialog1 = LoadDialog("Standard", "Dialog1")

    oDialog1.Execute()

End Sub

Sub Sample1

    BasicLibraries.LoadLibrary("Tools")

    oDialog1 = LoadDialog("Standard", "Dialog1")

    REM سۆزلىشىش رامكا مودىلىغا ئېرىشىدۇ

    oDialog1Model = oDialog1.Model

    REM  Label1 نىڭ خېتىنى كۆرسىتىدۇ

    oLabel1 = oDialog1.GetControl("Label1")

    MsgBox oLabel1.Text

    REM كونترول Label1 نىڭ يېڭى خېتىنى تەڭشەيدۇ

    oLabel1.Text = "New Files"

    REM كونترول CheckBox1 نىڭ مودىل خاسلىقىنى كۆرسىتىدۇ

    oCheckBox1Model = oDialog1Model.CheckBox1

    MsgBox oCheckBox1Model.Dbg_Properties

    REM  CheckBox1 نىڭ كونترول مودىلىغا يېڭى ھالەت تەڭشەيدۇ

    oCheckBox1Model.State = 1

    REM كونترول CommandButton1 نىڭ مودىلى خاسلىقىنى كۆرسىتىدۇ

    oCMD1Model = oDialog1Model.CommandButton1

    MsgBox oCMD1Model.Dbg_Properties

    REM كونترول CommandButton1 نىڭ خاسلىقىنى كۆرسىتىدۇ

    oCMD1 = oDialog1.GetControl("CommandButton1")

    MsgBox oCMD1.Dbg_Properties

    REM سۆزلىشىش رامكا ئىجرا قىل

    oDialog1.Execute()

End Sub

Sub AddEntry

    BasicLibraries.LoadLibrary("Tools")

    oDialog1 = LoadDialog("Standard", "Dialog1")

    REM  ListBox قا يېڭى تۈر قوشىدۇ

    oDialog1Model = oDialog1.Model

    oListBox = oDialog1.GetControl("ListBox1")

    Dim iCount as integer

    iCount = oListbox.ItemCount

    oListbox.additem("New Item" & iCount,0)

End Sub

Sub RemoveEntry

    BasicLibraries.LoadLibrary("Tools")

    oDialog1 = LoadDialog("Standard", "Dialog1")

    REM  ListBox دىكى بىرىنچى تۈرنى ئۆچۈرىدۇ

    oDialog1Model = oDialog1.Model

    oListBox = oDialog1.GetControl("ListBox1")

    oListbox.removeitems(0,1)

End Sub