Funções de informação
Esta categoria contém as funções de Informação.
Os dados da tabela seguinte servem de base para alguns dos exemplos das descrições de funções:
C |
D |
|
2 |
valor x |
valor y |
3 |
-5 |
-3 |
4 |
-2 |
0 |
5 |
-1 |
1 |
6 |
0 |
3 |
7 |
2 |
4 |
8 |
4 |
6 |
9 |
6 |
8 |
ATUAL
Esta função devolve o resultado à data da avaliação da fórmula à qual esta pertence (ou seja, o resultado no âmbito máximo dessa avaliação). É utilizada principalmente em conjunto com a função ESTILO(), para aplicar os estilos selecionados a uma célula consoante o seu conteúdo.
Sintaxe
ATUAL()
Exemplo
=1+2+ATUAL()
O exemplo devolve 6. A fórmula é calculada da esquerda para a direita da seguinte forma: 1 + 2 é igual a 3, fornecendo o resultado à data quando ATUAL() é detetado. Assim, ATUAL() devolve 3, que é adicionado ao 3 original de forma a obter 6.
=A2+B2+ESTILO(SE(ATUAL()>10;”Vermelho”;”Padrão”))
O exemplo devolve A2 + B2 (ESTILO devolve 0 aqui). Se esta soma for maior que 10, o estilo Vermelho é aplicado à célula. Consulte a função ESTILO para obter mais esclarecimentos.
="choo"&ATUAL()
O exemplo devolve choochoo.
CÉL
Devolve informações sobre o endereço, formatação ou conteúdo de uma célula.
Sintaxe
CÉL("tipo_info"; referência)
tipo_info é o texto que especifica o tipo de informação da célula que pretende devolver. A cadeia de caracteres é sempre em inglês. A utilização de maiúsculas ou minúsculas é opcional.
tipo_info |
Significado |
COL |
Devolve o número da coluna referenciada. =CÉL("COL";D2) devolve 4. |
ROW |
Devolve o número da linha referenciada. =CÉL("LIN";D2) devolve 2. |
SHEET |
Devolve o número da folha referenciada. =CÉL("Folha";Folha3.D2) devolve 3. |
ADDRESS |
Devolve o endereço absoluto da célula referenciada. =CÉL("ENDEREÇO";D2) devolve $D$2. =CÉL("ENDEREÇO";Folha3.D2) devolve $Folha3.$D$2. =CÉLULA("ENDEREÇO";'X:\dr\teste.ods'#$Folha1.D2) devolve 'file:///X:/dr/teste.ods'#$Folha1.$D$2. |
FILENAME |
Devolve o nome de ficheiro e o número de folha da célula referenciada. =CÉLULA("FILENAME";D2) devolve 'file:///X:/dr/own.ods'#$Folha1, se a fórmula do documento X:\dr\own.ods estiver localizada na Folha1. =CÉLULA("FILENAME";'X:\dr\test.ods'#$Folha1.D2) devolve 'file:///X:/dr/test.ods'#$Folha1. |
COORD |
Devolve o endereço completo da célula em notação Lotus™. =CÉL("COORD"; D2) devolve $A:$D$2. =CÉL("COORD"; Folha3.D2) devolve $C:$D$2. |
CONTENTS |
Devolve o conteúdo da célula referenciada, sem qualquer formatação. |
TYPE |
Devolve o tipo de conteúdo da célula. b = blank. Célula vazia l = label. Texto, resultado de uma fórmula na forma de texto v = value. Valor, resultado de uma fórmula na forma de número |
WIDTH |
Devolve a largura da coluna referenciada. A unidade corresponde ao número de zeros (0) que podem ser colocados dentro da coluna com o texto e o tamanho padrão. |
PREFIX |
Devolve o alinhamento da célula referenciada. ' = alinhar à esquerda ou justificado à esquerda " = alinhar à direita ^ = centrado \ = repetir (atualmente inativo) |
PROTECT |
Devolve o estado da proteção da célula. 1 = a célula está protegida 0 = a célula não está protegida |
FORMAT |
Devolve uma cadeia de caracteres que indica o formato do número. , = número com separador de milhares F = número sem separador de milhares C = formato monetário S = representação exponencial, por exemplo, 1,234+E56 P = percentagem Nos formatos acima, o número de casas decimais é mostrado na forma de número. Exemplo: o formato de número # ##0,0 devolve ,1 e o formato de número 00,000% devolve P3 D1 = MMM-D-AA, MM-D-AA e formatos semelhantes D2 = DD-MM D3 = MM-AA D4 = DD-MM-AAAA HH:MM:SS D5 = MM-DD D6 = HH:MM:SS AM/PM D7 = HH:MM D8 = HH:MM:SS D9 = HH:MM G = Todos os outros formatos - (Menos) no fim = os números negativos são formatados a cor () (parênteses) no fim = existe um parêntese de abertura no código de formatação |
COLOR |
Devolve 1 caso tenham sido formatados a cores valores negativos, caso contrário devolve 0. |
PARENTHESES |
Devolve 1 se o código de formatação tiver um parêntese de abertura "(", caso contrário devolve 0. |
referência (lista de opções) corresponde à posição da célula que será examinada. Se a Referência for um intervalo, a célula será transferida para o canto superior esquerdo do intervalo. Se faltar a Referência, o LibreOffice Calc utiliza a posição da célula na qual esta fórmula está localizada. O Microsoft Excel utiliza a referência da célula na qual o cursor está localizado.
FÓRMULA
Devolve a fórmula de uma célula como cadeia de texto.
Sintaxe
FÓRMULA(referência)
referência é à referência a uma célula que possua a fórmula.
Uma referência inválida ou uma referência a uma célula que não contenha uma fórmula resultará no valor de erro #N/D.
Exemplo
Se a célula A8 incluir a fórmula =SOMA(1;2;3) então
=FÓRMULA(A8) devolve o texto =SOMA(1;2;3).
INFO
Devolve informações específicas sobre o ambiente de trabalho atual. A função recebe um único argumento de texto e devolve os dados dependendo desse parâmetro.
Sintaxe
INFO("texto")
A tabela seguinte lista os valores para o parâmetro texto e os valores de retorno da função INFO.
Valor para "texto" |
Valor devolvido |
"osversion" |
Sempre "Windows (32-bit) NT 5.01", por questões de compatibilidade |
"system" |
O tipo do sistema operativo. |
"release" |
O identificador de edição do produto, por exemplo "300m25(Build:9876)" |
"numfile" |
Sempre 1, por questões de compatibilidade |
"recalc" |
Modo de recalcular a fórmula atual, "Automático" ou "Manual" (localizada no idioma do LibreOffice) |
Outras aplicações de folha de cálculo podem aceitar valores localizados para o parâmetro Tipo, mas o LibreOffice Calc apenas aceita os valores em inglês.
Exemplo
=INFO("release") devolve o número de edição do produto LibreOffice em utilização.
=INFO(D5) com a célula D5 contendo uma cadeia de texto system, devolve o tipo de sistema operativo.
N
Converte um valor em número. Devolve 0 se o parâmetro for um texto ou FALSO.
Se existir um erro, a função devolve o valor de erro.
Sintaxe
N(valor)
valor é o parâmetro a converter em número. N() devolve o valor numérico, se possível. Devolve os valores VERDADEIRO ou FALSO como 1 e 0, respetivamente. Se valor for texto devolve 0.
Exemplo
=N(123) devolve 123
=N(VERDADEIRO()) devolve 1
=N(FALSO()) devolve 0
=N("abc") devolve 0
=N(1/0) devolve #DIV/0!
NÃO.DISP
Devolve o valor de erro #N/D.
Sintaxe
NÃO.DISP()
Exemplo
=NÃO.DISP() converte o conteúdo da célula em #N/D.
SE.ERRO
Devolve o valor se a célula não tiver um erro ou o valor alternativo se existir erro.
Sintaxe
SE.ERRO(valor;valor_alternativo)
valor é o valor ou expressão a devolver se valor não for nem resultar em erro.
valor_alternativo é o valor ou expressão a devolver se valor for ou resultar num erro.
Exemplo
=SE.ERRO(C8;C9) em que a célula C8 contém =1/0 devolve o valor de C9, uma vez que 1/0 é um erro.
=SE.ERRO(C8;C9) em que a célula C8 contém 13 devolve 13, que é o valor da célula C8 e que não é um erro.
SE.ND
Devolve um valor se a célula não contiver o erro #N/D (valor indisponível) ou o valor alternativo se o contiver.
Sintaxe
SE.ND(valor;valor_alternativo)
valor é o valor ou expressão a devolver se valor não for nem resultar em um erro #N/D.
valor_alternativo é o valor ou expressão a devolver se valor for ou resultar em erro #N/D.
Exemplo
=SE.ND(D3;D4) devolve o valor de D3, se D3 não for ou resultar num erro #N/D. Caso constrário, devolve o valor de D4.
TIPO
Devolve o tipo de dados do valor, em que 1 = número, 2 = texto, 4 = booleano, 8 = fórmula, 16 = valor de erro e 64 = matriz.
Sintaxe
TIPO(valor)
valor é um valor específico para o qual é determinado o tipo de dados.
Exemplo (consulte a tabela de exemplo acima)
=TIPO(C2) devolve 2 como resultado.
=TIPO(D9) devolve 1 como resultado.
É.CÉL.VAZIA
Devolve VERDADEIRO se a referência a uma célula estiver vazia. Esta função é utilizada para determinar se o conteúdo de uma célula está ou não vazio. Uma célula que possua uma fórmula não está vazia.
Sintaxe
É.CÉL.VAZIA(valor)
valor é o conteúdo que será testado.
Exemplo
=É.CÉL.VAZIA(D2) devolve FALSO como resultado.
É.ERRO
Testa se há condições de erro, exceto o valor de erro #N/D, e devolve VERDADEIRO ou FALSO.
Sintaxe
É.ERRO(valor)
valor corresponde a qualquer valor ou expressão em que é realizado um teste para determinar se existe um valor de erro diferente de #N/D.
Exemplo
=É.ERRO(C8), em que a célula C8 contém =1/0 devolve VERDADEIRO, uma vez que 1/0 corresponde a um erro.
=É.ERRO(C9), em que a célula C9 contém =NÃO.DISP() devolve FALSO, uma vez que É.ERRO() ignora o erro #N/D.
É.ERROS
Testa condições de erro, incluindo o valor de erro #N/D, e devolve VERDADEIRO ou FALSO.
Sintaxe
É.ERROS(valor)
valor é o valor ou referência a ser testada. A função É.ERROS() devolve VERDADEIRO se existir um erro e FALSO se não existir.
Exemplo
=É.ERROS(C8), em que a célula C8 contém =1/0 devolve VERDADEIRO, uma vez que 1/0 corresponde a um erro.
=É.ERROS(C9), em que a célula C9 contém =NÃO.DISP() devolve VERDADEIRO.
É.LÓGICO
Testa um valor lógico (VERDADEIRO ou FALSO).
Se existir um erro, a função devolve FALSO.
Sintaxe
É.LÓGICO(valor)
Devolve VERDADEIRO se valor for um valor lógico (VERDADEIRO ou FALSO) e devolve FALSO se não for.
Exemplo
=É.LÓGICO(99) devolve FALSO, uma vez que 99 é um número e não um valor lógico.
=É.LÓGICO(É.NÃO.DISP(D4)) devolve VERDADEIRO independentemente do conteúdo da célula D4, uma vez que É.NÃO.DISP() devolve um valor lógico.
É.NÃO.DISP
Devolve VERDADEIRO se uma célula contiver o valor de erro #N/D (valor não disponível).
Se existir um erro, a função devolve FALSO.
Sintaxe
É.NÃO.DISP(valor)
valor é o valor ou expressão que será testada.
Exemplo
=É.NÃO.DISP(D3) devolve FALSO como resultado.
É.NÃO.TEXTO
Efetua um teste que verifica se o conteúdo da célula corresponde a números ou texto, e devolve FALSO se o conteúdo for texto.
Se existir um erro, a função devolve VERDADEIRO.
Sintaxe
É.NÃO.TEXTO(valor)
valor é qualquer valor ou expressão onde é realizado um teste de forma a determinar se se trata de um de texto, ou números ou de um valor booleano.
Exemplo
=É.NÃO.TEXTO(D2) devolve FALSO, se a célula D2 incluir o texto abcdef.
=É.NÃO.TEXTO(D9) devolve VERDADEIRO, se a célula D9 incluir o número 8.
É.NÚM
Devolve VERDADEIRO se o valor for referente a um número.
Sintaxe
É.NÚM(valor)
valor é qualquer expressão que será testada de forma a determinar se a mesma se trata de um número ou de texto.
Exemplo
=É.NÚM(C3) devolve VERDADEIRO, se a célula C3 incluir o número 4.
=É.NÚM(C2) devolve FALSO, se a célula C2 incluir o texto abcdef.
É.REF
Testa se o argumento é uma referência. Devolve VERDADEIRO se o argumento for uma referência ou FALSO se não o for. Quando recebe uma referência, a função não examina o valor ao qual está a ser feita referência.
Sintaxe
É.REF(valor)
valor é o valor que será testado para determinar se é uma referência.
Exemplo
=É.REF(C5) devolve o resultado VERDADEIRO, uma vez que C5 é uma referência válida.
=É.REF("abcdef") devolve sempre FALSO, uma vez que um texto nunca pode ser uma referência.
=É.REF(4) devolve FALSO.
=É.REF(INDIRETO("A6")) devolve VERDADEIRO, uma vez que INDIRETO corresponde a uma função que devolve uma referência.
=É.REF(ENDEREÇO(1; 1; 2;"Folha2")) devolve FALSO, uma vez que ENDEREÇO corresponde a uma função que devolve um texto, embora pareça uma referência.
É.TEXTO
Devolve VERDADEIRO se o conteúdo da célula for referente a texto.
Se existir um erro, a função devolve FALSO.
Sintaxe
É.TEXTO(valor)
valor é o valor, número, valor booleano ou valor de erro que será testado.
Exemplo
=É.TEXTO(D9) devolve VERDADEIRO, se a célula D9 incluir o texto abcdef.
=É.TEXTO(C3) devolve FALSO, se a célula C3 incluir o número 3.
ÉFÓRMULA
Devolve VERDADEIRO se uma célula for uma célula de fórmula.
Sintaxe
ÉFÓRMULA(referência)
referência indica a referência a uma célula na qual será realizado um teste de forma a determinar se a célula contém uma fórmula.
Exemplo
=ÉFÓRMULA(C4) devolve FALSO, se a célula C4 incluir o número 5.
ÉPAR
Devolve VERDADEIRO se o valor for um número inteiro par, ou FALSO se o valor for ímpar.
Sintaxe
ÉPAR(valor)
valor é o valor que será verificado.
Se o valor não for for um número inteiro, quaisquer dígitos após a vírgula decimal serão ignorados. O sinal do valor também será ignorado.
Exemplo
=ÉPAR(48) devolve VERDADEIRO
=ÉPAR(33) devolve FALSO
=ÉPAR(0) devolve VERDADEIRO
=ÉPAR(-2,1) devolve VERDADEIRO
=ÉPAR(3,999) devolve FALSO
ÉPAR_ADD
Efetua um teste de números pares. Devolve 1 se o número devolver um número inteiro ao ser dividido por 2.
Sintaxe
ÉPAR_ADD(número)
número é o número a ser testado.
Exemplo
=ÉPAR_ADD(5) devolve 0.
=ÉPAR_ADD(A1) devolve 1 se a célula A1 incluir o número 2.
ÉÍMPAR
Devolve VERDADEIRO se o valor for ímpar, ou FALSO se o número for par.
Sintaxe
ÉÍMPAR(valor)
valor é o valor que será verificado.
Se o valor não for for um número inteiro, quaisquer dígitos após a vírgula decimal serão ignorados. O sinal do valor também será ignorado.
Exemplo
=ÉÍMPAR(33) devolve VERDADEIRO
=ÉÍMPAR(48) devolve FALSO
=ÉÍMPAR(3,999) devolve VERDADEIRO
=ÉÍMPAR(-3,1) devolve VERDADEIRO
ÉÍMPAR_ADD
Devolve VERDADEIRO (1) se o número não devolver um número inteiro ao ser dividido por 2.
Sintaxe
ÉÍMPAR_ADD(número)
número é o número a ser testado.
Exemplo
=ÉÍMPAR_ADD(5) devolve 1.