MkDir Statement

Létrehoz egy új könyvtárat egy adatmédiumon.

Szintaxis:

MkDir Szöveg As String

Paraméterek:

Szöveg: String (karakterlánc) kifejezés, amely megadja a létrehozandó könyvtár elérési útját és nevét. URL-jelölést is használhat.

Ha az elérési út nincs megadva, akkor a könyvtárat az aktuális könyvtárban hozza létre.

Error codes:

5 Érvénytelen eljáráshívás

76 Az elérési út nem található

Példa:

Sub ExampleFileIO

' Példa a fájlok rendezéséhez használt függvényekre

Const sFile1 As String = "file://c|/autoexec.bat"

Const sDir1 As String = "file://c|/Temp"

Const sSubDir1 As String ="Test"

Const sFile2 As String = "Copied.tmp"

Const sFile3 As String = "Renamed.tmp"

Dim sFile As String

    sFile = sDir1 + "/" + sSubDir1

    ChDir( sDir1 )

    If Dir(sSubDir1,16)="" Then ' Létezik a könyvtár?

        MkDir sSubDir1

        MsgBox sFile,0,"Könyvtár létrehozása"

    End If

    sFile = sFile + "/" + sFile2

    FileCopy sFile1 , sFile

    MsgBox fSysURL(CurDir()),0,"Aktuális könyvtár"

    MsgBox sFile & Chr(13) & FileDateTime( sFile ),0,"Létrehozási idő"

    MsgBox sFile & Chr(13)& FileLen( sFile ),0,"Fájl hossza"

    MsgBox sFile & Chr(13)& GetAttr( sFile ),0,"Fájlattribútumok"

    Name sFile As sDir1 + "/" + sSubDir1 + "/" + sFile3

    ' Átnevezés ugyanabban a könyvtárban

    sFile = sDir1 + "/" + sSubDir1 + "/" + sFile3

    SetAttr( sFile, 0 ) 'Az összes attribútum törlése

    MsgBox sFile & Chr(13) & GetAttr( sFile ),0,"Új fájlattribútumok"

    Kill sFile

    RmDir sDir1 + "/" + sSubDir1

End Sub

 

' Konvertálja az URL-ben lévő elérési utat

Function fSysURL( fSysFp As String ) As String

Dim iPos As String

    iPos = 1

    iPos = Instr(iPos,fSysFp, getPathSeparator())

    Do While iPos > 0

        Mid( fSysFp, iPos , 1,"/")

        iPos = Instr(iPos+1,fSysFp, getPathSeparator())

    Loop

    ' kettőspont DOS-ban

    iPos = Instr(1,fSysFp,":")

    If iPos > 0 Then Mid( fSysFp, iPos , 1,"|")

    fSysURL = "file://" & fSysFp

End Function