Funções de texto
Essa seção contém descrições das funções de Texto.
ARRUMAR
Remove os espaços de uma cadeia de caracteres, deixando apenas um único caractere de espaço entre as palavras.
Sintaxe
ARRUMAR("Texto")
Texto refere-se ao texto com espaços removidos.
Exemplo
ARRUMAR(" Olá mundo ") devolve Olá mundo, sem os espaços antes e depois do texto e com apenas um espaço entre as palavras.
ASC
A função ASC converte caracteres ASCII e katakana de largura inteira para meia largura. Retorna um texto.
Consulte https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions para ver a tabela de conversões.
Sintaxe
ASC("Texto")
Texto é o texto que contém os caracteres a converter.
Veja também a função JIS.
BAHTTEXT
Converte um número em texto tailandês, incluindo nomes da moeda tailandesa.
Sintaxe
BAHTTEXT(Número)
Número é qualquer número. "Baht" será anexado à parte integral do número, e "Satang" será anexado à parte decimal do número.
Exemplo
=BAHTTEXT(12.65) retorna um texto em caracteres tailandeses significando "Doze Baht e sessenta e cinco Satang".
BASE
Converte um número inteiro positivo para uma base específica em um texto a partir do sistema de numeração. São usados os dígitos 0–9 e as letras A–Z.
Sintaxe
BASE(Número; Radical; [TamanhoMínimo])
Número é o inteiro positivo a converter.
Radical indica a base do sistema de numeração. Pode ser qualquer inteiro positivo entre 2 e 36.
TamanhoMínimo (opcional) determina o tamanho mínimo da cadeia de caracteres criada. Se o texto for mais curto que o indicado em TamanhoMínimo, zeros são adicionados à esquerda do texto.
Exemplo
=BASE(17;10;4) retorna 0017 no sistema decimal.
=BASE(17;2) retorna 10001 no sistema binário.
=BASE(255;16;4) retorna 00FF no sistema hexadecimal.
CARACT
Converte um número em um caractere de acordo com a tabela de código atual. O número pode ser um inteiro de dois ou três dígitos.
Sintaxe
CARACT(Número)
Número é um número entre 1 e 255 representando o código do caractere.
Exemplo
=CARACT(100) retorna o caractere «d».
="abc" & CHAR(10) & "def" insere um caractere de nova linha em uma cadeia de caracteres.
CARACT.UNICODE
Converte um número de código em um caractere Unicode ou letra.
Sintaxe
CARACT.UNICODE(número)
Exemplo
=CARACT.UNICODE(169) retornará o caractere de Copyright ©.
Veja também a função UNICODE().
CONCATENAR
Combina várias cadeias de caracteres de texto em apenas uma cadeia de caracteres.
Sintaxe
CONCATENAR("Texto1"; ...; "Texto30")
Texto 1; Texto 2; ... representa até 30 trechos de texto que serão combinados num só texto.
Exemplo
=CONCATENAR("Bom ";"dia ";"Dona ";"Maria") retorna: Bom dia Dona Maria.
CÓDIGO
Retorna um código numérico para o primeiro caractere em uma cadeia de caracteres de texto.
Sintaxe
CÓDIGO("Texto")
Texto é o texto onde o código do primeiro caractere será encontrado.
Exemplo
=CÓDIGO("Hieronymus") retorna 72, =CÓDIGO("hieroglyphic") retorna 104.
O código utilizado aqui não se refere ao ASCII, mas à tabela de códigos carregada no momento.
DECIMAL
Converte texto com caracteres de um sistema de numeração para um inteiro positivo na base do radical. O radical deve estar entre 2 e 36. Espaços e tabulações serão ignorados. O campo Texto não é sensível à caixa.
Se o radical for 16, serão ignorados x, 0x, X ou 0X anteriores ao número e h ou H posteriores ao número. Se o radical for 2, serão ignorados b ou B posteriores ao número. Caracteres que não pertencem ao sistema de numeração geram um erro.
Sintaxe
DECIMAL("Texto"; Radical)
Texto é o texto a converter. Para diferenciar entre um número hexadecimal, tal como A1 e a referência à célula A1, você deve colocar o número entre aspas, por exemplo, "A1" ou "FACE".
Radical indica a base do sistema de numeração. Pode ser qualquer inteiro positivo entre 2 e 36.
Exemplo
=DECIMAL("17";10) retorna 17.
=DECIMAL("FACE";16) retorna 64206.
=DECIMAL("0101";2) retorna 5.
DEF.NÚM.DEC
Retorna um número como texto com um número determinado de casas decimais e separadores de milhar opcionais.
Sintaxe
DEF.NÚM.DEC(Número; Decimais; SemSeparadorDeMilhar)
Número refere-se ao número que será formatado.
Decimais refere-se ao número de casas decimais que serão exibidas.
SemSeparadorDeMilhar (opcional) determina se o separador de milhar será utilizado. Se o parâmetro for um número diferente de zero, o separador de milhar será suprimido. Se o separador for zero ou se faltar, o separador de milhar de sua configuração atual de locale será exibido.
Exemplo
=DEF.NÚM.DEC(1234567,89;3) retorna 1.234.567,890 como um texto.
=DEF.NÚM.DEC(1234567.89;3;1) retorna 1234567.890 como um texto.
DIREITA
Retorna o último caractere ou caracteres de um texto.
Sintaxe
DIREITA("Texto"; Número)
Texto é o texto cuja parte direita será determinada.
Número (opcional) é o número de caracteres da parte direita do texto.
Exemplo
=DIREITA("Sun";2) retorna un.
DIREITAB
Retorna o último caractere ou caracteres dum texto com DBCS (conjunto de caracteres de bytes duplos).
Sintaxe
DIREITAB("Texto"; Número)
Texto é o texto em que a parte direita será determinada.
número (opcional) especifica o número de caracteres a retornar pela função DIREITAB, em bytes.
Exemplos
DIREITAB("中国";1) retorna " " (1 byte é só metade de um caractere DBCS e um caractere de espaço será retornado).
DIREITAB("中国";2) retorna "国" (2 bytes constituem um caractere DBCS completo).
DIREITAB("中国";3) retorna " 国" (3 bytes constituem meio caractere DBCS e um caractere DBCS inteiro, um espaço em branco será retornado para a primeira metade).
DIREITAB("中国";4) retorna "中国" (4 bytes constituem dois caracteres DBCS completos).
DIREITAB("office";3) retorna "ice" (3 caracteres não-DBCS cada um consistindo de 1 byte).
ESQUERDA
Retorna o primeiro caractere ou caracteres de um texto.
Sintaxe
ESQUERDA("Texto"; Número)
Texto é o texto onde as palavras iniciais parciais serão determinadas.
Número (opcional) especifica o número de caracteres do texto inicial. Se o parâmetro estiver ausente, apenas um caractere será retornado.
Exemplo
=ESQUERDA("saída";3) retorna “saí”.
ESQUERDAB
Retorna os primeiros caracteres de um texto em DBCS (conjunto de caracteres de bytes duplos).
Sintaxe
ESQUERDAB("Texto"; Número)
Texto é a cadeia de texto cujas letras iniciais deseja determinar.
Número (opcional) especifica o número de caracteres a extrair com ESQUERDAB, em bytes. Se este parâmetro não for definido, um caractere será retornado.
Exemplos
ESQUERDAB("中国";1) retorna " " (1 byte é só metade de um caractere DBCS e a função retorna um espaço no lugar).
ESQUERDAB("中国";2) retorna "中" (2 bytes constituem um caractere DBCS completo).
ESQUERDAB("中国";3) retorna "中 " (3 bytes constituem um caractere DBCS e meio; o último caractere retornado é portanto um caractere de espaço).
ESQUERDAB("中国";4) retorna "中国" (4 bytes constituem dois caracteres DBCS completos).
ESQUERDAB("office";3) retorna "off" (3 caracteres não-DBCS, cada um consistindo de 1 byte).
EXATO
Compara duas cadeias de caracteres de texto e retorna VERDADEIRO se elas forem idênticas. Esta função faz distinção entre maiúsculas e minúsculas.
Sintaxe
EXATO("Texto1"; "Texto2")
Texto1 refere-se ao primeiro texto da comparação.
Texto2 é o segundo texto para comparar.
Exemplo
=EXATO("microsystems";"Microsystems") retorna FALSO.
EXT.TEXTO
Retorna uma cadeia de caracteres de texto de um texto. Os parâmetros especificam a posição inicial e o número de caracteres.
Sintaxe
EXT.TEXTO("Texto"; Início; Número)
Texto é o texto contendo os caracteres a extrair.
Início é a posição do primeiro caractere no texto a extrair.
Número especifica o número de caracteres na parte do texto.
Exemplo
=EXT.TEXTO("office";2;2) retorna ff.
EXT.TEXTOB
Retorna uma cadeia de caracteres de um texto em DBCS (conjunto de caracteres de bytes duplos). Os parâmetros especificam a posição inicial e o número de caracteres.
Sintaxe
EXT.TEXTOB("Texto"; Início; Número)
Texto é o texto contendo os caracteres a extrair.
Início é a posição do primeiro caractere no texto a extrair.
Número especifica o número de caracteres a retornar do texto, em bytes.
Exemplos
EXT.TEXTOB("中国";1;0) retorna "" (0 bytes é sempre uma cadeia de caracteres vazia).
EXT.TEXTOB("中国";1;1) retorna " " (1 byte é só meio caractere DBCS e, portanto, o resultado é um caractere de espaço).
EXT.TEXTOB("中国";1;2) retorna "中" (2 bytes constituem um caractere DBCS completo).
EXT.TEXTOB("中国";1;3) retorna "中 " (3 bytes constituem um caractere DBCS e meio, e o último byte resulta num caractere de espaço).
EXT.TEXTOB("中国";1;4) retorna "中国" (4 bytes constituem dois caracteres DBCS completos).
EXT.TEXTOB("中国";2;1) retorna " " (o byte na posição 2 não está no início de um caractere de uma cadeia DBCS; retorna 1 caractere de espaço).
EXT.TEXTOB("中国";2;2) retorna " " (o byte na posição 2 aponta para a última metade do primeiro caractere na cadeia DBCS; os dois bytes demandados constituem o último byte do primeiro caractere e a primeira metade do segundo caractere na cadeia; dois caracteres de espaço são então retornados).
EXT.TEXTOB("中国";2;3) retorna " 国" (o byte na posição 2 não está no início de um caractere numa cadeia DBCS; retorna um espaço para o byte na posição 2).
EXT.TEXTOB("中国";3;1) retorna " " (o byte na posição 3 está no começo de um caractere numa cadeia DBCS, mas 1 byte é somente metade de um caractere DBCS e um espaço será retornado em seu lugar).
EXT.TEXTOB("中国";3;2) retorna "国" (o byte na posição 3 está no começo de um caractere numa cadeia DBCS, e 2 bytes constituem um caractere DBCS).
EXT.TEXTOB("office";2;3) retorna "ffi" (o byte na posição 2 está no começo de um caractere numa cadeia que não é DBCS, e 3 bytes de uma cadeia não-DBCS constituem 3 caracteres).
JIS
A função JIS converte caracteres ASCII e katakana de meia largura para largura inteira. Retorna um texto.
Consulte https://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions para ver a tabela de conversões.
Sintaxe
JIS("Texto")
Texto é o texto que contém os caracteres a converter.
Veja também a função ASC.
MAIÚSCULA
Converte a cadeia de caracteres especificada no campo texto em letras maiúsculas.
Sintaxe
MAIÚSCULAS("Texto")
Texto refere-se às letras minúsculas que deseja converter em maiúsculas.
Exemplo
=MAIÚSCULA("Bom dia") retorna BOM DIA.
MINÚSCULA
Converte todas as letras maiúsculas de uma cadeia de caracteres de texto em letras minúsculas.
Sintaxe
MINÚSCULAS("Texto")
Texto refere-se ao texto a ser convertido.
Exemplo
=MINÚSCULA("Sun") retorna sun.
MOEDA
Converte um número para um valor em formato monetário, arredondado para a casa decimal especificada. No campo Valor entre o número a converter em moeda. Opcionalmente, você pode inserir a quantidade de casas decimais no campo Decimais. Se não houver valor especificado, todos os números em formato monetário serão exibidos com duas casas decimais.
Você define o formato monetário nas configurações do seu sistema.
Sintaxe
MOEDA(Valor; Decimais)
Valor é um número, uma referência a uma célula contendo um número, ou uma fórmula que retorna um número.
Decimais é o número opcional de casas decimais.
Exemplo
=MOEDA(255) retorna $255,00.
=MOEDA(367.456;2) retorna $367,46. Utilize o separador decimal que corresponde a definição da locale atual.
MUDAR
Substitui parte de uma cadeia de caracteres de texto por uma cadeia de caracteres de texto diferente. Esta função pode ser usada para substituir caracteres e números (que são automaticamente convertidos para texto). O resultado da função é sempre exibido como texto. Se você pretende executar outros cálculos com um número que foi substituído por texto, você precisará convertê-lo de volta para um número usando a função VALOR.
Todos os textos que contiverem números deverão estar entre aspas se você não desejar que eles sejam interpretados como números e convertidos automaticamente em texto.
Sintaxe
MUDAR("Texto"; Posição; Tamanho; "NovoTexto")
Texto refere-se ao texto no qual uma parte será substituída.
Posição refere-se à posição dentro do texto onde a substituição começa.
Tamanho é o número de caracteres no Texto a substituir.
NovoTexto refere-se ao texto que substitui Texto.
Exemplo
=MUDAR("1234567";1;1;"444") retorna "444234567". Um caractere na posição 1 é a substituído pelo texto NovoTexto.
NÚM.CARACT
Retorna o tamanho da cadeia de caracteres incluindo espaços.
Sintaxe
NÚM.CARACT("Texto")
Texto é o texto cujo tamanho será determinado.
Exemplo
=NÚM.CARACT("Boa tarde") retorna 9.
=NÚM.CARACT(12345.67) retorna 8.
NÚM.CARACTB
Para idiomas em DBCS (conjunto de caracteres em duplo byte), retorna o número de bytes usados para representar os caracteres num texto.
Sintaxe
NÚM.CARACTB("Texto")
Texto é o texto cujo tamanho será determinado.
Exemplos
NÚM.CARACTB("中") retorna 2 (1 caractere DBCS consistindo de 2 bytes).
NÚM.CARACTB("中国") retorna 4 (2 caracteres DBCS cada um consistindo de 2 bytes).
NÚM.CARACTB("office") retorna 6 (6 caracteres não-DBCS cada um consistindo de 1 byte).
=NÚM.CARACTB("Boa tarde") retorna 9.
=NÚM.CARACTB(12345.67) retorna 8.
PESQUISAR
Retorna a posição de um segmento de texto dentro de uma cadeia de caracteres. Você pode definir o início da pesquisa como uma opção. O texto de pesquisa pode ser um número ou qualquer cadeia de caracteres. A pesquisa não distingue maiúsculas e minúsculas.
Sintaxe
PESQUISAR("ProcurarTexto"; "Texto"; Posição)
ProcurarTexto é o texto a ser localizado.
Texto é o texto onde a pesquisa ocorrerá.
Posição (opcional) é a posição no texto onde a pesquisa deve começar.
Exemplo
=PESQUISAR(54;998877665544) retorna 10.
PRI.MAIÚSCULA
Coloca em maiúscula a primeira letra de cada palavra de uma cadeia de caracteres de texto.
Sintaxe
PRI.MAIÚSCULA("Texto")
Texto refere-se ao texto a ser convertido.
Exemplo
=PRI.MAIÚSCULA("open office") retorna Open Office.
PROCURAR
Retorna a posição de um segmento de texto dentro de uma cadeia de caracteres. Você pode definir o início da pesquisa como uma opção. O texto de pesquisa pode ser um número ou qualquer cadeia de caracteres. A pesquisa não distingue maiúsculas e minúsculas.
Sintaxe
PROCURAR("ProcurarTexto"; "Texto"; Posição)
ProcurarTexto refere-se ao texto a encontrar.
Texto é o texto onde a pesquisa ocorre.
Posição (opcional) é a posição no texto a partir da qual a pesquisa começa.
Exemplo
=PROCURAR(76;998877665544) retorna 6.
REPT
Repete uma cadeia de caracteres pelo número de cópias.
Sintaxe
REPT("Texto"; Número)
Texto é o texto a repetir.
Número é o número de repetições.
O resultado pode ter no máximo 255 caracteres.
Exemplo
=REPT("Bom dia";2) retorna Bom diaBom dia.
ROMANO
Converte um número em algarismos romanos. O intervalo de valores deve ser entre 0 e 3999, os modos podem ser números inteiros de 0 a 4.
Sintaxe
ROMANO(Número; Modo)
Número é o número que será convertido em algarismos romanos.
Modo (opcional) indica o grau de simplificação. Quanto maior for o valor, maior será a simplificação do número romano.
Exemplo
=ROMANO(999) retorna CMXCIX
=ROMANO(999;0) retorna CMXCIX
=ROMANO(999;1) retorna LMVLIV
=ROMANO(999;2) retorna XMIX
=ROMANO(999;3) retorna VMIV
=ROMANO(999;4) retorna IM
SUBSTITUIR
Substitui o texto antigo pelo novo em uma cadeia de caracteres.
Sintaxe
SUBSTITUIR("Texto"; "PesquisarTexto"; "NovoTexto"; Ocorrência)
Texto é o texto no qual os segmentos de texto serão trocados.
PesquisarTexto é o segmento de texto que será substituído (repetidas vezes).
NovoTexto é o texto que deve substituir o trecho de texto.
Ocorrência (opcional) indica qual ocorrência do texto de pesquisa deve ser substituído. Se o parâmetro for omitido, o texto de pesquisa é substituído em todo o texto.
Exemplo
=SUBSTITUIR("123123123";"3";"abc") retorna 12abc12abc12abc.
=SUBSTITUIR("123123123";"3";"abc";2) retorna 12312abc123.
T
Essa função retorna o texto de destino ou uma cadeia de caracteres de texto em branco se o destino não for texto.
Sintaxe
T(Valor)
Se Valor for um texto ou se referir a um texto, T retorna esse texto; caso contrário, ele retorna um texto em branco.
Exemplo
=T(12345) retorna uma cadeia de caracteres vazia.
=T("12345") retorna o texto 12345.
TEXTO
Converte um número em texto de acordo com o formato determinado.
Sintaxe
TEXTO(Número; Formato)
Número é o número que será convertido.
Formato é o texto que define o formato. Utilize separadores de decimal e milhar de acordo com o idioma definido no formato de célula.
Exemplo
=TEXTO(12,34567;"###,##") retorna o texto 12,35
=TEXTO(12,34567;"000,00") retorna o texto 012,35
TIRAR
Todos os caracteres não imprimíveis são removidos da cadeia de caracteres.
Sintaxe
TIRAR("Texto")
Texto refere-se ao texto no qual deve-se remover todos os caracteres não imprimíveis.
UNICODE
Retorna o código numérico para o primeiro caractere Unicode em uma cadeia de caracteres de texto.
Sintaxe
UNICODE("Texto")
Exemplo
=UNICODE("©") retornará o número Unicode 169 para o caractere de Copyright.
Veja também a função CARACT.UNICODE()
VALOR
Converte uma cadeia de caracteres de texto em um número.
Sintaxe
VALOR("Texto")
Texto é o texto a converter em um número.
Exemplo
=VALOR("4321") retorna 4321.
ÁRABE
Calcula o valor de um número romano. O intervalo de valor deve ser entre 0 e 3999.
Sintaxe
ÁRABE("Texto")
Texto é o texto que representa um número romano.
Exemplo
=ÁRABE("MXIV") retorna 1014
=ÁRABE("MMII") retorna 2002