Математические функции

Эта категория содержит математические функции для Calc. Для вызова мастера функций выберите Вставка – Функция.

[text/scalc/01/func_aggregate.xhp#aggregate_head not found].

This function returns an aggregate result of the calculations in the range. You can use different aggregate functions listed below. The Aggregate function enables you to omit hidden rows, errors, SUBTOTAL and other AGGREGATE function results in the calculation.

[text/scalc/01/func_sumifs.xhp#sumifs_head not found].

Returns the sum of the values of cells in a range that meets multiple criteria in multiple ranges.

ABS

Возвращает абсолютное значение числа.

Синтаксис

ABS (Число)

Число: число для расчета абсолютного значения. Абсолютное значение числа – это его значение без знака +/-.

Пример

=ABS(-56) возвращает значение 56.

=ABS(12) возвращает значение 12.

=ABS(0) возвращает значение 0.

ACOS

Вычисляет арккосинус числа.

Синтаксис

ACOS(Число)

Эта функция возвращает тригонометрический арккосинус числа, т.е. угол (в радианах), косинус которого равен числу. Возвращается угол от 0 до пи.

Функция DEGREES возвращает угол в градусах.

Пример

=ACOS(-1) возвращает значение 3,14159265358979 (пи радиан).

=DEGREES(ACOS(0.5)) возвращает значение 60. Косинус 60 градусов равен 0,5.

ACOSH

Возвращает гиперболический арккосинус числа.

Синтаксис

ACOSH(Число)

Эта функция возвращает гиперболический арккосинус числа, т.е. число, гиперболический косинус которого равен числу.

Число должно быть больше или равно 1.

Пример

=ACOSH(1) возвращает значение 0.

=ACOSH(COSH(4)) возвращает значение 4.

ACOT

Возвращает арккотангенс данного числа.

Синтаксис

ACOT(Число)

Эта функция возвращает тригонометрический арккотангенс числа, т.е. угол (в радианах), котангенс которого равен числу. Возвращается угол от 0 до пи.

Функция DEGREES возвращает угол в градусах.

Пример

=ACOT(1) возвращает значение 0,785398163397448 (пи/4 радиан).

=DEGREES(ACOT(1)) возвращает значение 45. Тангенс 45 градусов равен 1.

ACOTH

Возвращает гиперболический арккотангенс числа.

Синтаксис

ACOTH(Число)

Эта функция возвращает гиперболический котангенс числа, т.е. число, гиперболический тангенс которого равен числу.

Если число находится между -1 и 1 включительно, возникает ошибка.

Пример

=ACOTH(1.1) возвращает гиперболический арккотангенс 1,1, приблизительно 1,52226.

ASIN

Возвращает арксинус числа.

Синтаксис

ASIN(Число)

Эта функция возвращает тригонометрический арксинус числа, т.е. угол (в радианах), синус которого равен числу. Возвращается угол от -пи/2 до +пи/2.

Функция DEGREES возвращает угол в градусах.

Пример

=ASIN(0) возвращает значение 0.

=ASIN(1) возвращает значение 1,5707963267949 (пи/2 радиан).

=DEGREES(ASIN(0.5)) возвращает значение 30. Синус 30 градусов равен 0,5.

ASINH

Возвращает гиперболический арксинус числа.

Синтаксис

ASINH(Число)

Эта функция возвращает гиперболический арксинус числа, т.е. число, гиперболический синус которого равен числу.

Пример

=ASINH(-90) возвращает значение 5,1929877 (приблизительно).

=ASINH(SINH(4)) возвращает значение 4.

ATAN

Возвращает арктангенс числа.

Синтаксис

ATAN(Число)

Эта функция возвращает тригонометрический арктангенс числа, т.е. угол (в радианах), тангенс которого равен числу. Возвращается угол от -пи/2 до пи/2.

Функция DEGREES возвращает угол в градусах.

Пример

=ATAN(1) возвращает значение 0,785398163397448 (пи/4 радиан).

=DEGREES(ATAN(1)) возвращает значение 45. Тангенс 45 градусов равен 1.

ATAN2

Возвращает арктангенс для указанных координат X и Y.

Синтаксис

ATAN2(Число X; Число Y)

Число_X: значение координаты x.

Число_Y: значение координаты y.

ATAN2 возвращает тригонометрический арктангенс, т.е. угол (в радианах) между осью X и линией из точки "Число X, Число Y" к источнику. Возвращается угол от -пи до пи.

Функция DEGREES возвращает угол в градусах.

Пример

=ATAN2(20;20) возвращает значение 0,785398163397448 (пи/4 радиан).

=DEGREES(ATAN2 (12,3;12,3)) возвращает значение 45. Тангенс 45 градусов равен 1.

ATANH

Возвращает гиперболический арктангенс числа.

Синтаксис

ATANH(Число)

Эта функция возвращает гиперболический арктангенс числа, т.е. число, гиперболический тангенс которого равен числу.

Число должно соответствовать правилу -1 < число <1.

Пример

=ATANH(0) возвращает значение 0.

CEILING

Округляет число в большую сторону до целого или кратного с заданной точностью.

Синтаксис

CEILING(число; приращение; режим)

Число: число для округления.

Точность: число, до кратного которому требуется округлить значение.

Mode is an optional value. If the Mode value is given and not equal to zero, and if Number and Significance are negative, then rounding is done based on the absolute value of Number, i.e. negative numbers are rounded away from zero. If the Mode value is equal to zero or is not given, negative numbers are rounded towards zero.

Пример

=CEILING(-11;-2) возвращает значение -10.

=CEILING(-11;-2;0) возвращает значение -10.

=CEILING(-11;-2;1) возвращает значение -12.

CEILING.MATH

Rounds a number up to the nearest multiple of Significance.

Syntax

CEILING.MATH(Number; Significance; Mode)

Number is the number that is to be rounded up.

Significance is the number to whose multiple the value is to be rounded up.

Mode is an optional value. If the Mode value is given and not equal to zero, and if Number and Significance are negative, then rounding is done based on the absolute value of Number, i.e. negative numbers are rounded away from zero. If the Mode value is equal to zero or is not given, negative numbers are rounded towards zero.

Example

=CEILING.MATH(-10;-3) returns -9

=CEILING.MATH(-10;-3;0) returns -9

=CEILING.MATH(-10;-3;1) returns -12

CEILING.PRECISE

Rounds a number up to the nearest multiple of Significance, regardless of sign of Significance

Синтаксис

CEILING.PRECISE(Number; Significance)

Число: число для округления.

Точность: число, до кратного которому требуется округлить значение.

Пример

=CEILING.PRECISE(-11; -2) возвращает -10.

CEILING.XCL

Rounds a number away from zero to the nearest multiple of Significance.

Syntax

CEILING.XCL(Number; Significance)

Number is the number that is to be rounded.

Significance is the number to whose multiple the value is to be rounded.

Example

=CEILING.XCL(1;3) returns 3

=CEILING.XCL(7;4) returns 8

=CEILING.XCL(-10;-3) returns -12

COMBIN

Возвращает число комбинаций элементов без повторений.

Синтаксис

COMBIN(Число1; Число2)

Количество1: количество элементов в множестве.

Количество2: количество элементов для выбора из множества.

COMBIN возвращает число упорядоченных способов выбора этих элементов. Например, если имеются 3 элемента A, B и C, два элемента можно выбрать тремя различными способами, а именно, AB, AC и BC.

COMBIN реализует формулу: Count1!/(Count2!*(Count1-Count2)!)

Пример

=COMBIN(3;2) возвращает значение 3.

COMBINA

Возвращает количество комбинаций подмножества элементов с учетом повторений.

Синтаксис

COMBINA(Число1; Число2)

Количество1: количество элементов в множестве.

Количество2: количество элементов для выбора из множества.

Функция COMBINA возвращает число уникальных способов выбора этих элементов, порядок выбора игнорируется и разрешается несколько экземпляров одного элемента. Например, если имеются 3 элемента A, B и C, два элемента можно выбрать шестью различными способами, т.е. AA, AB, AC, BB, BC и CC.

COMBINA использует следующую формулу: (Count1+Count2-1)! / (Count2!(Count1-1)!)

Пример

=COMBINA(3;2) возвращает значение 6.

CONVERT_OOO

Пересчёт из одной единицы измерения в другую. Коэффициенты пересчёта приводятся в списке в настройке.

Список коэффициентов пересчёта содержал одновременно старые европейские валюты и евро (см. примеры ниже). Для пересчёта этих валют предлагается использовать новую функцию EUROCONVERT.

Синтаксис

CONVERT_OOO(value;"text";"text")

Пример

=CONVERT_OOO(100;"ATS";"EUR") returns the Euro value of 100 Austrian Schillings.

=CONVERT_OOO(100;"EUR";"DEM") converts 100 Euros into German Marks.

COS

Возвращает косинус заданного угла (в радианах).

Синтаксис

COS(Число)

Возвращает (тригонометрический) косинус числа - угла в радианах.

Для возвращения косинуса угла в градусах следует использовать функцию RADIANS.

Примеры

=COS(PI()/2) возвращает значение 0, т.е. косинус пи/2 радиан.

=COS(RADIANS(60)) возвращает значение 0,5, т.е. косинус 60 градусов.

COSH

Возвращает гиперболический косинус числа.

Синтаксис

COSH(Число)

Возвращает гиперболический косинус числа.

Пример

=COSH(0) возвращает значение 1, т.е. гиперболический косинус 0.

COT

Возвращает котангенс заданного угла (в радианах).

Синтаксис

COT(Число)

Возвращает (тригонометрический) котангенс числа - угла в радианах.

Для возврата котангенса угла в степенях используйте функцию RADIANS.

Котангенс угла эквивалентен 1, разделённой на тангенс этого угла.

Примеры:

=COT(PI()/4) возвращает значение 1, т.е. котангенс пи/4 радиан.

=COT(RADIANS(45)) возвращает значение 1, т.е. котангенс 45 градусов.

COTH

Вычисляет гиперболический котангенс числа (угла).

Синтаксис

COTH(Число)

Возвращает гиперболический котангенс числа.

Пример

=COTH(1) возвращает гиперболический котангенс 1, приблизительно 1,3130.

CSC

Возвращает косеканс заданного (в радианах) угла. Косеканс угла - это 1, делённая на синус этого угла.

Синтаксис

CSC(Число)

Возвращает (тригонометрический) косеканс числа - угла в радианах.

Для получения косеканса угла, заданного в градусах, следует использовать функцию RADIANS.

Примеры

=CSC(PI()/4) возвращает приблизительно 1.4142135624, значение, обратное синусу PI/4.

=CSC(RADIANS(30)) возвращает значение 2, т.е. косеканс 30 градусов.

CSCH

Возвращает гиперболичекский косеканс числа.

Синтаксис

CSCH(Число)

Возвращает гиперболический косеканс числа.

Пример

=CSCH(1) возвращает приблизительно 0.8509181282, гиперболический косеканс 1.

DEGREES

Служит для преобразования радианов в градусы.

Синтаксис

DEGREES(число)

Число: угол в градусах для преобразования в радианы.

Пример

=DEGREES(PI()) возвращает 180 градусов.

EUROCONVERT

Выполняет преобразование старых европейских национальных валют в/из евро.

Синтаксис

EUROCONVERT(значение;"исходная_валюта";"целевая_валюта", максимальная_точность, точность_триангуляции)

Значение: сумма в валюте для пересчёта.

Параметры Исходная_валюта и Целевая_валюта являются соответственно исходными и целевыми единицами валюты для пересчёта. Значения этих параметров должны быть текстовыми и соответствовать официальному сокращению валюты (например, "EUR"). Курсы (приведены по отношению к евро) установлены Европейской Комиссией.

Параметр Максимальная_точность является необязательным. Если параметр опущен или имеет значение FALSE, то результат округляется в соответствии с количеством десятичных знаков после запятой в значении целевой валюты. Если параметр "Максимальная_точность" имеет значение TRUE, то результат не округляется.

Параметр Точность_триангуляции является необязательным. Если значение параметра "Точность_триангуляции" указано и >=3, промежуточный результат триангуляционного преобразования (денежное_значение1,EUR,денежное_значение2) округляется с этой точностью. Если параметр "Точность_триангуляции" опущен, то промежуточный результат не округляется. Кроме того, если целевой валютой является "EUR", то параметр "Точность_триангуляции" используется как будто требуется триангуляция, и применяется пересчёт из евро в евро.

Примеры

=EUROCONVERT(100;"ATS";"EUR") выполняет пересчёт 100 австрийских шиллингов в евро.

=EUROCONVERT(100;"EUR";"DEM") выполняет пересчёт 100 евро в немецкие марки.

EVEN

Округление положительного числа в большую сторону до следующего чётного числа, а отрицательного целого числа в меньшую сторону до следующего чётного числа.

Синтаксис

EVEN(Число)

Возвращает результат округления числа в большую сторону до следующего чётного целого числа.

Примеры

=EVEN(2.3) возвращает значение 4.

=EVEN(2) возвращает значение 2.

=EVEN(0) возвращает значение 0.

=EVEN(-0.5) возвращает значение -2.

EXP

Возвращает e в указанной степени.

Синтаксис

EXP(Число)

Число: степень, в которую требуется возвести число "e".

Пример

=EXP(1) возвращает значение 2,71828182845904, т.е. математическую константу "e" до степени точности Calc.

FACT

Возвращает факториал числа.

Синтаксис

FACT(Число)

Возвращает Число!, т.е. факториал числа, вычисленный как 1*2*3*4* ... * Число.

=FACT(0) по определению возвращает 1.

Факториал отрицательного числа возвращает ошибку "Недопустимый аргумент".

Пример

=FACT(3) возвращает значение 6.

=FACT(0) возвращает значение 1.

FLOOR

Округляет число в меньшую сторону до кратного с заданной точностью.

Синтаксис

FLOOR(Число; Точность; Режим)

Число: число для округления в меньшую сторону.

Точность: число, до кратного которому требуется округлить значение.

Mode is an optional value. If the Mode value is given and not equal to zero, and if Number and Significance are negative, then rounding is done based on the absolute value of Number, i.e. negative numbers are rounded towards zero. If the Mode value is equal to zero or is not given, negative numbers are rounded away from zero.

Пример

=FLOOR(-11;-2) возвращает значение -12.

=FLOOR(-11;-2;0) возвращает значение -12.

=FLOOR(-11;-2;1) возвращает значение -10.

FLOOR.PRECISE

Rounds a number down to the nearest multiple of Significance, regardless of sign of Significance

Синтаксис

FLOOR.PRECISE(Number; Significance)

Число: число для округления в меньшую сторону.

Точность: число, до кратного которому требуется округлить значение.

Пример

=FLOOR.PRECISE(-11; -2) возвращает -12.

GCD

Возвращает наибольший общий делитель для двух или более целых чисел.

Самый большой общий делитель - наибольшее положительное целое число, на которое каждое из данных целых чисел делится без остатка.

Синтаксис

GCD(Целое число 1; Целое число 2; ...; Целое число 30)

Целое число1…30: до 30 целых чисел, для которых требуется вычислить наибольший общий делитель.

Пример

=GCD(16;32;24) выдаёт результат 8, поскольку 8 является наибольшим числом, на которое 16, 24 и 32 делятся без остатка.

=GCD(B1:B3), если ячейки B1, B2, B3 содержат 9, 12, 9, возвращает 3.

GCD_EXCEL2003

The result is the greatest common divisor of a list of numbers.

Синтаксис

GCD_EXCEL2003(Number(s))

Число(а): список, содержащий не более 30 чисел.

Пример

=GCD_EXCEL2003(5;15;25) returns 5.

INT

Округляет число до ближайшего меньшего целого.

Синтаксис

INT(Число)

Возвращает результат округления числа до ближайшего меньшего целого.

Отрицательные числа округляются до меньшего целого.

Пример

=INT(5.7) возвращает значение 5.

=INT(-1.3) возвращает значение -2.

ISO.CEILING

Rounds a number up to the nearest multiple of Significance, regardless of sign of Significance

Синтаксис

ISO.CEILING(Number; Significance)

Число: число для округления.

Точность: число, до кратного которому требуется округлить значение.

Пример

=ISO.CEILING(-11; -2) возвращает -10.

LCM

Возвращает наименьшее общее кратное для одного или нескольких целых чисел.

Синтаксис

LCM(Целое число1; Целое число2; ...; Целое число30)

Целое число1…30: до 30 целых чисел, для которых требуется вычислить наименьшее общее кратное.

Пример

При вводе в текстовые поля 1, 2 и 3 чисел 512; 1024 и 2000 возвращается значение 128 000.

LCM_EXCEL2003

The result is the lowest common multiple of a list of numbers.

Синтаксис

LCM_EXCEL2003(Number(s))

Число(а): список, содержащий не более 30 чисел.

Пример

=LCM_EXCEL2003(5;15;25) returns 75.

LN

Возвращает натуральный логарифм числа (по основанию e). Основание е - это константа с приблизительным значением 2,71828182845904.

Синтаксис

LN(Число)

Число: число для расчета натурального логарифма.

Пример

=LN(3) возвращает натуральный логарифм 3 (приблизительно 1,0986).

=LN(EXP(321)) возвращает значение 321.

LOG

Возвращает логарифм числа по указанному основанию.

Синтаксис

LOG(Число; Основание)

Число: число для расчета логарифма.

Основание (необязательный параметр): основание для расчета логарифма. Если этот параметр опущен, то используется основание 10.

Пример

=LOG(10;3) возвращает логарифм 10 по основанию 3 (приблизительно 2,0959).

=LOG(7^4;7) возвращает значение 4.

LOG10

Возвращает десятичный логарифм числа.

Синтаксис

LOG10(Число)

Возвращает десятичный логарифм числа.

Пример

=LOG10(5) возвращает десятичный логарифм 5 (приблизительно 0,69897).

MOD

Возвращает остаток от деления одного числа на другое.

Синтаксис

MOD(Делимое; Делитель)

Для целочисленных аргументов эта функция возвращает остаток от деления делимого на делитель, т.е. остаток от деления значения Делимое на значение Делитель.

Эта функция реализована как Делимое - Делитель * INT(Делимое/Делитель), и эта формула возвращает результат, если аргументы - не целые числа.

Пример

=MOD(22;3) возвращает значение 1, т.е. остаток от деления 22 на 3.

=MOD(11.25;2.5) возвращает значение 1,25.

MROUND

Округление числа до ближайшего кратного значения другого числа.

Синтаксис

MROUND(Число; Кратное)

Округление числа до ближайшего кратногочисла.

Также можно использовать Кратное * ROUND(число/кратное).

Пример

=MROUND(15.5; 3) возвращает значение 15, поскольку 15,5 ближе к 15 (= 3*5), чем к 18 (= 3*6).

=MROUND(1.4;0.5) возвращает значение 1,5 (= 0,5*3).

MULTINOMIAL

Returns the factorial of the sum of the arguments divided by the product of the factorials of the arguments.

Синтаксис

MULTINOMIAL(Число(а))

Число(а): список, содержащий не более 30 чисел.

Пример

=MULTINOMIAL(F11:H11): если ячейки диапазона F11:H11 содержат значения 2, 3 и 4 возвращает значение 1260. Это соответствует формуле = (2+3+4)! / (2!*3!*4!)

ODD

Возвращает число, округленное до ближайшего нечётного целого.

Синтаксис

ODD(Число)

Возвращает результат округления числа в большую сторону до следующего нечётного числа.

Пример

=ODD(1.2) возвращает значение 3.

=ODD(1) возвращает значение 1.

=ODD(0) возвращает значение 1.

=ODD(-3.1) возвращает значение -5.

PI

Возвращает 3,14159265358979 - значение математической константы "пи" до 14 знаков после запятой.

Синтаксис

PI()

Пример

=PI() возвращает значение 3,14159265358979.

POWER

Возвращает результат возведения числа в степень.

Синтаксис

POWER(Base; Exponent)

Возвращает основание Base, возведенное в степень Exponent.

Того же результата можно достичь при использовании оператора возведения в степень ^:

Base^Exponent

Пример

=POWER(4;3) возвращает значение 64, т.е. 4 в степени 3.

=4^3 также возвращает 4 в степени 3.

PRODUCT

Служит для умножения всех аргументов и получения произведения.

Синтаксис

PRODUCT(Число1; Число2; ...; Число30)

Число1…30: до 30 аргументов, которые используются для вычисления произведения.

PRODUCT возвращает произведение Число1 * Число2 * Число3 * ...

Пример

=PRODUCT(2;3;4) возвращает значение 24.

QUOTIENT

Возвращает целочисленную часть результата операции деления.

Синтаксис

QUOTIENT(Числитель; Знаменатель)

Возвращает целочисленную часть числителя, разделённого на знаменатель.

QUOTIENT is equivalent to INT(numerator/denominator) for same-sign numerator and denominator, except that it may report errors with different error codes. More generally, it is equivalent to INT(numerator/denominator/SIGN(numerator/denominator))*SIGN(numerator/denominator).

Пример

=QUOTIENT(11; 3) возвращает число 3. Остаток 2 отбрасывается.

RADIANS

Преобразует градусы в радианы.

Синтаксис

RADIANS(Число)

Число: угол в градусах для преобразования в радианы.

Пример

=RADIANS(90) возвращает значение 1,5707963267949, т.е. пи/2 до степени точности Calc.

RAND

Возвращает случайное число от 0 до 1.

Синтаксис

RAND()

This function produces a new random number each time Calc recalculates. To force Calc to recalculate manually press F9.

Для генерации случайных неповторимых чисел следует скопировать ячейки, содержащие =RAND(), и выбрать Правка - Вставить как (без выбора Вставить все и Формулы и с выбором Числа).

Пример

=RAND() возвращает случайное число от 0 до 1.

RANDBETWEEN

Возвращает случайное целое число из указанного диапазона.

Синтаксис

RANDBETWEEN (Нижнее; Верхнее)

Возвращает случайное целое число между целыми нижним и верхним значениями (оба включаются в расчёт).

Результатом выполнения этой функции при каждом повторном вычислении Calc является новое случайное число. Для перевода Calc в режим повторного вычисления вручную следует нажать SHIFT++F9.

Для генерации случайных неповторимых чисел следует скопировать ячейки, содержащие эту функцию, и выбрать Правка - Вставить как (без выбора Вставить все и Формулы и с выбором Числа).

Пример

=RANDBETWEEN(20;30) возвращает произвольное целое число от 20 до 30.

ROUND

Округление числа до указанного количества знаков после запятой.

Синтаксис

ROUND(Число; Количество)

Возвращает число с округлением до количества знаков после запятой. Если количество опущено или равно нулю, то округление производится до ближайшего целого числа. При отрицательном количестве округление выполняется до ближайшего десятка, сотни, тысячи и т.д.

Эта функция округляет число до ближайшего числа. См. ROUNDDOWN и ROUNDUP (варианты).

Пример

=ROUND(2,348;2) возвращает значение 2,35.

=ROUND(-32.4834;3) возвращает значение -32.483. Измените формат ячейки таким образом, чтобы отображались все десятичные разряды.

=ROUND(2.348;0) возвращает значение 2.

=ROUND(2.5) возвращает значение 3.

=ROUND(987.65;-2) возвращает значение 1000.

ROUNDDOWN

Округление числа в меньшую сторону (к нулю) до определенной точности.

Синтаксис

ROUNDDOWN(Число; Количество)

Возвращает число, округленное (к нулю) до количества знаков после запятой. Если количество не указано или равняется нулю, округление проводится до целого числа. Если количество отрицательно, округление выполняется до ближайшего десятка (сотни, тысячи и т.д.).

Эта функция округляет число в направлении к нулю. См. ROUNDUP и ROUND (варианты).

Пример

=ROUNDDOWN(1.234;2) возвращает значение 1.23.

=ROUNDDOWN(45.67;0) возвращает значение 45.

=ROUNDDOWN(-45.67) возвращает значение -45.

=ROUNDDOWN(987.65;-2) возвращает значение 900.

ROUNDUP

Служит для округления числа в большую сторону (от нуля) до определенной точности.

Синтаксис

ROUNDUP(Число; Количество)

Возвращает число, округленное (от нуля) до количества знаков после запятой. Если количество не указано или равняется нулю, округление проводится до целого числа. Если количество отрицательно, округление выполняется до ближайшего десятка (сотни, тысячи и т.д.).

Эта функция округляет число в направлении от нуля. См. ROUNDDOWN и ROUND (варианты).

Пример

=ROUNDUP(1.1111;2) возвращает значение 1.12.

=ROUNDUP(1.2345;1) возвращает значение 1,3.

=ROUNDUP(45.67;0) возвращает значение 46.

=ROUNDUP(-45.67) возвращает значение -46.

=ROUNDUP(987.65;-2) возвращает значение 1000.

SEC

Возвращает секанс заданного (в радианах) угла. Секанс угла - это 1, делённая на косинус этого угла.

Синтаксис

SEC(Число)

Возвращает (тригонометрический) секанс числа - угла в радианах.

Чтобы получить секанс угла, заданного в градусах, используйте функцию RADIANS.

Примеры

=SEC(PI()/4) возвращает приблизительно 1.4142135624, величину, обратную косинусу PI/4.

=SEC(RADIANS(60)) возвращает 2, секанс 60 градусов.

SECH

Возвращает гиперболичексий секанс числа.

Синтаксис

SECH(Число)

Возвращает гиперболический секанс числа.

Пример

=SECH(0) возвращает 1, гиперболический секанс 0.

SERIESSUM

Суммирование первых членов степенного ряда.

SERIESSUM(x;n;m;коэффициенты) = коэффициент_1*x^n + коэффициент_2*x^(n+m) + коэффициент_3*x^(n+2m) +...+ коэффициент_i*x^(n+(i-1)m)

Синтаксис

SERIESSUM(X; N; М; Коэффициенты)

X: вводимое значение для степенного ряда.

Н - начальная степень.

П: приращение, на которое требуется увеличить Н.

Коэффициенты: ряд коэффициентов. Для каждого коэффициента сумма ряда увеличивается на один раздел.

SIGN

Возвращает знак числа. Возвращает 1, если число положительно, -1, если отрицательно и 0, если равно нулю.

Синтаксис

SIGN(Число)

Число: число, знак которого требуется определить.

Пример

=SIGN(3.4) возвращает значение 1.

=SIGN(-4.5) возвращает значение -1.

SIN

Возвращает синус заданного угла (в радианах).

Синтаксис

SIN(Число)

Возвращает (тригонометрический) синус числа (угол в радианах).

Для возвращения синуса угла в градусах следует использовать функцию RADIANS.

Пример

=SIN(PI()/2) возвращает значение 1, т.е. синус пи/2 радиан.

=SIN(RADIANS(30)) возвращает значение 0,5, т.е. синус 30 градусов.

SINH

Вычисляет гиперболический синус числа.

Синтаксис

SINH(Число)

Возвращает гиперболический синусчисла.

Пример

=SINH(0) возвращает значение 0, т.е. гиперболический синус 0.

SQRT

Возвращает положительный квадратный корень числа.

Синтаксис

SQRT(Число)

Возвращает положительный квадратный корень числа.

Число должно быть положительным.

Пример

=SQRT(16) возвращает значение 4.

=SQRT(-16) возвращает ошибку недопустимый аргумент.

SQRTPI

Возвращает квадратный корень от (пи, умноженного на число).

Синтаксис

SQRTPI(Число)

Возвращает положительный квадратный корень от (пи, умноженного на Число).

Это действие эквивалентно SQRT(пи()*число).

Пример

=SQRTPI(2) возвращает квадратный корень из (2пи), приблизительно 2,506628.

SUBTOTAL

Служит для расчета промежуточных итогов. Если диапазон уже содержит промежуточные итоги, они не используются в дальнейших расчетах. Использование этой функции совместно с автофильтрами позволяет учитывать только фильтрованные записи.

Синтаксис

SUBTOTAL(Функция; Диапазон)

Функция: число, обозначающее одну из следующих функций:

Индекс функции (includes hidden values)	Function index (ignores hidden values)	Функция
1	101	AVERAGE
2	102	COUNT
3	103	COUNTA
4	104	MAX
5	105	MIN
6	106	PRODUCT
7	107	STDEV
8	108	STDEVP
9	109	SUM
10	110	VAR
11	111	VARP

Use numbers 1-11 to include manually hidden rows or 101-111 to exclude them; filtered-out cells are always excluded.

Диапазон: диапазон, ячейки которого включаются в расчёт.

Пример

You have a table in the cell range A1:B6 containing a bill of material for 10 students. Row 2 (Pen) is manually hidden. You want to see the sum of the figures that are displayed; that is, just the subtotal for the filtered rows. In this case the correct formula would be:

	A	B
1	ITEM	QUANTITY
2	Pen	10
3	Pencil	10
4	Notebook	10
5	Rubber	10
6	Sharpener	10

=SUBTOTAL(9;B2:B6) returns 50.

=SUBTOTAL(109;B2:B6) returns 40.

SUM

Служит для сложения всех чисел в диапазоне ячеек.

Синтаксис

SUM(Число1; Число2; ...; Число30)

Число1…30: до 30 аргументов, сумму которых требуется вычислить.

Пример

При вводе в текстовые поля 1, 2 и 3 чисел 2; 3 и 4 возвращается значение 9.

=SUM(A1;A3;B5) вычисляет сумму этих трёх ячеек. =SUM(A1:E10) вычисляет сумму всех ячеек в диапазоне A1:E10.

Условия, связанные с помощью оператора AND, можно использовать в функции SUM() следующим образом.

Предположим, что в таблицу были введены счета. Столбец A содержит даты, столбец B - суммы. Требуется создать формулу для расчета общей суммы за определенный месяц, например, сумму за период с >=2008-01-01 по <2008-02-01. The range with the date values covers A1:A40, the range containing the amounts to be totaled is B1:B40. C1 contains the start date, 2008-01-01, т.е. дату счетов, которые необходимо включить, а C2 - дату 2008-02-01, начиная с которой счета не учитываются.

Введите следующую формулу в качестве формулы массива:

=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

Для ввода этой формулы в качестве формулы массива необходимо нажать клавиши SHIFT+ВВОД вместо нажатия клавиши ВВОД по завершении ввода формулы. После этого формула будет отображаться на панели формул в фигурных скобках.

{=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

Формула основывается на том, что результатом сравнения будет 1, если условия выполняются, или 0 - если нет. Отдельные результаты сравнения обрабатываются как массив и применяются в умножении матриц, после чего отдельные значения складываются в конечную матрицу.

SUMIF

Служит для сложения значений ячеек, указанных в условии. Эта функция применяется для поиска определенного значения в диапазоне ячеек.

Синтаксис

SUMIF(Диапазон; Условия; Диапазон суммирования)

Диапазон: диапазон ячеек, которые требуется проверить на соответствие условию.

Условие: ячейка, которая содержит условие поиска, либо само условие поиска. Если условие записано в формуле, его необходимо заключить в двойные кавычки.

Диапазон суммирования: диапазон, значения которого суммируются. Если этот параметр не указан, то суммируются значения, принадлежащие диапазону.

Пример

Для суммирования только отрицательных чисел: =SUMIF(A1:A10;"<0")

=SUMIF(A1:A10;">0";B1:10) суммирует значения из диапазона B1:B10 только в том случае, если соответствующие им значения в диапазоне A1:A10 больше 0.

Некоторые примеры синтаксиса, которые могут использоваться с SUMIF(), приведены в описании COUNTIF().

SUMSQ

Служит для расчета суммы квадратов чисел (сложения квадратов аргументов).

Синтаксис

SUMSQ(Число1; Число2; ...; Число30)

Число1…30: до 30 аргументов, сумму квадратов которых требуется вычислить.

Пример

При вводе в текстовые поля 1, 2 и 3 чисел 2; 3 и 4 возвращается значение 29.

TAN

Возвращает тангенс заданного угла (в радианах).

Синтаксис

TAN(Число)

Возвращает (тригонометрический) тангенс числа - угла в радианах.

Для возвращения тангенса угла в градусах следует использовать функцию RADIANS.

Пример

= TAN (PI()/4) возвращает значение 1, т.е. тангенс пи/4 радиан.

=TAN(RADIANS(45)) возвращает значение 1, т.е. тангенс 45 градусов.

TANH

Возвращает гиперболический тангенс числа.

Синтаксис

TANH(Число)

Возвращает гиперболический тангенс числа.

Пример

=TANH(0) возвращает значение 0, т.е. гиперболический тангенс 0.

TRUNC

Усечение числа путём удаления знаков после запятой.

Синтаксис

TRUNC(Число; Количество)

Возвращает число с количеством знаков после запятой не более чем количество. Дополнительные знаки после запятой отбрасываются независимо от знака.

Поведение TRUNC(число; 0) соответствует INT(число) для положительных чисел, но для отрицательных чисел округление фактически производится в сторону нуля.

Пример

=TRUNC(1.239;2) возвращает значение 1.23. "9" отбрасывается.

=TRUNC(-1.234999;3) возвращает значение -1,234. Все "9" отбрасываются.