ÁTLAGHA függvény

Visszaadja egy tartomány adott feltételnek megfelelő összes cellájának számtani közepét. Az ÁTLAGHA függvény összeadja a logikai tesztnek megfelelő összes találatot, és elosztja ezt az összeget a kiválasztott értékek számával.

Szintaxis

ÁTLAGHA(tartomány; feltételek [; átlag_tartomány ])

tartomány - kötelező argumentum. Egy tömb, nevesített tartomány neve, átlagolandó számokat tartalmazó sor vagy oszlop fejléce, vagy számok vagy a feltétel szövege.

feltételek - kötelező argumentum. Feltétel kifejezésként, vagy kifejezést tartalmazó cellahivatkozásként, amely megadja, mely cellák használandók az átlag kiszámításához. A kifejezés tartalmazhat szöveget, számokat, reguláris kifejezéseket (ha engedélyezett a számítás beállításaiban) vagy helyettesítő karaktereket (ha engedélyezett a számítás beállításaiban).

átlag_tartomány - elhagyható. Értékek tartománya az átlag kiszámításához.

Jegyzet ikon

Ha az átlag_tartomány nincs megadva, akkor a tartomány lesz felhasználva az átlag kiszámításához és a feltétel szerinti kereséshez is. Ha az átlag_tartomány meg van adva, akkor a tartomány csak a feltétel teszteléséhez lesz felhasználva, míg az átlag_tartomány az átlag kiszámításához.
A feltételeknek karakterlánc kifejezésnek kell lenniük, azaz a feltételeket "idézőjelek" közé kell tenni, a függvénynevek, cellahivatkozások és a karakterlánc-összefűzés művelet (&) kivételével.


Jegyzet ikon

Ez a függvény az Open Document Format for Office Applications (OpenDocument) szabvány 1.2-es verziójának része. (ISO/IEC 26300:2-2015)


Figyelmeztetés ikon

Ha az átlag kiszámítására használt értékek tartományában egy cella üres vagy szöveget tartalmaz, akkor az ÁTLAGHA függvény figyelmen kívül hagyja.
Ha a teljes tartomány üres, csak szöveget tartalmaz, vagy egyik érték sem felel meg a feltételnek (vagy ezek tetszőleges kombinációja), akkor a függvény #ZÉRÓOSZTÓ! hibát ad vissza.


Példák

Figyelje meg a következő táblázatot

A

B

C

1

Termék neve

Eladások

Bevétel

2

tollbetét

20

65

3

toll

35

85

4

jegyzőkönyv

20

190

5

könyv

17

180

6

tolltartó

nem

nem


Figyelmeztetés ikon

In all examples below, ranges for calculation contain the row #6, which is ignored because it contains text.


Figyelmeztetés ikon

A lentebbi összes számításban az átlagszámításhoz használt tartomány tartalmazza a 6. sort, de mivel szöveget tartalmaz, figyelmen kívül marad.


Egyszerű használat

=ÁTLAGHA(B2:B6;"<35")

Kiszámítja a B2:B6 tartomány azon értékeinek átlagát, amelyek 35-nél kisebbek. A visszaadott érték 19, mert a 2. sor nem vesz részt a számításban.

=ÁTLAGHA(B2:B6;"<"&MAX(B2:B6))

Kiszámítja ugyanezen tartomány azon értékeinek átlagát, amelyek a tartomány legnagyobb értékénél kisebbek. A visszaadott érték 19, mert a legnagyobb érték (a 2. sorban) nem vesz részt a számításban.

=ÁTLAGHA(B2:B6;">"&KICSI(B2:B6;1))

Kiszámítja ugyanezen tartomány azon értékeinek átlagát, amelyek a tartomány legkisebb értékénél nagyobbak. A visszaadott érték 25, mert az első legkisebb érték (a 4. sorban) nem vesz részt a számításban.

Az átlag_tartomány használata

=ÁTLAGHA(B2:B6;"<35";C2:C6)

A függvény megkeresi a 35-nél kisebb értékeket a B2:B6 tartományban, és kiszámítja a megfelelő értékek átlagát a C2:C6 tartományból. Visszatérési értéke 145, mert a második sor nem vesz részt a számolásban.

=ÁTLAGHA(B2:B6;">"&MIN(B2:B6);C2:C6)

A függvény megkeresi a B2:B6 tartomány legkisebb értékétől nagyobb értékeket a B2:B6 tartományban, és kiszámítja a megfelelő értékek átlagát a C2:C6 tartományból. A visszaadott érték 113,3, mert a negyedik sor (ahol a B2:B6 tartomány legkisebb értéke van) nem vesz részt a számításban.

=ÁTLAGHA(B2:B6;"<"&NAGY(B2:B6;2);C2:C6)

A függvény megkeresi a B2:B6 tartomány második legnagyobb értékétől kisebb értékeket a B2:B6 tartományban, és kiszámítja a megfelelő értékek átlagát a C2:C6 tartományból. A visszaadott érték 180, mert csak a negyedik sor vesz részt a számításban.

Reguláris kifejezések használata

=ÁTLAGHA(A2:A6;"toll";B2:B6)

A függvény megkeresi az A2:A6 tartományban a pontosan a „toll” szót tartalmazó cellákat, és kiszámítja a B2:B6 tartományban megfelelő értékek átlagát. A 35-öt adja vissza, mert csak a második sor vesz részt a számításban. A keresés az A2:A6 tartományban történik, de az értékek a B2:B6 tartományból kerülnek visszaadásra.

=ÁTLAGHA(A2:A6;"toll.*";B2:B6)

A függvény megkeresi az A2:A6 tartományban „toll” szóval kezdődő és tetszőleges karakterekre végződő értékű cellákat, és kiszámítja a megfelelő értékek átlagát a B2:B6 tartományban. A visszaadott érték 27,5, mert a „tolltartó” is megfelel a feltételnek, így az első két sor vesz részt a számításban.

=ÁTLAGHA(A2:A6;".*könyv.*";B2:B6)

A függvény megkeresi az A2:A6 tartományban „könyv” szót tartalmazó, és tetszőleges más karakterekkel kezdődő és végződő értékű cellákat, és kiszámítja a megfelelő értékek átlagát a B2:B6 tartományban. A visszaadott érték 18,5, mert csak a harmadik és negyedik sor vesz részt a számításban.

Hivatkozás cellára feltételként

Ha egyszerűen szeretne feltételt módosítani, akkor érdemes egy külön cellában megadni, és erre a cellára mutató hivatkozást használni az ÁTLAGHA függvény feltételében.

=ÁTLAGHA(A2:A6;".*"&E2&".*";B2:B6)

A függvény megkeresi az A2:A6 tartományban az E2 cellában megadott karaktereket tartalmazó, és tetszőleges más karakterekkel kezdődő és végződő értékű cellákat, és kiszámítja a megfelelő értékek átlagát a B2:B6 tartományban. Ha az E2 = könyv, a visszaadott érték 18,5.

=ÁTLAGHA(B2:B6;"<"&E2;C2:C6)

A függvény megkeresi a B2:B6 tartományban az E2 cellában megadottól kisebb értékű cellákat, és kiszámítja a megfelelő értékek átlagát a C2:C6 tartományban. Ha az E2 = 35, a visszaadott érték 145.