Funções de banco de dados
Essa seção aborda as funções usadas com dados organizados na forma de uma linha de dados de um registro.
A categoria Banco de dados pode ser confundida com um banco de dados integrado no LibreOffice. Todavia, não há ligação entre um banco de dados no LibreOffice e a categoria Banco de dados no LibreOffice Calc.
Dados de exemplo:
Os dados a seguir serão usados em alguns exemplos de descrição das funções:
O intervalo A1:E10 lista as crianças convidadas para o aniversário do Joe. As seguintes informações são fornecidas em cada entrada: a coluna A mostra o nome, a coluna B mostra a série escolar e as demais colunas mostram a idade em anos, a distância até o colégio em metros e o peso em quilogramas.
A |
B |
C |
D |
E |
|
1 |
Nome |
Série |
Idade |
Distância até a Escola |
Peso |
2 |
Andy |
3 |
9 |
150 |
40 |
3 |
Betty |
4 |
10 |
1000 |
42 |
4 |
Charles |
3 |
10 |
300 |
51 |
5 |
Daniel |
5 |
11 |
1200 |
48 |
6 |
Eva |
2 |
8 |
650 |
33 |
7 |
Francisco |
2 |
7 |
300 |
42 |
8 |
Greta |
1 |
7 |
200 |
36 |
9 |
Harry |
3 |
9 |
1200 |
44 |
10 |
Irene |
2 |
8 |
1000 |
42 |
11 |
|||||
12 |
|||||
13 |
Nome |
Série |
Idade |
Distância até a Escola |
Peso |
14 |
>600 |
||||
15 |
|||||
16 |
BDCONTAR |
5 |
A fórmula na célula B16 é =BDCONTAR(A1:E10;D1;A13:E14)
Parâmetros das funções de banco de dados:
Os itens a seguir são definições de parâmetros para todas as funções de banco de dados:
BancoDeDados é o intervalo de células que define o banco de dados.
CampoDoBancoDeDados especifica a coluna onde a função opera após o critério de pesquisa do primeiro parâmetro ser aplicado e as linhas de dados serem selecionadas. Não está relacionado ao critério de pesquisa em si. Para o parâmetro CampoDoBancoDeDados, insira uma referência a uma célula de cabeçalho ou um número para especificar a coluna dentro da área do banco de dados, começando com 1. Para referenciar uma coluna por meio de um nome literal de coluna, coloque sinais de interrogação em torno do nome do cabeçalho.
CritérioDePesquisa é o intervalo de células contendo os critérios de pesquisa. Ao escrever vários critérios na mesma linha, eles serão conectados por um E lógico. Ao escrever os critérios em linhas diferentes, eles serão conectados por um OU lógico. Células vazias no critério de pesquisa serão ignoradas.
Selecione LibreOffice - PreferênciasFerramentas - Opções - LibreOffice Calc - Calcular para definir como o LibreOffice Calc atua ao pesquisar entradas idênticas.
Veja também a página Wiki sobre Contagem condicional e Resumo
BDCONTAR
BDCONTAR conta o número de linhas (registros) em um banco de dados que correspondam aos critérios de pesquisa especificados e contenham valores numéricos na coluna CampoDoBancoDeDados.
Sintaxe
BDCONTAR ( BancoDeDados; [ CampoDoBancoDeDados ]; CritérioDePesquisa )
Se o argumento CampoDoBancoDeDados for omitido, BDCONTAR retorna a contagem de todos os registros que satisfazem o critério de pesquisa. Para o parâmetro CampoDoBancoDeDados, insira uma referência a uma célula de cabeçalho ou um número para especificar a coluna dentro da área do banco de dados, começando com 1. Para referenciar uma coluna por meio de um nome literal de coluna, coloque sinais de interrogação em torno do nome do cabeçalho.
Exemplo
No exemplo acima (role para cima), queremos saber quantas crianças devem viajar mais de 600 metros até a escola. O resultado será armazenado na célula B16. Coloque o cursor na célula B16. Digite a fórmula=BDCONTAR(A1:E10;D1;A13:E14) em B16. O Assistente de função lhe ajuda a inserir os intervalos.
BancoDeDados é o intervalo de dados a avaliar, incluindo seus cabeçalhos: neste caso A1:E10. CampoDoBancoDeDados especifica a coluna para o critério de pesquisa: neste caso, a coluna com os valores numéricos de distância. CritérioDePesquisa é o intervalo de entrada dos parâmetros de busca: neste caso, A13:E14.
Para conhecer quantas crianças do segundo ano tem mais de 7 anos, exclua a entrada >600 na célula D14 e entre 2na célula B14 sob Grau, e entre >7 na célula C14 a direita. O resultado é 2. Duas crianças estão no segundo ano e com mais de 7 anos de idade. Como ambos os critérios estão na mesma linha, eles estão conectados por um E lógico.
BDCONTARA
BDCONTARA conta o número de linhas (registros) em um banco de dados que correspondam às condições de pesquisa especificadas e que contenham valores numéricos ou alfanuméricos.
Sintaxe
BDCONTARA(Banco de Dados; [Campo do banco de dados]; Critérios de pesquisa)
Se o argumento CampoDoBancoDeDados for omitido, BDCONTARA retorna a contagem de todos os registros que satisfazem os critérios. Para o parâmetro CampoDoBancoDeDados, insira uma referência a uma célula de cabeçalho ou um número para especificar a coluna dentro da área do banco de dados, começando com 1. Para referenciar uma coluna por meio de um nome literal de coluna, coloque sinais de interrogação em torno do nome do cabeçalho.
Exemplo
No exemplo acima (role para cima), você pode pesquisar pelo número de crianças cujo nome começa com E ou uma letra subsequente. Edite a fórmula em B16 para =BDCONTARA(A1:E10;"Name";A13:E14). Exclua o critério de pesquisa antigo e digite >=E em Nome no campo A14. O resultado é 5. Se remover todos os valores numéricos para Greta na linha 8, o resultado muda pra 4. A linha 8 não será mais incluída na contagem por que não possui mais valores. O nome Greta é um texto e não um valor. Note que o parâmetro CampoDoBancoDeDados deve apontar para uma coluna que contém valores.
BDDESVPA
BDDESVPA calcula o desvio padrão de uma população com base em todas as células de um intervalo de dados que corresponde aos critérios de pesquisa. Os registros do exemplo são tratados como a população inteira.
Sintaxe
BDDESVPA(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)
Exemplo
Para descobrir o desvio padrão do peso de todas as crianças da mesma idade na festa de aniversário do Joe (role para cima), insira a seguinte fórmula na célula B16:
=BDDESVPA(A1:E10;"Peso";A13:E14)
Na linha 14, sob Idade, entre 7,8,9 e assim por diante, um após o outro. O resultado é o desvio padrão do peso para todas as crianças de mesma idade, cujo peso foi conferido.
BDEST
BDEST calcula o desvio padrão de uma população com base em uma amostra, utilizando os números de uma coluna de banco de dados que correspondam às condições especificadas. Os registros são tratados como uma amostra de dados. Isso significa que as crianças do exemplo representam uma parte de todas as crianças. Note que um resultado representativo não pode ser obtido de uma amostra com menos de mil registros.
Sintaxe
BDEST(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)
Exemplo
Para descobrir o desvio padrão dos pesos de todas as crianças da mesma idade no exemplo (role para cima), insira a seguinte fórmula na célula B16:
=BDEST(A1:E10;"Peso";A13:E14)
Na linha 14, em Idade, digite 7, 8, 9, sucessivamente. O resultado mostrado é o desvio padrão do peso de todas as crianças dessa idade.
BDEXTRAIR
BDEXTRAIR retorna o conteúdo da célula referenciada em um banco de dados que corresponda aos critérios de pesquisa especificados. Em caso de erro, a função retorna #VALOR! quando nenhuma linha for encontrada ou Err502 quando mais de uma célula for encontrada.
Sintaxe
BDEXTRAIR(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)
Exemplo
No exemplo acima (role para cima), queremos determinar em qual série a criança está, cujo nome foi inserido na célula A14. A fórmula é digitada na célula B16 e difere ligeiramente daquelas dos exemplos anteriores porque somente uma coluna (um campo do banco de dados) pode ser inserida para CampoDoBancoDeDados. Digite a seguinte fórmula:
=BDEXTRAIR(A1:E10;"Série";A13:E14)
Digite o nome Frank em A14 e você verá o resultado 2. Frank está na segunda série. Digite "Idade" no lugar de "Série" e você verá a idade de Frank.
Ou entre o valor 11 na célula C14 somente, e exclua as demais entradas nessa linha. Edite a fórmula em B16 como segue:
=BDEXTRAIR(A1:E10;"Nome";A13:E14)
Em vez da série, o nome será consultado. A resposta será exibida imediatamente: Daniel é a única criança com 11 anos de idade.
BDMULTIPL
BDMULTIPL multiplica todas as células de um intervalo de dados cujo conteúdo corresponda aos critérios de pesquisa.
Sintaxe
BDMULTIPL(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)
Exemplo
Com o exemplo da festa de aniversário acima (role para cima), não há nenhuma aplicação importante dessa função.
BDMÁX
BDMÁX retorna o maior valor de célula (campo) em um banco de dados (todos os registros) que corresponda às condições de pesquisa especificadas.
Sintaxe
BDMÁX(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)
Exemplo
Para descobrir o peso da criança mais pesada em cada série no exemplo acima (role para cima), insira a seguinte fórmula na célula B16:
=BDMÁX(A1:E10;"Peso";A13:E14)
Em Série, digite 1, 2, 3, e assim sucessivamente. Depois de digitar um número de série, o peso do aluno mais pesado da série aparece.
BDMÉDIA
BDMÉDIA retorna a média dos valores de todas as células (campos) em todas as linhas (registros de banco de dados) que correspondam aos critérios de pesquisa especificados.
Sintaxe
BDMÉDIA(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)
Exemplo
Para descobrir o peso médio de todas as crianças da mesma idade no exemplo acima (role para cima), insira a seguinte fórmula na célula B16:
=BDMÉDIA(A1:E10;"Peso";A13:E14)
Na linha 14, em Idade, digite 7, 8, 9, sucessivamente. O peso médio de todas as crianças de mesma idade aparece.
BDMÍN
BDMÍN retorna o conteúdo mínimo de uma célula (campo) em um banco de dados que corresponde aos critérios de pesquisa especificados.
Sintaxe
BDMÍN(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)
Exemplo
Para descobrir a menor distância até a escola para as crianças de cada série no exemplo acima (role para cima), insira a seguinte fórmula na célula B16:
=BDMÍN(A1:E10;"Distância até a Escola";A13:E14)
Na linha 14, sob Série, entre 1, 2, 3, e assim por diante, um após o outro. A menor distância da escola para cada série aparece.
BDSOMA
BDSOMA retorna o total de todas as células em todas as linhas (registros) de um campo do banco de dados que correspondam aos critérios de pesquisa especificados.
Sintaxe
BDSOMA(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)
Exemplo
Para descobrir a soma das distâncias até a escola de todas as crianças da festa de aniversário do Joe (role para cima) que estão na segunda série, insira a seguinte fórmula na célula B16:
=BDSOMA(A1:E10;"Distância até a Escola";A13:E14)
Digite 2 na linha 14 em Série. A soma (1950) das distâncias da escola para todos os alunos que estão na segunda série será exibida.
BDVAREST
BDVAREST retorna a variância de todas as células de um banco de dados para todos os registros que correspondam aos critérios de pesquisa especificados. Os registros do exemplo são tratados como uma amostra de dados. Um resultado representativo não pode ser obtido de uma amostra de população com menos de mil registros.
Sintaxe
BDVAREST(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)
Exemplo
Para descobrir a variância do peso de todas as crianças da mesma idade no exemplo acima (role para cima), insira a seguinte fórmula na célula B16:
=BDVAREST(A1:E10;"Peso";A13:E14)
Na linha 14, em Idade, digite 7, 8, 9, sucessivamente. Você verá como resultado a variância dos valores de peso de todas as crianças dessa idade.
BDVARP
BDVARP calcula a variância de todos os valores das células em todos os registros de um banco de dados que correspondam aos critérios de pesquisa especificados. Os registros do exemplo são tratados como uma população inteira.
Sintaxe
BDVARP(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)
Exemplo
Para descobrir a diferença de peso de todas as crianças da mesma idade na festa de aniversário do João (role para cima), insira a seguinte fórmula na célula B16:
=BDVARP(A1:E10;"Peso";A13:E14)
Na linha 14, sob Idade, digite 7, 8, 9, e assim por diante, um após outro. A diferença do valor do peso para todas as crianças dessa idade presentes à festa de aniversário do Joe aparece.