TAL.VISS.SETT-funksjonen

Returnerer kor mange celler som oppfyller kriteria i fleire område.

Syntaks

TAL.VISS.SETT(Område1; Kriterium1[; Område2; Kriterium2 [; ...]])

Område1 – nødvendig argument. Dette kan vera eit celleområde, namnet på eit namngjeve område eller etiketten på ei rad eller ein kolonne som inneheld verdiar som vert brukte for å telja og å finna det tilsvarande kriteriet.

Kriterium1 må ha eit argument. Eit strenguttrykk som representerer eit logisk vilkår eller ein cellereferanse til eit slikt uttrykk. Uttrykket kan innehalda tekst, tal, regulære uttrykk eller jokerteikn (viss det er opna for desse i innstillingane for utrekningane).

Område2 – Valfri. Område2 og alle dei følgjande tyder det same som Område1.

Kriterium2 – Valfritt. Kriterium2 og alle etterfølgjande betyr det same som Kriterium1.

Område1, Område2, … og Kriterium1, Kriterium2, ... må ha same storleik, elles returnerer funksjonen feil:502 - Ugyldig argument.

Den logiske relasjonen mellom kriteria kan definerast som logisk OG (konjunksjon). Med andre ord, viss alle gjevne kriteria vert oppfylde, vert verdien frå den tilsvarande cella i det gjevne Funksjons_område tatt med i utrekningane.

Funksjonen kan ha opp til 255 argument. Dette betyr at du kan ha 127 kriterieområde og kriteria for desse.

Viss ei celle inneheld SANN vert dette handtert som 1, medan USANN vert handtert som 0 (null).

Denne funksjonen høyrer til Open Document Format for Office Applications (OpenDocument) standard versjon 1.2. (ISO/IEC 26300:2-2015)

Eksempel

Studer denne tabellen

	A	B	C
1	Produktnamn	Sal	Inntekt
2	blyant	20	65
3	penn	35	85
4	notisbok	20	190
5	bok	17	180
6	penal	ikkje	ikkje

Alle eksempla nedanfor inneheld rad nummer 6, men denne vert ignorert sidan ho inneheld tekst.

Enkel bruk

=TAL.VISS.SETT(B2:B6;">=20")

Tel kor mange rader i området B2:B6 som har verdiar større enn eller lik 20. Returnerer 3 fordi den femte og sjette rada ikkje oppfyller kriteria.

=TAL.VISS.SETT(B2:B6;">=20";C2:C6;">70")

Tel kor mange rader i området C2:C6 som samstundes har verdiar større enn 70 og verdiar større enn eller lik 20 i området B2:B6. Returnerer 2 fordi den andre, femte og sjette rada ikkje oppfyller minst eitt kriterium.

Bruka regulære uttrykk og nøsta funksjonar

=TAL.VISS.SETT(B2:B6;"[:alpha:]*")

Tel kor mange rader i området B2:B6 som inneheld alfabetsymbol. Returnerer 1 fordi berre den sjette rada oppfyller kriteriet.

=TAL.VISS.SETT(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAKS(B2:B6))

Tel kor mange rader det er i området B2:B6. Reknar ikkje med rader som inneheld maksimums- og minimumsverdien i dette området. Returnerer 2 fordi den tedje, femte og sjette rada ikkje oppfyller minst eitt kriterium.

=TAL.VISS.SETT(A2:A6;"pen.*";B2:B6;"<"&MAKS(B2:B6))

Tel kor mange rader som samsvarar med alle cellene i området A2:A6 som byrjar med «pen» og alle cellene i området B2:B6 unntatt dei som inneheld minimum. Returnerer 1 fordi berre den andre rada oppfyller alle kriteria.

Referanse til ei celle som kriterium

Dersom du ønskjer å lett kunna endra eit kriterium, kan du skrive dette inn i ei eige celle og bruke ein referanse til denne cella som kriterium i funksjonen TAL.VISS.SETT. For eksempel kan funksjonen ovanfor skrivast slik:

=TAL.VISS.SETT(A2:A6;E2&".*";B2:B6;"<"&MAKS(B2:B6))

Viss E2 = pen vil funksjonen returnere 1 fordi lenkja til cella er bytt ut med innhaldet og såleis verkar som funksjonen ovanfor.