Informasjonsfunksjonar

Denne kategorien inneheld informasjonsfunksjonane.

For å bruka denne funksjonen …

Set inn → Funksjon → Kategori Informasjon

Dataa i denne tabellen tener som grunnlag for nokre av eksempla i funksjonsbeskrivingane:

	C	D
2	X-verdi	Y-verdi
3	-5	-3
4	-2	0
5	-1	1
6	0	3
7	2	4
8	4	6
9	6	8

CELLE (CELL på engelsk)

Returnerer informasjon om adresse, formatering eller innhald i ei celle.

Syntaks

CELLE(Infotype; Referanse)

Infotype er tekststrengen som viser informasjonstypen. Denne strengen er alltid på engelsk. Bruk av store og små bokstaver er valfritt.

Infotype	Tyding
COL	Returnerer nummeret på den refererte kolonnen. CELLE("COL"; D2) returnerer 4.
ROW	Returnerer nummeret på den refererte rada. CELLE("ROW"; D2) returnerer 2.
SHEET	Returnerer nummeret på det refererte arket. CELLE("Sheet"; Ark3.D2) returnerer 3.
ADDRESS	Returnerer den absolutte adressa til den refererte cella CELLE("ADDRESS"; D2) returnerer $D$2. CELLE("ADRESSE"; Ark3.D2) returnerer $Ark3.$D$2. =CELLE("ADDRESS";'X:\dr\test.ods'#$Ark1.D2) returnerer 'file:///X:/dr/test.ods'#$Ark1.$D$2.
FILENAME	Returnerer filnamnet og arknummeret for den refererte cella. CELLE("FILENAME"; D2) returnerer 'fil:///X:/dr/eigen.ods'#$Ark1 dersom formelen i det gjeldande dokumentet X:\dr\eigen.ods finst i Ark1. =CELLE("FILENAME";'X:\dr\test.ods'#$Ark1.D2) returnerer 'file:///X:/dr/test.ods'#$Ark1.
COORD	Returnerer den fullstendige celleadressa i Lotus™-notasjon. CELLE("COORD"; D2) returnerer $A:$D$2. CELLE("COORD"; Ark3.D2) returmnerer $C:$D$2.
CONTENTS	Returnerer innhaldet av den refererte cella utan formatering.
TYPE	Returnerer typen av celleinnhaldet. b = tom. Tom celle l = etikett. Tekst, resultat av ein formel som tekst v = Verdi. Verdi, resultat av ein formel som eit tal
WIDTH	Returnerer breidda av den refererte kolonnen. Eininga er talet på nullar (0) som passar inn i kolonnen i standardskrifttypen og standardstorleiken.
PREFIX	Returnerer justeringa for den refererte cella. ' = juster venstre eller venstre-blokkjustert " = juster høgre ^ = midtstilt \ = gjentakande (for tida inaktiv)
PROTECT	Returnerer status for cellevernet for cella. 1 = cella er verna 0 = cella er ikkje verna
FORMAT	Returnerer ein tekststreng som viser talformatet. , = tal med tusenskilje F = tal utan tusenskilje C = valutaformat S = eksponentiell representasjon, for eksempel 1,234+E56 P = prosentdel I formata nemnde ovanfor er talet på desimalar etter desimalteiknet gjeve som eit tal. Eksempel: talformatet #.##0,0 returnerer .1 og talformatet 00,000% returnerer P3 D1 = MMM-D-YY, MM-D-YY og liknande format D2 = DD-MM D3 = MM-YY D4 = DD-MM-YYYY HH:MM:SS D5 = MM-DD D6 = TT:MM:SS AM/PM D7 = TT:MM AM/PM D8 = TT:MM:SS D9 = TT:MM G = Alle andre format - (minus) til sist = negative tal er formaterte med farge () (parentesar) til sist = det er ein startparentes i formatkoden
COLOR	Returnerer 1 viss negative verdiar er formaterte med farge, elles 0.
PARENTHESES	Returnerer 1 viss formateringskoden inneheld ein startparentes (, elles 0.

Referanse (i lista av innstillingar) er den celleposisjonen som skal undersøkjast. Viss Referanse er eit område, vert cella flytt til øvre, venstre hjørne av området. Viss Referanse manglar, bruker LibreOffice Calc den cella som denne formelen er i. Microsoft Excel bruker referansen til cella der peikaren er.

ERF (ISERR på engelsk)

Testar for feilvilkåra, med unntak av feilverdien #I/T, og returnerer SANN eller USANN.

Dersom det oppstår ein feil, vil funksjonen returnera ein logisk eller numerisk verdi.

Syntaks

ERF(Verdi)

Verdi er ein verdi eller eit uttrykk som vert testa for å fastslå om det er ein annan feilverdi enn #I/T i uttrykket.

Eksempel

=ERF(C8) der celle C8 inneheld verdien =1/0 returnerer SANN fordi 1/0 er ein feil.

=ERF(C9) der celle C9 inneheld =IT(), returnerer USANN fordi ERF() ignorerer feilen #I/T.

ERFEIL (ISERROR på engelsk)

Testar for feil, også feilverdien #I/T, og returnerer SANN eller USANN.

Dersom det oppstår ein feil, vil funksjonen returnera ein logisk eller numerisk verdi.

Syntaks

ERFEIL(Verdi)

Verdi er eller refererer til den verdien som kan testast. ER.FEIL() returnerer SANN dersom det er ein feil og ellers USANN.

Eksempel

=ER.FEIJL(C8) der celle C8 inneheld =1/0 returnerer SANN, fordi 1/0 er ein feil.

=ER.FEIL (C9) der celle C9 inneheld =IT() returnerer SANN.

ERFORMEL (ISFORMULA på engelsk)

Returnerer SANN om ei celle er ei formelcelle.

Dersom det oppstår ein feil, vil funksjonen returnera ein logisk eller numerisk verdi.

Syntaks

ERFORMEL(Referanse)

Referanseer referansen til ei celle som skal testast om den inneheld ein formel.

Eksempel

ERFORMEL(C4) returnerer USANN dersom cella C4 inneheld talet 5.

ERIKKJETEKST (ISNONTEXT på engelsk)

Testar om celleinnhaldet er tekst eller tal og returnerer USANN dersom innhaldet er tekst.

Dersom det oppstår ein feil, returnerer funksjonen tilbake SANN.

Syntaks

ERIKKJETEKST(Verdi)

Verdi er ein verdi eller eit uttrykk som skal testast for å finne ut om det er ein tekst, eit tal eller ein logisk verdi.

Eksempel

ERIKKJETEKST(D2) returnerer USANN dersom celle D2 inneheld teksten abcdef.

ERIKKJETEKST(D9) returnerer SANN dersom celle D9 inneheld talet 8.

ERIT (ISNA på engelsk)

Returnerer SANN om ei celle inneheld feilverdien #I/T (verdi ikkje tilgjengeleg).

Dersom det oppstår ein feil, vil funksjonen returnere USANN.

Syntaks

ERIT(Verdi)

Verdi er ein verdi eller eit uttrykk som skal kontrollerast.

Eksempel

=ERIT(D3) returnerer USANN som resultat.

ERLOGISK (ISLOGICAL på engelsk)

Testar for ein logisk verdi (SANN eller USANN).

Dersom det oppstår ein feil, vil funksjonen returnere USANN.

Syntaks

ERLOGISK(Verdi)

Returnerer SANN dersom Verdi er ein logisk verdi (SANN eller USANN). Returnerer elles USANN.

Eksempel

=ERLOGISK(99) returnerer USANN fordi 99 er eit tal og ikkje ein logisk verdi.

=ERLOGISK(ERIT (D4)) returnerer SANN same kva celle D4 inneheld fordi ERIT() returnerer ein logisk verdi.

ERODDETAL (ISODD på engelsk)

Returnerer SANN om verdien er eit oddetal eller USANN om verdien er eit partal.

Syntaks

ERODDETAL(Verdi)

Verdi er innhaldet som skal granskast.

Viss «Verdi» ikkje er eit heiltal, vert alle sifra etter desimalteiknet ignorerte. Også forteiknet framføre «Verdi» vert ignorert.

Eksempel

=ERODDETAL(33) returnerer SANN.

=ERREF(4) returnerer USANN.

=ERODDETAL(3,999) returnerer SANN.

=ERODDETAL(-3,1) returnerer SANN

ERODDE_ADD (ISODD_ADD på engelsk)

Returnerer SANN (1) dersom talet ikkje returnerer eit heilt tal når det vert delt på 2.

Funksjonane som har eit namn som endar med _ADD eller _EXEL2003 returnerer det same resultatet som dei tilsvarande funksjonane i Microsoft Excel 2003 (utan denne endinga). Bruk dei same funksjonane utan endinga for å få resultat basert på internasjonal standard.

Syntaks

ERODDE_ADD(Tal)

Tal er talet som skal kontrollerast.

Eksempel

=ERODDE_ADD(5) returnerer 1.

ERPARTAL (ISEVEN på engelsk)

Returnerer SANN viss verdien er eit partal og USANN viss verdien er eit oddetal.

Syntaks

ERPARTAL(Verdi)

Verdi er innhaldet som skal granskast.

Viss «Verdi» ikkje er eit heiltal, vert alle sifra etter desimalteiknet ignorerte. Også forteiknet framføre «Verdi» vert ignorert.

Eksempel

=ERPARTAL(48) returnerer SANN

=ERPARTAL(33) returnerer USANN

=ERPARTAL(0) returnerer SANN

ERPARTAL(-2,1) returnerer SANN.

=ERPARTAL(3,999) returnerer USANN.

ERPARTAL_ADD (ISEVEN_ADD på engelsk)

Testar på partal. Returnerer 1 dersom talet er eit heiltal etter divisjon med 2.

Syntaks

ERPARTAL_ADD(Tal)

Tal er talet som skal kontrollerast.

Eksempel

ERPARTAL_ADD(5) returnerer 0.

ERPARTAL_ADD(A1) returnerer 1 viss celle A1 inneheld talet 2.

ERREF (ISREF på engelsk)

Testar om argumentet er ein referanse. Returnerer SANN viss argumentet er ein referanse, elles USANN. Viss det er ein referanse, så undersøkjer denne funksjonen ikkje verdien som det vert referert til.

Dersom det oppstår ein feil, vil funksjonen returnera ein logisk eller numerisk verdi.

Syntaks

ERREF(Verdi)

Verdi er verdien som skal testast for å fastslå om det er ein referanse.

Eksempel

=ERREF(C5) returnerer resultatet SANN fordi C5 er ein gyldig referanse.

=ERREF("abcdef") returnerer alltid USANN fordi ein tekst ikkje kan vere ein referanse.

=ERREF(4) returnerer USANN.

=ERREF(INDIREKTE("A6")) returnerer SANN, fordi INDIREKTE er ein funksjon som returnerer ein referanse.

=ERREF(ADRESSE(1; 1; 2; "Ark2")) returnerer USANN fordi ADRESSE er ein funksjon som returnerer ein tekst, sjølv om denne ser ut som ein referanse.

ERTAL (ISNUMBER på engelsk)

Returnerer SANN om verdien refererer til eit tal.

Dersom det oppstår ein feil, vil funksjonen returnera ein logisk eller numerisk verdi.

Syntaks

ERTAL(Verdi)

Verdi er uttrykket som skal testast for å finne ut om det er eit tal eller ein tekst.

Eksempel

ERTAL(C3) returnerer SANN dersom cella C3 inneheld talet 4.

ERTAL(C2) returnerer USANN dersom cella C2 inneheld teksten abcdef.

ERTEKST (ISTEXT på engelsk)

Returnerer SANN om celleinnhaldet refererer til tekst.

Dersom det oppstår ein feil, vil funksjonen returnere USANN.

Syntaks

ERTEKST(Verdi)

Verdi er ein verdi, eit tal, ein logisk verdi, eller ein feilverdi som skal testast.

Eksempel

ERTEKST(D9) returnerer SANN viss celle D9 inneheld teksten abcdef.

ERTEKST(C3) returnerer USANN dersom celle C3 inneheld talet 3.

ERTOM (ISBLANK på engelsk)

Returnerer SANN om referansen til ei celle er tom. Denne funksjonen vert brukt for å avgjera om ei celle er tom. Ei celle med ein formel i er ikkje tom.

Dersom det oppstår ein feil, vil funksjonen returnera ein logisk eller numerisk verdi.

Syntaks

ERTOM(Verdi)

Verdi er innhaldet som skal testast.

Eksempel

=ERTOM(D2) returnerer resultatet USANN.

FORMEL (FORMULA på engelsk)

Viser formelen i ei formelcelle som ein tekststreng.

Syntaks

FORMEL(Referanse)

Referanse er ein referanse til ei celle som inneheld ein formel.

Ein ugyldig referanse eller ein referanse til ei celle utan formel resulterer i feilverdien #I/T.

Eksempel

Dersom celle A8 inneheld formelen =SUMMER(1;2;3), så

=FORMEL(A8) returnerer teksten =SUMMER(1;2;3).

GJELDANDE (CURRENT på engelsk)

Denne funksjonen reknar ut resultatet til dags dato for formelen som han vert brukt i (med andre ord resultatet så langt som utrekningane er nådd til nå). Hovudføremålet er, saman med funksjonen STIL(), å bruka utvalde stilar på ei celle avhengig av innhaldet i cella.

Syntaks

GJELDANDE()

Eksempel

=1+2+GJELDANDE()

Eksempelet returnerer 6. Formelen vert rekna ut frå venstre til høgre som: 1 + 2 er lik 3, gjev resultatet til dags dato, når GJELDANDE() er tald med; GJELDANDE() gjev difor 3, som vert lagt til dei opphavlege 3 som altså gjev 6.

=A2+B2+STIL(VISS(GJELDANDE()>10;”Raud”;”Standard”))

Dette eksempelet returnerer A2 + B2 (STIL returnerer 0 her). Dersom summen er større enn 10, vert stilen Raud brukt på cella. Sjå funksjonen STIL for meir forklaring.

="tøff"&GJELDANDE()

Eksempelet returnerer tøfftøff.

INFO

Returnerer spesifikk informasjon om det gjeldande arbeidsmiljøet. Funksjonen tar i mot eit enkelt tekstargument og returnerer data avhengig av denne parameteren.

Syntaks

INFO("Type")

Den følgjande tabellen er ei liste med verdiar for tekstparameteren Type og returverdiane for INFO-funksjonen.

Verdi for "Type"	Returverdi
"osversion"	Alltid "Windows (32-bit) NT 5.01", av kompatibilitetsgrunnar
"system"	Type operativsystem. "WNT" for Microsoft Windows "LINUX" for Linux "SOLARIS" for Solaris
"release"	Identifisering av produktversjonen, for eksempel "300m25(Build:9876)"
"numfile"	Alltid 1 av kompatibilitetsgrunnar
"recalc"	Gjeldande metode for å rekne ut formlane på nytt er anten «Automatisk» eller «Manuelt» (omsett til LibreOffice-språk)

Andre reknearkprogram godtar kanskje lokaliserte verdiar for parameteren Type, men LibreOffice Calc godtar berre dei engelske verdiane.

Eksempel

=INFO("release") returnerer produktversjonsnummeret for LibreOffice i bruk.

=INFO(D5) der cella D5 som inneheld tekststrengen system returnerer operativsystemtype.

IT (NA på engelsk)

Returnerer feilverdien #I/T («ikkje tilgjengeleg»).

Syntaks

IT()

Eksempel

=IT() gjer innhaldet av cella om til #I/T.

N

Returnerer den numeriske verdien av den gjevne parameteren. Returnerer 0 dersom parameteren er ein tekst eller er USANN.

Dersom der oppstår ein feil, returnerer funksjonen feilverdien.

Syntaks

N(verdi)

Verdi er parameteren som skal konverterast til eit tal. N() returnerer den numeriske verdien dersom dette er mogleg. Dei logiske verdiane SANN og USANN vert returnerte som 1 og 0. Tekst vert returnert som 0.

Eksempel

=N(123) returnerer 123

=N(SANN()) returnerer 1

=N(USANN()) returnerer 0

=N("abc") returnerer 0

=N(1/0) returnerer #DIV/0!

TYPE

Returnerer verditypen, der 1 = tal, 2 = tekst, 4 = logisk verdi, 8 = formel, 16 = feilverdi, 64 = tabell.

Dersom det oppstår ein feil, vil funksjonen returnera ein logisk eller numerisk verdi.

Syntaks

TYPE(Verdi)

Verdi er ein bestemt verdi som datatypen vert bestemt ut i frå.

Eksempel (sjå eksempeltabellen ovanfor)

TYPE(C2) returnerer 2 som eit resultat.

TYPE(D9) returnerer 1 som eit resultat.

VISS.IT (ISNA på engelsk)

Returnerer celleverdien dersom cella ikkje inneheld #I/T (verdien ikkje tilgjengeleg), elles den alternative verdien.

Syntaks

VISS.IT(Verdi;Alternativ_verdi)

Verdi er den verdien eller det uttrykket som vert returnert dersom det ikkje er likt eller resulterer i ein #I/T-feil.

Alternativ_verdi er den verdien eller det uttrykket som vert returnert dersom uttrykket eller verdien av Verdi er lik eller resulterer i ein #I/T-feil.

Eksempel

=VISS.IT(D3;D4) returnerer verdien av D3 viss D3 ikkje resulterer i ein #I/T-feil, elles D4.

VISSFEIL (IFERROR på engelsk)

Returnerer celleverien dersom cella ikkje inneheld ein feilverdi, elles den alternative verdien.

Syntaks

VISSFEIL(Verdi;Alternativ_verdi)

Verdi er den verdien eller uttrykket som vert returnert dersom det ikkje er likt eller er feil.

Alternativ_verdi er den verdien eller det uttrykket som vert returnert dersom uttrykket eller verdien av Verdi er likt eller er feil.

Eksempel

=VISSFEIL(C8;C9) der celle C8 inneheld =1/0 returnerer verdien av C9 fordi 1/0 er ein feil.

=VISSFEIL(C8;C9) der celle C8 inneheld =13 returnerer 13, som er verdien av C8, fordi dette ikkje er feil.

Funksjonar etter kategori