Funzione MIN.PIÙ.SE
Restituisce il minimo dei valori delle celle in un intervallo che soddisfa più criteri in intervalli multipli.
Sintassi
MIN.PIÙ.SE(Intervallo_Funz; Intervallo1; Criterio1 [ ; Intervallo; Criterio2 [;...]]))
Intervallo_Funz – argomento obbligatorio. Intervallo di celle, il nome di un'area indicata, la dicitura di una colonna o di una riga che contiene valori per il calcolo del minimo.
Intervallo_Funz e Intervallo1, Intervallo2... devono possedere la stessa dimensione, in caso contrario la funzione restituisce err:502 - Argomento non valido.
La relazione logica tra i criteri definibili come E logico (congiunzione). In altre parole, se, e solo se, tutti i criteri sono soddisfatti, viene inserito nel calcolo un valore derivante dalla cella corrispondente del Intervallo_Func specificato.
La funzione può possedere fino a 255 argomenti, nel senso che potete specificare 127 intervalli di criteri e i criteri ad essi relativi.
Se una cella contenesse VERO, sarebbe considerata 1; se contenesse FALSO, sarebbe considerata 0 (zero).
Questa funzione appartiene all'Open Document Format for Office Applications (OpenDocument), versione standard 1.2 (ISO/IEC 26300:2-2015).
Esempi
Considerate la tabella seguente
|
A |
B |
C |
|
|
1 |
Nome prodotto |
Vendite |
Ricavo |
|
2 |
matita |
20 |
65 |
|
3 |
penna |
35 |
85 |
|
4 |
notebook |
20 |
190 |
|
5 |
libro |
17 |
180 |
|
6 |
astuccio |
non |
non |
In tutti gli esempi riportati sotto, gli intervalli per il calcolo contengono la riga #6, che viene ignorata poiché contiene testo.
Uso semplice
=MIN.PIÙ.SE(B2:B6;B2:B6;"<35")
Calcola il minimo dei valori dell'intervallo B2:B6, minori o uguali a 20. Restituisce 17.
=MIN.PIÙ.SE(C2:C6;B2:B6;">=20";C2:C6;">90")
Calcola il minimo dei valori dell'intervallo C2:C6 minori di 90 e che corrispondono alle celle dell'intervallo B2:B6 con valori maggiori o uguali a 20. Restituisce 190.
Uso delle espressioni regolari e delle funzioni annidate
=MIN.PIÙ.SE(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))
Calcola il minimo dei valori dell'intervallo C2:C6 che corrispondono a tutti i valori dell'intervallo B2:B6, eccetto il suo minimo e minimo. Restituisce 65.
=MIN.PIÙ.SE(C2:C6;A2:A6;".*book";B2:B6;"<="&MAX(B2:B6))
Calcola il minimo dei valori dell'intervallo C2:C6 che corrispondono a tutte le celle dell'intervallo A2:A6 che iniziano con "book" e a tutte le celle dell'intervallo B2:B6, eccetto il suo minimo. Restituisce 180.
Fare riferimento a una cella come criterio
Per cambiare in modo facile un criterio, potete specificarlo in una cella separata, utilizzando un riferimento alla cella all'interno della condizione della funzione MIN.PIÙ.SE. Per esempio, la funzione sopra citata può essere riscritta nel modo seguente:
=MIN.PIÙ.SE(C2:C6;A2:A6;".*"&E2;B2:B6;"<"&MAX(B2:B6))
Se E2 = "book", la funzione restituisce 180, perché il riferimento alla cella è sostituito dal suo contenuto.
