Функтсияҳои Молиявӣ Қисми Дуюм

Бозгашт ба Функтсияҳои Молиявӣ Қисми Якум

Гузариш ба Функтсияҳои Молиявӣ Қисми Сеюм

CUMIPMT

Даромади ҷамъшудаи пардохтшударо барои давраи сармоягузорӣ ҳисоб мекунад.

Синтаксис

CUMIPMT(Rate; NPer; PV; S; E; Type)

Rate курси даврӣ.

NPER: давраи пардохт.

PV: арзиши ҳозира.

S: давраи аввал.

E: давраи охирон.

Type: санаи пардохт.

Намуна

Даромад чӣ қадар аст бо курси солонаи даромад 5.5 %, бо давраи падохти моҳона дар 2 сол ва арзиши ҳозираи 5,000 воҳиди арзӣ? Давраи аввал моҳи 4 ва давраи охир моҳи 6 бошад. Пардохт дар аввали ҳар моҳ гузаронида шавад.

CUMIPMT(5.5%/12;24;5000;4;6;1) = -57.54 воҳиди арзӣ.

CUMIPMT_ADD

Даромади ҷамъшудаи давраро ҳисоб мекунад.

Синтаксис

CUMIPMT_ADD(Rate; NPer; PV; StartPeriod; EndPeriod; Type)

Rate: курси даромад барои ҳар як давра.

NPER: шумораи умумии давраҳо.

PV: арзиши ҳозира.

Start period: давраи аввали пардохт.

End period: давраи охири пардохт.

Type: мӯҳлат.

Намуна

Ҳисобкуни:

Rate: 9.00 дарсади солона (9% / 12 = 0.0075), Duration: 30 сол (NPER = 30 * 12 = 360), Pv: 125000 воҳиди арзӣ.

Шумо чӣ қадар пардохт мекунед дар соли дуюми қарз?

=CUMIPMT_ADD(0.0075;360;125000;13;24;0) натиҷа -11135.23.

Дар моҳи аввал шумо ин маблағро пардохт мекунед:

=CUMIPMT_ADD(0.0075;360;125000;1;1;0) натиҷа -937.50.

CUMPRINC

Даромади ҷамъшудаи пардохтшударо барои давраи сармоягузорӣ ҳисоб мекунад.

Синтаксис

CUMPRINC(Rate; NPer; PV; S; E; Type)

Rate курси даврӣ.

NPER: давраи пардохт.

PV: арзиши ҳозира.

S: давраи аввал.

E: давраи охирон.

Type: санаи пардохт.

Намуна

Чӣ қадар пардохти даврии моҳона калон аст дар курси даромади 8.75% барои давраи 3 сол? Арзиши нақди 5,000 воҳиди арзӣ ва дар аввали давра пардохт карда мешавад. Арзиши оянда 8,000 воҳиди арзӣ мебошад.

CUMPRINC(5.5%/12;36;15000;10;18;0) = -3669.74 воҳиди арзӣ.

CUMPRINC_ADD

Барқароршавии кумулятивии қарзро ҳисоб мекунад.

Синтаксис

CUMPRINC_ADD(Rate; NPer; PV; StartPeriod; EndPeriod; Type)

Rate: курси даромад барои ҳар як давра.

NPER: шумораи умумии давраҳо.

PV: арзиши ҳозира.

Start period: давраи аввали пардохт.

End period: давраи охири пардохт.

Type: мӯҳлат.

Намуна

Ҳисобкуни:

Rate: 9.00 дарсади солона (9% / 12 = 0.0075), Duration: 30 сол (давраи пардохт = 30 * 12 = 360), NPV: 125000 воҳиди арзӣ.

Шумо чӣ қадар пардохт мекунед дар соли дуюми қарз?

CUMPRINC_ADD(0.0075;360;125000;13;24;0) натиҷа -934.1071

Дар моҳи аввал шумо ин маблағро пардохт мекунед:

CUMPRINC_ADD(0.0075;360;125000;1;1;0) натиҷа -68.27827

DOLLARDE

Арзиши додашударо ба каср табдил медиҳад.

Синтаксис

DOLLARDE(FractionalDollar; Fraction)

Fractional dollar:рақам ҳамчун қисми даҳӣ.

Fraction: коэфитсиенти тақсимкунанда.

Намуна

=DOLLARDE(1.02;16) stands for 1 and 2/16. This returns 1.125.

=DOLLARDE(1.1;8) stands for 1 and 1/8. This returns 1.125.

DOLLARFR

Арзиши додашударо ба каср табдил медиҳад.

Синтаксис

DOLLARFR(DecimalDollar; Fraction)

Decimal dollar: адади даҳӣ.

Fraction: коэфитсиенти тақсимкунанда.

Намуна

=DOLLARFR(1.125;16). натиҷа 1.02 барои 1 ҷамъи 2/16.

=DOLLARFR(1.125;8). Натиҷа 1.1 барои 1 ҷамъи 1/8.

DURATION

Шумораи давраҳоро барои сармоягузори барои ба даст овардани арзиши дилхоҳ ҳисоб мекунад.

Синтаксис

DURATION(Rate; PV; FV)

Rate: доимӣ, курси даромад.

PV: арзиши ҳозира.

FV: арзиши оянда.

Намуна

Бо курси даромади 4.75%, арзиши нақдинаи 25,000 воҳиди арзӣ ва арзиши ояндаи 1,000,000 воҳиди арзӣ, дарозии 79.49 давраи пардохтӣ. Пардохти даврӣ 1,000,000/79.49=12,850.20.

MDURATION

Дарозии саҳмияи даромади муайяншуда доштаро ҳисоб мекунад.

Синтаксис

MDURATION(Settlement; Maturity; Coupon; Yield; Frequency; Basis)

Оғоз: санаи хариди саҳмия.

Интиҳо: санаи охири саҳмия.

Coupon: курси солонаи даромад

Yield: зиёдшавии арзиш.

Зуддӣ: шумораи пардохҳои даромад (1, 2 ё 4).

Намуна

Сашмия дар санаи 1/1/2001 харида шудааст; санаи охири мӯҳлат 1/1/2006. Курси номиналии даромад 8% аст. (зуддӣ 2). Дар асоси баланси рӯзона (асоси 3) мӯҳлати дарозии тағирдодашуда чанд аст?

=MDURATION("2001-01-01"; "2006-01-01"; 0.08; 0.09; 2; 3) returns 4.02 years.

MIRR

Дарсади дохилии пардохти силсилаи сармоягузориро ҳисоб мекунад.

Синтаксис

MIRR(Values; Investment; ReinvestRate)

Values: ба диапазони чашмакҳо ё массиве, ки таркибашон пардохтҳо мебошанд.

investment: дарсади даромад аз сармоягузорӣ

reinvest_rate: дарсади даромади азнавсармоягузорӣ

Намуна

Бо назардошти таркиби чашмакҳо баробари A1=-5, A2=10, A3=15, ва A4=8, ва арзиши сармоягузории 0.5 ва арзиши азнавсармоягузории 0.1, натиҷа 94.16% мебошад.

NOMINAL

Дарсади даромади солонаро бо назардошти дарсади ҷорӣ ва шумораи давраҳои сол ҳисоб мекунад.

Синтаксис

NOMINAL(EffectiveRate; NPerY)

EFFECT_RATE: дарсади ҷории даромад

NPERY: шумораи пардохтҳои солона.

Намуна

Дарсади номиналӣ барои дарсади ҷории даромади 13.5% чанд аст, агар дувоздаҳ давраи пардохти дар сол бошад.

=NOMINAL(13.5%;12) = 12.73%. The nominal interest rate per year is 12.73%.

NOMINAL_ADD

Дарсади даромади солонаро бо назардошти дарсади ҷорӣ ва шумораи давраҳои сол ҳисоб мекунад.

Синтаксис

NOMINAL_ADD(EffectiveRate; NPerY)

Effective rate: дарсади ҷории даромади солона.

Npery: шумораи пардохтҳои солона.

Намуна

Дарсади номиналӣ барои 5.3543% дарсади ҷории даромад ва пардохти чорякӣ чанд аст.

=NOMINAL_ADD(5.3543%; 4) натиҷа 0.0525 or 5.25%.

NPV

Returns the present value of an investment based on a series of periodic cash flows and a discount rate. To get the net present value, subtract the cost of the project (the initial cash flow at time zero) from the returned value.

If the payments take place at irregular intervals, use the XNPV function.

Синтаксис

NPV(Rate; Value1; Value2; ...; Value30)

RATE: дарсади гузашт.

Value1, Value2, ..., Value30 are up to 30 values, which represent deposits or withdrawals.

Намуна

What is the net present value of periodic payments of 10, 20 and 30 currency units with a discount rate of 8.75%. At time zero the costs were paid as -40 currency units.

NPV(8.75%;10;20;30) = 49.43 воҳиди арзӣ.

PMT

Пардохти давриро барои даромад бо дасади доимӣ ҳисоб мекунад.

Синтаксис

PMT(Rate; NPer; PV; FV; Type)

Rate курси даврӣ.

NPER: Шумораи давраҳо.

PV: арзиши ҳозира.

FV (ихтиёрӣ): арзиши оянда.

Type (ихтиёрӣ): Санаи охири пардохт. Тип=1 пардохт дар аввал ва Тип=0 дар охири давра.

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

Намуна

Давраҳои пардохти чанд мебошанд барои дарсади даромади 1.99% агар мӯҳлати пардохт 3 сол ва арзиши нақдина 25,000 воҳиди арзӣ бошад. 36 моҳ бо 36 давраи пардохт ва дарсади даромад барои давра 1.99%/12 бошад.

PMT(1.99%/12;36;25000) = -715.96 воҳиди арзӣ.

PPMT

Пардохтро барои сармояи ибтидоӣ барои давраи додашуда, ки дар асоси пардохтҳои даврӣ ва доимӣ ҳисоб мекунад.

Синтаксис

PPMT(Rate; Period; NPer; PV; FV; Type)

Rate курси даврӣ.

Period: давра. P=1 барои аввал ва P=NPER барои охирон.

NPER: шумораи умумии давраҳо, ки даромад ҳисоб карда шудааст.

PV. арзиши ҳозира.

FV (ихтиёрӣ): арзиши оянда.

Type (ихтиёрӣ): санаи пардохт.

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

Намуна

Чӣ қадар пардохти даврии моҳона калон аст дар курси даромади 8.75% барои давраи 3 сол? Арзиши нақди 5,000 воҳиди арзӣ ва дар аввали давра пардохт карда мешавад. Арзиши оянда 8,000 воҳиди арзӣ мебошад.

PPMT(8.75%/12;1;36;5000;8000;1) = -350.99 воҳиди арзӣ.

PRICE

Арзиши бозории маблағгузорӣ бо арзиши миёнаи 100 воҳиди арзӣ ҳисоб мекунад.

Синтаксис

PRICE(Settlement; Maturity; Rate; Yield; Redemption; Frequency; Basis)

Оғоз: санаи хариди саҳмия.

Интиҳо: санаи охири саҳмия.

Курс: Курси солонаи даромад

Yield: зиёдшавии арзиш.

Redemption: арзиши барқарории 100 воҳиди арзии арзиши баланс.

Зуддӣ: шумораи пардохҳои даромад (1, 2 ё 4).

Намуна

Саҳмия дар 2/15/1999 харида шудааст; санаи мӯҳлати истифода 11/15/2007 аст. Курси номиналии даромад 5.75%. (зуддӣ 2). Ҳисоб бо асоси 0 чунин аст:

=PRICE("2/15/1999"; "11/15/2007"; 0.0575; 0.065; 100; 2; 0) натиҷа 95.04287.

PRICEDISC

Нархро барои 100 воҳиди арзии сармояи бе даромад ҳисоб мекунад.

Синтаксис

PRICEDISC(Settlement; Maturity; Discount; Redemption; Basis)

Оғоз: санаи хариди саҳмия.

Интиҳо: санаи охири саҳмия.

Discount: гузашт дар дарсад.

Redemption: арзиши барқарории 100 воҳиди арзии арзиши баланс.

Намуна

Саҳмия дар 2/15/1999 харида шудааст; санаи маӯлати истифода 3/1/1999. Гузашт 5.25%. Дар асоси 2 ҳисобкунии гузашт чунин аст:

=PRICEDISC("2/15/1999"; "3/1/1999"; 0.0525; 100; 2) натиҷа 99.79583.

PRICEMAT

Нархро барои 100 воҳиди арзи саҳмия, ки даромадро дар санаи мӯҳлати охири истифода ҳисоб мекунад.

Синтаксис

PRICEMAT(Settlement; Maturity; Issue; Rate; Yield; Basis)

Оғоз: санаи хариди саҳмия.

Интиҳо: санаи охири саҳмия.

Issue: санаи барориши саҳмия.

Rate: курси даромад дар санаи барориши саҳмия.

Yield: зиёдшавии арзиш.

Намуна

Settlement date: 15 Февраи 1999, maturity date: 13 Феврали 1999, issue date: 11 Ноябри 1998. Interest rate: 6.1 дарсад, 6.1 дарсад, асос: 30/360 = 0.

Нарх чунин ҳисоб карда мешавад:

=PRICEMAT("2/15/1999";"4/13/1999";"11/11/1998"; 0.061; 0.061;0) нарх 99.98449888.

SLN

Хӯрдашавии хаттии воситаҳои асосиро барои як давра ҳисоб мекунад.

Синтаксис

SLN(Cost; Salvage; Life)

Cost хароҷот.

Salvage арзиш дар охир.

LIFE: мӯҳлати истифода.

Намуна

Воситаҳои асосӣ бо арзиши ибтидоии 50,000 воҳиди арзӣ бояд дар 7 сол хурдашавӣ ҳисоб карда шавад. Арзиш дар охири давра бояд 3,500 воҳиди арзӣ бошад.

SLN(50000;3,500;84) = 553.57 воҳиди арзӣ.

TBILLEQ

Calculates the annual return on a treasury bill. A treasury bill is purchased on the settlement date and sold at the full par value on the maturity date, that must fall within the same year. A discount is deducted from the purchase price.

Синтаксис

TBILLEQ(Settlement; Maturity; Discount)

Оғоз: санаи хариди саҳмия.

Интиҳо: санаи охири саҳмия.

Гузашт: дарсади гузашт.

Намуна

Settlement date: 31 Марти 1999, maturity date: 1 Июни 1999, discount: 9.14 дарсад.

Ҳисобкунӣ:

=TBILLEQ("3/31/99";"6/1/99"; 0.0914) натиҷа 0.094151 ё 9.4151 дарсад.

TBILLPRICE

Нархи чиптаи сармояро барои 100 воҳиди арзӣ ҳисоб мекунад.

Синтаксис

TBILLPRICE(Settlement; Maturity; Discount)

Оғоз: санаи хариди саҳмия.

Интиҳо: санаи охири саҳмия.

Discount: дарсади гузашт.

Намуна

Settlement date: 31 Марти 1999, maturity date: 1 Июни 1999, discount: 9 дарсад.

Ҳисобкунӣ:

=TBILLPRICE("3/31/99";"6/1/99"; 0.09) натиҷа 98.45.

TBILLYIELD

Бозгашти чиптаи сармояро ҳисоб мекунад.

Синтаксис

TBILLYIELD(Settlement; Maturity; Price)

Оғоз: санаи хариди саҳмия.

Интиҳо: санаи охири саҳмия.

Price: нарх барои 100 воҳид.

Намуна

Settlement date: 31 Марти 1999, maturity date: 1 Июни 1999, price: 98.45 воҳиди арзӣ.

Ҳисобкунӣ:

=TBILLYIELD("3/31/99";"6/1/99"; 98.45) натиҷа 0.091417 ё 9.1417 дарсад.

YIELD

Даромади саҳмияро ҳисоб мекунад.

Синтаксис

YIELD(Settlement; Maturity; Rate; Price; Redemption; Frequency; Basis)

Оғоз: санаи хариди саҳмия.

Интиҳо: санаи охири саҳмия.

Rate: даромади солона аз саҳмия.

Price: арзиши саҳмия дар 100 воҳиди арзӣ.

Redemption: арзиши барқарории 100 воҳиди арзии арзиши баланс.

Зуддӣ: шумораи пардохҳои даромад (1, 2 ё 4).

Намуна

Саҳмия дар санаи 2/15/1999 харида шудааст. Санаи мӯҳлати охир 11/15/2007. Дарсади даромад 5.75%. Нарх 95.04287 воҳиди арзӣ. Даромад дар нимсола пардохт карда мешавад (зуддӣ = 2) ва асос 0 аст. Даромад чӣ қадар аст?

=YIELD("2/15/1999"; "11/15/2007"; 0.0575 ;95.04287; 100; 2; 0) натиҷа 0.065 or 6.5 дарсад.

YIELDDISC

Даромади солонаи саҳмияро ҳисоб мекунад.

Синтаксис

YIELDDISC(Settlement; Maturity; Price; Redemption; Basis)

Оғоз: санаи хариди саҳмия.

Интиҳо: санаи охири саҳмия.

Price: арзиши саҳмия дар 100 воҳиди арзӣ.

Redemption: арзиши барқарории 100 воҳиди арзии арзиши баланс.

Намуна

Саҳмия дар санаи 2/15/1999 харида шудааст. Вай дар санаи 3/1/1999 ба итмом мерасад. Нарх 99.795 воҳиди арзӣ дар 100 воҳиди арзии балансӣ, арзиши барориш 100 воҳид. Асос 2 аст:

=YIELDDISC("2/15/1999"; "3/1/1999"; 99.795; 100; 2) натиҷа 0.052823 ё 5.2823 дарсад.

YIELDMAT

Даромади солонаи саҳмияро ҳисоб мекунад, ки санаи пардохти он дар охири мӯҳлат гузаронида мешавад.

Синтаксис

YIELDMAT(Settlement; Maturity; Issue; Rate; Price; Basis)

Оғоз: санаи хариди саҳмия.

Интиҳо: санаи охири саҳмия.

Issue: санаи барориши саҳмия.

Rate: курси даромад дар санаи барориши саҳмия.

Price: арзиши саҳмия дар 100 воҳиди арзӣ.

Намуна

Саҳмия дар санаи 3/15/1999 харида шудааст. Санаи мӯлати охирон 11/3/1999. Санаи барориш 11/8/1998. Дарсади даромад 6.25%, нарх 100.0123 воҳид. Асос 0 аст:

=YIELDMAT("3/15/1999"; "11/3/1999"; "11/8/1998"; 0.0625; 100.0123; 0) натиҷа 0.060954 ё 6.0954 дарсад.

Бозгашт ба Функтсияҳои Молиявӣ Қисми Якум

Гузариш ба Функтсияҳои Молиявӣ Қисми Сеюм