Pénzügyi függvények - első rész

A kategória a LibreOffice Calc pénzügyi függvényeit tartalmazza.

ACCRINT

Egy értékpapír felhalmozott kamatát rendszeres fizetés esetére számítja ki.

Szintaxis

ACCRINT(kibocsátás; első_kamat; kifizetés; kamatláb; névérték; gyakoriság; alap)

A kibocsátás (szükséges) az értékpapír kibocsátásának dátuma.

Az első_kamat (szükséges) az értékpapír első kamatfizetési dátuma.

A kifizetés (szükséges) az a dátum, ameddig a kamatfelhalmozódást ki kell számolni.

A kamatláb (szükséges) az évi nominális kamatláb (szelvény kamatlába)

A névérték (szükséges) az értékpapír névértéke.

A gyakoriság (szükséges) a kamatfizetések száma évente (1, 2 vagy 4).

Példa

Egy értékpapírt 2001. 02. 28-án bocsátanak ki. Az első kamat 2001. 08. 31-én esedékes. A kifizetés dátuma 2001. 05. 01. A kamatláb 0,1, azaz 10%, és a névérték 1000 pénzegység. A kamatok félévente kerülnek kifizetésre (vagyis a gyakoriság 2). A számítás alapjául az USA módszer (0) szolgál. Mennyi kamat halmozódott fel?

Az =ACCRINT("2001-02-28";"2001-08-31";"2001-05-01";0,1;1000;2;0) eredménye 16,94444.

ACCRINTM

Egy értékpapír felhalmozott kamatát a lejáratkor történő egy összegbeni kifizetésre számítja ki.

Szintaxis

ACCRINT(kibocsátás; kifizetés; kamatláb; névérték; alap)

A kibocsátás (szükséges) az értékpapír kibocsátásának dátuma.

A kifizetés (szükséges) az a dátum, ameddig a kamatfelhalmozódást ki kell számolni.

A kamatláb (szükséges) az évi nominális kamatláb (szelvény kamatlába).

A névérték (szükséges) az értékpapír névértéke.

Példa

Egy értékpapírt kibocsátanak 2001. április 1-jén. Az esedékesség dátuma 2001. június 15. A kamatláb 0,1, azaz 10%, és a névérték 1000 pénzegység. A napos/éves számítás alapját a napi egyenleg képezi (3). Mennyi kamat halmozódott fel?

Az =ACCRINTM("2001-04-01";"2001-06-15";0,1;1000;3) eredménye 20,54795.

AMORDEGRC

Degresszív amortizációként kiszámítja egy elszámolási időszak értékcsökkenésének mértékét. Az AMORLINC függvénytől eltérően ez az értékcsökkenési élettartamtól független értékcsökkenési együtthatót használ.

Szintaxis

AMORDEGRC(költség; vásárlás_dátuma; első_időszak; maradványérték; időszak; százalék; alap)

A költség a beszerzési költségek.

A vásárlás_dátuma a beszerzés dátuma.

Az első_időszak az első kifizetési időszak végének dátuma.

A maradványérték a tőkeeszköz maradványértéke az értékcsökkenési időtartam végén.

Az időszak a kérdéses kifizetési időszak.

A százalék az értékcsökkenés százalékos mértéke.

AMORLINC

Az értékcsökkenés mértékét egy könyvelési időszakra lineáris amortizációként számítja ki. Ha egy állóeszközt az elszámolási időszak során vásárol, akkor az értékcsökkenés arányos része kerül figyelembe vételre.

Szintaxis

AMORLINC(költség; vásárlás_dátuma; első_időszak; maradványérték; időszak; százalék; alap)

A költség a beszerzési költségek.

A vásárlás_dátuma a beszerzés dátuma.

Az első_időszak az első kifizetési időszak végének dátuma.

A maradványérték a tőkeeszköz maradványértéke az értékcsökkenési időtartam végén.

Az időszak a kérdéses kifizetési időszak.

A százalék az értékcsökkenés százalékos mértéke.

BMR

Kiszámítja egy befektetés belső megtérülési rátáját. Az értékek rendszeres időközű pénzáramlási értékeket jelölnek, amelyek között legalább egy negatívnak (kifizetés), és legalább egy pozitívnak (bevétel) kell lennie.

Ha a kifizetések rendszertelen időközönként történnek, akkor használja az XIRR függvényt.

Szintaxis

BMR(értékek; becslés)

Az értékek az értékeket tartalmazó tömb.

A becslés (opcionális) a becsült érték. A belső megtérülési érték számítása során a függvény iterációs módszert használ. Ha csupán néhány értéket tud megadni, akkor tanácsos egy kezdeti becslést megadni ahhoz, hogy az iterációt lehetővé tegye.

Példa

Feltéve, hogy a cellák A1=-10000, A2=3500, A3=7600 és A4=1000, a =BMR(A1:A4) képlet a 11,33% eredményt adja vissza.

DISC

Egy értékpapír leszámítolási (értékcsökkenési) értékét számítja ki százalékban.

Szintaxis

DISC("kifizetés"; "esedékesség"; ár; visszaváltás; alap)

A kifizetés az értékpapír vásárlásának dátuma.

Az esedékesség az értékpapír esedékességének (lejáratának) dátuma.

Az ár az értékpapír ára 100 egységnyi névértékre vonatkoztatva.

A visszaváltás az értékpapír visszaváltási értéke 100 egységnyi névértékre vonatkoztatva.

Példa

Egy értékpapírt 2001. január 25-én vásárol meg, az esedékesség dátuma 2001. november 15. Az ár (vásárlási ár) 97, a visszaváltási érték 100. A napi elszámolással (3. bázis) milyen magas a kifizetés (leszámítolás)?

A =DISC("2001-01-25";"2001-11-15";97;100;3) eredményül 0,0372-et, vagyis 3,72%-ot ad.

DURATION_ADD

Kiszámítja a fix kamatozású értékpapír időtartamát években.

Szintaxis

DURATION_ADD("kifizetés"; "esedékesség"; kamatláb; hozam; gyakoriság; alap)

A kifizetés az értékpapír vásárlásának dátuma.

Az esedékesség az értékpapír esedékességének (lejáratának) dátuma.

A kamatláb a szelvény évi kamatlába (a kamatfizetés nominális rátája).

A hozam az értékpapír éves hozama.

A gyakoriság a kamatfizetések száma évente (1, 2 vagy 4).

Példa

Egy értékpapírt 2001. január 1-jén vásárol, az esedékesség dátuma 2006. január 1-je. A befektetés kamatfizetési rátája 8%. A hozam 9,0%-os. A kamatok félévente kerülnek kifizetésre (vagyis a gyakoriság 2). Napiegyenleg-számítás (3-as alap) felhasználásával milyen hosszú az időtartam?

=DURATION_ADD("2001-01-01";"2006-01-01";0,08;0,09;2;3)

EFFECTIVE

Kiszámítja egy névleges kamatlábhoz tartozó éves kamatláb nettó értékét.

A névleges kamat a számítási időszak végén esedékes kamatösszeget jelöli. Az effektív kamat a kifizetések számával nő. Más szóval, a kamat gyakran a számítási időszak végét megelőzően (havi vagy negyedéves) részletek formájában kerül kifizetésre.

Szintaxis

EFFECTIVE(névleges_kamat; időszakok_száma)

A névleges_kamat a névleges kamat.

Az időszakok_száma az évente esedékes kamatkifizetési időszakok száma.

Példa

Ha az évi névleges kamatláb 9,75%, és négy kamatszámítási periódus van meghatározva, mekkora a tényleges kamatláb (effektív kamatláb)?

=EFFECTIVE(9,75%;4) = 10,11% – az éves effektív kamatláb ezért 10,11%.

EFFECT_ADD

Az effektív éves kamatlábat számítja ki a névleges kamatláb és az évenkénti kamatfizetések száma alapján.

Szintaxis

EFFECT_ADD(névleges_kamat; időszakok_száma)

A névleges_kamat az éves névleges kamatláb.

Az időszakok_száma a kamatkifizetések évenkénti időszakainak száma.

Példa

Mekkora az 5,25% éves névleges kamatozású, negyedévenként fizető értékpapír effektív éves kamatlába?

Az =EFFECT_ADD(0,0525;4) függvény visszatérési értéke 0,053543 vagy 5.3543%.

KCS2

Eredményül egy eszköz adott időszak alatti értékcsökkenését számítja ki a lineáris leírási modell alkalmazásával.

Az értékcsökkenés ezen formáját akkor használja, ha - a lineáris amortizációval szemben - az amortizáció kezdetekor magasabb értékcsökkenéssel kíván számolni. Az értékcsökkenés minden egyes amortizációs időszak során a kezdeti értékből addig már levont amortizációval csökken.

Szintaxis

KCS2(költség; maradványérték; leírási_idő; időszak; hónap)

A költség az eszköz kezdeti ára.

A maradványérték az eszköz értéke az értékcsökkenés végén.

A leírási_idő azon időszak, amely során az eszköz elértéktelenedik.

Az időszak az egyes időszakok hossza. Az időszak hosszát, illetve az értékcsökkenés időtartamát azonos dátumegységben kell megadni.

A hónap (opcionális) a hónapok száma az értékcsökkenés első évében. Ha nem adja meg, akkor a függvény alapértelmezés szerint a 12 értéket használja.

Példa

Egy eredetileg 25 000 pénzegység értékű számítógéprendszerre kívánja a 3 éves időtartam alatt bekövetkező értékcsökkenést meghatározni. A maradványérték legyen 1000 pénzegység. Egy időszak 30 napból áll.

=KCS2(25000;1000;36;1;6) = 1075,00 pénzegység.

A számítógéprendszer rögzített csökkenésű értékcsökkenése 1075,00 pénzegység.

KCSA

Egy tárgyi eszköz értékcsökkenését számítja ki adott időszakra, az évek számjegyösszegével dolgozó módszer alapján.

Az értékcsökkenés ezen formáját akkor használja, ha - a lineáris amortizációval szemben - magasabb kezdeti értékcsökkenéssel kíván számolni. Az amortizációs érték minden egyes időszakkal csökken. A módszer rendszerint az olyan eszközök esetében kerül felhasználásra, amelyek értékvesztesége magasabb röviddel a vásárlás után (például, gépjárművek, számítógépek). Fontos megjegyezni, hogy ezen számítási típus használatával a leltári érték sosem éri el a nulla értéket.

Szintaxis

KCSA(költség; maradványérték; leírási_idő; időszak; faktor)

A költség rögzíti az eszköz kezdeti árát.

A maradványérték rögzíti az eszköz értékét az élettartam végén.

A leírási_idő azon időszakok (például évek vagy hónapok) száma, amelyek meghatározzák az eszköz felhasználási idejét.

Az időszak meghatározza, hogy az értéket mely időszakra kívánja kiszámítani.

A faktor (opcionális) az amortizáció csökkenésének faktora. Ha nem ad meg értéket, akkor az alapértelmezett faktor 2.

Példa

Egy eredetileg 75 000 pénzegység értékű számítógéprendszerre kívánja az 5 év alatt havonta bekövetkező értékcsökkenést meghatározni. Az értékcsökkenés végén az érték legyen 1 pénzegység. A faktor 2.

=KCSA(75000;1;60;12;2) = 1721,81 pénzegység. Tehát a vásárlás napját követő tizenkettedik hónapban számított kétszeres mértékű amortizáció 1721,81 pénzegység.

LRÉSZLETKAMAT

A változatlan törlesztési részletfizetések kamatszintjét számítja ki.

Szintaxis

LRÉSZLETKAMAT(kamatláb; időszak; időszakok_száma; befektetés)

A kamatláb az időszakos kamatláb.

Az időszak a kamatszámításhoz használt részletfizetések száma.

Az időszakok_száma a törlesztési időszakok összes száma.

A befektetés a befektetés összege.

Példa

A két éves futamidejű, havi törlesztésű, évi 12% kamatozású, 120 000 pénzegység összegű hitel másfél év utáni kamatszintje érdekli.

=LRÉSZLETKAMAT(1%;18;24;120000) = -300 pénzegység. 1,5 év után a havi kamat 300 pénzegység értéket ér el.

MÉ

Kiszámítja egy befektetés rendszeres időszakonként történő kifizetéséből származó jelenértékét.

A függvény segítségével kiszámíthatja azt az összeget, amelyre - a mai napon, fix kamatozással befektetve, egy meghatározott számú időszak múlva - egy adott összeget (annuitást) kap kézhez. Ezen kívül meghatározhatja, hogy mennyi pénz maradjon az időszak letelte után. Azt is meghatározza, hogy az összeg az egyes időszakok elején vagy pedig végén kerüljön kifizetésre.

Az értékeket megadhatja szám, kifejezés vagy cellahivatkozás formájában. Ha például az éves kamatláb 8%, de időszakként hónapot kíván használni, akkor a kamatláb értékét 8%/12 alakban adja meg. A LibreOffice Calc automatikusan kiszámítja a megfelelő tényezőt.

Szintaxis

MÉ(kamatláb; időszakok_száma; részlet; jövőérték; típus)

A kamatláb az időszakra érvényes kamatlábat határozza meg.

Az időszakok_száma az időszakok összesített száma (kifizetési időszak).

A részlet az időszakonként esedékes törlesztőrészletek száma.

A jövőérték (opcionális) meghatározza az utolsó törlesztőrészlet befizetését követően fennmaradó jövőértéket.

A típus (opcionális) a törlesztések esedékességét jelöli. A típus = 1 az időszak eleji, a típus = 0 (alapértelmezett) pedig az időszak végi esedékességet jelöli.

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

Példa

Mi a befektetés jelenértéke akkor, ha havonta 500 pénzegység kerül kifizetésre és az éves kamatláb 8%? A fizetési időszak 48 hónap, és a törlesztőidőszak végén 20000 pénzegységnek szükséges megmaradnia.

=MÉ(8%/12;48;500;20000) = -35019,37 pénzegység. A meghatározott feltételek mellett 35019,37 pénzegységet szükséges a mai napon letétbe helyeznie akkor, ha 48 hónapon keresztül havi 500 pénzegységet kíván kézhez kapni oly módon, hogy a végén 20000 pénzegység marad. Az egyeztetés megmutatja, hogy 48 x 500 pénzegység + 20000 pénzegység = 44000 pénzegység. A különbség az érték, illetve a letétbe helyezett 35000 pénzegység között maga a kifizetett kamat.

Ha értékek helyett a képletben hivatkozásokat ad meg, akkor tetszőleges számú „ha-akkor” példahelyzetre elvégezheti a számításokat. Tartsa szem előtt: ha állandókra hivatkozik, akkor azt abszolút hivatkozásként kell megtennie. A függvény ilyen és ehhez hasonló felhasználására példákat az értékcsökkenés függvényeknél talál.

RECEIVED

Rögzített kamatú értékpapírra bármely adott időpontban fizetett kamatot számítja ki.

Szintaxis

RECEIVED("kifizetés"; "esedékesség"; befektetés; leszámítolás; alap)

A kifizetés az értékpapír vásárlásának dátuma.

Az esedékesség az értékpapír esedékességének (lejáratának) dátuma.

A befektetés a vásárlás összege.

A leszámítolás az értékpapír beszerzési árának diszkont rátája (leszámítolási százaléka)

Példa

Kifizetés dátuma: 1999. február 15., esedékesség dátuma: 1999. május 15., befektetés összege: 1000 pénzegység, leszámítolás: 5,75 százalék, alap: napi egyenleg/360 = 2.

Az esedékesség napján a megkapott összeg az alábbi módon számolható ki:

A =RECEIVED("1999-02-15";"1999-05-15";1000;0,0575;2) eredményül 1014,420266-ot ad.

ÉSZÖ

Kiszámítja a számtani értékcsökkenés sebességét.

A függvény segítségével kiszámíthatja egy tárgyi eszköz teljes értékcsökkenési idejének egy adott időszakára eső értékcsökkenés mértékét. A számtani csökkenésű értékcsökkenési arány az értékcsökkenés mértékét az egyik időszakról a következőre egy adott összeggel csökkenti.

Szintaxis

ÉSZÖ(költség; maradványérték; leírási_idő; időszak)

A költség az eszköz kezdeti ára.

A maradványérték az eszköz értéke az értékcsökkenés után.

A leírási_idő az az időtartam, amennyi idő alatt az eszköz leírása megtörténik.

Az időszak meghatározza, hogy az értékcsökkenést mely időszakra kívánja kiszámítani.

Példa

Egy eredetileg 50 000 pénzegység árú videorendszerre kívánja az éves értékcsökkenést meghatározni a következő 5 év során. A maradványérték legyen 10 000 pénzegység. Az értékcsökkenést az első évre vonatkozóan kívánja meghatározni.

=ÉSZÖ(50000;10000;5;1)=13333,33 pénzegység. Az első évben az értékcsökkenés mértéke 13333,33 pénzegység.

Az egyes időszakokra eső értékcsökkenés alakulását a legkönnyebben egy értékcsökkenési táblázat megadásával tekintheti át. Ha a LibreOffice Calc programban rendelkezésre álló különböző értékcsökkenési képleteket egymás mellett adja meg, akkor összehasonlíthatja, hogy az értékcsökkenés melyik formája a legmegfelelőbb. A táblázatot az alábbiak szerint adja meg:

	A	B	C	D	E
1	Kezdeti költség	Maradványérték	Hasznos élettartam	Időperiódus	É.cs. ÉSZÖ
2	50 000 pénzegység	10 000 pénzegység	5	1	13 333,33 pénzegység
3				2	10 666,67 pénzegység
4				3	8 000,00 pénzegység
5				4	5 333,33 pénzegység
6				5	2 666,67 pénzegység
7				6	0,00 pénzegység
8				7
9				8
10				9
11				10
12
13	>0			Összeg	40 000,00 pénzegység

A képlet az E2-ben a következő:

=ÉSZÖ($A$2;$B$2;$C$2;D2)

Ezt a képletet másolja be az E oszlopba E11-ig (válassza ki az E2-t, majd húzza le a cella bal alsó sarkát az egérrel).

Az E13 cella tartalmazza azon képletet, amely az értékcsökkenési összegek összesített értékét ellenőrzi. A képlet a SZUMHA függvényt alkalmazza, mivel az E8:E11 tartományban található negatív értékeket nem szabad figyelembe venni. A >0 feltételt az A13 cella tartalmazza. Az E13 cellában megadott képlet a következő:

=SZUMHA(E2:E11;A13)

Most nézze meg az értékcsökkenést 10 periódusra, vagy 1 pénzegységnyi maradványértékre, vagy adjon meg más kezdeti költséget, és így tovább...

Pénzügyi függvények - második rész

Pénzügyi függvények - harmadik rész