회계 함수 1장

이 범주에는 LibreOffice Calc의 수학적 회계 함수가 포함됩니다.

ACCRINT

정기적으로 납입하는 경우 유가 증권의 미지급 이자를 계산합니다.

구문

ACCRINT(발행; 첫 이자; 결산; 비율; 평가; 지급 빈도; 기준)

발행은 유가 증권의 발행일입니다.

첫 이자는 유가 증권의 첫 번째 이자일입니다.

Settlement는 이자가 쌓여서 계산되는 날입니다.

비율은 이자의 연간 명목 비율(이자표 이자율)입니다.

액면은 유가 증권의 액면 가치입니다.

빈도는 연간 이자 지불 횟수(1, 2, 4)입니다.

은 해[年]를 어떤 방식으로 계산할지 나타냅니다.

기초

계산

0 또는 없음

US-방식 (NASD), 30일씩 12달

1

정확한 그 달의 일수, 정확한 그 해의 일수

2

정확한 그 달의 일수, 그 해 360일

3

정확한 그 달의 일수, 그 해 365일

4

유럽-방식, 30일씩 12달


유가증권이 2001년 2월 28일에 발행되었습니다. 첫번째 이자 지급기일은 2001년 8월 31일로 정해졌습니다. 결산 일자는 2001년 5월 1일입니다.명목이자는 0,1 또는 10%, 액면가격은 1000 통화단위가 될것입니다. 이자는 반년마다 지급됩니다(빈도는 2). 기초는 US-방식 (0)입니다. 이자는 얼마나 쌓였습니까?

=ACCRINT("2001-02-28";"2001-08-31";"2001-05-01";0.1;1000;2;0)은 16.94444를 반환합니다.

ACCRINTM

결산 날짜에 일시불로 지불하는 경우 담보의 미지급 이자를 계산합니다.

구문

ACCRINTM(발행; 결산; 비율; 평가; 기준)

발행은 유가 증권의 발행일입니다.

Settlement는 이자가 쌓여서 계산되는 날입니다.

비율은 이자의 연간 명목 비율(이자표 이자율)입니다.

액면은 유가 증권의 액면 가치입니다.

은 해[年]를 어떤 방식으로 계산할지 나타냅니다.

기초

계산

0 또는 없음

US-방식 (NASD), 30일씩 12달

1

정확한 그 달의 일수, 정확한 그 해의 일수

2

정확한 그 달의 일수, 그 해 360일

3

정확한 그 달의 일수, 그 해 365일

4

유럽-방식, 30일씩 12달


유가증권이 2001년 4월 1일에 발행되었습니다. 만기일은 2001년 6월 15일로 정해졌습니다. 명목이자는 0,1 또는 10%, 액면가액은1000 통화단위입니다. 일/연간 결산의 기초는 일별로 정합니다. (3). 이자는 얼마나 쌓였습니까?

=ACCRINTM("2001-04-01";"2001-06-15";0.1;1000;3)은 20.54795를 반환합니다.

AMORDEGRC

결산 기간 동안의 감가 상각액을 체감 상각으로 계산합니다. AMORLINC와 달리 여기에서는 감가 상각 수명과 무관한 감가 상각 계수가 사용됩니다.

구문

AMORDEGRC(비용; 구매날짜; 1차 기간; 잔존가치; 기간; 비율; 기준)

Cost는 취득 비용입니다.

DatePurchased는 취득일입니다.

FirstPeriod는 첫 번째 결산 기간의 마지막 날입니다.

잔존 가치는 감가상각이 가능한 수명 끝에 남은 자본 자산의 잔존 가치입니다.

Period는 고려되는 결산 기간입니다.

비율은 감가상각의 비율입니다.

은 해[年]를 어떤 방식으로 계산할지 나타냅니다.

기초

계산

0 또는 없음

US-방식 (NASD), 30일씩 12달

1

정확한 그 달의 일수, 정확한 그 해의 일수

2

정확한 그 달의 일수, 그 해 360일

3

정확한 그 달의 일수, 그 해 365일

4

유럽-방식, 30일씩 12달


AMORLINC

결산 기간 동안의 감사 상각액을 선형 상각으로 계산합니다. 결산 기간 동안 자본 자산을 구매한 경우 비례 감가 상각액이 고려됩니다.

구문

AMORLINC(비용; 구매날짜; 1차 기간; 잔존가치; 기간; 비율; 기준)

Cost는 취득 비용을 의미합니다.

DatePurchased는 취득일입니다.

FirstPeriod는 첫 번째 결산 기간의 마지막 날입니다.

잔존 가치는 감가상각이 가능한 수명 끝에 남은 자본 자산의 잔존 가치입니다.

Period는 고려되는 결산 기간입니다.

비율은 감가상각의 비율입니다.

은 해[年]를 어떤 방식으로 계산할지 나타냅니다.

기초

계산

0 또는 없음

US-방식 (NASD), 30일씩 12달

1

정확한 그 달의 일수, 정확한 그 해의 일수

2

정확한 그 달의 일수, 그 해 360일

3

정확한 그 달의 일수, 그 해 365일

4

유럽-방식, 30일씩 12달


DB

산술적 체감 방법을 사용하여 지정한 기간 동안 자산의 감가 상각을 구합니다.

(일차원적 감가 상각과는 달리) 감가 상각 초기에 보다 높은 감가 상각값을 얻으려는 경우 이 감가 상각 형태를 사용합니다. 감가 상각값은 감가 상각 기간마다 구입가에서 이미 공제된 감가 상각만큼 감소합니다.

구문

DB(비용; 잔존가치; 내구년한; 기간; 월)

비용은 자산의 초기 비용입니다.

잔존 가치는 감가상각 이후에 남은 자산의 가치입니다.

Life는 자산이 감가상각되는 기간입니다.

Period는 각 기간의 길이입니다. 기간은 감가상각 기간과 동일한 날짜 단위로 입력해야 합니다.

Month(옵션)은 감가상각의 첫 해의 전체 월 수를 나타냅니다. 항목을 정의하지 않으면 12가 기본 값으로 사용됩니다.

구입가 25,000 통화 단위의 컴퓨터를 3년의 기간에 걸쳐 감가 상각해야 합니다. 잔여값은 시간의 경과 후 1,000 통화 단위여야 합니다. 주기는 30일입니다.

=DB(25000;1000;36;1;6) = 1,075.00 통화 단위

컴퓨터의 기하학적-체감 감가 상각은 1,075.00 통화 단위입니다.

DDB

산술적 체감 방법을 사용하여 지정한 기간 동안 자산의 감가 상각을 구합니다.

선형 감가 상각과 달리 초기 감가 상각 값이 높아야 하는 경우 이러한 형태의 감각 상각을 사용합니다. 감가 상각 값은 각 기간이 지날수록 감소하며, 일반적으로 구매 직후에 값 손실이 더 높은 자산(예: 차량, 컴퓨터 등)에 사용됩니다. 이 계산 유형에서는 장부 가격이 0에 도달하지 않는다는 점에 주의합니다.

구문

DDB(비용; 잔존가치; 내구년한; 기간; 감소비율)

비용은 자산의 초기 비용을 결정합니다.

잔존 가치는 수명이 지난 자산의 가치를 결정합니다.

기한은 자산을 얼마나 오래 사용할 수 있는지 정의하는 개월수 또는 햇수입니다.

기간은 계산되어질 값의 기간을 지정합니다.

Factor(옵션)은 감가상각이 줄어드는 인자입니다. 값을 입력하지 않으면 기본 인자는 2입니다.

구입액이 75,000 통화 단위인 컴퓨터를 5년에 걸쳐 매달 감가 상각합니다 .나머지 금액은 1 통화 단위여야 합니다. 요인은 2입니다.

=DDB(75000;1;60;12;2) = 1,721.81 통화 단위. 구매 후 첫 달 동안의 이중 체감은 1,721.81 통화 단위입니다.

DISC

유가 증권의 정기 납입액(할인)을 백분율로 계산합니다.

구문

DISC("결산"; "만기일"; 가격; 상환; 기준)

결산은 유가 증권의 취득일입니다.

만기는 유가 증권의 만기일입니다.

가격은 액면 가치로 100 통화 단위 당 유가 증권의 가격(취득 가격)입니다.

상황은 액면 가치로 100 통화 단위 당 유가 증권의 상환 가치입니다.

은 해[年]를 어떤 방식으로 계산할지 나타냅니다.

기초

계산

0 또는 없음

US-방식 (NASD), 30일씩 12달

1

정확한 그 달의 일수, 정확한 그 해의 일수

2

정확한 그 달의 일수, 그 해 360일

3

정확한 그 달의 일수, 그 해 365일

4

유럽-방식, 30일씩 12달


유가증권을 2001년 1월 25일에 구입하였고, 만기일은 2001년 11월 15일입니다. 시가(구입가격)는 97, 상환가는 100입니다. 일별로 정해 계산한다고 할 때(기초 3), 분할지불(할인액)은 얼마입니까?

=DISC("2001-01-25";"2001-11-15";97;100;3)은 약 0.0372 또는 3.72 퍼센트를 반환합니다.

DURATION_ADD

몇 년 동안의 고정 이자 담보의 기간을 계산합니다.

참고 아이콘

The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.


구문

DURATION_ADD("결산"; "만기일"; 이자율; 투자 수익; 이자 지급 횟수; 기준 날짜)

결산은 유가 증권의 취득일입니다.

만기는 유가 증권의 만기일입니다.

Coupon은 연간 이자표 이자율(명목 이자율)입니다.

수익은 유가 증권의 연간 수익입니다.

빈도는 연간 이자 지불 횟수(1, 2, 4)입니다.

은 해[年]를 어떤 방식으로 계산할지 나타냅니다.

기초

계산

0 또는 없음

US-방식 (NASD), 30일씩 12달

1

정확한 그 달의 일수, 정확한 그 해의 일수

2

정확한 그 달의 일수, 그 해 360일

3

정확한 그 달의 일수, 그 해 365일

4

유럽-방식, 30일씩 12달


유가증권을 2001년 1월 1일에 구입하였고, 만기일자는 2006년 1월 1일입니다. 명목 이자율은 8%이고 투자수익은 9.0%이며, 이자는 반년마다 지급됩니다(빈도 2). 일별 잔여 이자 계산(기준 3)을 이용하면 수정된 기간은 얼마입니까?

=DURATION_ADD("2001-01-01";"2006-01-01";0.08;0.09;2;3)

EFFECTIVE

명목 이자율에 대한 연간 순 이자율을 구합니다.

명목 이자는 계산 기간 말의 이자 만기에 관련되지만 이자는 주로 매달, 계산 기간 종료 전 다른 기간 또는 4분기에 지분에 따라 만료되어 실제로는 미리 지불되는 것이므로, 분할 지불의 횟수와 함께 실제 이자는 증가합니다.

구문

EFFECTIVE(Nom; P)

Nom은 명목 이자입니다.

P는 연간 이자 지불 기간 수입니다.

연간 명목 이자가 9.75%이고 네 번의 이자 계산 기간이 정의되어 있다면 이 경우 실제 이자율(실제 이자)은 얼마입니까?

=EFFECTIVE(9.75%;4) = 10.11% 따라서 연간 유효 이자율은 10.11%입니다.

EFFECT_ADD

연간 명목 이자율과 이자 납입 횟수를 기준으로 연간 실질 이자율을 계산합니다.

참고 아이콘

The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.


구문

EFFECT_ADD(명목이자율; NPerY)

NominalRate은 연간 명목 이자율입니다.

NPerY 는 연간 이자 지불 횟수입니다.

5,25%의 명목이자와 4분의 1년마다의 지급에 있어서 얼마의 실제이자가 발생합니까?

=EFFECT_ADD(0.0525;4)는 0.053543 이나 5.3534% 을 반환합니다.

IRR

투자에 대한 내부 수익률을 계산합니다. 이 값은 정기적인 캐시 플로우 값을 나타내며, 값 중 하나 이상은 각각 음수(지출)와 양수(수입)가 되어야 합니다.

If the payments take place at irregular intervals, use the XIRR function.

구문

IRR(Values; Guess)

Values는 값을 포함한 배열을 나타냅니다.

Guess(옵션)은 추산된 값입니다. 내부적인 수익률을 계산하기 위해 반복적인 방식이 사용됩니다. 몇 가지 값 밖에 제공할 수 없다면 반복을 사용하기 위해 초기 추측값을 제공해야 합니다.

셀 내용이 A1=-10000, A2=3500, A3=7600, A4=1000라는 가정 하에 수식 =IRR(A1:A4)의 결과는 11,33%가 나옵니다.

경고 아이콘

Because of the iterative method used, it is possible for IRR to fail and return Error 523, with "Error: Calculation does not converge" in the status bar. In that case, try another value for Guess.


ISPMT

고정 분할 상각 상환액의 이자 수준을 계산합니다.

구문

ISPMT(이자; 기간; 총 기간; 투자)

비율은 주기적인 이자율을 지정합니다.

Period는 이자 계산을 위한 할부 수입니다.

TotalPeriods는 할부 기간의 전체 수입니다.

Invest는 투자 액수입니다.

120,000달러의 부채를 2년 동안 월부로 상환할 경우 12%의 연간 이자율로 1.5년 후의 이자 수준을 구합니다.

=ISPMT(1%;18;24;120000) = -300 통화 단위입니다. 1.5년 이후에 월별 이자의 액수는 300 통화 단위가 됩니다.

PV

일련의 정기 납입액에서 얻어지는 투자의 현재 가치를 구합니다.

이 함수를 사용하면 특정한 횟수의 주기로 매번 특정한 금액(배당금)을 지급받으려는 경우 오늘 어느 정도의 돈을 투자해야 할지 계산할 수 있습니다. 이 경우, 이 주기의 만기에 얼마의 돈이 남아 있어야 하는지도 선택적으로 지정할 수 있습니다. 또한, 지불 금액이 주기의 초기 또는 말기에 지급될 것인지를 지정할 수 있습니다.

수치를 숫자나 식 또는 참조로 입력할 수 있습니다. 예를 들면, 년간 8%의 이자를 받지만 월 주기를 입력하려는 경우 필드 이자에 8%/12를 입력하십시오. 그러면 LibreOffice Calc는 자동으로 올바른 요인을 계산합니다.

구문

PV(이자; NPer; Pmt; FV; 형식)

Rate은 기간 당 이자율을 정의합니다.

NPer는 기간(지불 기간)의 전체 수입니다.

Pmt는 기간마다 하는 정기적 지불입니다.

FV(옵션)는 최종 할부를 마친 이후에 남아 있는 미래 가치를 정의합니다.

Type(옵션) 지불 마감일을 나타냅니다. Type = 1은 마감이 기간의 시작이라는 것을 의미하고 Type = 0(기본 값)은 마감이 기간의 끝이라는 것을 의미합니다.

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

매달 500 통화 단위를 납입하고 연 이율이 8%에 달할 경우 투자의 현재 가치는 얼마입니까? 지불 기간은 48개월이며 최종 수치로는 20.000 통화 단위가 남아야 합니다.

=PV(8%/12;48;500;20000) = -35,019.37 통화 단위입니다. 지정된 조건에서 48개월 동안 매월 500 통화 단위를 받고 마지막에 20,000 통화 단위가 남으려면 오늘 35,019.37 통화 단위를 예금해야 합니다. 교차 확인은 48 x 500 통화 단위 + 20,000 통화 단위 = 44,000 통화 단위라는 것을 보여줍니다. 이 액수와 예금된 35,000 통화 단위 사이의 차이는 지불된 이자를 나타냅니다.

수치를 직접 입력하지 않고 참조로 수식에 입력하면 간편하게 임의의 "What-if"-시나리오가 계산됩니다. 상수에 대한 참조는 절대 참조로 정의해야 한다는 점을 기억하십시오. 이러한 유형을 적용하는 예는 감가 상각 함수에서 제공합니다.

RECEIVED

주어진 시점에 고정 이자 담보에 대해 지불된 수납액을 계산합니다.

구문

RECEIVED("결산"; "만기일"; 투자; 감가; 기준)

결산은 유가 증권의 취득일입니다.

만기는 유가 증권의 만기일입니다.

Investment는 구매 합입니다.

할인은 유가 증권 취득에 대한 할인 비율입니다.

은 해[年]를 어떤 방식으로 계산할지 나타냅니다.

기초

계산

0 또는 없음

US-방식 (NASD), 30일씩 12달

1

정확한 그 달의 일수, 정확한 그 해의 일수

2

정확한 그 달의 일수, 그 해 360일

3

정확한 그 달의 일수, 그 해 365일

4

유럽-방식, 30일씩 12달


결산일: 1999년 2월 15일, 만기일: 1999년 5월 15일, 투자금액: 1000 통화 단위, 할인액: 5,75 퍼센트, 기초: 일별정확성/360 = 2.

만기일까지의 지급 금액은 다음과 같이 산출됩니다.

=RECEIVED("1999-02-15";"1999-05-15";1000;0.0575;2)은 1014.420266을 반환합니다.

SYD

산술적 하락 감가 상각 이자율을 구합니다.

이 함수를 사용하여, 개체의 전체 감가 상각 기간동안 한 주기에 대해 감가 상각액을 계산할 수 있습니다. 계수형 감가 상각은 주기마다 감가 상각 함계를 고정 금액만큼 감소시킵니다.

구문

SYD(비용; 잔존가치; 내구년한; 기간)

비용은 자산의 초기 비용입니다.

잔존 가치는 감가상각 이후에 남은 자산의 가치입니다.

Life는 자산이 감가상각되는 기간입니다.

기간은 감가상각이 계산되는 기간을 정의합니다.

구입가 50,000 통화 단위인 비디오는 5년에 걸쳐 매년 감가 상각되어야 합니다. 나머지 금액은 10,000 통화 단위여야 합니다. 감가 상각은 첫 해에 대해 산출되어야 합니다.

=SYD(50000;10000;5;1)=13,333.33 통화 단위입니다. 첫 해의 감가상각 액수는 13,333.33 통화 단위입니다.

기간당 감가 상각율을 한 눈에 볼 수 있도록 감가 상각 표를 정의하는 것이 좋습니다. LibreOffice Calc의 여러 감가 상각 수식을 차례로 입력하면 감가 상각 중 이 경우에 가장 유리한 형태인지 알 수 있습니다. 다음과 같이 테이블을 입력하십시오.

A

B

C

D

E

1

초기 비용

잔존 가치

유효 수명

기간

Deprec. SYD

2

50,000 통화 단위

10,000 통화 단위

5

1

13,333.33 통화 단위

3

2

10,666.67 통화 단위

4

3

8,000.00 통화 단위

5

4

5,333.33 통화 단위

6

5

2,666.67 통화 단위

7

6

0.00 통화 단위

8

7

9

8

10

9

11

10

12

13

>0

합계

40,000.00 통화 단위


E2의 수식은 다음과 같습니다:

=SYD($A$2;$B$2;$C$2;D2)

이 수식은 E열에서 E10까지 중복됩니다 (E2를 선택한 다음 마우스를 사용하여 오른쪽 하단 모서리를 아래로 드래그).

셀 E13에는 관리를 위해 모든 감가 상각액을 합산하는 수식이 있습니다. E8:E11에 있는 음의 값은 고려되어서는 안되므로 SUMIF 함수를 사용합니다. 조건 >0은 셀 A13에 있습니다. E13의 수식은 다음과 같습니다:

=SUMIF(E2:E11;A13)

이제 10년에 걸친 감가 상각이나 잔여값이 1 통화 단위일 경우를 보거나 다른 구입가를 입력할 수 있습니다.

회계 함수 2장

회계 함수 3장

Functions by Category