Função MÉDIA.SE

Devolve a média aritmética de todas as células do intervalo que cumprem uma condição. A função MÉDIA.SE soma todos os valores que cumprem a condição e divide essa soma pelo número de valores selecionados.

Sintaxe

MÉDIA.SE(intervalo; critérios; intervalo_média)

intervalo - argumento obrigatório. Consiste numa ou mais células cuja média pretende calcular, incluindo números ou nomes, matrizes ou referências que contenham números.

critérios - obrigatório. Uma condição na forma de expressão ou referência de célula que define as células a utilizar para calcular a média. A expressão pode conter texto, números, expressões regulares (se ativas nas opções de cálculo) e/ou caracteres universais (se ativos nas opções de cálculo).

intervalo_média - argumento opcional. É o conjunto de células do qual pretende obter a média.

Ícone de nota

Se intervalo_média não for especificado, será utilizado intervalo para o cálculo da média e para o critério de pesquisa. Se intervalo_média for especificado, intervalo será utilizado para o teste do critério e intervalo_média será utilizado para calcular a média.
O critério necessita de ser uma expressão de texto, mais concretamente, critérios tem de escrito com aspas ("critérios"), a menos que utilize nomes de funções, referências a células, ou uma concatenação (&).


Ícone de nota

Esta função é parte integrante da norma Open Document Format for Office Applications (OpenDocument), versão 1.2 (ISO/IEC 26300:2-2015).


Ícone de aviso

Se uma célula do intervalo estiver vazia ou contiver texto, a função MÉDIA.SE ignora essa célula.
Se todo o intervalo estiver vazio, apenas contiver texto, ou nenhum dos valores cumpre os critérios (ou uma combinação de qualquer uma das anteriores), a função devolve o erro #DIV/0!.


Exemplos

Considere a seguinte tabela

A

B

C

1

Nome do produto

Vendas

Rendimento

2

pencil

20

65

3

pen

35

85

4

caderno

20

190

5

book

17

180

6

pencil-case

não

não


Ícone de aviso

In all examples below, ranges for calculation contain the row #6, which is ignored because it contains text.


Ícone de aviso

Em todos os cálculos abaixo, o intervalo para calcular a média contém a linha #6, mas esta será ignorada porque contém texto.


Utilização

=MÉDIA.SE(B2:B6;"<35")

Calcula a média dos valores no intervalo B2:B6 que sejam inferiores a 35. Devolve 19, uma vez que a segunda linha não participa no cálculo.

=MÉDIA.SE(B2:B6;"<"&MÁXIMO(B2:B6))

Calcula a média dos valores do intervalo B2:B6 que sejam inferiores ao valor máximo do intervalo. Devolve 19, uma vez que o maior valor do intervalo (segunda linha) não participa no cálculo.

=MÉDIA.SE(B2:B6;">"&MENOR(B2:B6;1))

Calcula a média dos valores no intervalo B2:B6 que sejam superiores ao menor valor do intervalo. Devolve 25, uma vez que o menor valor (segunda linha) não participa no cálculo.

Utilização de intervalo_média

=MÉDIA.SE(B2:B6;"<35";C2:C6)

A função pesquisa que valores do intervalo B2:B6 são inferiores a a 35 e calcula a média dos valores correspondentes no intervalo C2:C6. Devolve 145, uma vez que a segunda linha não participa no cálculo.

=MÉDIA.SE(B2:B6;">"&MÍNIMO(B2:B6);C2:C6)

A função pesquisa que valores do intervalo B2:B6 são superiores ao menor valor do intervalo B2:B6 e calcula a média dos valores correspondentes no intervalo C2:C6. Devolve 113,3, uma vez que a quarta linha (linha em que está o menor valor) não participa no cálculo.

=MÉDIA.SE(B2:B6;"<"&MAIOR(B2:B6;2);C2:C6)

A função pesquisa que valores do intervalo B2:B6 são inferiores ao segundo maior valor do intervalo B2:B6 e calcula a média dos valores correspondentes no intervalo C2:C6. Devolve 180, uma vez que apenas a quarta linha participa no cálculo.

Utilizar expressões regulares

=MÉDIA.SE(A2:A6;"pen";B2:B6)

A função procura as células do intervalo A2:A6 que apenas contenham a palavra “pen” e calcula a média dos valores correspondentes no intervalo B2:B6. Devolve 35, porque apenas a segunda linha participa nos cálculos.. A procura é efetuada no intervalo A2:A6, mas os valores devolvidos pertencem ao intervalo B2:B6.

=MÉDIA.SE(A2:A6;"pen.*";B2:B6)

A função procura as células do intervalo A2:A6 que se iniciem com “pen” e que terminem com quaisquer outros caracteres, calculando a média dos correspondentes valores no intervalo B2:B6. Devolve 27,5 porque agora também “pencil” satisfaz a condição, o que faz com que a segunda linha também entre no cálculo.

=MÉDIA.SE(A2:A6;".*book.*";B2:B6)

A função procura as células do intervalo A2:A6 que iniciem com “book” e que terminem com qualquer outro carácter e calcula a média dos valores correspondentes no intervalo B2:B6. Devolve 18,5 porque apenas a terceira e a quarta linha participam no cálculo.

Referência a uma célula como critério

Se quiser alterar o critério facilmente, pode especificar o critério numa célula distinta e utilizar uma referência à célula como condição da função MÉDIA.SE.

=MÉDIA.SE(A2:A6;".*"&E2&".*";B2:B6)

A função procura as células do intervalo A2:A6 que contenham a combinação de caracteres especificados em E2 (iniciando ou terminando com outras combinações de caracteres) e calcula a média dos valores correspondentes do intervalo B2:B6. Se E2 = book, a função devolve 18,5.

=MÉDIA.SE(B2:B6;"<"&E2;C2:C6)

A função procura que células do intervalo A2:A6 possuem um valor inferior ao especificado em E2 e calcula a média dos valores correspondentes no intervalo B2:B6. Se E2=35, a função devolve 145.