LICZ.WARUNKI function

Zwraca liczbę komórek, które spełniają kryteria w wielokrotności zakresów.

Składnia

LICZ.WARUNKI(Zakres1; Kryterium1 [; Zakres2; Kryterium2 [; ...]])

Zakres1 – argument wymagany. Zakres komórek, nazwa nazwanego zakresu lub etykieta kolumny, lub wiersz zawierający wartości do zliczenia i znalezienia odpowiadającego kryterium.

Criterion1 – required argument. A string expression representing a logical condition or a cell reference to such string expression. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

Zakres2 – Opcjonalnie. Zakres2 i wszystkie następujące oznaczają to samo co Zakres1.

Kryterium2 – opcjonalne. Kryterium2 i wszystkie następujące oznaczają to samo jak Kryterium1.

Ikona ostrzeżenia

Zakres1, zakres2,... i kryterium1, kryterium2, ... muszą mieć ten sam rozmiar, w przeciwym przypadku funkcja zwróci Błąd:502 - nieprawidłowy argument.


Ikona notatki

The logical relation between criteria can be defined as logical AND (conjunction). In other words, if and only if all given criteria are met, a value from the corresponding cell of the given Func_Range is taken into calculation.


Ta funkcja może mieć do 255 argumentów, co oznacza, że ​​można podać 127 zakresów kryteriów i kryteriów dla nich.

Ikona ostrzeżenia

Jeśli komórka zawiera PRAWDA, jest traktowana jak 1. Jeśli zawiera FAŁSZ – jak 0 (zero).


Ikona notatki

Funkcja ta jest częścią standardu Open Document Format for Office Applications (OpenDocument) w wersji 1.2. (ISO/IEC 26300:2-2015)


Przykłady

Poniżej opisano działanie tego pola na tabeli

A

B

C

1

Nazwa produktu

Sprzedaże

Przychód

2

ołówek

20

65

3

ołów

35

85

4

notes

20

190

5

książka

17

180

6

piórnik

nie

nie


Ikona ostrzeżenia

We wszystkich przykładach poniżej, zakresy dla sumy obliczeń zawierają wiersz #6, który jest ignorowany, ponieważ zawiera tekst.


Proste użycie

=LICZ.WARUNKI(B2:B6;">=20")

Oblicza ilość wierszy z zakresu B2:B6 z wartościami większymi niż lub równymi do 20. Zwraca 3, ponieważ piąty i szósty wiersz nie spełniają kryterium.

=LICZ.WARUNKI(B2:B6;">=20";C2:C6;">70")

Oblicza ilość wierszy zawierających jednocześnie wartości większe niż 70 w zakresie C2:C6 oraz wartości większe niż lub równe do 20 w zakresie B2:B6.Zwraca 2, ponieważ drugi, piąty i szósty wiersz nie nie spełniają co najmniej jednego kryterium.

Użycie wyrażeń regularnych i funkcji zagnieżdżonych

=LICZ.WARUNKI(B2:B6;"[:alfa:]*")

Oblicza ilość wierszy z zakresu B2:B6, które zawierają wyłącznie symbole alfabetu. Zwraca 1, ponieważ tylko szósty wiersz spełnia kryterium.

=LICZ.WARUNKI(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAKS(B2:B6))

Oblicza ilość wierszy z zakresu B2:B6, wyłączając wiersze z minimalnymi i maksymalnymi wartościami tego zakresu. Zwraca 2, ponieważ trzeci, piąty i szósty wiersz nie spełniają co najmniej jednego kryterium.

=LICZ.WARUNKI(A2:A6;"ołów.*";B2:B6;"<"&MAKS(B2:B6))

Oblicza ilość wierszy, które odpowiadają wszystkim komórkom z zakresu A2:A6 zaczynającym się od słowa "ołów" i do wszystkich komórek z zakresu B2:B6, oprócz ich maksimum. Zwraca 1, ponieważ tylko drugi wiersz spełnia wszystkie kryteria.

Odwołanie do komórki jako kryterium

Jeśli chcesz łatwo zmienić kryterium, możesz określić je w osobnej komórce i użyć odwołań do tej komórki w warunku funkcji LICZ.WARUNKI. Na przykład: powyższa funkcja może być przepisana następująco:

=LICZ.WARUNKI(A2:A6;E2&".*";B2:B6;"<"&MAKS(B2:B6))

Jeśli E2 = ołów, funkcja zwraca 1, ponieważ łącze do komórki jest zastąpione jego treścią i działa jak funkcja powyżej.

Otwórz plik z przykładem: